configure.ac

   1 # *****************************************************************************
   2 # Versioning
   3 # *****************************************************************************
   4
   5 m4_define([ev_major_version],[2])
   6 m4_define([ev_minor_version],[31])
   7 m4_define([ev_micro_version],[4])
   8 m4_define([ev_extra_version],[1])
   9 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version().ev_extra_version])
  10
  11 # The evince API version
  12 m4_define([ev_api_version], [2.30])
  13
  14 # Libtool versioning. The backend and view libraries have separate versions.
  15 # Before making a release, the libtool version should be modified.
  16 # The string is of the form C:R:A.
  17 # - If interfaces have been changed or added, but binary compatibility has
  18 #   been preserved, change to C+1:0:A+1
  19 # - If binary compatibility has been broken (eg removed or changed interfaces)
  20 #   change to C+1:0:0
  21 # - If the interface is the same as the previous version, change to C:R+1:A
  22
  23 # Libtool version of the backend library
  24 m4_define([ev_document_lt_current],[2])
  25 m4_define([ev_document_lt_revision],[0])
  26 m4_define([ev_document_lt_age],[0])
  27 m4_define([ev_document_lt_version_info],[ev_document_lt_current:ev_document_lt_revision:ev_document_lt_age])
  28 m4_define([ev_document_lt_current_minus_age],[m4_eval(ev_document_lt_current - ev_document_lt_age)])
  29
  30 # Libtool version of the view library
  31 m4_define([ev_view_lt_current],[2])
  32 m4_define([ev_view_lt_revision],[0])
  33 m4_define([ev_view_lt_age],[0])
  34 m4_define([ev_view_lt_version_info],[ev_view_lt_current:ev_view_lt_revision:ev_view_lt_age])
  35 m4_define([ev_view_lt_current_minus_age],[m4_eval(ev_view_lt_current - ev_view_lt_age)])
  36
  37 # Binary version for the document backends
  38 m4_define([ev_binary_version],[ev_document_lt_current])
  39
  40 # *****************************************************************************
  41
  42 AC_PREREQ([2.57])
  43 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
  44 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2 no-dist-gzip])
  45
  46 AC_CONFIG_HEADERS([config.h])
  47 AC_CONFIG_MACRO_DIR([m4])
  48
  49 if test -z "$enable_maintainer_mode"; then
  50   enable_maintainer_mode=yes
  51 fi
  52 AM_MAINTAINER_MODE([enable])
  53
  54 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  55
  56 AM_PROG_LIBTOOL
  57
  58 AC_ISC_POSIX
  59 AC_PROG_CC
  60 AM_PROG_CC_STDC
  61 AM_PROG_CC_C_O
  62 AC_PROG_CXX
  63 AC_STDC_HEADERS
  64
  65 AC_PROG_SED
  66 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  67 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  68
  69 GNOME_MAINTAINER_MODE_DEFINES
  70 GNOME_COMPILE_WARNINGS
  71 GNOME_CXX_WARNINGS
  72
  73 dnl FIXME: remove this when required gtk+ >= 2.19.7
  74 DISABLE_DEPRECATED=
  75 AC_SUBST([DISABLE_DEPRECATED])
  76
  77 IT_PROG_INTLTOOL([0.35.0])
  78
  79 GETTEXT_PACKAGE=evince
  80 AC_SUBST(GETTEXT_PACKAGE)
  81 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  82 AM_GLIB_GNU_GETTEXT
  83
  84 m4_pattern_allow([AM_V_GEN])dnl Make autoconf not complain about the rule below
  85 EV_INTLTOOL_EVINCE_BACKEND_RULE='%.evince-backend:   %.evince-backend.in   $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; $(AM_V_GEN) LC_ALL=C $(INTLTOOL_MERGE) -d -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@'
  86 AC_SUBST([EV_INTLTOOL_EVINCE_BACKEND_RULE])
  87
  88 GLIB_GSETTINGS
  89
  90 # Check which platform to use
  91
  92 AC_MSG_CHECKING([for which platform to build])
  93 AC_ARG_WITH([platform],
  94   [AS_HELP_STRING([--with-platform=gnome|win32|hildon],
  95                   [Setting platform (default: gnome)])],
  96   [case "$withval" in
  97     gnome|win32|hildon) ;;
  98     *) AC_MSG_ERROR([invalid argument "$withval" for --with-platform]) ;;
  99    esac],
 100   [case "$host" in
 101      *-*-mingw*|*-*-cygwin*) with_platform="win32" ;;
 102      *) with_platform=gnome ;;
 103    esac])
 104
 105 AC_MSG_RESULT([$with_platform])
 106
 107 if test "$with_platform" = "win32"; then
 108   AC_CHECK_TOOL([WINDRES],[windres])
 109   AC_MSG_CHECKING([for native Win32])
 110   case "$host" in
 111     *-*-mingw*)
 112       os_win32=yes
 113       ;;
 114     *)
 115       os_win32=no
 116       ;;
 117   esac
 118   AC_MSG_RESULT([$os_win32])
 119 fi
 120
 121 AM_CONDITIONAL([PLATFORM_HILDON],[test "$with_platform" = "hildon"])
 122 AM_CONDITIONAL([PLATFORM_WIN32],[test "$with_platform" = "win32"])
 123
 124 dnl Specify required versions of dependencies
 125 GTK_REQUIRED=2.21.2
 126 GLIB_REQUIRED=2.25.9
 127 KEYRING_REQUIRED=2.22.0
 128 AC_SUBST([GLIB_REQUIRED])
 129 AC_SUBST([GTK_REQUIRED])
 130
 131 GNOME_ICON_THEME_REQUIRED=2.17.1
 132 LIBXML_REQUIRED=2.5.0
 133
 134 dnl Check dependencies
 135
 136 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
 137 # BACKEND_CFLAGS   for backend implementations.
 138 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
 139 # FRONTEND_LIBS
 140 # SHELL_CFLAGS     for shell implementation.
 141 # SHELL_LIBS
 142
 143 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
 144 PKG_CHECK_MODULES(LIBVIEW, gtk+-2.0 >= $GTK_REQUIRED gail >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 145 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
 146 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 147 PKG_CHECK_MODULES(PREVIEWER, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 148
 149 SHELL_PLATFORM_PKGS=
 150 case "$with_platform" in
 151   hildon) AC_DEFINE([PLATFORM_HILDON],[1],[Define if building for the hildon platform])
 152           SHELL_PLATFORM_PKGS="hildon-1 hildon-fm-2 libosso"
 153           ;;
 154   gnome)
 155         # Evince has a rather soft run-time dependency on hicolor-icon-theme.
 156         # If the hicolor theme is not available, Evince fails to display some
 157         # icons. Because we cannot check for it at run-time, we instead
 158         # would like to require the icon theme at compile-time. But, because
 159         # the hicolor-icon-theme does not have a pkgconfig file, on gnome we
 160         # require the gnome icon theme instead.
 161         SHELL_PLATFORM_PKGS="gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED"
 162         # The totem-screensaver and egg_smclient code use x11 directly.
 163         SHELL_PLATFORM_PKGS="$SHELL_PLATFORM_PKGS x11"
 164         ;;
 165   *)
 166         # On all other platforms we issue a warning about the runtime
 167         # dependency.
 168         AC_MSG_WARN([Evince has a soft run-time dependency on hicolor-icon-theme. You are advised to have this theme installed when running Evince.]);
 169         SHELL_PLATFORM_PKGS=""
 170         ;;
 171 esac
 172
 173 PKG_CHECK_MODULES([SHELL_CORE],[libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gthread-2.0 $SHELL_PLATFORM_PKGS])
 174
 175 # *********
 176 # SM client
 177 # *********
 178
 179 GDK_TARGET="$($PKG_CONFIG --variable target gdk-2.0)"
 180
 181 AC_MSG_CHECKING([which smclient backend to use])
 182 AC_ARG_WITH([smclient],
 183   [AS_HELP_STRING([--with-smclient-backend=no|xsmp|win32|quartz],
 184                   [Setting smclient backend (default:auto)])],
 185   [],
 186   [case "$GDK_TARGET" in
 187     x11) case "$with_platform" in
 188            gnome) with_smclient=xsmp ;;
 189            *) with_smclient=no ;;
 190          esac ;;
 191     win32|quartz) with_smclient=$GDK_TARGET ;;
 192     *) with_smclient=no ;;
 193    esac])
 194
 195 AC_MSG_RESULT([$with_smclient])
 196
 197 if test "$with_smclient" != "no"; then
 198   AC_DEFINE([WITH_SMCLIENT],[1],[Define if smclient is enabled])
 199
 200   case "$with_smclient" in
 201     xsmp) SMCLIENT_PKGS="sm >= 1.0.0" ;;
 202     *) SMCLIENT_PKGS="" ;;
 203   esac
 204
 205   PKG_CHECK_MODULES([SMCLIENT],[gtk+-2.0 gthread-2.0 $SMCLIENT_PKGS])
 206   AC_SUBST([SMCLIENT_CFLAGS])
 207   AC_SUBST([SMCLIENT_LIBS])
 208 fi
 209
 210 AM_CONDITIONAL([WITH_SMCLIENT],[test "$with_smclient" != "no"])
 211 AM_CONDITIONAL([WITH_SMCLIENT_XSMP],[test "$with_smclient" = "xsmp"])
 212 AM_CONDITIONAL([WITH_SMCLIENT_WIN32],[test "$with_smclient" = "win32"])
 213 AM_CONDITIONAL([WITH_SMCLIENT_QUARTZ],[test "$with_smclient" = "quartz"])
 214
 215 # ***
 216
 217 BACKEND_LIBTOOL_FLAGS="-module -avoid-version -no-undefined -export-symbols \$(top_srcdir)/backend/backend.symbols"
 218 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
 219
 220 dnl ===== Check special functions
 221 evince_save_LIBS=$LIBS
 222 LIBS="$LIBS $BACKEND_LIBS"
 223 AC_CHECK_FUNCS(cairo_format_stride_for_width)
 224 LIBS=$evince_save_LIBS
 225
 226 # ******************
 227 # GKT+ Unix Printing
 228 # ******************
 229
 230 AC_MSG_CHECKING([whether gtk+-unix-print support is requested])
 231 AC_ARG_WITH([gtk-unix-print],
 232   [AS_HELP_STRING([--without-gtk-unix-print],
 233                   [Disable the use of gtk-unix-print])],
 234   [],[case "$os_win32" in
 235         yes) with_gtk_unix_print=no ;;
 236         *) with_gtk_unix_print=yes ;;
 237       esac])
 238
 239 AC_MSG_RESULT([$with_gtk_unix_print])
 240
 241 if test "$with_gtk_unix_print" = "yes"; then
 242    PKG_CHECK_MODULES(GTKUNIXPRINT, [gtk+-unix-print-2.0 >= $GTK_REQUIRED])
 243    AC_DEFINE([GTKUNIXPRINT_ENABLED], [1], [Define if gtk+-unix-print is enabled.])
 244 fi
 245
 246 # *********************
 247 # GNOME Keyring support
 248 # *********************
 249
 250 AC_ARG_WITH(keyring,
 251         [AS_HELP_STRING([--without-keyring],
 252                         [Disable the use of gnome-keyring])],
 253         [],
 254         [case "$with_platform" in
 255            gnome) with_keyring=yes ;;
 256            hildon|win32) with_keyring=no ;;
 257          esac])
 258
 259 AM_CONDITIONAL([WITH_KEYRING],[test "$with_keyring" = "yes"])
 260
 261 if test "$with_keyring" = "yes"; then
 262         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
 263         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
 264 fi
 265
 266 # ****
 267 # DBUS
 268 # ****
 269
 270 AC_ARG_ENABLE([dbus],
 271   [AS_HELP_STRING([--disable-dbus], [Disable support for dbus])],
 272   [],
 273   [case "$with_platform" in
 274       gnome) enable_dbus=yes ;;
 275       hildon) enable_dbus=no ;;
 276     esac])
 277
 278 if test "$enable_dbus" = "yes"; then
 279   AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 280
 281    PKG_CHECK_MODULES([EV_DAEMON], [gio-2.0 >= $GLIB_REQUIRED])
 282 fi
 283
 284 AM_CONDITIONAL([ENABLE_DBUS], [test "$enable_dbus" = "yes"])
 285
 286 dnl ========= Check for GConf
 287
 288 AC_MSG_CHECKING([whether GConf support is requested])
 289 AC_ARG_WITH([gconf],
 290   [AS_HELP_STRING([--without-gconf],
 291                   [Disable the use of gconf])],
 292   [],
 293   [case "$os_win32" in
 294      yes) with_gconf=no ;;
 295      *) with_gconf=yes ;;
 296    esac])
 297 AC_MSG_RESULT([$with_gconf])
 298
 299 AM_CONDITIONAL([WITH_GCONF],[test "$with_gconf" = "yes"])
 300
 301 if test "$with_gconf" = "yes"; then
 302    PKG_CHECK_MODULES([GCONF],[gconf-2.0])
 303    AC_DEFINE([WITH_GCONF],[1],[Define if GConf support is enabled])
 304
 305    AM_GCONF_SOURCE_2
 306
 307    AC_PATH_PROG([GCONFTOOL], [gconftool-2], [false])
 308    if test "$GCONFTOOL" = "false"; then
 309       AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 310    fi
 311 else
 312    AM_CONDITIONAL([GCONF_SCHEMAS_INSTALL],false)
 313 fi
 314
 315 dnl Debug mode
 316
 317 AC_ARG_ENABLE([debug],
 318         AS_HELP_STRING([--enable-debug],
 319                        [Turn on evince debug mode]),
 320         [enable_debug=$enableval],
 321         [enable_debug=no])
 322
 323 if test "x$enable_debug" = "xyes"; then
 324    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 325 fi
 326
 327 AC_ARG_ENABLE([tests],
 328         AS_HELP_STRING([--enable-tests], [Enable the tests]),
 329         [enable_tests=$enableval],
 330         [enable_tests=yes])
 331
 332 AM_CONDITIONAL(ENABLE_TESTS, test x$enable_tests = xyes)
 333
 334 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 335 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 336 AC_SUBST(LIBDOCUMENT_CFLAGS)
 337 AC_SUBST(LIBDOCUMENT_LIBS)
 338
 339 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 340 LIBVIEW_LIBS="$LIBVIEW_LIBS $GTKUNIXPRINT_LIBS -lm"
 341 AC_SUBST(LIBVIEW_CFLAGS)
 342 AC_SUBST(LIBVIEW_LIBS)
 343
 344 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 345 BACKEND_LIBS="$BACKEND_LIBS -lm"
 346 AC_SUBST(BACKEND_CFLAGS)
 347 AC_SUBST(BACKEND_LIBS)
 348
 349 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $KEYRING_CFLAGS $GCONF_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 350 SHELL_LIBS="$SHELL_CORE_LIBS $KEYRING_LIBS $GCONF_LIBS -lz -lm"
 351 AC_SUBST(SHELL_CFLAGS)
 352 AC_SUBST(SHELL_LIBS)
 353
 354 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 355 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 356 AC_SUBST(FRONTEND_CFLAGS)
 357 AC_SUBST(FRONTEND_LIBS)
 358
 359 EV_DAEMON_CFLAGS="$EV_DAEMON_CFLAGS $DEBUG_FLAGS"
 360 AC_SUBST([EV_DAEMON_CFLAGS])
 361 AC_SUBST([EV_DAEMON_LIBS])
 362
 363 # Check for Nautilus property page build
 364 AC_ARG_ENABLE([nautilus],
 365   [AS_HELP_STRING([--disable-nautilus],
 366                   [Disable build of nautilus extensions])],
 367   [],
 368   [case "$with_platform" in
 369      gnome) enable_nautilus=yes ;;
 370      *) enable_nautilus=no ;;
 371     esac])
 372
 373 if test "$enable_nautilus" = "yes" ; then
 374   PKG_CHECK_MODULES([NAUTILUS],[gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension],
 375                     [],[AC_MSG_ERROR([libnautilus-extension not found; use --disable-nautilus to disable the nautilus extensions])])
 376   NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 377   AC_SUBST([nautilusextensiondir],[$NAUTILUS_EXTENSION_DIR])
 378   AC_SUBST(NAUTILUS_CFLAGS)
 379   AC_SUBST(NAUTILUS_LIBS)
 380
 381   AC_DEFINE([HAVE_NAUTILUS],[1], [defined if you build the nautilus plugin])
 382 fi
 383
 384 AM_CONDITIONAL([ENABLE_NAUTILUS],[test "$enable_nautilus" = "yes"])
 385
 386 # Check for thumbnailer build
 387
 388 AC_ARG_ENABLE([thumbnailer],
 389   [AS_HELP_STRING([--disable-thumbnailer],
 390                   [Disable GNOME thumbnailer])],
 391   [],
 392   [case "$with_platform" in
 393      gnome) enable_thumbnailer=yes ;;
 394      *) enable_thumbnailer=no ;;
 395     esac])
 396
 397 AM_CONDITIONAL([ENABLE_THUMBNAILER],[test "$enable_thumbnailer" = "yes"])
 398
 399 # ***************
 400 # Print Previewer
 401 # ***************
 402
 403 AC_ARG_ENABLE([previewer],
 404   [AS_HELP_STRING([--disable-previewer],
 405                   [Disable the GNOME Document Previewer])],
 406   [],
 407   [case "$with_platform" in
 408       gnome) enable_previewer=yes ;;
 409       *) enable_previewer=no ;;
 410     esac])
 411
 412 if test x$enable_previewer = "xyes" ; then
 413   PKG_CHECK_MODULES([PREVIEWER],[gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED])
 414 fi
 415
 416 AM_CONDITIONAL([ENABLE_PREVIEWER],[test "$enable_previewer" = "yes"])
 417 PREVIEWER_CFLAGS="$PREVIEWER_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 418 PREVIEWER_LIBS="$PREVIEWER_LIBS $GTKUNIXPRINT_LIBS -lz"
 419 AC_SUBST(PREVIEWER_CFLAGS)
 420 AC_SUBST(PREVIEWER_LIBS)
 421
 422 # ***
 423 # GIR
 424 # ***
 425
 426 AC_MSG_CHECKING([whether GObject introspection is requested])
 427 AC_ARG_ENABLE([introspection],
 428         AS_HELP_STRING([--enable-introspection],
 429                        [Enable GObject introspection]),
 430         [enable_introspection=$enableval],
 431         [enable_introspection=no])
 432 AC_MSG_RESULT([$enable_introspection])
 433
 434 G_IR_SCANNER=
 435 G_IR_COMPILER=
 436 G_IR_GENERATE=
 437 GIRDIR=
 438 GIRTYPELIBDIR=
 439
 440 if test "$enable_introspection" = "yes"; then
 441   GOBJECT_INTROSPECTION_REQUIRED=0.6
 442   PKG_CHECK_MODULES([GOBJECT_INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
 443
 444   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
 445   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
 446   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
 447   GIRDIR="$($PKG_CONFIG --variable=girdir gobject-introspection-1.0)"
 448   GIRTYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
 449 fi
 450
 451 AC_SUBST([G_IR_SCANNER])
 452 AC_SUBST([G_IR_COMPILER])
 453 AC_SUBST([G_IR_GENERATE])
 454 AC_SUBST([GIRDIR])
 455 AC_SUBST([GIRTYPELIBDIR])
 456
 457 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
 458
 459 dnl ================== portability checks ===========================================
 460
 461 dnl for backtrace()
 462 AC_CHECK_HEADERS([execinfo.h])
 463
 464 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 465   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 466   ],[],[#include <langinfo.h>])
 467
 468 dnl ================== pdf checks ===================================================
 469 AC_ARG_ENABLE([pdf],
 470   [AS_HELP_STRING([--disable-pdf],
 471                   [Disable the PDF support])],
 472   [enable_pdf=$enableval],
 473   [enable_pdf=yes])
 474
 475 if test "x$enable_pdf" = "xyes"; then
 476     POPPLER_REQUIRED=0.14.0
 477     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED,enable_pdf=yes,enable_pdf=no)
 478
 479     if test "x$enable_pdf" = "xyes"; then
 480             evince_save_LIBS=$LIBS
 481             LIBS="$LIBS $POPPLER_LIBS"
 482             AC_CHECK_FUNCS(poppler_page_get_text_layout)
 483             LIBS=$evince_save_LIBS
 484             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 485             if test x$enable_cairo_pdf = xyes; then
 486                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 487             fi
 488
 489             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 490             if test x$enable_cairo_ps = xyes; then
 491                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 492             fi
 493     else
 494             AC_MSG_ERROR("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 495     fi
 496 fi
 497
 498 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 499 dnl ================== end of pdf checks ============================================
 500
 501 dnl libspectre (used by ps and dvi backends)
 502 SPECTRE_REQUIRED=0.2.0
 503 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 504 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 505 if test "x$have_spectre" = "xyes"; then
 506    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 507 fi
 508
 509 dnl ================== ps checks ====================================================
 510 AC_ARG_ENABLE(ps,
 511         [AS_HELP_STRING([--disable-ps],
 512                         [Disable the PostScript backend])],
 513         [enable_ps=$enableval],
 514         [enable_ps=yes])
 515
 516 if test "x$enable_ps" = "xyes"; then
 517    if test "x$have_spectre" = "xyes"; then
 518       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 519    else
 520       enable_ps="no"
 521       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 522    fi
 523 fi
 524 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 525 dnl ======================== End of ps checks ===================================
 526
 527 dnl ================== tiff checks ===================================================
 528 AC_ARG_ENABLE(tiff,
 529             [AS_HELP_STRING([--disable-tiff],
 530                             [Disable the support of multipage tiff])],
 531             [enable_tiff=$enableval],
 532             [enable_tiff=yes])
 533
 534 if test "x$enable_tiff" = "xyes"; then
 535     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 536     if test "x$enable_tiff" = "xyes"; then
 537         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 538         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 539     fi
 540     if test "x$enable_tiff" = "xyes"; then
 541             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 542     else
 543             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 544     fi
 545 fi
 546
 547 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 548 dnl ================== end of tiff checks ============================================
 549
 550 dnl ================== djvu checks ===================================================
 551
 552 AC_ARG_ENABLE(djvu,
 553             [AS_HELP_STRING([--disable-djvu],
 554                             [Disable the support of djvu viewer])],
 555             [enable_djvu=$enableval],
 556             [enable_djvu=yes])
 557
 558 if test "x$enable_djvu" = "xyes"; then
 559     DJVULIBRE_REQUIRED=3.5.17
 560     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 561
 562     if test "x$enable_djvu" = "xyes"; then
 563         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 564     else
 565         AC_MSG_WARN([
 566 ** Djvu support is disabled since a recent version of the djvulibre
 567 ** library was not found. You need at least djvulibre-3.5.17 which
 568 ** can be found on http://djvulibre.djvuzone.org
 569 ])
 570     fi
 571 fi
 572
 573 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 574
 575 dnl ================== End of djvu checks ===================================================
 576
 577 dnl ================== dvi checks ===================================================
 578
 579 AC_ARG_ENABLE(dvi,
 580             [AS_HELP_STRING([--disable-dvi],
 581             [Disable the support of dvi viewer])],
 582             [enable_dvi=$enableval],
 583             [enable_dvi=yes])
 584
 585 AC_ARG_ENABLE(t1lib,
 586             [AS_HELP_STRING([--enable-t1lib],
 587                             [Compile with support of t1lib for type1 fonts in dvi])],
 588             [enable_type1_fonts=$enableval],
 589             [enable_type1_fonts=no])
 590
 591 if test "x$enable_dvi" = "xyes"; then
 592     AC_C_CONST
 593     AC_C_INLINE
 594     AC_TYPE_SIZE_T
 595     AC_CHECK_SIZEOF(long, 4)
 596     AC_CHECK_SIZEOF(int, 4)
 597     AC_CHECK_SIZEOF(short, 2)
 598     AC_CHECK_SIZEOF(void *, 4)
 599     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 600
 601     if test "x$enable_dvi" = "xyes"; then
 602         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 603     else
 604         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 605     fi
 606 fi
 607 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 608
 609 if test "x$enable_dvi" = "xyes"; then
 610     if test "x$enable_type1_fonts" = "xyes"; then
 611         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 612     fi
 613
 614     if test "x$enable_type1_fonts" = xyes; then
 615         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 616     fi
 617 else
 618     enable_type1_fonts=no
 619 fi
 620 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 621
 622 dnl ================== End of dvi checks ===================================================
 623
 624 dnl ================== pixbuf checks ===================================================
 625
 626 AC_ARG_ENABLE(pixbuf,
 627             [AS_HELP_STRING([--enable-pixbuf],
 628                             [Compile with support of pixbuf])],
 629             [enable_pixbuf=$enableval],
 630             [enable_pixbuf=no])
 631
 632 if test "x$enable_pixbuf" = "xyes"; then
 633         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 634 fi
 635
 636 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 637
 638 dnl ================== End of pixbuf checks ===================================================
 639
 640 dnl ================== comic book checks ===================================================
 641
 642 AC_ARG_ENABLE(comics,
 643         [AS_HELP_STRING([--enable-comics],
 644                         [Compile with support for comic book archives])],
 645         [enable_comics=$enableval],
 646         [enable_comics=yes])
 647
 648 if test "x$enable_comics" = "xyes"; then
 649         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 650 fi
 651 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 652
 653 dnl ================== End of comic book checks ============================================
 654
 655 dnl ================== impress book checks ===================================================
 656
 657 AC_ARG_ENABLE(impress,
 658         [AS_HELP_STRING([--enable-impress],
 659                         [Compile with support for impress presentations])],
 660         [enable_impress=$enableval],
 661         [enable_impress=no])
 662
 663 if test "x$enable_impress" = "xyes"; then
 664         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 665 fi
 666 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 667
 668 dnl ================== End of impress book checks ============================================
 669
 670 dnl =================== Mime types list ====================================================
 671
 672 if test "x$enable_pdf" = "xyes" ; then
 673         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 674 fi
 675 if test "x$enable_ps" = "xyes" ; then
 676         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 677 fi
 678 if test "x$enable_dvi" = "xyes"; then
 679         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 680 fi
 681 if test "x$enable_djvu" = "xyes"; then
 682         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 683 fi
 684 if test "x$enable_tiff" = "xyes"; then
 685         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 686 fi
 687 if test "x$enable_comics" = "xyes"; then
 688         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;application/x-cbt;"
 689 fi
 690 if test "x$enable_pixbuf" = "xyes"; then
 691         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 692 fi
 693 if test "x$enable_impress" = "xyes"; then
 694         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 695 fi
 696 AC_SUBST(EVINCE_MIME_TYPES)
 697
 698 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 699
 700 # *****************
 701 # Help files
 702 # *****************
 703
 704 GNOME_DOC_INIT([], gnome_doc_utils=yes, gnome_doc_utils=no)
 705
 706 AC_ARG_ENABLE(help,
 707     [AS_HELP_STRING([--disable-help], [Disable offline help files])],
 708     [enable_help=$enableval],
 709     [enable_help=yes])
 710
 711 if test "x$enable_help" = "xyes" && test "x$os_win32" = "xyes" ; then
 712     AC_MSG_WARN([Offline help is disabled (not implemented on Windows).])
 713     enable_help=no
 714 fi
 715
 716 if test "x$enable_help" = "xyes" && test "x$gnome_doc_utils" == "xno"; then
 717     AC_MSG_ERROR(
 718        [gnome-doc-utils not found; use --disable-help to disable help files]
 719     )
 720 fi
 721
 722 if test "x$enable_help" = "xyes"; then
 723     AC_DEFINE([OFFLINE_HELP_ENABLED], [1], [Enable offline help])
 724 fi
 725
 726 AM_CONDITIONAL(ENABLE_HELP, test "x$enable_help" = "xyes")
 727
 728 # *****************
 729 # API documentation
 730 # *****************
 731
 732 GTK_DOC_CHECK([1.13],[--flavour no-tmpl])
 733
 734 AC_SUBST([GLIB_PREFIX],[$($PKG_CONFIG --variable=prefix glib-2.0)])
 735 AC_SUBST([GTK_PREFIX],[$($PKG_CONFIG --variable=prefix gtk+-2.0)])
 736
 737 # ******************
 738 # Backends directory
 739 # ******************
 740
 741 AC_SUBST([backenddir],"\$(libdir)/evince/ev_binary_version/backends")
 742 AC_SUBST([backend_binary_version],"ev_binary_version")
 743
 744 # **********
 745 # Versioning
 746 # **********
 747
 748 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
 749 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
 750 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
 751
 752 AC_SUBST([EV_API_VERSION],[ev_api_version])
 753 AC_SUBST([EV_API_VERSION_U],[AS_TR_SH([ev_api_version])])
 754 AC_SUBST([EV_BINARY_VERSION],[ev_binary_version])
 755
 756 AC_SUBST([EV_DOCUMENT_LT_VERSION_INFO],[ev_document_lt_version_info])
 757 AC_SUBST([EV_DOCUMENT_LT_CURRENT_MINUS_AGE],[ev_document_lt_current_minus_age])
 758 AC_SUBST([EV_VIEW_LT_VERSION_INFO],[ev_view_lt_version_info])
 759 AC_SUBST([EV_VIEW_LT_CURRENT_MINUS_AGE],[ev_view_lt_current_minus_age])
 760
 761 # *****************************************************************************
 762 # *****************************************************************************
 763
 764 AC_CONFIG_FILES([
 765 backend/Makefile
 766 backend/comics/Makefile
 767 backend/djvu/Makefile
 768 backend/dvi/Makefile
 769 backend/dvi/mdvi-lib/Makefile
 770 backend/impress/Makefile
 771 backend/pdf/Makefile
 772 backend/pixbuf/Makefile
 773 backend/ps/Makefile
 774 backend/tiff/Makefile
 775 cut-n-paste/Makefile
 776 cut-n-paste/gimpcellrenderertoggle/Makefile
 777 cut-n-paste/smclient/Makefile
 778 cut-n-paste/toolbar-editor/Makefile
 779 cut-n-paste/zoom-control/Makefile
 780 cut-n-paste/totem-screensaver/Makefile
 781 cut-n-paste/synctex/Makefile
 782 data/evince.desktop.in
 783 data/Makefile
 784 data/icons/Makefile
 785 data/icons/16x16/Makefile
 786 data/icons/16x16/apps/Makefile
 787 data/icons/16x16/actions/Makefile
 788 data/icons/16x16/mimetypes/Makefile
 789 data/icons/22x22/Makefile
 790 data/icons/22x22/apps/Makefile
 791 data/icons/22x22/actions/Makefile
 792 data/icons/22x22/mimetypes/Makefile
 793 data/icons/24x24/Makefile
 794 data/icons/24x24/apps/Makefile
 795 data/icons/24x24/actions/Makefile
 796 data/icons/24x24/mimetypes/Makefile
 797 data/icons/32x32/Makefile
 798 data/icons/32x32/actions/Makefile
 799 data/icons/32x32/mimetypes/Makefile
 800 data/icons/48x48/Makefile
 801 data/icons/48x48/apps/Makefile
 802 data/icons/48x48/actions/Makefile
 803 data/icons/scalable/Makefile
 804 data/icons/scalable/apps/Makefile
 805 data/icons/scalable/actions/Makefile
 806 data/icons/scalable/mimetypes/Makefile
 807 help/Makefile
 808 help/reference/Makefile
 809 help/reference/libdocument/Makefile
 810 help/reference/libdocument/version.xml
 811 help/reference/libview/Makefile
 812 help/reference/libview/version.xml
 813 help/reference/shell/Makefile
 814 help/reference/shell/version.xml
 815 libdocument/Makefile
 816 libdocument/ev-version.h
 817 libmisc/Makefile
 818 libview/Makefile
 819 Makefile
 820 po/Makefile.in
 821 previewer/Makefile
 822 properties/Makefile
 823 shell/Makefile
 824 test/Makefile
 825 thumbnailer/Makefile
 826 ])
 827
 828 AC_CONFIG_FILES(evince-document-[]ev_api_version[].pc:evince-document.pc.in)
 829 AC_CONFIG_FILES(evince-view-[]ev_api_version[].pc:evince-view.pc.in)
 830
 831 AC_OUTPUT
 832
 833 echo "
 834 Configure summary:
 835         Platform...........:  $with_platform
 836         GConf Support......:  $with_gconf
 837         GTK+ Unix Print....:  $with_gtk_unix_print
 838         Keyring Support....:  $with_keyring
 839         DBUS Support.......:  $enable_dbus
 840         SM client support..:  $with_smclient
 841         Help files.........:  $enable_help
 842         Nautilus Plugin....:  $enable_nautilus
 843         Thumbnailer........:  $enable_thumbnailer
 844         Previewer..........:  $enable_previewer
 845         Gtk-Doc Support....:  $enable_gtk_doc
 846         Debug mode.........:  $enable_debug
 847         GObj. Introspection:  $enable_introspection
 848         Tests..............:  $enable_tests
 849
 850         PDF Backend........:  $enable_pdf
 851         PostScript Backend.:  $enable_ps
 852         TIFF Backend.......:  $enable_tiff
 853         DJVU Backend.......:  $enable_djvu
 854         DVI Backend........:  $enable_dvi
 855         Pixbuf Backend.....:  $enable_pixbuf
 856         Comics Backend.....:  $enable_comics
 857         Impress Backend....:  $enable_impress
 858 "