]> www.fi.muni.cz Git - evince.git/blob - configure.ac
[release] 2.31.5
[evince.git] / configure.ac
1 # *****************************************************************************
2 # Versioning
3 # *****************************************************************************
4
5 m4_define([ev_major_version],[2])
6 m4_define([ev_minor_version],[31])
7 m4_define([ev_micro_version],[5])
8 m4_define([ev_extra_version],[])
9 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version()ev_extra_version])
10
11 # The evince API version
12 m4_define([ev_api_version], [2.30])
13
14 # Libtool versioning. The backend and view libraries have separate versions.
15 # Before making a release, the libtool version should be modified.
16 # The string is of the form C:R:A.
17 # - If interfaces have been changed or added, but binary compatibility has
18 #   been preserved, change to C+1:0:A+1
19 # - If binary compatibility has been broken (eg removed or changed interfaces)
20 #   change to C+1:0:0
21 # - If the interface is the same as the previous version, change to C:R+1:A
22
23 # Libtool version of the backend library
24 m4_define([ev_document_lt_current],[2])
25 m4_define([ev_document_lt_revision],[0])
26 m4_define([ev_document_lt_age],[0])
27 m4_define([ev_document_lt_version_info],[ev_document_lt_current:ev_document_lt_revision:ev_document_lt_age])
28 m4_define([ev_document_lt_current_minus_age],[m4_eval(ev_document_lt_current - ev_document_lt_age)])
29
30 # Libtool version of the view library
31 m4_define([ev_view_lt_current],[2])
32 m4_define([ev_view_lt_revision],[0])
33 m4_define([ev_view_lt_age],[0])
34 m4_define([ev_view_lt_version_info],[ev_view_lt_current:ev_view_lt_revision:ev_view_lt_age])
35 m4_define([ev_view_lt_current_minus_age],[m4_eval(ev_view_lt_current - ev_view_lt_age)])
36
37 # Binary version for the document backends
38 m4_define([ev_binary_version],[ev_document_lt_current])
39
40 # *****************************************************************************
41
42 AC_PREREQ([2.57])
43 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
44 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2 no-dist-gzip])
45
46 AC_CONFIG_HEADERS([config.h])
47 AC_CONFIG_MACRO_DIR([m4])
48
49 if test -z "$enable_maintainer_mode"; then
50   enable_maintainer_mode=yes
51 fi
52 AM_MAINTAINER_MODE([enable])
53
54 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
55
56 AM_PROG_LIBTOOL
57
58 AC_ISC_POSIX
59 AC_PROG_CC
60 AM_PROG_CC_STDC
61 AM_PROG_CC_C_O
62 AC_PROG_CXX
63 AC_STDC_HEADERS
64
65 AC_PROG_SED
66 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
67 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
68
69 GNOME_MAINTAINER_MODE_DEFINES
70 GNOME_COMPILE_WARNINGS
71 GNOME_CXX_WARNINGS
72
73 dnl FIXME: remove this when required gtk+ >= 2.19.7
74 DISABLE_DEPRECATED=
75 AC_SUBST([DISABLE_DEPRECATED])
76
77 IT_PROG_INTLTOOL([0.35.0])
78
79 GETTEXT_PACKAGE=evince
80 AC_SUBST(GETTEXT_PACKAGE)
81 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
82 AM_GLIB_GNU_GETTEXT
83
84 m4_pattern_allow([AM_V_GEN])dnl Make autoconf not complain about the rule below
85 EV_INTLTOOL_EVINCE_BACKEND_RULE='%.evince-backend:   %.evince-backend.in   $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; $(AM_V_GEN) LC_ALL=C $(INTLTOOL_MERGE) -d -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@'
86 AC_SUBST([EV_INTLTOOL_EVINCE_BACKEND_RULE])
87
88 GLIB_GSETTINGS
89
90 # Check which platform to use
91
92 AC_MSG_CHECKING([for which platform to build])
93 AC_ARG_WITH([platform],
94   [AS_HELP_STRING([--with-platform=gnome|win32|hildon],
95                   [Setting platform (default: gnome)])],
96   [case "$withval" in
97     gnome|win32|hildon) ;;
98     *) AC_MSG_ERROR([invalid argument "$withval" for --with-platform]) ;;
99    esac],
100   [case "$host" in
101      *-*-mingw*|*-*-cygwin*) with_platform="win32" ;;
102      *) with_platform=gnome ;;
103    esac])
104
105 AC_MSG_RESULT([$with_platform])
106
107 if test "$with_platform" = "win32"; then
108   AC_CHECK_TOOL([WINDRES],[windres])
109   AC_MSG_CHECKING([for native Win32])
110   case "$host" in
111     *-*-mingw*)
112       os_win32=yes
113       ;;
114     *)
115       os_win32=no
116       ;;
117   esac
118   AC_MSG_RESULT([$os_win32])
119 fi
120
121 AM_CONDITIONAL([PLATFORM_HILDON],[test "$with_platform" = "hildon"])
122 AM_CONDITIONAL([PLATFORM_WIN32],[test "$with_platform" = "win32"])
123
124 dnl Specify required versions of dependencies
125 GTK_REQUIRED=2.90.5
126 GLIB_REQUIRED=2.25.11
127 KEYRING_REQUIRED=2.22.0
128 AC_SUBST([GLIB_REQUIRED])
129 AC_SUBST([GTK_REQUIRED])
130
131 GNOME_ICON_THEME_REQUIRED=2.17.1
132 LIBXML_REQUIRED=2.5.0
133
134 dnl Check dependencies
135
136 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
137 # BACKEND_CFLAGS   for backend implementations.
138 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
139 # FRONTEND_LIBS
140 # SHELL_CFLAGS     for shell implementation.
141 # SHELL_LIBS
142
143
144 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-3.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
145 PKG_CHECK_MODULES(LIBVIEW, gtk+-3.0 >= $GTK_REQUIRED gail-3.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
146 PKG_CHECK_MODULES(BACKEND, gtk+-3.0 >= $GTK_REQUIRED)
147 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-3.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
148 PKG_CHECK_MODULES(PREVIEWER, gtk+-3.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
149
150 SHELL_PLATFORM_PKGS=
151 case "$with_platform" in
152   hildon) AC_DEFINE([PLATFORM_HILDON],[1],[Define if building for the hildon platform])
153           SHELL_PLATFORM_PKGS="hildon-1 hildon-fm-2 libosso"
154           ;;
155   gnome)
156         # Evince has a rather soft run-time dependency on hicolor-icon-theme.
157         # If the hicolor theme is not available, Evince fails to display some
158         # icons. Because we cannot check for it at run-time, we instead
159         # would like to require the icon theme at compile-time. But, because
160         # the hicolor-icon-theme does not have a pkgconfig file, on gnome we
161         # require the gnome icon theme instead.
162         SHELL_PLATFORM_PKGS="gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED"
163         # The totem-screensaver and egg_smclient code use x11 directly.
164         SHELL_PLATFORM_PKGS="$SHELL_PLATFORM_PKGS x11"
165         ;;
166   *)
167         # On all other platforms we issue a warning about the runtime
168         # dependency.
169         AC_MSG_WARN([Evince has a soft run-time dependency on hicolor-icon-theme. You are advised to have this theme installed when running Evince.]);
170         SHELL_PLATFORM_PKGS=""
171         ;;
172 esac
173
174 PKG_CHECK_MODULES([SHELL_CORE],[libxml-2.0 >= $LIBXML_REQUIRED gtk+-3.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gthread-2.0 $SHELL_PLATFORM_PKGS])
175
176 # *********
177 # SM client
178 # *********
179
180 GDK_TARGET="$($PKG_CONFIG --variable target gdk-3.0)"
181
182 AC_MSG_CHECKING([which smclient backend to use])
183 AC_ARG_WITH([smclient],
184   [AS_HELP_STRING([--with-smclient-backend=no|xsmp|win32|quartz],
185                   [Setting smclient backend (default:auto)])],
186   [],
187   [case "$GDK_TARGET" in
188     x11) case "$with_platform" in
189            gnome) with_smclient=xsmp ;;
190            *) with_smclient=no ;;
191          esac ;;
192     win32|quartz) with_smclient=$GDK_TARGET ;;
193     *) with_smclient=no ;;
194    esac])
195    
196 AC_MSG_RESULT([$with_smclient])
197
198 if test "$with_smclient" != "no"; then
199   AC_DEFINE([WITH_SMCLIENT],[1],[Define if smclient is enabled])
200
201   case "$with_smclient" in
202     xsmp) SMCLIENT_PKGS="sm >= 1.0.0" ;;
203     *) SMCLIENT_PKGS="" ;;
204   esac
205
206   PKG_CHECK_MODULES([SMCLIENT],[gtk+-3.0 gthread-2.0 $SMCLIENT_PKGS])
207   AC_SUBST([SMCLIENT_CFLAGS])
208   AC_SUBST([SMCLIENT_LIBS])
209 fi
210
211 AM_CONDITIONAL([WITH_SMCLIENT],[test "$with_smclient" != "no"])
212 AM_CONDITIONAL([WITH_SMCLIENT_XSMP],[test "$with_smclient" = "xsmp"])
213 AM_CONDITIONAL([WITH_SMCLIENT_WIN32],[test "$with_smclient" = "win32"])
214 AM_CONDITIONAL([WITH_SMCLIENT_QUARTZ],[test "$with_smclient" = "quartz"])
215
216 # ***
217
218 BACKEND_LIBTOOL_FLAGS="-module -avoid-version -no-undefined -export-symbols \$(top_srcdir)/backend/backend.symbols"
219 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
220
221 dnl ===== Check special functions
222 evince_save_LIBS=$LIBS
223 LIBS="$LIBS $BACKEND_LIBS"
224 AC_CHECK_FUNCS(cairo_format_stride_for_width)
225 LIBS=$evince_save_LIBS
226
227 # ******************
228 # GKT+ Unix Printing
229 # ******************
230
231 AC_MSG_CHECKING([whether gtk+-unix-print support is requested])
232 AC_ARG_WITH([gtk-unix-print],
233   [AS_HELP_STRING([--without-gtk-unix-print],
234                   [Disable the use of gtk-unix-print])],
235   [],[case "$os_win32" in
236         yes) with_gtk_unix_print=no ;;
237         *) with_gtk_unix_print=yes ;;
238       esac])
239       
240 AC_MSG_RESULT([$with_gtk_unix_print])
241
242 if test "$with_gtk_unix_print" = "yes"; then
243    PKG_CHECK_MODULES(GTKUNIXPRINT, [gtk+-unix-print-3.0 >= $GTK_REQUIRED])
244    AC_DEFINE([GTKUNIXPRINT_ENABLED], [1], [Define if gtk+-unix-print is enabled.])
245 fi
246
247 # *********************
248 # GNOME Keyring support
249 # *********************
250
251 AC_ARG_WITH(keyring,
252         [AS_HELP_STRING([--without-keyring],
253                         [Disable the use of gnome-keyring])],
254         [],
255         [case "$with_platform" in
256            gnome) with_keyring=yes ;;
257            hildon|win32) with_keyring=no ;;
258          esac])
259
260 AM_CONDITIONAL([WITH_KEYRING],[test "$with_keyring" = "yes"])
261
262 if test "$with_keyring" = "yes"; then
263         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
264         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
265 fi
266
267 # ****
268 # DBUS
269 # ****
270
271 AC_ARG_ENABLE([dbus],
272   [AS_HELP_STRING([--disable-dbus], [Disable support for dbus])],
273   [],
274   [case "$with_platform" in
275       gnome) enable_dbus=yes ;;
276       hildon) enable_dbus=no ;;
277     esac])
278
279 if test "$enable_dbus" = "yes"; then
280   AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
281
282    PKG_CHECK_MODULES([EV_DAEMON], [gio-2.0 >= $GLIB_REQUIRED])
283 fi
284
285 AM_CONDITIONAL([ENABLE_DBUS], [test "$enable_dbus" = "yes"])
286
287 dnl ========= Check for GConf
288
289 AC_MSG_CHECKING([whether GConf support is requested])
290 AC_ARG_WITH([gconf],
291   [AS_HELP_STRING([--without-gconf],
292                   [Disable the use of gconf])],
293   [],
294   [case "$os_win32" in
295      yes) with_gconf=no ;;
296      *) with_gconf=yes ;;
297    esac])
298 AC_MSG_RESULT([$with_gconf])
299
300 AM_CONDITIONAL([WITH_GCONF],[test "$with_gconf" = "yes"])
301
302 if test "$with_gconf" = "yes"; then
303    PKG_CHECK_MODULES([GCONF],[gconf-2.0])
304    AC_DEFINE([WITH_GCONF],[1],[Define if GConf support is enabled])
305
306    AM_GCONF_SOURCE_2
307
308    AC_PATH_PROG([GCONFTOOL], [gconftool-2], [false])
309    if test "$GCONFTOOL" = "false"; then
310       AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
311    fi
312 else
313    AM_CONDITIONAL([GCONF_SCHEMAS_INSTALL],false)
314 fi
315
316 dnl Debug mode
317
318 AC_ARG_ENABLE([debug],
319         AS_HELP_STRING([--enable-debug],
320                        [Turn on evince debug mode]),
321         [enable_debug=$enableval],
322         [enable_debug=no])
323
324 if test "x$enable_debug" = "xyes"; then
325    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
326 fi
327
328 AC_ARG_ENABLE([tests],
329         AS_HELP_STRING([--enable-tests], [Enable the tests]),
330         [enable_tests=$enableval],
331         [enable_tests=yes])
332
333 AM_CONDITIONAL(ENABLE_TESTS, test x$enable_tests = xyes)
334
335 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
336 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
337 AC_SUBST(LIBDOCUMENT_CFLAGS)
338 AC_SUBST(LIBDOCUMENT_LIBS)
339
340 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
341 LIBVIEW_LIBS="$LIBVIEW_LIBS $GTKUNIXPRINT_LIBS -lm"
342 AC_SUBST(LIBVIEW_CFLAGS)
343 AC_SUBST(LIBVIEW_LIBS)
344
345 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
346 BACKEND_LIBS="$BACKEND_LIBS -lm"
347 AC_SUBST(BACKEND_CFLAGS)
348 AC_SUBST(BACKEND_LIBS)
349
350 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $KEYRING_CFLAGS $GCONF_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
351 SHELL_LIBS="$SHELL_CORE_LIBS $KEYRING_LIBS $GCONF_LIBS -lz -lm"
352 AC_SUBST(SHELL_CFLAGS)
353 AC_SUBST(SHELL_LIBS)
354
355 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
356 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
357 AC_SUBST(FRONTEND_CFLAGS)
358 AC_SUBST(FRONTEND_LIBS)
359
360 EV_DAEMON_CFLAGS="$EV_DAEMON_CFLAGS $DEBUG_FLAGS"
361 AC_SUBST([EV_DAEMON_CFLAGS])
362 AC_SUBST([EV_DAEMON_LIBS])
363
364 # Check for Nautilus property page build
365 AC_ARG_ENABLE([nautilus],
366   [AS_HELP_STRING([--disable-nautilus],
367                   [Disable build of nautilus extensions])],
368   [],
369   [case "$with_platform" in
370      gnome) enable_nautilus=yes ;;
371      *) enable_nautilus=no ;;
372     esac])
373
374 if test "$enable_nautilus" = "yes" ; then
375   PKG_CHECK_MODULES([NAUTILUS],[gtk+-x11-3.0 $MM gthread-2.0 libnautilus-extension],
376                     [],[AC_MSG_ERROR([libnautilus-extension not found; use --disable-nautilus to disable the nautilus extensions])])
377   NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
378   AC_SUBST([nautilusextensiondir],[$NAUTILUS_EXTENSION_DIR])
379   AC_SUBST(NAUTILUS_CFLAGS)
380   AC_SUBST(NAUTILUS_LIBS)
381
382   AC_DEFINE([HAVE_NAUTILUS],[1], [defined if you build the nautilus plugin])
383 fi
384
385 AM_CONDITIONAL([ENABLE_NAUTILUS],[test "$enable_nautilus" = "yes"])
386
387 # Check for thumbnailer build
388
389 AC_ARG_ENABLE([thumbnailer],
390   [AS_HELP_STRING([--disable-thumbnailer],
391                   [Disable GNOME thumbnailer])],
392   [],
393   [case "$with_platform" in
394      gnome) enable_thumbnailer=yes ;;
395      *) enable_thumbnailer=no ;;
396     esac])
397
398 AM_CONDITIONAL([ENABLE_THUMBNAILER],[test "$enable_thumbnailer" = "yes"])
399
400 # ***************
401 # Print Previewer
402 # ***************
403
404 AC_ARG_ENABLE([previewer],
405   [AS_HELP_STRING([--disable-previewer],
406                   [Disable the GNOME Document Previewer])],
407   [],
408   [case "$with_platform" in
409       gnome) enable_previewer=yes ;;
410       *) enable_previewer=no ;;
411     esac])
412
413 if test x$enable_previewer = "xyes" ; then
414   PKG_CHECK_MODULES([PREVIEWER],[gtk+-3.0 >= $GTK_REQUIRED gtk+-unix-print-3.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED])
415 fi
416
417 AM_CONDITIONAL([ENABLE_PREVIEWER],[test "$enable_previewer" = "yes"])
418 PREVIEWER_CFLAGS="$PREVIEWER_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
419 PREVIEWER_LIBS="$PREVIEWER_LIBS $GTKUNIXPRINT_LIBS -lz"
420 AC_SUBST(PREVIEWER_CFLAGS)
421 AC_SUBST(PREVIEWER_LIBS)
422
423 # ***
424 # GIR
425 # ***
426
427 AC_MSG_CHECKING([whether GObject introspection is requested])
428 AC_ARG_ENABLE([introspection],
429         AS_HELP_STRING([--enable-introspection],
430                        [Enable GObject introspection]),
431         [enable_introspection=$enableval],
432         [enable_introspection=no])
433 AC_MSG_RESULT([$enable_introspection])
434
435 G_IR_SCANNER=
436 G_IR_COMPILER=
437 G_IR_GENERATE=
438 GIRDIR=
439 GIRTYPELIBDIR=
440
441 if test "$enable_introspection" = "yes"; then
442   GOBJECT_INTROSPECTION_REQUIRED=0.6
443   PKG_CHECK_MODULES([GOBJECT_INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
444
445   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
446   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
447   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
448   GIRDIR="$($PKG_CONFIG --variable=girdir gobject-introspection-1.0)"
449   GIRTYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
450 fi
451
452 AC_SUBST([G_IR_SCANNER])
453 AC_SUBST([G_IR_COMPILER])
454 AC_SUBST([G_IR_GENERATE])
455 AC_SUBST([GIRDIR])
456 AC_SUBST([GIRTYPELIBDIR])
457
458 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
459
460 dnl ================== portability checks ===========================================
461
462 dnl for backtrace()
463 AC_CHECK_HEADERS([execinfo.h])
464
465 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
466   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
467   ],[],[#include <langinfo.h>])
468
469 dnl ================== pdf checks ===================================================
470 AC_ARG_ENABLE([pdf],
471   [AS_HELP_STRING([--disable-pdf],
472                   [Disable the PDF support])],
473   [enable_pdf=$enableval],
474   [enable_pdf=yes])
475
476 if test "x$enable_pdf" = "xyes"; then
477     POPPLER_REQUIRED=0.14.0
478     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED,enable_pdf=yes,enable_pdf=no)
479
480     if test "x$enable_pdf" = "xyes"; then
481             evince_save_LIBS=$LIBS
482             LIBS="$LIBS $POPPLER_LIBS"
483             AC_CHECK_FUNCS(poppler_page_get_text_layout)
484             AC_CHECK_FUNCS(poppler_page_get_selected_text)
485             LIBS=$evince_save_LIBS
486             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
487             if test x$enable_cairo_pdf = xyes; then
488                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
489             fi
490
491             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
492             if test x$enable_cairo_ps = xyes; then
493                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
494             fi
495     else
496             AC_MSG_ERROR("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
497     fi 
498 fi
499
500 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
501 dnl ================== end of pdf checks ============================================
502
503 dnl libspectre (used by ps and dvi backends)
504 SPECTRE_REQUIRED=0.2.0 
505 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
506 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
507 if test "x$have_spectre" = "xyes"; then
508    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
509 fi
510
511 dnl ================== ps checks ====================================================
512 AC_ARG_ENABLE(ps,
513         [AS_HELP_STRING([--disable-ps],
514                         [Disable the PostScript backend])],
515         [enable_ps=$enableval],
516         [enable_ps=yes])
517
518 if test "x$enable_ps" = "xyes"; then
519    if test "x$have_spectre" = "xyes"; then
520       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
521    else
522       enable_ps="no"
523       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
524    fi
525 fi
526 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
527 dnl ======================== End of ps checks ===================================
528
529 dnl ================== tiff checks ===================================================
530 AC_ARG_ENABLE(tiff,
531             [AS_HELP_STRING([--disable-tiff],
532                             [Disable the support of multipage tiff])],
533             [enable_tiff=$enableval],
534             [enable_tiff=yes])
535
536 if test "x$enable_tiff" = "xyes"; then
537     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
538     if test "x$enable_tiff" = "xyes"; then
539         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
540         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
541     fi
542     if test "x$enable_tiff" = "xyes"; then
543             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
544     else
545             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
546     fi 
547 fi
548
549 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
550 dnl ================== end of tiff checks ============================================
551
552 dnl ================== djvu checks ===================================================
553
554 AC_ARG_ENABLE(djvu,
555             [AS_HELP_STRING([--disable-djvu],
556                             [Disable the support of djvu viewer])],
557             [enable_djvu=$enableval],
558             [enable_djvu=yes])
559
560 if test "x$enable_djvu" = "xyes"; then
561     DJVULIBRE_REQUIRED=3.5.17
562     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
563
564     if test "x$enable_djvu" = "xyes"; then
565         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
566     else
567         AC_MSG_WARN([   
568 ** Djvu support is disabled since a recent version of the djvulibre 
569 ** library was not found. You need at least djvulibre-3.5.17 which 
570 ** can be found on http://djvulibre.djvuzone.org 
571 ])
572     fi 
573 fi
574
575 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
576
577 dnl ================== End of djvu checks ===================================================
578
579 dnl ================== dvi checks ===================================================
580
581 AC_ARG_ENABLE(dvi,
582             [AS_HELP_STRING([--disable-dvi],
583             [Disable the support of dvi viewer])],
584             [enable_dvi=$enableval],
585             [enable_dvi=yes])
586
587 AC_ARG_ENABLE(t1lib,
588             [AS_HELP_STRING([--enable-t1lib],
589                             [Compile with support of t1lib for type1 fonts in dvi])],
590             [enable_type1_fonts=$enableval],
591             [enable_type1_fonts=no])
592
593 if test "x$enable_dvi" = "xyes"; then
594     AC_C_CONST
595     AC_C_INLINE
596     AC_TYPE_SIZE_T
597     AC_CHECK_SIZEOF(long, 4)
598     AC_CHECK_SIZEOF(int, 4)
599     AC_CHECK_SIZEOF(short, 2)
600     AC_CHECK_SIZEOF(void *, 4)
601     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
602
603     if test "x$enable_dvi" = "xyes"; then
604         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
605     else
606         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
607     fi
608 fi
609 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
610
611 if test "x$enable_dvi" = "xyes"; then
612     if test "x$enable_type1_fonts" = "xyes"; then
613         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
614     fi
615
616     if test "x$enable_type1_fonts" = xyes; then
617         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
618     fi
619 else 
620     enable_type1_fonts=no
621 fi
622 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
623
624 dnl ================== End of dvi checks ===================================================
625
626 dnl ================== pixbuf checks ===================================================
627
628 AC_ARG_ENABLE(pixbuf,
629             [AS_HELP_STRING([--enable-pixbuf],
630                             [Compile with support of pixbuf])],
631             [enable_pixbuf=$enableval],
632             [enable_pixbuf=no])
633             
634 if test "x$enable_pixbuf" = "xyes"; then
635         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
636 fi
637
638 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
639
640 dnl ================== End of pixbuf checks ===================================================
641
642 dnl ================== comic book checks ===================================================
643  
644 AC_ARG_ENABLE(comics,
645         [AS_HELP_STRING([--enable-comics],
646                         [Compile with support for comic book archives])],
647         [enable_comics=$enableval],
648         [enable_comics=yes])
649         
650 if test "x$enable_comics" = "xyes"; then
651         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
652 fi
653 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
654
655 dnl ================== End of comic book checks ============================================
656
657 dnl ================== impress book checks ===================================================
658
659 AC_ARG_ENABLE(impress,
660         [AS_HELP_STRING([--enable-impress],
661                         [Compile with support for impress presentations])],
662         [enable_impress=$enableval],
663         [enable_impress=no])
664         
665 if test "x$enable_impress" = "xyes"; then
666         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
667 fi 
668 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
669
670 dnl ================== End of impress book checks ============================================
671
672 dnl =================== Mime types list ====================================================
673
674 if test "x$enable_pdf" = "xyes" ; then
675         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
676 fi
677 if test "x$enable_ps" = "xyes" ; then
678         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
679 fi
680 if test "x$enable_dvi" = "xyes"; then
681         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
682 fi
683 if test "x$enable_djvu" = "xyes"; then
684         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
685 fi
686 if test "x$enable_tiff" = "xyes"; then
687         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
688 fi
689 if test "x$enable_comics" = "xyes"; then
690         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;application/x-cbt;"
691 fi
692 if test "x$enable_pixbuf" = "xyes"; then
693         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
694 fi
695 if test "x$enable_impress" = "xyes"; then
696         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
697 fi
698 AC_SUBST(EVINCE_MIME_TYPES)
699
700 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
701
702 # *****************
703 # Help files
704 # *****************
705
706 GNOME_DOC_INIT([], gnome_doc_utils=yes, gnome_doc_utils=no)
707
708 AC_ARG_ENABLE(help,
709     [AS_HELP_STRING([--disable-help], [Disable offline help files])],
710     [enable_help=$enableval],
711     [enable_help=yes])
712
713 if test "x$enable_help" = "xyes" && test "x$os_win32" = "xyes" ; then
714     AC_MSG_WARN([Offline help is disabled (not implemented on Windows).])
715     enable_help=no
716 fi
717
718 if test "x$enable_help" = "xyes" && test "x$gnome_doc_utils" == "xno"; then
719     AC_MSG_ERROR(
720        [gnome-doc-utils not found; use --disable-help to disable help files]
721     )
722 fi
723
724 if test "x$enable_help" = "xyes"; then
725     AC_DEFINE([OFFLINE_HELP_ENABLED], [1], [Enable offline help])
726 fi
727
728 AM_CONDITIONAL(ENABLE_HELP, test "x$enable_help" = "xyes")
729
730 # *****************
731 # API documentation
732 # *****************
733
734 GTK_DOC_CHECK([1.13],[--flavour no-tmpl])
735
736 AC_SUBST([GLIB_PREFIX],[$($PKG_CONFIG --variable=prefix glib-2.0)])
737 AC_SUBST([GTK_PREFIX],[$($PKG_CONFIG --variable=prefix gtk+-3.0)])
738
739 # ******************
740 # Backends directory
741 # ******************
742
743 AC_SUBST([backenddir],"\$(libdir)/evince/ev_binary_version/backends")
744 AC_SUBST([backend_binary_version],"ev_binary_version")
745
746 # **********
747 # Versioning
748 # **********
749
750 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
751 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
752 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
753
754 AC_SUBST([EV_API_VERSION],[ev_api_version])
755 AC_SUBST([EV_API_VERSION_U],[AS_TR_SH([ev_api_version])])
756 AC_SUBST([EV_BINARY_VERSION],[ev_binary_version])
757
758 AC_SUBST([EV_DOCUMENT_LT_VERSION_INFO],[ev_document_lt_version_info])
759 AC_SUBST([EV_DOCUMENT_LT_CURRENT_MINUS_AGE],[ev_document_lt_current_minus_age])
760 AC_SUBST([EV_VIEW_LT_VERSION_INFO],[ev_view_lt_version_info])
761 AC_SUBST([EV_VIEW_LT_CURRENT_MINUS_AGE],[ev_view_lt_current_minus_age])
762
763 # *****************************************************************************
764 # *****************************************************************************
765
766 AC_CONFIG_FILES([
767 backend/Makefile
768 backend/comics/Makefile
769 backend/djvu/Makefile
770 backend/dvi/Makefile
771 backend/dvi/mdvi-lib/Makefile
772 backend/impress/Makefile
773 backend/pdf/Makefile
774 backend/pixbuf/Makefile
775 backend/ps/Makefile
776 backend/tiff/Makefile
777 cut-n-paste/Makefile
778 cut-n-paste/gimpcellrenderertoggle/Makefile
779 cut-n-paste/smclient/Makefile
780 cut-n-paste/toolbar-editor/Makefile
781 cut-n-paste/zoom-control/Makefile
782 cut-n-paste/totem-screensaver/Makefile
783 cut-n-paste/synctex/Makefile
784 data/evince.desktop.in
785 data/Makefile
786 data/icons/Makefile
787 data/icons/16x16/Makefile
788 data/icons/16x16/apps/Makefile
789 data/icons/16x16/actions/Makefile
790 data/icons/16x16/mimetypes/Makefile
791 data/icons/22x22/Makefile
792 data/icons/22x22/apps/Makefile
793 data/icons/22x22/actions/Makefile
794 data/icons/22x22/mimetypes/Makefile
795 data/icons/24x24/Makefile
796 data/icons/24x24/apps/Makefile
797 data/icons/24x24/actions/Makefile
798 data/icons/24x24/mimetypes/Makefile
799 data/icons/32x32/Makefile
800 data/icons/32x32/actions/Makefile
801 data/icons/32x32/mimetypes/Makefile
802 data/icons/48x48/Makefile
803 data/icons/48x48/apps/Makefile
804 data/icons/48x48/actions/Makefile
805 data/icons/scalable/Makefile
806 data/icons/scalable/apps/Makefile
807 data/icons/scalable/actions/Makefile
808 data/icons/scalable/mimetypes/Makefile
809 help/Makefile
810 help/reference/Makefile
811 help/reference/libdocument/Makefile
812 help/reference/libdocument/version.xml
813 help/reference/libview/Makefile
814 help/reference/libview/version.xml
815 help/reference/shell/Makefile
816 help/reference/shell/version.xml
817 libdocument/Makefile
818 libdocument/ev-version.h
819 libmisc/Makefile
820 libview/Makefile
821 Makefile
822 po/Makefile.in
823 previewer/Makefile
824 properties/Makefile
825 shell/Makefile
826 test/Makefile
827 thumbnailer/Makefile
828 ])
829
830 AC_CONFIG_FILES(evince-document-[]ev_api_version[].pc:evince-document.pc.in)
831 AC_CONFIG_FILES(evince-view-[]ev_api_version[].pc:evince-view.pc.in)
832
833 AC_OUTPUT
834
835 echo "
836 Configure summary:
837         Platform...........:  $with_platform
838         GConf Support......:  $with_gconf
839         GTK+ Unix Print....:  $with_gtk_unix_print
840         Keyring Support....:  $with_keyring
841         DBUS Support.......:  $enable_dbus
842         SM client support..:  $with_smclient
843         Help files.........:  $enable_help
844         Nautilus Plugin....:  $enable_nautilus
845         Thumbnailer........:  $enable_thumbnailer
846         Previewer..........:  $enable_previewer
847         Gtk-Doc Support....:  $enable_gtk_doc
848         Debug mode.........:  $enable_debug
849         GObj. Introspection:  $enable_introspection
850         Tests..............:  $enable_tests
851
852         PDF Backend........:  $enable_pdf
853         PostScript Backend.:  $enable_ps
854         TIFF Backend.......:  $enable_tiff
855         DJVU Backend.......:  $enable_djvu
856         DVI Backend........:  $enable_dvi
857         Pixbuf Backend.....:  $enable_pixbuf
858         Comics Backend.....:  $enable_comics
859         Impress Backend....:  $enable_impress
860 "