configure.ac

   1 # *****************************************************************************
   2 # Versioning
   3 # *****************************************************************************
   4
   5 m4_define([ev_major_version],[2])
   6 m4_define([ev_minor_version],[31])
   7 m4_define([ev_micro_version],[1])
   8 m4_define([ev_extra_version],[])
   9 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version()ev_extra_version])
  10
  11 # The evince API version
  12 m4_define([ev_api_version], [2.30])
  13
  14 # Libtool versioning. The backend and view libraries have separate versions.
  15 # Before making a release, the libtool version should be modified.
  16 # The string is of the form C:R:A.
  17 # - If interfaces have been changed or added, but binary compatibility has
  18 #   been preserved, change to C+1:0:A+1
  19 # - If binary compatibility has been broken (eg removed or changed interfaces)
  20 #   change to C+1:0:0
  21 # - If the interface is the same as the previous version, change to C:R+1:A
  22
  23 # Libtool version of the backend library
  24 m4_define([ev_document_lt_current],[2])
  25 m4_define([ev_document_lt_revision],[0])
  26 m4_define([ev_document_lt_age],[0])
  27 m4_define([ev_document_lt_version_info],[ev_document_lt_current:ev_document_lt_revision:ev_document_lt_age])
  28 m4_define([ev_document_lt_current_minus_age],[m4_eval(ev_document_lt_current - ev_document_lt_age)])
  29
  30 # Libtool version of the view library
  31 m4_define([ev_view_lt_current],[2])
  32 m4_define([ev_view_lt_revision],[0])
  33 m4_define([ev_view_lt_age],[0])
  34 m4_define([ev_view_lt_version_info],[ev_view_lt_current:ev_view_lt_revision:ev_view_lt_age])
  35 m4_define([ev_view_lt_current_minus_age],[m4_eval(ev_view_lt_current - ev_view_lt_age)])
  36
  37 # Binary version for the document backends
  38 m4_define([ev_binary_version],[ev_document_lt_current])
  39
  40 # *****************************************************************************
  41
  42 AC_PREREQ([2.57])
  43 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
  44 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2 no-dist-gzip])
  45
  46 AC_CONFIG_HEADERS([config.h])
  47 AC_CONFIG_MACRO_DIR([m4])
  48
  49 if test -z "$enable_maintainer_mode"; then
  50   enable_maintainer_mode=yes
  51 fi
  52 AM_MAINTAINER_MODE([enable])
  53
  54 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  55
  56 AM_PROG_LIBTOOL
  57
  58 AC_ISC_POSIX
  59 AC_PROG_CC
  60 AM_PROG_CC_STDC
  61 AM_PROG_CC_C_O
  62 AC_PROG_CXX
  63 AC_STDC_HEADERS
  64
  65 AC_PROG_SED
  66 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  67 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  68
  69 GNOME_MAINTAINER_MODE_DEFINES
  70 GNOME_COMPILE_WARNINGS
  71 GNOME_CXX_WARNINGS
  72
  73 dnl FIXME: remove this when required gtk+ >= 2.19.7
  74 DISABLE_DEPRECATED=
  75 AC_SUBST([DISABLE_DEPRECATED])
  76
  77 IT_PROG_INTLTOOL([0.35.0])
  78
  79 GETTEXT_PACKAGE=evince
  80 AC_SUBST(GETTEXT_PACKAGE)
  81 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  82 AM_GLIB_GNU_GETTEXT
  83
  84 m4_pattern_allow([AM_V_GEN])dnl Make autoconf not complain about the rule below
  85 EV_INTLTOOL_EVINCE_BACKEND_RULE='%.evince-backend:   %.evince-backend.in   $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; $(AM_V_GEN) LC_ALL=C $(INTLTOOL_MERGE) -d -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@'
  86 AC_SUBST([EV_INTLTOOL_EVINCE_BACKEND_RULE])
  87
  88 GLIB_GSETTINGS
  89
  90 # Check which platform to use
  91
  92 AC_MSG_CHECKING([for which platform to build])
  93 AC_ARG_WITH([platform],
  94   [AS_HELP_STRING([--with-platform=gnome|win32|hildon],
  95                   [Setting platform (default: gnome)])],
  96   [case "$withval" in
  97     gnome|win32|hildon) ;;
  98     *) AC_MSG_ERROR([invalid argument "$withval" for --with-platform]) ;;
  99    esac],
 100   [case "$host" in
 101      *-*-mingw*|*-*-cygwin*) with_platform="win32" ;;
 102      *) with_platform=gnome ;;
 103    esac])
 104
 105 AC_MSG_RESULT([$with_platform])
 106
 107 if test "$with_platform" = "win32"; then
 108   AC_CHECK_TOOL([WINDRES],[windres])
 109   AC_MSG_CHECKING([for native Win32])
 110   case "$host" in
 111     *-*-mingw*)
 112       os_win32=yes
 113       ;;
 114     *)
 115       os_win32=no
 116       ;;
 117   esac
 118   AC_MSG_RESULT([$os_win32])
 119 fi
 120
 121 AM_CONDITIONAL([PLATFORM_HILDON],[test "$with_platform" = "hildon"])
 122 AM_CONDITIONAL([PLATFORM_WIN32],[test "$with_platform" = "win32"])
 123
 124 dnl Specify required versions of dependencies
 125 DBUS_GLIB_REQUIRED=0.70
 126 GTK_REQUIRED=2.21.0
 127 GLIB_REQUIRED=2.25.6
 128 KEYRING_REQUIRED=2.22.0
 129 AC_SUBST([GLIB_REQUIRED])
 130 AC_SUBST([GTK_REQUIRED])
 131
 132 GNOME_ICON_THEME_REQUIRED=2.17.1
 133 LIBXML_REQUIRED=2.5.0
 134
 135 dnl Check dependencies
 136
 137 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
 138 # BACKEND_CFLAGS   for backend implementations.
 139 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
 140 # FRONTEND_LIBS
 141 # SHELL_CFLAGS     for shell implementation.
 142 # SHELL_LIBS
 143
 144 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
 145 PKG_CHECK_MODULES(LIBVIEW, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 146 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
 147 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 148 PKG_CHECK_MODULES(PREVIEWER, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 149
 150 SHELL_PLATFORM_PKGS=
 151 case "$with_platform" in
 152   hildon) AC_DEFINE([PLATFORM_HILDON],[1],[Define if building for the hildon platform])
 153           SHELL_PLATFORM_PKGS="hildon-1 hildon-fm-2 libosso"
 154           ;;
 155   gnome)
 156         # Evince has a rather soft run-time dependency on hicolor-icon-theme.
 157         # If the hicolor theme is not available, Evince fails to display some
 158         # icons. Because we cannot check for it at run-time, we instead
 159         # would like to require the icon theme at compile-time. But, because
 160         # the hicolor-icon-theme does not have a pkgconfig file, on gnome we
 161         # require the gnome icon theme instead.
 162         SHELL_PLATFORM_PKGS="gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED"
 163         # The totem-screensaver and egg_smclient code use x11 directly.
 164         SHELL_PLATFORM_PKGS="$SHELL_PLATFORM_PKGS x11"
 165         ;;
 166   *)
 167         # On all other platforms we issue a warning about the runtime
 168         # dependency.
 169         AC_MSG_WARN([Evince has a soft run-time dependency on hicolor-icon-theme. You are advised to have this theme installed when running Evince.]);
 170         SHELL_PLATFORM_PKGS=""
 171         ;;
 172 esac
 173
 174 PKG_CHECK_MODULES([SHELL_CORE],[libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gthread-2.0 $SHELL_PLATFORM_PKGS])
 175
 176 # *********
 177 # SM client
 178 # *********
 179
 180 GDK_TARGET="$($PKG_CONFIG --variable target gdk-2.0)"
 181
 182 AC_MSG_CHECKING([which smclient backend to use])
 183 AC_ARG_WITH([smclient],
 184   [AS_HELP_STRING([--with-smclient-backend=no|xsmp|win32|quartz],
 185                   [Setting smclient backend (default:auto)])],
 186   [],
 187   [case "$GDK_TARGET" in
 188     x11) case "$with_platform" in
 189            gnome) with_smclient=xsmp ;;
 190            *) with_smclient=no ;;
 191          esac ;;
 192     win32|quartz) with_smclient=$GDK_TARGET ;;
 193     *) with_smclient=no ;;
 194    esac])
 195
 196 AC_MSG_RESULT([$with_smclient])
 197
 198 if test "$with_smclient" != "no"; then
 199   AC_DEFINE([WITH_SMCLIENT],[1],[Define if smclient is enabled])
 200
 201   case "$with_smclient" in
 202     xsmp) SMCLIENT_PKGS="sm >= 1.0.0" ;;
 203     *) SMCLIENT_PKGS="" ;;
 204   esac
 205
 206   PKG_CHECK_MODULES([SMCLIENT],[gtk+-2.0 gthread-2.0 $SMCLIENT_PKGS])
 207   AC_SUBST([SMCLIENT_CFLAGS])
 208   AC_SUBST([SMCLIENT_LIBS])
 209 fi
 210
 211 AM_CONDITIONAL([WITH_SMCLIENT],[test "$with_smclient" != "no"])
 212 AM_CONDITIONAL([WITH_SMCLIENT_XSMP],[test "$with_smclient" = "xsmp"])
 213 AM_CONDITIONAL([WITH_SMCLIENT_WIN32],[test "$with_smclient" = "win32"])
 214 AM_CONDITIONAL([WITH_SMCLIENT_QUARTZ],[test "$with_smclient" = "quartz"])
 215
 216 # ***
 217
 218 BACKEND_LIBTOOL_FLAGS="-module -avoid-version -no-undefined -export-symbols \$(top_srcdir)/backend/backend.symbols"
 219 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
 220
 221 dnl ===== Check special functions
 222 evince_save_LIBS=$LIBS
 223 LIBS="$LIBS $BACKEND_LIBS"
 224 AC_CHECK_FUNCS(cairo_format_stride_for_width)
 225 LIBS=$evince_save_LIBS
 226
 227 # ******************
 228 # GKT+ Unix Printing
 229 # ******************
 230
 231 AC_MSG_CHECKING([whether gtk+-unix-print support is requested])
 232 AC_ARG_WITH([gtk-unix-print],
 233   [AS_HELP_STRING([--without-gtk-unix-print],
 234                   [Disable the use of gtk-unix-print])],
 235   [],[case "$os_win32" in
 236         yes) with_gtk_unix_print=no ;;
 237         *) with_gtk_unix_print=yes ;;
 238       esac])
 239
 240 AC_MSG_RESULT([$with_gtk_unix_print])
 241
 242 if test "$with_gtk_unix_print" = "yes"; then
 243    PKG_CHECK_MODULES(GTKUNIXPRINT, [gtk+-unix-print-2.0 >= $GTK_REQUIRED])
 244    AC_DEFINE([GTKUNIXPRINT_ENABLED], [1], [Define if gtk+-unix-print is enabled.])
 245 fi
 246
 247 # *********************
 248 # GNOME Keyring support
 249 # *********************
 250
 251 AC_ARG_WITH(keyring,
 252         [AS_HELP_STRING([--without-keyring],
 253                         [Disable the use of gnome-keyring])],
 254         [],
 255         [case "$with_platform" in
 256            gnome) with_keyring=yes ;;
 257            hildon|win32) with_keyring=no ;;
 258          esac])
 259
 260 AM_CONDITIONAL([WITH_KEYRING],[test "$with_keyring" = "yes"])
 261
 262 if test "$with_keyring" = "yes"; then
 263         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
 264         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
 265 fi
 266
 267 # ****
 268 # DBUS
 269 # ****
 270
 271 AC_ARG_ENABLE([dbus],
 272   [AS_HELP_STRING([--disable-dbus], [Disable support for dbus])],
 273   [],
 274   [case "$with_platform" in
 275       gnome) enable_dbus=yes ;;
 276       hildon) enable_dbus=no ;;
 277     esac])
 278
 279 if test "$enable_dbus" = "yes"; then
 280   PKG_CHECK_MODULES([DBUS],[dbus-glib-1 >= $DBUS_GLIB_REQUIRED],[],
 281                     [AC_MSG_ERROR([DBUS not found; use --disable-dbus to disable DBUS support])])
 282
 283   AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 284   if test x$DBUS_BINDING_TOOL = "xno" ; then
 285           AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 286   fi
 287
 288   AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 289 fi
 290
 291 AC_SUBST([DBUS_CFLAGS])
 292 AC_SUBST([DBUS_LIBS])
 293
 294 AM_CONDITIONAL([ENABLE_DBUS], [test "$enable_dbus" = "yes"])
 295
 296 if test "$enable_dbus" = "yes"; then
 297    PKG_CHECK_MODULES([EV_DAEMON], [gthread-2.0 gio-2.0 >= $GLIB_REQUIRED])
 298 fi
 299
 300 dnl ========= Check for GConf
 301
 302 AC_MSG_CHECKING([whether GConf support is requested])
 303 AC_ARG_WITH([gconf],
 304   [AS_HELP_STRING([--without-gconf],
 305                   [Disable the use of gconf])],
 306   [],
 307   [case "$os_win32" in
 308      yes) with_gconf=no ;;
 309      *) with_gconf=yes ;;
 310    esac])
 311 AC_MSG_RESULT([$with_gconf])
 312
 313 AM_CONDITIONAL([WITH_GCONF],[test "$with_gconf" = "yes"])
 314
 315 if test "$with_gconf" = "yes"; then
 316    PKG_CHECK_MODULES([GCONF],[gconf-2.0])
 317    AC_DEFINE([WITH_GCONF],[1],[Define if GConf support is enabled])
 318
 319    AM_GCONF_SOURCE_2
 320
 321    AC_PATH_PROG([GCONFTOOL], [gconftool-2], [false])
 322    if test "$GCONFTOOL" = "false"; then
 323       AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 324    fi
 325 else
 326    AM_CONDITIONAL([GCONF_SCHEMAS_INSTALL],false)
 327 fi
 328
 329 dnl Debug mode
 330
 331 AC_ARG_ENABLE([debug],
 332         AS_HELP_STRING([--enable-debug],
 333                        [Turn on evince debug mode]),
 334         [enable_debug=$enableval],
 335         [enable_debug=no])
 336
 337 if test "x$enable_debug" = "xyes"; then
 338    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 339 fi
 340
 341 AC_ARG_ENABLE([tests],
 342         AS_HELP_STRING([--enable-tests], [Enable the tests]),
 343         [enable_tests=$enableval],
 344         [enable_tests=yes])
 345
 346 AM_CONDITIONAL(ENABLE_TESTS, test x$enable_tests = xyes)
 347
 348 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 349 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 350 AC_SUBST(LIBDOCUMENT_CFLAGS)
 351 AC_SUBST(LIBDOCUMENT_LIBS)
 352
 353 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 354 LIBVIEW_LIBS="$LIBVIEW_LIBS $GTKUNIXPRINT_LIBS -lm"
 355 AC_SUBST(LIBVIEW_CFLAGS)
 356 AC_SUBST(LIBVIEW_LIBS)
 357
 358 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 359 BACKEND_LIBS="$BACKEND_LIBS -lm"
 360 AC_SUBST(BACKEND_CFLAGS)
 361 AC_SUBST(BACKEND_LIBS)
 362
 363 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS $KEYRING_CFLAGS $GCONF_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 364 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS $KEYRING_LIBS $GCONF_LIBS -lz -lm"
 365 AC_SUBST(SHELL_CFLAGS)
 366 AC_SUBST(SHELL_LIBS)
 367
 368 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 369 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 370 AC_SUBST(FRONTEND_CFLAGS)
 371 AC_SUBST(FRONTEND_LIBS)
 372
 373 EV_DAEMON_CFLAGS="$EV_DAEMON_CFLAGS $DEBUG_FLAGS"
 374 AC_SUBST([EV_DAEMON_CFLAGS])
 375 AC_SUBST([EV_DAEMON_LIBS])
 376
 377 # Check for Nautilus property page build
 378 AC_ARG_ENABLE([nautilus],
 379   [AS_HELP_STRING([--disable-nautilus],
 380                   [Disable build of nautilus extensions])],
 381   [],
 382   [case "$with_platform" in
 383      gnome) enable_nautilus=yes ;;
 384      *) enable_nautilus=no ;;
 385     esac])
 386
 387 if test "$enable_nautilus" = "yes" ; then
 388   PKG_CHECK_MODULES([NAUTILUS],[gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension],
 389                     [],[AC_MSG_ERROR([libnautilus-extension not found; use --disable-nautilus to disable the nautilus extensions])])
 390   NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 391   AC_SUBST([nautilusextensiondir],[$NAUTILUS_EXTENSION_DIR])
 392   AC_SUBST(NAUTILUS_CFLAGS)
 393   AC_SUBST(NAUTILUS_LIBS)
 394
 395   AC_DEFINE([HAVE_NAUTILUS],[1], [defined if you build the nautilus plugin])
 396 fi
 397
 398 AM_CONDITIONAL([ENABLE_NAUTILUS],[test "$enable_nautilus" = "yes"])
 399
 400 # Check for thumbnailer build
 401
 402 AC_ARG_ENABLE([thumbnailer],
 403   [AS_HELP_STRING([--disable-thumbnailer],
 404                   [Disable GNOME thumbnailer])],
 405   [],
 406   [case "$with_platform" in
 407      gnome) enable_thumbnailer=yes ;;
 408      *) enable_thumbnailer=no ;;
 409     esac])
 410
 411 AM_CONDITIONAL([ENABLE_THUMBNAILER],[test "$enable_thumbnailer" = "yes"])
 412
 413 # ***************
 414 # Print Previewer
 415 # ***************
 416
 417 AC_ARG_ENABLE([previewer],
 418   [AS_HELP_STRING([--disable-previewer],
 419                   [Disable the GNOME Document Previewer])],
 420   [],
 421   [case "$with_platform" in
 422       gnome) enable_previewer=yes ;;
 423       *) enable_previewer=no ;;
 424     esac])
 425
 426 if test x$enable_previewer = "xyes" ; then
 427   PKG_CHECK_MODULES([PREVIEWER],[gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED])
 428 fi
 429
 430 AM_CONDITIONAL([ENABLE_PREVIEWER],[test "$enable_previewer" = "yes"])
 431 PREVIEWER_CFLAGS="$PREVIEWER_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 432 PREVIEWER_LIBS="$PREVIEWER_LIBS $GTKUNIXPRINT_LIBS -lz"
 433 AC_SUBST(PREVIEWER_CFLAGS)
 434 AC_SUBST(PREVIEWER_LIBS)
 435
 436 # ***
 437 # GIR
 438 # ***
 439
 440 AC_MSG_CHECKING([whether GObject introspection is requested])
 441 AC_ARG_ENABLE([introspection],
 442         AS_HELP_STRING([--enable-introspection],
 443                        [Enable GObject introspection]),
 444         [enable_introspection=$enableval],
 445         [enable_introspection=no])
 446 AC_MSG_RESULT([$enable_introspection])
 447
 448 G_IR_SCANNER=
 449 G_IR_COMPILER=
 450 G_IR_GENERATE=
 451 GIRDIR=
 452 GIRTYPELIBDIR=
 453
 454 if test "$enable_introspection" = "yes"; then
 455   GOBJECT_INTROSPECTION_REQUIRED=0.6
 456   PKG_CHECK_MODULES([GOBJECT_INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
 457
 458   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
 459   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
 460   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
 461   GIRDIR="$($PKG_CONFIG --variable=girdir gobject-introspection-1.0)"
 462   GIRTYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
 463 fi
 464
 465 AC_SUBST([G_IR_SCANNER])
 466 AC_SUBST([G_IR_COMPILER])
 467 AC_SUBST([G_IR_GENERATE])
 468 AC_SUBST([GIRDIR])
 469 AC_SUBST([GIRTYPELIBDIR])
 470
 471 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
 472
 473 dnl ================== portability checks ===========================================
 474
 475 dnl for backtrace()
 476 AC_CHECK_HEADERS([execinfo.h])
 477
 478 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 479   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 480   ],[],[#include <langinfo.h>])
 481
 482 dnl ================== pdf checks ===================================================
 483 AC_ARG_ENABLE([pdf],
 484   [AS_HELP_STRING([--disable-pdf],
 485                   [Disable the PDF support])],
 486   [enable_pdf=$enableval],
 487   [enable_pdf=yes])
 488
 489 if test "x$enable_pdf" = "xyes"; then
 490     POPPLER_REQUIRED=0.12.0
 491     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED,enable_pdf=yes,enable_pdf=no)
 492
 493     if test "x$enable_pdf" = "xyes"; then
 494             evince_save_LIBS=$LIBS
 495             LIBS="$LIBS $POPPLER_LIBS"
 496             AC_CHECK_FUNCS(poppler_page_render)
 497             AC_CHECK_FUNCS(poppler_page_get_image)
 498             AC_CHECK_FUNCS(poppler_annot_file_attachment_get_attachment)
 499             LIBS=$evince_save_LIBS
 500
 501             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 502             if test x$enable_cairo_pdf = xyes; then
 503                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 504             fi
 505
 506             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 507             if test x$enable_cairo_ps = xyes; then
 508                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 509             fi
 510     else
 511             AC_MSG_ERROR("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 512     fi
 513 fi
 514
 515 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 516 dnl ================== end of pdf checks ============================================
 517
 518 dnl libspectre (used by ps and dvi backends)
 519 SPECTRE_REQUIRED=0.2.0
 520 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 521 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 522 if test "x$have_spectre" = "xyes"; then
 523    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 524 fi
 525
 526 dnl ================== ps checks ====================================================
 527 AC_ARG_ENABLE(ps,
 528         [AS_HELP_STRING([--disable-ps],
 529                         [Disable the PostScript backend])],
 530         [enable_ps=$enableval],
 531         [enable_ps=yes])
 532
 533 if test "x$enable_ps" = "xyes"; then
 534    if test "x$have_spectre" = "xyes"; then
 535       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 536    else
 537       enable_ps="no"
 538       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 539    fi
 540 fi
 541 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 542 dnl ======================== End of ps checks ===================================
 543
 544 dnl ================== tiff checks ===================================================
 545 AC_ARG_ENABLE(tiff,
 546             [AS_HELP_STRING([--disable-tiff],
 547                             [Disable the support of multipage tiff])],
 548             [enable_tiff=$enableval],
 549             [enable_tiff=yes])
 550
 551 if test "x$enable_tiff" = "xyes"; then
 552     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 553     if test "x$enable_tiff" = "xyes"; then
 554         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 555         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 556     fi
 557     if test "x$enable_tiff" = "xyes"; then
 558             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 559     else
 560             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 561     fi
 562 fi
 563
 564 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 565 dnl ================== end of tiff checks ============================================
 566
 567 dnl ================== djvu checks ===================================================
 568
 569 AC_ARG_ENABLE(djvu,
 570             [AS_HELP_STRING([--disable-djvu],
 571                             [Disable the support of djvu viewer])],
 572             [enable_djvu=$enableval],
 573             [enable_djvu=yes])
 574
 575 if test "x$enable_djvu" = "xyes"; then
 576     DJVULIBRE_REQUIRED=3.5.17
 577     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 578
 579     if test "x$enable_djvu" = "xyes"; then
 580         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 581     else
 582         AC_MSG_WARN([
 583 ** Djvu support is disabled since a recent version of the djvulibre
 584 ** library was not found. You need at least djvulibre-3.5.17 which
 585 ** can be found on http://djvulibre.djvuzone.org
 586 ])
 587     fi
 588 fi
 589
 590 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 591
 592 dnl ================== End of djvu checks ===================================================
 593
 594 dnl ================== dvi checks ===================================================
 595
 596 AC_ARG_ENABLE(dvi,
 597             [AS_HELP_STRING([--disable-dvi],
 598             [Disable the support of dvi viewer])],
 599             [enable_dvi=$enableval],
 600             [enable_dvi=yes])
 601
 602 AC_ARG_ENABLE(t1lib,
 603             [AS_HELP_STRING([--enable-t1lib],
 604                             [Compile with support of t1lib for type1 fonts in dvi])],
 605             [enable_type1_fonts=$enableval],
 606             [enable_type1_fonts=no])
 607
 608 if test "x$enable_dvi" = "xyes"; then
 609     AC_C_CONST
 610     AC_C_INLINE
 611     AC_TYPE_SIZE_T
 612     AC_CHECK_SIZEOF(long, 4)
 613     AC_CHECK_SIZEOF(int, 4)
 614     AC_CHECK_SIZEOF(short, 2)
 615     AC_CHECK_SIZEOF(void *, 4)
 616     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 617
 618     if test "x$enable_dvi" = "xyes"; then
 619         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 620     else
 621         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 622     fi
 623 fi
 624 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 625
 626 if test "x$enable_dvi" = "xyes"; then
 627     if test "x$enable_type1_fonts" = "xyes"; then
 628         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 629     fi
 630
 631     if test "x$enable_type1_fonts" = xyes; then
 632         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 633     fi
 634 else
 635     enable_type1_fonts=no
 636 fi
 637 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 638
 639 dnl ================== End of dvi checks ===================================================
 640
 641 dnl ================== pixbuf checks ===================================================
 642
 643 AC_ARG_ENABLE(pixbuf,
 644             [AS_HELP_STRING([--enable-pixbuf],
 645                             [Compile with support of pixbuf])],
 646             [enable_pixbuf=$enableval],
 647             [enable_pixbuf=no])
 648
 649 if test "x$enable_pixbuf" = "xyes"; then
 650         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 651 fi
 652
 653 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 654
 655 dnl ================== End of pixbuf checks ===================================================
 656
 657 dnl ================== comic book checks ===================================================
 658
 659 AC_ARG_ENABLE(comics,
 660         [AS_HELP_STRING([--enable-comics],
 661                         [Compile with support for comic book archives])],
 662         [enable_comics=$enableval],
 663         [enable_comics=yes])
 664
 665 if test "x$enable_comics" = "xyes"; then
 666         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 667 fi
 668 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 669
 670 dnl ================== End of comic book checks ============================================
 671
 672 dnl ================== impress book checks ===================================================
 673
 674 AC_ARG_ENABLE(impress,
 675         [AS_HELP_STRING([--enable-impress],
 676                         [Compile with support for impress presentations])],
 677         [enable_impress=$enableval],
 678         [enable_impress=no])
 679
 680 if test "x$enable_impress" = "xyes"; then
 681         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 682 fi
 683 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 684
 685 dnl ================== End of impress book checks ============================================
 686
 687 dnl =================== Mime types list ====================================================
 688
 689 if test "x$enable_pdf" = "xyes" ; then
 690         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 691 fi
 692 if test "x$enable_ps" = "xyes" ; then
 693         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 694 fi
 695 if test "x$enable_dvi" = "xyes"; then
 696         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 697 fi
 698 if test "x$enable_djvu" = "xyes"; then
 699         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 700 fi
 701 if test "x$enable_tiff" = "xyes"; then
 702         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 703 fi
 704 if test "x$enable_comics" = "xyes"; then
 705         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;application/x-cbt;"
 706 fi
 707 if test "x$enable_pixbuf" = "xyes"; then
 708         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 709 fi
 710 if test "x$enable_impress" = "xyes"; then
 711         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 712 fi
 713 AC_SUBST(EVINCE_MIME_TYPES)
 714
 715 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 716
 717 # *****************
 718 # Help files
 719 # *****************
 720
 721 GNOME_DOC_INIT([], gnome_doc_utils=yes, gnome_doc_utils=no)
 722
 723 AC_ARG_ENABLE(help,
 724     [AS_HELP_STRING([--disable-help], [Disable offline help files])],
 725     [enable_help=$enableval],
 726     [enable_help=yes])
 727
 728 if test "x$enable_help" = "xyes" && test "x$os_win32" = "xyes" ; then
 729     AC_MSG_WARN([Offline help is disabled (not implemented on Windows).])
 730     enable_help=no
 731 fi
 732
 733 if test "x$enable_help" = "xyes" && test "x$gnome_doc_utils" == "xno"; then
 734     AC_MSG_ERROR(
 735        [gnome-doc-utils not found; use --disable-help to disable help files]
 736     )
 737 fi
 738
 739 if test "x$enable_help" = "xyes"; then
 740     AC_DEFINE([OFFLINE_HELP_ENABLED], [1], [Enable offline help])
 741 fi
 742
 743 AM_CONDITIONAL(ENABLE_HELP, test "x$enable_help" = "xyes")
 744
 745 # *****************
 746 # API documentation
 747 # *****************
 748
 749 GTK_DOC_CHECK([1.13],[--flavour no-tmpl])
 750
 751 AC_SUBST([GLIB_PREFIX],[$($PKG_CONFIG --variable=prefix glib-2.0)])
 752 AC_SUBST([GTK_PREFIX],[$($PKG_CONFIG --variable=prefix gtk+-2.0)])
 753
 754 # ******************
 755 # Backends directory
 756 # ******************
 757
 758 AC_SUBST([backenddir],"\$(libdir)/evince/ev_binary_version/backends")
 759 AC_SUBST([backend_binary_version],"ev_binary_version")
 760
 761 # **********
 762 # Versioning
 763 # **********
 764
 765 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
 766 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
 767 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
 768
 769 AC_SUBST([EV_API_VERSION],[ev_api_version])
 770 AC_SUBST([EV_API_VERSION_U],[AS_TR_SH([ev_api_version])])
 771 AC_SUBST([EV_BINARY_VERSION],[ev_binary_version])
 772
 773 AC_SUBST([EV_DOCUMENT_LT_VERSION_INFO],[ev_document_lt_version_info])
 774 AC_SUBST([EV_DOCUMENT_LT_CURRENT_MINUS_AGE],[ev_document_lt_current_minus_age])
 775 AC_SUBST([EV_VIEW_LT_VERSION_INFO],[ev_view_lt_version_info])
 776 AC_SUBST([EV_VIEW_LT_CURRENT_MINUS_AGE],[ev_view_lt_current_minus_age])
 777
 778 # *****************************************************************************
 779 # *****************************************************************************
 780
 781 AC_CONFIG_FILES([
 782 backend/Makefile
 783 backend/comics/Makefile
 784 backend/djvu/Makefile
 785 backend/dvi/Makefile
 786 backend/dvi/mdvi-lib/Makefile
 787 backend/impress/Makefile
 788 backend/pdf/Makefile
 789 backend/pixbuf/Makefile
 790 backend/ps/Makefile
 791 backend/tiff/Makefile
 792 cut-n-paste/Makefile
 793 cut-n-paste/gimpcellrenderertoggle/Makefile
 794 cut-n-paste/smclient/Makefile
 795 cut-n-paste/toolbar-editor/Makefile
 796 cut-n-paste/zoom-control/Makefile
 797 cut-n-paste/totem-screensaver/Makefile
 798 data/evince.desktop.in
 799 data/Makefile
 800 data/icons/Makefile
 801 data/icons/16x16/Makefile
 802 data/icons/16x16/apps/Makefile
 803 data/icons/16x16/actions/Makefile
 804 data/icons/16x16/mimetypes/Makefile
 805 data/icons/22x22/Makefile
 806 data/icons/22x22/apps/Makefile
 807 data/icons/22x22/actions/Makefile
 808 data/icons/22x22/mimetypes/Makefile
 809 data/icons/24x24/Makefile
 810 data/icons/24x24/apps/Makefile
 811 data/icons/24x24/actions/Makefile
 812 data/icons/24x24/mimetypes/Makefile
 813 data/icons/32x32/Makefile
 814 data/icons/32x32/actions/Makefile
 815 data/icons/32x32/mimetypes/Makefile
 816 data/icons/48x48/Makefile
 817 data/icons/48x48/apps/Makefile
 818 data/icons/48x48/actions/Makefile
 819 data/icons/scalable/Makefile
 820 data/icons/scalable/apps/Makefile
 821 data/icons/scalable/actions/Makefile
 822 data/icons/scalable/mimetypes/Makefile
 823 help/Makefile
 824 help/reference/Makefile
 825 help/reference/libdocument/Makefile
 826 help/reference/libdocument/version.xml
 827 help/reference/libview/Makefile
 828 help/reference/libview/version.xml
 829 help/reference/shell/Makefile
 830 help/reference/shell/version.xml
 831 libdocument/Makefile
 832 libdocument/ev-version.h
 833 libmisc/Makefile
 834 libview/Makefile
 835 Makefile
 836 po/Makefile.in
 837 previewer/Makefile
 838 properties/Makefile
 839 shell/Makefile
 840 test/Makefile
 841 thumbnailer/Makefile
 842 ])
 843
 844 AC_CONFIG_FILES(evince-document-[]ev_api_version[].pc:evince-document.pc.in)
 845 AC_CONFIG_FILES(evince-view-[]ev_api_version[].pc:evince-view.pc.in)
 846
 847 AC_OUTPUT
 848
 849 echo "
 850 Configure summary:
 851         Platform...........:  $with_platform
 852         GConf Support......:  $with_gconf
 853         GTK+ Unix Print....:  $with_gtk_unix_print
 854         Keyring Support....:  $with_keyring
 855         DBUS Support.......:  $enable_dbus
 856         SM client support..:  $with_smclient
 857         Help files.........:  $enable_help
 858         Nautilus Plugin....:  $enable_nautilus
 859         Thumbnailer........:  $enable_thumbnailer
 860         Previewer..........:  $enable_previewer
 861         Gtk-Doc Support....:  $enable_gtk_doc
 862         Debug mode.........:  $enable_debug
 863         GObj. Introspection:  $enable_introspection
 864         Tests..............:  $enable_tests
 865
 866         PDF Backend........:  $enable_pdf
 867         PostScript Backend.:  $enable_ps
 868         TIFF Backend.......:  $enable_tiff
 869         DJVU Backend.......:  $enable_djvu
 870         DVI Backend........:  $enable_dvi
 871         Pixbuf Backend.....:  $enable_pixbuf
 872         Comics Backend.....:  $enable_comics
 873         Impress Backend....:  $enable_impress
 874 "