SCX/Car.pm

   1 #!/usr/bin/perl -w
   2
   3 package SCX::Car;
   4
   5 use strict;
   6 use Time::HiRes qw(gettimeofday);
   7
   8 sub new {
   9         my ($class, $args) = @_;
  10
  11         my $self = {
  12                 gui      => $args->{gui},
  13                 driver   => $args->{driver} || '--',
  14                 throttle => undef,
  15                 fuel     => 0,
  16                 lap      => 0,
  17                 laptime  => 0,
  18                 avg_lap  => 0,
  19                 car_img  => $args->{car_img},
  20                 id       => $args->{id},
  21                 order    => $args->{id},
  22                 track    => $args->{track},
  23         };
  24
  25         bless $self, $class;
  26
  27         return $self;
  28 }
  29
  30 sub gui { return shift->{gui}; }
  31
  32 sub track { return shift->{track}; }
  33
  34 sub same {
  35         my ($self, $key, $val) = @_;
  36
  37         return 1 if !defined $self->{$key} && !defined $val
  38                 || (defined $self->{$key} && defined $val
  39                         && $self->{$key} eq $val);
  40
  41         $self->{$key} = $val;
  42         return undef;
  43 }
  44
  45 sub set_throttle {
  46         my ($self, $val, $time) = @_;
  47
  48         return if $self->same('throttle', $val);
  49
  50         if ($self->track->{start_in_progress} && $val) {
  51                 $self->{early_start} = 1;
  52                 $self->gui->set_name($self->{order}, 'Early start!');
  53         }
  54
  55         if ($self->{in_pit_lane} && defined $val) {
  56                 $self->{last_finish_time} = $time;
  57                 if ($val > 3) {
  58                         $self->leave_pit_lane;
  59                 }
  60         }
  61
  62         $self->gui->set_throttle($self->{order}, $val);
  63 }
  64
  65
  66 sub set_fuel {
  67         my ($self, $val) = @_;
  68
  69         return if $self->same('fuel', $val);
  70         $self->gui->set_fuel($self->{order}, $val);
  71 }
  72
  73 sub set_light {
  74         # TODO
  75 }
  76
  77 sub set_backbutton {
  78         # TODO
  79 }
  80
  81 sub set_model {
  82         my ($self, $name) = @_;
  83
  84         return if $self->same('car_img', $name);
  85         $self->gui->set_car_icon($self->{order}, $name);
  86 }
  87
  88 sub set_lap {
  89         my ($self, $lap_nr) = @_;
  90
  91         if (!$lap_nr) {
  92                 $self->{avg_lap} = undef;
  93                 $self->{lap} = $lap_nr;
  94                 $self->gui->set_avg_lap($self->{order}, undef);
  95                 $self->gui->set_lap($self->{order}, $lap_nr);
  96                 return;
  97         }
  98
  99         return if $self->same('lap', $lap_nr);
 100         $self->gui->set_lap($self->{order}, $lap_nr);
 101         if ($self->track->{race_running} && $self->{lap} > 1) {
 102                 my $now = $self->{last_finish_time};
 103                 my $avg = ($now - $self->track->{race_running_since})
 104                         / ($self->{lap} - 1);
 105                 $self->{avg_lap} = $avg;
 106                 $self->gui->set_avg_lap($self->{order}, $self->{avg_lap});
 107         }
 108 }
 109
 110 sub set_laptime {
 111         my ($self, $lap_time) = @_;
 112
 113         if (!defined $lap_time) {
 114                 $self->gui->set_best_lap($self->{order}, undef);
 115                 $self->{best_lap} = undef;
 116         }
 117
 118         return if $self->same('laptime', $lap_time);
 119
 120         $self->gui->set_laptime($self->{order}, $lap_time);
 121
 122         if (defined $lap_time) {
 123                 if ($lap_time > 1.0 && !$self->{in_pit_lane}
 124                         && $self->track->{race_running}
 125                         && (!defined $self->{best_lap}
 126                                 || $self->{best_lap} > $lap_time
 127                         )) {
 128
 129                         $self->{best_lap} = $lap_time;
 130                         my $global = $self->{track}->check_best_lap($lap_time,
 131                                 $self->{driver}
 132                         );
 133                         $self->gui->set_best_lap($self->{order}, $lap_time,
 134                                 $global);
 135                 }
 136         }
 137 }
 138
 139 sub set_driver {
 140         my ($self, $driver_name) = @_;
 141
 142         return if $self->same('driver', $driver_name);
 143         $self->gui->set_name($self->{order}, $driver_name);
 144 }
 145
 146 sub enter_pit_lane {
 147         my ($self) = @_;
 148
 149         return if $self->{in_pit_lane};
 150
 151         $self->{in_pit_lane} = 1;
 152         $self->gui->enter_pit_lane($self->{order});
 153 }
 154
 155 sub leave_pit_lane {
 156         my ($self) = @_;
 157
 158         return if !$self->{in_pit_lane};
 159
 160         $self->{in_pit_lane} = 0;
 161         $self->gui->leave_pit_lane($self->{order});
 162 }
 163
 164 sub set_order {
 165         my ($self, $pos) = @_;
 166
 167         $self->{order} = $pos;
 168
 169         $self->gui->set_name($self->{order}, $self->{driver});
 170         $self->gui->set_car_icon($self->{order}, $self->{car_img});
 171         $self->gui->set_throttle($self->{order}, $self->{throttle});
 172         $self->gui->set_lap($self->{order}, $self->{lap});
 173         $self->gui->set_laptime($self->{order}, $self->{laptime});
 174         $self->gui->set_best_lap($self->{order}, $self->{best_lap});
 175         $self->gui->set_avg_lap($self->{order}, $self->{avg_lap});
 176         $self->gui->set_fuel($self->{order}, $self->{fuel});
 177         $self->gui->set_car_id($self->{order}, $self->{id} + 1);
 178         $self->gui->set_distance($self->{order},
 179                 $self->{time_diff}, $self->{lap_diff});
 180         if ($self->{in_pit_lane}) {
 181                 $self->gui->enter_pit_lane;
 182         }
 183 }
 184
 185 sub reset {
 186         my ($self) = @_;
 187
 188         $self->set_lap(0);
 189         $self->set_laptime(undef);
 190         $self->{in_pit_lane} = 0;
 191         $self->{early_start} = undef;
 192         $self->{last_finish_time} = undef;
 193         $self->{first_finish_time} = undef;
 194         $self->{time_diff} = undef;
 195         $self->{lap_diff} = undef;
 196 }
 197
 198 sub finish_line {
 199         my ($self, $time, $regular) = @_;
 200
 201         if (defined $self->{last_finish_time}
 202                 && $time - $self->{last_finish_time} < 2) {
 203
 204                 $self->{last_finish_time} = $time;
 205                 if ($regular && $self->{in_pit_lane}) {
 206                         $self->leave_pit_lane;
 207                 }
 208                 return undef;
 209         }
 210
 211         if ($regular) {
 212                 if (defined $self->{first_finish_time}) {
 213                         $self->set_laptime($time - $self->{first_finish_time});
 214                 }
 215         } else {
 216                 $self->enter_pit_lane;
 217         }
 218
 219         $self->{first_finish_time} = $self->{last_finish_time} = $time;
 220
 221         if ($self->track->{race_running}) {
 222                 $self->set_lap($self->{lap} + 1);
 223         }
 224
 225         return 1;
 226 }
 227
 228 sub recalc_distance {
 229         my ($self, $lap_first, $time_first) = @_;
 230
 231         return if !defined $lap_first || !defined $self->{lap}
 232                 || !defined $time_first || !defined $self->{first_finish_time};
 233
 234         my $time;
 235
 236         if ($self->{lap} == $lap_first) {
 237                 if ($self->{first_finish_time} == $time_first) {
 238                         $time = $self->{first_finish_time}
 239                                 - $self->track->{race_running_since};
 240                 } else {
 241                         $self->{time_diff} = $self->{first_finish_time}
 242                                 - $time_first;
 243                 }
 244         } else {
 245                 $self->{lap_diff} = $lap_first - $self->{lap};
 246         }
 247
 248         $self->gui->set_distance($self->{order}, $time,
 249                 $self->{lap_diff}, $self->{time_diff});
 250 }
 251
 252 1;
 253