ft-scout-landing-gear-support.scad

   1 infty = 100;
   2 eps = 0.01;
   3
   4 fuse_w = 40;
   5 gear_w = fuse_w - 16;
   6 gear_l = 40; // 26
   7 spring_l = 6;
   8
   9 base_w = fuse_w - 10;
  10 base_l = gear_l + 5;
  11 base_h = 1.2;
  12 base_beam_w = spring_l + 2;
  13 base_reinf_h = 1.5;
  14 base_reinf_w = 2;
  15
  16 rear_spring_l = 2.5;
  17 rear_spring_rear_l = 6;
  18 rear_beam_w = rear_spring_l + 4;
  19 rear_spring_w = 3;
  20 rear_spring_front_bot_w = 15;
  21 rear_spring_bot_w = 10;
  22 rear_slot_w = 1.4;
  23
  24 side_spring_bot_w = 3.5;
  25 side_spring_w = 1.5;
  26
  27 hook_wall = 1;
  28 hook_in = 1.7;
  29 hook_h = base_h + base_reinf_h/2;
  30 side_hook_angle = 4;
  31 side_hook_angle_cut = 10;
  32
  33 module body() {
  34         // wide beam
  35         hull() {
  36                 translate([0, -base_w/2, 0])
  37                         cube([base_beam_w, base_w, base_h]);
  38                 translate([base_beam_w/2-base_reinf_w/2, -base_w/2, base_h-eps])
  39                         cube([base_reinf_w, base_w, base_reinf_h + eps]);
  40         }
  41
  42         // long center beam
  43         hull() {
  44                 translate([base_beam_w/2, -rear_beam_w/2, 0])
  45                         cube([base_l - base_beam_w/2, rear_beam_w, base_h]);
  46                 translate([base_beam_w/2, -base_reinf_w/2, base_h-eps])
  47                         cube([base_l - base_beam_w/2, base_reinf_w, base_reinf_h + eps]);
  48         }
  49
  50         // rear hook - front part
  51         hull() {
  52                 translate([gear_l-rear_spring_front_bot_w/2, -rear_spring_l/2, base_h])
  53                         cube([rear_spring_front_bot_w/2-rear_slot_w/2, rear_spring_l, eps]);
  54                 translate([gear_l-rear_spring_w/2, -rear_spring_l/2, hook_h+hook_in+hook_wall-eps])
  55                         cube([rear_spring_w/2-rear_slot_w, rear_spring_l, eps]);
  56         }
  57         // rear hook - rear part
  58         hull() {
  59                 translate([gear_l, -rear_spring_rear_l/2, base_h])
  60                         cube([rear_spring_bot_w/2, rear_spring_rear_l, eps]);
  61                 translate([gear_l, -rear_spring_rear_l/2, hook_h+hook_in+hook_wall-eps])
  62                         cube([rear_spring_w/2, rear_spring_rear_l, eps]);
  63         }
  64
  65         // side hooks
  66         for (y = [-1, 1]) scale([1, y, 1]) intersection() {
  67                 translate([0, gear_w/2, eps]) rotate([0, 0, -side_hook_angle])
  68                         translate([-10, 0, 0]) hull() {
  69                         translate([0, -side_spring_bot_w, 0])
  70                         cube([20, 2*side_spring_bot_w, base_h-eps]);
  71                         translate([0, -side_spring_w, 0])
  72                         cube([20, 2*side_spring_w, hook_h + hook_in + hook_wall-eps]);
  73                 }
  74                 // above the beam
  75                 translate([0, -base_w/2, base_h/2])
  76                         cube([base_beam_w, base_w, infty]);
  77                 // cut the front sides
  78 /*
  79                 translate([0, gear_w/2 + 1.25, eps])
  80                 rotate([0, 0, -side_hook_angle_cut])
  81                         translate([-5, 0, 0])
  82                         cube(20);
  83 */
  84
  85         }
  86 }
  87
  88 difference() {
  89         body();
  90         // rear hole
  91         translate([gear_l, 0, hook_h+hook_in/2])
  92         rotate([90, 90, 0])
  93         translate([0, 0, -rear_beam_w/2-eps])
  94                 cylinder(h = rear_beam_w+2*eps, r = hook_in/2, $fn = 6);
  95         // rear slot above the hole
  96         // translate([gear_l-rear_slot_w/2, -rear_beam_w/2+eps, hook_h+hook_in/2])
  97         //      cube([rear_slot_w, rear_beam_w+2*eps, infty]);
  98         // side slots
  99         for (y = [-1, 1]) scale([1, y, 1]) {
 100                 translate([0, gear_w/2, hook_h+hook_in/2]) {
 101                         rotate([0, 90, -side_hook_angle])
 102                         translate([0, 0, -10])
 103                         cylinder(r1 = hook_in, r2 = hook_in/2, h = 20, $fn = 6);
 104
 105                         rotate([0, 0, -side_hook_angle])
 106                         rotate([25, 0, 0])
 107                         hull() {
 108                                 translate([-10, -rear_slot_w, 0])
 109                                         cube([eps, 2*rear_slot_w, 20]);
 110                                 translate([10, -rear_slot_w/2, 0])
 111                                         cube([eps, rear_slot_w, 20]);
 112                         }
 113                 }
 114         }
 115 }