SCX/Car.pm

   1 #!/usr/bin/perl -w
   2
   3 package SCX::Car;
   4
   5 use strict;
   6 use Time::HiRes qw(gettimeofday);
   7
   8 sub new {
   9         my ($class, $args) = @_;
  10
  11         my $self = {
  12                 gui      => $args->{gui},
  13                 driver   => $args->{driver} || '--',
  14                 throttle => undef,
  15                 button   => undef,
  16                 fuel     => 0,
  17                 lap      => 0,
  18                 laptime  => 0,
  19                 avg_lap  => 0,
  20                 state    => 'greenflag',
  21                 car_img  => $args->{car_img},
  22                 id       => $args->{id},
  23                 order    => $args->{id},
  24                 track    => $args->{track},
  25         };
  26
  27         bless $self, $class;
  28
  29         return $self;
  30 }
  31
  32 sub gui { return shift->{gui}; }
  33
  34 sub track { return shift->{track}; }
  35
  36 sub same {
  37         my ($self, $key, $val) = @_;
  38
  39         return 1 if !defined $self->{$key} && !defined $val
  40                 || (defined $self->{$key} && defined $val
  41                         && $self->{$key} eq $val);
  42
  43         $self->{$key} = $val;
  44         return undef;
  45 }
  46
  47 sub set_throttle {
  48         my ($self, $val, $button, $time) = @_;
  49
  50         return if $self->same('throttle', $val)
  51                 && $self->same('button', $button);
  52
  53         if ($self->track->{start_in_progress} && $val) {
  54                 $self->{early_start} = 1;
  55                 $self->gui->set_name($self->{order}, 'Early start!');
  56         }
  57
  58         if ($self->{in_pit_lane} && defined $val) {
  59                 $self->{last_finish_time} = $time;
  60                 if ($val > 3) {
  61                         $self->leave_pit_lane;
  62                 }
  63         }
  64
  65         $self->gui->set_throttle($self->{order}, $val, $button);
  66 }
  67
  68
  69 sub set_fuel {
  70         my ($self, $val) = @_;
  71
  72         return if $self->same('fuel', $val);
  73         $self->gui->set_fuel($self->{order}, $val);
  74 }
  75
  76 sub set_light {
  77         # TODO
  78 }
  79
  80 sub set_backbutton {
  81         # TODO
  82 }
  83
  84 sub set_model {
  85         my ($self, $name) = @_;
  86
  87         return if $self->same('car_img', $name);
  88         $self->gui->set_car_icon($self->{order}, $name);
  89 }
  90
  91 sub set_lap {
  92         my ($self, $lap_nr) = @_;
  93
  94         if (!$lap_nr) {
  95                 $self->{avg_lap} = undef;
  96                 $self->{lap} = $lap_nr;
  97                 $self->gui->set_avg_lap($self->{order}, undef);
  98                 $self->gui->set_lap($self->{order}, $lap_nr);
  99                 return;
 100         }
 101
 102         return if $self->same('lap', $lap_nr);
 103         $self->gui->set_lap($self->{order}, $lap_nr);
 104         if ($self->track->{race_running} && $self->{lap} > 1) {
 105                 my $now = $self->{last_finish_time};
 106                 my $avg = ($now - $self->track->{race_running_since})
 107                         / ($self->{lap} - 1);
 108                 $self->{avg_lap} = $avg;
 109                 $self->gui->set_avg_lap($self->{order}, $self->{avg_lap});
 110         }
 111 }
 112
 113 sub set_laptime {
 114         my ($self, $lap_time) = @_;
 115
 116         if (!defined $lap_time) {
 117                 $self->gui->set_best_lap($self->{order}, undef);
 118                 $self->{best_lap} = undef;
 119         }
 120
 121         return if $self->same('laptime', $lap_time);
 122
 123         $self->gui->set_laptime($self->{order}, $lap_time);
 124
 125         if (defined $lap_time) {
 126                 if ($lap_time > 1.0 && !$self->{in_pit_lane}
 127                         && $self->track->{race_running}
 128                         && (!defined $self->{best_lap}
 129                                 || $self->{best_lap} > $lap_time
 130                         )) {
 131
 132                         $self->{best_lap} = $lap_time;
 133                         my $global = $self->{track}->check_best_lap($lap_time,
 134                                 $self->{driver}
 135                         );
 136                         $self->gui->set_best_lap($self->{order}, $lap_time,
 137                                 $global);
 138                 }
 139         }
 140 }
 141
 142 sub set_driver {
 143         my ($self, $driver_name) = @_;
 144
 145         return if $self->same('driver', $driver_name);
 146         $self->gui->set_name($self->{order}, $driver_name);
 147 }
 148
 149 sub enter_pit_lane {
 150         my ($self) = @_;
 151
 152         return if $self->{in_pit_lane};
 153
 154         $self->{in_pit_lane} = 1;
 155         $self->print_state;
 156 }
 157
 158 sub leave_pit_lane {
 159         my ($self) = @_;
 160
 161         return if !$self->{in_pit_lane};
 162
 163         $self->{in_pit_lane} = 0;
 164         $self->print_state;
 165 }
 166
 167 sub set_order {
 168         my ($self, $pos) = @_;
 169
 170         $self->{order} = $pos;
 171
 172         $self->gui->set_name($self->{order}, $self->{driver});
 173         $self->gui->set_car_icon($self->{order}, $self->{car_img});
 174         $self->gui->set_throttle($self->{order}, $self->{throttle},
 175                 $self->{button});
 176         $self->gui->set_lap($self->{order}, $self->{lap});
 177         $self->gui->set_laptime($self->{order}, $self->{laptime});
 178         $self->gui->set_best_lap($self->{order}, $self->{best_lap});
 179         $self->gui->set_avg_lap($self->{order}, $self->{avg_lap});
 180         $self->gui->set_fuel($self->{order}, $self->{fuel});
 181         $self->gui->set_car_id($self->{order}, $self->{id} + 1);
 182         $self->gui->set_distance($self->{order},
 183                 $self->{time_diff}, $self->{lap_diff});
 184         $self->gui->set_state($self->{order}, $self->{state});
 185         if ($self->{in_pit_lane}) {
 186                 $self->gui->enter_pit_lane;
 187         }
 188 }
 189
 190 sub print_state {
 191         my ($self) = @_;
 192
 193         if ($self->{in_pit_lane}) {
 194                 $self->{state} = 'pit';
 195         } elsif ($self->{running}) {
 196                 $self->{state} = 'go';
 197         } elsif ($self->{finished}) {
 198                 $self->{state} = 'finished';
 199         } elsif ($self->{early_start}) {
 200                 $self->{state} = 'disqualified';
 201         } else {
 202                 $self->{state} = 'greenflag';
 203         }
 204
 205         $self->gui->set_state($self->{order}, $self->{state});
 206 }
 207
 208 sub reset {
 209         my ($self) = @_;
 210
 211         $self->set_lap(0);
 212         $self->set_laptime(undef);
 213         $self->{in_pit_lane} = 0;
 214         $self->{early_start} = undef;
 215         $self->{last_finish_time} = undef;
 216         $self->{first_finish_time} = undef;
 217         $self->{time_diff} = undef;
 218         $self->{lap_diff} = undef;
 219 }
 220
 221 sub finish_line {
 222         my ($self, $time, $regular) = @_;
 223
 224         if (defined $self->{last_finish_time}
 225                 && $time - $self->{last_finish_time} < 2) {
 226
 227                 $self->{last_finish_time} = $time;
 228                 if ($regular && $self->{in_pit_lane}) {
 229                         $self->leave_pit_lane;
 230                 }
 231                 return undef;
 232         }
 233
 234         if ($regular) {
 235                 if (defined $self->{first_finish_time}) {
 236                         $self->set_laptime($time - $self->{first_finish_time});
 237                 }
 238         } else {
 239                 $self->enter_pit_lane;
 240         }
 241
 242         $self->{first_finish_time} = $self->{last_finish_time} = $time;
 243
 244         if ($self->track->{race_running}) {
 245                 $self->set_lap($self->{lap} + 1);
 246         }
 247
 248         return 1;
 249 }
 250
 251 sub recalc_distance {
 252         my ($self, $lap_first, $time_first) = @_;
 253
 254         return if !defined $lap_first || !defined $self->{lap}
 255                 || !defined $time_first || !defined $self->{first_finish_time};
 256
 257         my $time;
 258
 259         if ($self->{lap} == $lap_first) {
 260                 if ($self->{first_finish_time} == $time_first) {
 261                         $time = $self->{first_finish_time}
 262                                 - $self->track->{race_running_since};
 263                 } else {
 264                         $self->{time_diff} = $self->{first_finish_time}
 265                                 - $time_first;
 266                 }
 267         } else {
 268                 $self->{lap_diff} = $lap_first - $self->{lap};
 269         }
 270
 271         $self->gui->set_distance($self->{order}, $time,
 272                 $self->{lap_diff}, $self->{time_diff});
 273 }
 274
 275 1;
 276