leaderboard

   1 #!/usr/bin/perl -w
   2
   3 use v5.16;
   4 use Mojo::UserAgent -signatures;
   5 use Mojo::JSON qw(from_json);
   6 use Mojo::File qw(curfile);
   7 use Mojo::Util qw(getopt dumper);
   8 use POSIX;
   9
  10 my $board_id = 652041;
  11 my $my_name = 'Yenya';
  12 my $day = (localtime(time))[3];
  13 my $mode = 'r';
  14 my $cached = curfile->sibling('cache.json');
  15 getopt
  16         'n|name=s'      => \$my_name,
  17         'd|day=i'       => \$day,
  18         '1|first-task'  => sub { $mode = '1' },
  19         '2|second-task' => sub { $mode = '2' },
  20         'r|relative'    => sub { $mode = 'r' },
  21         'b|board=i'     => \$board_id
  22 or die "Usage: $0 [-n username] [-1|-2|-r] [-b board_id]\n";
  23
  24 if (!$cached->stat || time - $cached->stat->mtime > 900) {
  25         warn "Downloading cache.json\n";
  26         chomp(my $cookie = curfile->sibling('cookie')->slurp);
  27         my $res = Mojo::UserAgent->new->get(
  28                 "https://adventofcode.com/2021/leaderboard/private/view/$board_id.json",
  29                 { Cookie => $cookie }
  30         )->result;
  31
  32         $cached->spurt($res->body);
  33 }
  34
  35 my $json = from_json $cached->slurp;
  36
  37
  38 my %times;
  39 my $my_time;
  40 for my $name (keys %{ $json->{members} }) {
  41         my $member = $json->{members}->{$name};
  42         my $level = $member->{completion_day_level}->{$day}
  43                 or next;
  44         my $time;
  45         if ($mode eq 'r') {
  46                 next if !$level->{2};
  47                 $time = $level->{2}->{get_star_ts} - $level->{1}->{get_star_ts};
  48         } elsif ($mode eq '1') {
  49                 next if !$level->{1};
  50                 $time = $level->{1}->{get_star_ts};
  51         } elsif ($mode eq '2') {
  52                 next if !$level->{2};
  53                 $time = $level->{2}->{get_star_ts};
  54         }
  55         my $id_or_name = $member->{name} // 'Anonymous user #' . $member->{id};
  56         $times{ $id_or_name } = $time;
  57         $my_time = $time
  58                 if $id_or_name eq $my_name;
  59 }
  60
  61 for my $name (sort { $times{$a} <=> $times{$b} } keys %times) {
  62         $my_time //= $times{$name};
  63         printf("%6d %6d %s\n", $times{$name}, $times{$name} - $my_time, $name);
  64 }