configure.ac

   1 # *****************************************************************************
   2 # Versioning
   3 # *****************************************************************************
   4
   5 m4_define([ev_major_version],[2])
   6 m4_define([ev_minor_version],[30])
   7 m4_define([ev_micro_version],[0])
   8 m4_define([ev_extra_version],[])
   9 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version()ev_extra_version])
  10
  11 # The evince API version
  12 m4_define([ev_api_version], [2.30])
  13
  14 # Libtool versioning. The backend and view libraries have separate versions.
  15 # Before making a release, the libtool version should be modified.
  16 # The string is of the form C:R:A.
  17 # - If interfaces have been changed or added, but binary compatibility has
  18 #   been preserved, change to C+1:0:A+1
  19 # - If binary compatibility has been broken (eg removed or changed interfaces)
  20 #   change to C+1:0:0
  21 # - If the interface is the same as the previous version, change to C:R+1:A
  22
  23 # Libtool version of the backend library
  24 m4_define([ev_document_lt_current],[2])
  25 m4_define([ev_document_lt_revision],[0])
  26 m4_define([ev_document_lt_age],[0])
  27 m4_define([ev_document_lt_version_info],[ev_document_lt_current:ev_document_lt_revision:ev_document_lt_age])
  28 m4_define([ev_document_lt_current_minus_age],[m4_eval(ev_document_lt_current - ev_document_lt_age)])
  29
  30 # Libtool version of the view library
  31 m4_define([ev_view_lt_current],[2])
  32 m4_define([ev_view_lt_revision],[0])
  33 m4_define([ev_view_lt_age],[0])
  34 m4_define([ev_view_lt_version_info],[ev_view_lt_current:ev_view_lt_revision:ev_view_lt_age])
  35 m4_define([ev_view_lt_current_minus_age],[m4_eval(ev_view_lt_current - ev_view_lt_age)])
  36
  37 # Binary version for the document backends
  38 m4_define([ev_binary_version],[ev_document_lt_current])
  39
  40 # *****************************************************************************
  41
  42 AC_PREREQ([2.57])
  43 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
  44 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2 no-dist-gzip])
  45
  46 AC_CONFIG_HEADERS([config.h])
  47 AC_CONFIG_MACRO_DIR([m4])
  48
  49 if test -z "$enable_maintainer_mode"; then
  50   enable_maintainer_mode=yes
  51 fi
  52 AM_MAINTAINER_MODE([enable])
  53
  54 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  55
  56 AM_PROG_LIBTOOL
  57
  58 AC_ISC_POSIX
  59 AC_PROG_CC
  60 AM_PROG_CC_STDC
  61 AM_PROG_CC_C_O
  62 AC_PROG_CXX
  63 AC_STDC_HEADERS
  64
  65 AC_PROG_SED
  66 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  67 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  68
  69 GNOME_MAINTAINER_MODE_DEFINES
  70 GNOME_COMPILE_WARNINGS
  71 GNOME_CXX_WARNINGS
  72
  73 dnl FIXME: remove this when required gtk+ >= 2.19.7
  74 DISABLE_DEPRECATED=
  75 AC_SUBST([DISABLE_DEPRECATED])
  76
  77 IT_PROG_INTLTOOL([0.35.0])
  78
  79 GETTEXT_PACKAGE=evince
  80 AC_SUBST(GETTEXT_PACKAGE)
  81 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  82 AM_GLIB_GNU_GETTEXT
  83
  84 m4_pattern_allow([AM_V_GEN])dnl Make autoconf not complain about the rule below
  85 EV_INTLTOOL_EVINCE_BACKEND_RULE='%.evince-backend:   %.evince-backend.in   $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; $(AM_V_GEN) LC_ALL=C $(INTLTOOL_MERGE) -d -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@'
  86 AC_SUBST([EV_INTLTOOL_EVINCE_BACKEND_RULE])
  87
  88 # Check which platform to use
  89
  90 AC_MSG_CHECKING([for which platform to build])
  91 AC_ARG_WITH([platform],
  92   [AS_HELP_STRING([--with-platform=gnome|win32|hildon],
  93                   [Setting platform (default: gnome)])],
  94   [case "$withval" in
  95     gnome|win32|hildon) ;;
  96     *) AC_MSG_ERROR([invalid argument "$withval" for --with-platform]) ;;
  97    esac],
  98   [case "$host" in
  99      *-*-mingw*|*-*-cygwin*) with_platform="win32" ;;
 100      *) with_platform=gnome ;;
 101    esac])
 102
 103 AC_MSG_RESULT([$with_platform])
 104
 105 if test "$with_platform" = "win32"; then
 106   AC_CHECK_TOOL([WINDRES],[windres])
 107   AC_MSG_CHECKING([for native Win32])
 108   case "$host" in
 109     *-*-mingw*)
 110       os_win32=yes
 111       ;;
 112     *)
 113       os_win32=no
 114       ;;
 115   esac
 116   AC_MSG_RESULT([$os_win32])
 117 fi
 118
 119 AM_CONDITIONAL([PLATFORM_HILDON],[test "$with_platform" = "hildon"])
 120 AM_CONDITIONAL([PLATFORM_WIN32],[test "$with_platform" = "win32"])
 121
 122 dnl Specify required versions of dependencies
 123 DBUS_GLIB_REQUIRED=0.70
 124 GTK_REQUIRED=2.20.0
 125 GLIB_REQUIRED=2.18.0
 126 KEYRING_REQUIRED=2.22.0
 127 AC_SUBST([GLIB_REQUIRED])
 128 AC_SUBST([GTK_REQUIRED])
 129
 130 GNOME_ICON_THEME_REQUIRED=2.17.1
 131 LIBXML_REQUIRED=2.5.0
 132
 133 dnl Check dependencies
 134
 135 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
 136 # BACKEND_CFLAGS   for backend implementations.
 137 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
 138 # FRONTEND_LIBS
 139 # SHELL_CFLAGS     for shell implementation.
 140 # SHELL_LIBS
 141
 142 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
 143 PKG_CHECK_MODULES(LIBVIEW, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 144 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
 145 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 146 PKG_CHECK_MODULES(PREVIEWER, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 147
 148 SHELL_PLATFORM_PKGS=
 149 case "$with_platform" in
 150   hildon) AC_DEFINE([PLATFORM_HILDON],[1],[Define if building for the hildon platform])
 151           SHELL_PLATFORM_PKGS="hildon-1 hildon-fm-2 libosso"
 152           ;;
 153   gnome)
 154         # Evince has a rather soft run-time dependency on hicolor-icon-theme.
 155         # If the hicolor theme is not available, Evince fails to display some
 156         # icons. Because we cannot check for it at run-time, we instead
 157         # would like to require the icon theme at compile-time. But, because
 158         # the hicolor-icon-theme does not have a pkgconfig file, on gnome we
 159         # require the gnome icon theme instead.
 160         SHELL_PLATFORM_PKGS="gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED"
 161         # The totem-screensaver and egg_smclient code use x11 directly.
 162         SHELL_PLATFORM_PKGS="$SHELL_PLATFORM_PKGS x11"
 163         ;;
 164   *)
 165         # On all other platforms we issue a warning about the runtime
 166         # dependency.
 167         AC_MSG_WARN([Evince has a soft run-time dependency on hicolor-icon-theme. You are advised to have this theme installed when running Evince.]);
 168         SHELL_PLATFORM_PKGS=""
 169         ;;
 170 esac
 171
 172 PKG_CHECK_MODULES([SHELL_CORE],[libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gthread-2.0 $SHELL_PLATFORM_PKGS])
 173
 174 # *********
 175 # SM client
 176 # *********
 177
 178 GDK_TARGET="$($PKG_CONFIG --variable target gdk-2.0)"
 179
 180 AC_MSG_CHECKING([which smclient backend to use])
 181 AC_ARG_WITH([smclient],
 182   [AS_HELP_STRING([--with-smclient-backend=no|xsmp|win32|quartz],
 183                   [Setting smclient backend (default:auto)])],
 184   [],
 185   [case "$GDK_TARGET" in
 186     x11) case "$with_platform" in
 187            gnome) with_smclient=xsmp ;;
 188            *) with_smclient=no ;;
 189          esac ;;
 190     win32|quartz) with_smclient=$GDK_TARGET ;;
 191     *) with_smclient=no ;;
 192    esac])
 193
 194 AC_MSG_RESULT([$with_smclient])
 195
 196 if test "$with_smclient" != "no"; then
 197   AC_DEFINE([WITH_SMCLIENT],[1],[Define if smclient is enabled])
 198
 199   case "$with_smclient" in
 200     xsmp) SMCLIENT_PKGS="sm >= 1.0.0" ;;
 201     *) SMCLIENT_PKGS="" ;;
 202   esac
 203
 204   PKG_CHECK_MODULES([SMCLIENT],[gtk+-2.0 gthread-2.0 $SMCLIENT_PKGS])
 205   AC_SUBST([SMCLIENT_CFLAGS])
 206   AC_SUBST([SMCLIENT_LIBS])
 207 fi
 208
 209 AM_CONDITIONAL([WITH_SMCLIENT],[test "$with_smclient" != "no"])
 210 AM_CONDITIONAL([WITH_SMCLIENT_XSMP],[test "$with_smclient" = "xsmp"])
 211 AM_CONDITIONAL([WITH_SMCLIENT_WIN32],[test "$with_smclient" = "win32"])
 212 AM_CONDITIONAL([WITH_SMCLIENT_QUARTZ],[test "$with_smclient" = "quartz"])
 213
 214 # ***
 215
 216 BACKEND_LIBTOOL_FLAGS="-module -avoid-version -no-undefined -export-symbols \$(top_srcdir)/backend/backend.symbols"
 217 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
 218
 219 dnl ===== Check special functions
 220 evince_save_LIBS=$LIBS
 221 LIBS="$LIBS $BACKEND_LIBS"
 222 AC_CHECK_FUNCS(cairo_format_stride_for_width)
 223 AC_CHECK_FUNCS(gtk_print_operation_get_n_pages_to_print)
 224 LIBS=$evince_save_LIBS
 225
 226 # ******************
 227 # GKT+ Unix Printing
 228 # ******************
 229
 230 AC_MSG_CHECKING([whether gtk+-unix-print support is requested])
 231 AC_ARG_WITH([gtk-unix-print],
 232   [AS_HELP_STRING([--without-gtk-unix-print],
 233                   [Disable the use of gtk-unix-print])],
 234   [],[case "$os_win32" in
 235         yes) with_gtk_unix_print=no ;;
 236         *) with_gtk_unix_print=yes ;;
 237       esac])
 238
 239 AC_MSG_RESULT([$with_gtk_unix_print])
 240
 241 if test "$with_gtk_unix_print" = "yes"; then
 242    PKG_CHECK_MODULES(GTKUNIXPRINT, [gtk+-unix-print-2.0 >= $GTK_REQUIRED])
 243    AC_DEFINE([GTKUNIXPRINT_ENABLED], [1], [Define if gtk+-unix-print is enabled.])
 244 fi
 245
 246 # *********************
 247 # GNOME Keyring support
 248 # *********************
 249
 250 AC_ARG_WITH(keyring,
 251         [AS_HELP_STRING([--without-keyring],
 252                         [Disable the use of gnome-keyring])],
 253         [],
 254         [case "$with_platform" in
 255            gnome) with_keyring=yes ;;
 256            hildon|win32) with_keyring=no ;;
 257          esac])
 258
 259 AM_CONDITIONAL([WITH_KEYRING],[test "$with_keyring" = "yes"])
 260
 261 if test "$with_keyring" = "yes"; then
 262         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
 263         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
 264 fi
 265
 266 # ****
 267 # DBUS
 268 # ****
 269
 270 AC_ARG_ENABLE([dbus],
 271   [AS_HELP_STRING([--disable-dbus], [Disable support for dbus])],
 272   [],
 273   [case "$with_platform" in
 274       gnome) enable_dbus=yes ;;
 275       hildon) enable_dbus=no ;;
 276     esac])
 277
 278 if test "$enable_dbus" = "yes"; then
 279   PKG_CHECK_MODULES([DBUS],[dbus-glib-1 >= $DBUS_GLIB_REQUIRED],[],
 280                     [AC_MSG_ERROR([DBUS not found; use --disable-dbus to disable DBUS support])])
 281
 282   AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 283   if test x$DBUS_BINDING_TOOL = "xno" ; then
 284           AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 285   fi
 286
 287   AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 288 fi
 289
 290 AC_SUBST([DBUS_CFLAGS])
 291 AC_SUBST([DBUS_LIBS])
 292
 293 AM_CONDITIONAL([ENABLE_DBUS], [test "$enable_dbus" = "yes"])
 294
 295 if test "$enable_dbus" = "yes"; then
 296    PKG_CHECK_MODULES([EV_DAEMON], [gthread-2.0 gio-2.0 >= $GLIB_REQUIRED dbus-glib-1 >= $DBUS_GLIB_REQUIRED])
 297 fi
 298
 299 dnl ========= Check for GConf
 300
 301 AC_MSG_CHECKING([whether GConf support is requested])
 302 AC_ARG_WITH([gconf],
 303   [AS_HELP_STRING([--without-gconf],
 304                   [Disable the use of gconf])],
 305   [],
 306   [case "$os_win32" in
 307      yes) with_gconf=no ;;
 308      *) with_gconf=yes ;;
 309    esac])
 310 AC_MSG_RESULT([$with_gconf])
 311
 312 AM_CONDITIONAL([WITH_GCONF],[test "$with_gconf" = "yes"])
 313
 314 if test "$with_gconf" = "yes"; then
 315    PKG_CHECK_MODULES([GCONF],[gconf-2.0])
 316    AC_DEFINE([WITH_GCONF],[1],[Define if GConf support is enabled])
 317
 318    AM_GCONF_SOURCE_2
 319
 320    AC_PATH_PROG([GCONFTOOL], [gconftool-2], [false])
 321    if test "$GCONFTOOL" = "false"; then
 322       AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 323    fi
 324 else
 325    AM_CONDITIONAL([GCONF_SCHEMAS_INSTALL],false)
 326 fi
 327
 328 dnl Debug mode
 329
 330 AC_ARG_ENABLE([debug],
 331         AS_HELP_STRING([--enable-debug],
 332                        [Turn on evince debug mode]),
 333         [enable_debug=$enableval],
 334         [enable_debug=no])
 335
 336 if test "x$enable_debug" = "xyes"; then
 337    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 338 fi
 339
 340 AC_ARG_ENABLE([tests],
 341         AS_HELP_STRING([--enable-tests], [Enable the tests]),
 342         [enable_tests=$enableval],
 343         [enable_tests=yes])
 344
 345 AM_CONDITIONAL(ENABLE_TESTS, test x$enable_tests = xyes)
 346
 347 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 348 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 349 AC_SUBST(LIBDOCUMENT_CFLAGS)
 350 AC_SUBST(LIBDOCUMENT_LIBS)
 351
 352 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 353 LIBVIEW_LIBS="$LIBVIEW_LIBS $GTKUNIXPRINT_LIBS -lm"
 354 AC_SUBST(LIBVIEW_CFLAGS)
 355 AC_SUBST(LIBVIEW_LIBS)
 356
 357 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 358 BACKEND_LIBS="$BACKEND_LIBS -lm"
 359 AC_SUBST(BACKEND_CFLAGS)
 360 AC_SUBST(BACKEND_LIBS)
 361
 362 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS $KEYRING_CFLAGS $GCONF_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 363 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS $KEYRING_LIBS $GCONF_LIBS -lz -lm"
 364 AC_SUBST(SHELL_CFLAGS)
 365 AC_SUBST(SHELL_LIBS)
 366
 367 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 368 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 369 AC_SUBST(FRONTEND_CFLAGS)
 370 AC_SUBST(FRONTEND_LIBS)
 371
 372 EV_DAEMON_CFLAGS="$EV_DAEMON_CFLAGS $DEBUG_FLAGS"
 373 AC_SUBST([EV_DAEMON_CFLAGS])
 374 AC_SUBST([EV_DAEMON_LIBS])
 375
 376 # Check for Nautilus property page build
 377 AC_ARG_ENABLE([nautilus],
 378   [AS_HELP_STRING([--disable-nautilus],
 379                   [Disable build of nautilus extensions])],
 380   [],
 381   [case "$with_platform" in
 382      gnome) enable_nautilus=yes ;;
 383      *) enable_nautilus=no ;;
 384     esac])
 385
 386 if test "$enable_nautilus" = "yes" ; then
 387   PKG_CHECK_MODULES([NAUTILUS],[gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension],
 388                     [],[AC_MSG_ERROR([libnautilus-extension not found; use --disable-nautilus to disable the nautilus extensions])])
 389   NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 390   AC_SUBST([nautilusextensiondir],[$NAUTILUS_EXTENSION_DIR])
 391   AC_SUBST(NAUTILUS_CFLAGS)
 392   AC_SUBST(NAUTILUS_LIBS)
 393
 394   AC_DEFINE([HAVE_NAUTILUS],[1], [defined if you build the nautilus plugin])
 395 fi
 396
 397 AM_CONDITIONAL([ENABLE_NAUTILUS],[test "$enable_nautilus" = "yes"])
 398
 399 # Check for thumbnailer build
 400
 401 AC_ARG_ENABLE([thumbnailer],
 402   [AS_HELP_STRING([--disable-thumbnailer],
 403                   [Disable GNOME thumbnailer])],
 404   [],
 405   [case "$with_platform" in
 406      gnome) enable_thumbnailer=yes ;;
 407      *) enable_thumbnailer=no ;;
 408     esac])
 409
 410 AM_CONDITIONAL([ENABLE_THUMBNAILER],[test "$enable_thumbnailer" = "yes"])
 411
 412 # ***************
 413 # Print Previewer
 414 # ***************
 415
 416 AC_ARG_ENABLE([previewer],
 417   [AS_HELP_STRING([--disable-previewer],
 418                   [Disable the GNOME Document Previewer])],
 419   [],
 420   [case "$with_platform" in
 421       gnome) enable_previewer=yes ;;
 422       *) enable_previewer=no ;;
 423     esac])
 424
 425 if test x$enable_previewer = "xyes" ; then
 426   PKG_CHECK_MODULES([PREVIEWER],[gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED])
 427 fi
 428
 429 AM_CONDITIONAL([ENABLE_PREVIEWER],[test "$enable_previewer" = "yes"])
 430 PREVIEWER_CFLAGS="$PREVIEWER_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 431 PREVIEWER_LIBS="$PREVIEWER_LIBS $GTKUNIXPRINT_LIBS -lz"
 432 AC_SUBST(PREVIEWER_CFLAGS)
 433 AC_SUBST(PREVIEWER_LIBS)
 434
 435 # ***
 436 # GIR
 437 # ***
 438
 439 AC_MSG_CHECKING([whether GObject introspection is requested])
 440 AC_ARG_ENABLE([introspection],
 441         AS_HELP_STRING([--enable-introspection],
 442                        [Enable GObject introspection]),
 443         [enable_introspection=$enableval],
 444         [enable_introspection=no])
 445 AC_MSG_RESULT([$enable_introspection])
 446
 447 G_IR_SCANNER=
 448 G_IR_COMPILER=
 449 G_IR_GENERATE=
 450 GIRDIR=
 451 GIRTYPELIBDIR=
 452
 453 if test "$enable_introspection" = "yes"; then
 454   GOBJECT_INTROSPECTION_REQUIRED=0.6
 455   PKG_CHECK_MODULES([GOBJECT_INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
 456
 457   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
 458   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
 459   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
 460   GIRDIR="$($PKG_CONFIG --variable=girdir gobject-introspection-1.0)"
 461   GIRTYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
 462 fi
 463
 464 AC_SUBST([G_IR_SCANNER])
 465 AC_SUBST([G_IR_COMPILER])
 466 AC_SUBST([G_IR_GENERATE])
 467 AC_SUBST([GIRDIR])
 468 AC_SUBST([GIRTYPELIBDIR])
 469
 470 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
 471
 472 dnl ================== portability checks ===========================================
 473
 474 dnl for backtrace()
 475 AC_CHECK_HEADERS([execinfo.h])
 476
 477 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 478   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 479   ],[],[#include <langinfo.h>])
 480
 481 dnl ================== pdf checks ===================================================
 482 AC_ARG_ENABLE([pdf],
 483   [AS_HELP_STRING([--disable-pdf],
 484                   [Disable the PDF support])],
 485   [enable_pdf=$enableval],
 486   [enable_pdf=yes])
 487
 488 if test "x$enable_pdf" = "xyes"; then
 489     POPPLER_REQUIRED=0.12.0
 490     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED,enable_pdf=yes,enable_pdf=no)
 491
 492     if test "x$enable_pdf" = "xyes"; then
 493             evince_save_LIBS=$LIBS
 494             LIBS="$LIBS $POPPLER_LIBS"
 495             AC_CHECK_FUNCS(poppler_page_render)
 496             AC_CHECK_FUNCS(poppler_page_get_image)
 497             AC_CHECK_FUNCS(poppler_annot_file_attachment_get_attachment)
 498             LIBS=$evince_save_LIBS
 499
 500             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 501             if test x$enable_cairo_pdf = xyes; then
 502                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 503             fi
 504
 505             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 506             if test x$enable_cairo_ps = xyes; then
 507                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 508             fi
 509     else
 510             AC_MSG_ERROR("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 511     fi
 512 fi
 513
 514 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 515 dnl ================== end of pdf checks ============================================
 516
 517 dnl libspectre (used by ps and dvi backends)
 518 SPECTRE_REQUIRED=0.2.0
 519 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 520 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 521 if test "x$have_spectre" = "xyes"; then
 522    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 523 fi
 524
 525 dnl ================== ps checks ====================================================
 526 AC_ARG_ENABLE(ps,
 527         [AS_HELP_STRING([--disable-ps],
 528                         [Disable the PostScript backend])],
 529         [enable_ps=$enableval],
 530         [enable_ps=yes])
 531
 532 if test "x$enable_ps" = "xyes"; then
 533    if test "x$have_spectre" = "xyes"; then
 534       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 535    else
 536       enable_ps="no"
 537       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 538    fi
 539 fi
 540 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 541 dnl ======================== End of ps checks ===================================
 542
 543 dnl ================== tiff checks ===================================================
 544 AC_ARG_ENABLE(tiff,
 545             [AS_HELP_STRING([--disable-tiff],
 546                             [Disable the support of multipage tiff])],
 547             [enable_tiff=$enableval],
 548             [enable_tiff=yes])
 549
 550 if test "x$enable_tiff" = "xyes"; then
 551     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 552     if test "x$enable_tiff" = "xyes"; then
 553         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 554         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 555     fi
 556     if test "x$enable_tiff" = "xyes"; then
 557             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 558     else
 559             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 560     fi
 561 fi
 562
 563 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 564 dnl ================== end of tiff checks ============================================
 565
 566 dnl ================== djvu checks ===================================================
 567
 568 AC_ARG_ENABLE(djvu,
 569             [AS_HELP_STRING([--disable-djvu],
 570                             [Disable the support of djvu viewer])],
 571             [enable_djvu=$enableval],
 572             [enable_djvu=yes])
 573
 574 if test "x$enable_djvu" = "xyes"; then
 575     DJVULIBRE_REQUIRED=3.5.17
 576     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 577
 578     if test "x$enable_djvu" = "xyes"; then
 579         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 580     else
 581         AC_MSG_WARN([
 582 ** Djvu support is disabled since a recent version of the djvulibre
 583 ** library was not found. You need at least djvulibre-3.5.17 which
 584 ** can be found on http://djvulibre.djvuzone.org
 585 ])
 586     fi
 587 fi
 588
 589 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 590
 591 dnl ================== End of djvu checks ===================================================
 592
 593 dnl ================== dvi checks ===================================================
 594
 595 AC_ARG_ENABLE(dvi,
 596             [AS_HELP_STRING([--disable-dvi],
 597             [Disable the support of dvi viewer])],
 598             [enable_dvi=$enableval],
 599             [enable_dvi=yes])
 600
 601 AC_ARG_ENABLE(t1lib,
 602             [AS_HELP_STRING([--enable-t1lib],
 603                             [Compile with support of t1lib for type1 fonts in dvi])],
 604             [enable_type1_fonts=$enableval],
 605             [enable_type1_fonts=no])
 606
 607 if test "x$enable_dvi" = "xyes"; then
 608     AC_C_CONST
 609     AC_C_INLINE
 610     AC_TYPE_SIZE_T
 611     AC_CHECK_SIZEOF(long, 4)
 612     AC_CHECK_SIZEOF(int, 4)
 613     AC_CHECK_SIZEOF(short, 2)
 614     AC_CHECK_SIZEOF(void *, 4)
 615     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 616
 617     if test "x$enable_dvi" = "xyes"; then
 618         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 619     else
 620         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 621     fi
 622 fi
 623 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 624
 625 if test "x$enable_dvi" = "xyes"; then
 626     if test "x$enable_type1_fonts" = "xyes"; then
 627         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 628     fi
 629
 630     if test "x$enable_type1_fonts" = xyes; then
 631         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 632     fi
 633 else
 634     enable_type1_fonts=no
 635 fi
 636 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 637
 638 dnl ================== End of dvi checks ===================================================
 639
 640 dnl ================== pixbuf checks ===================================================
 641
 642 AC_ARG_ENABLE(pixbuf,
 643             [AS_HELP_STRING([--enable-pixbuf],
 644                             [Compile with support of pixbuf])],
 645             [enable_pixbuf=$enableval],
 646             [enable_pixbuf=no])
 647
 648 if test "x$enable_pixbuf" = "xyes"; then
 649         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 650 fi
 651
 652 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 653
 654 dnl ================== End of pixbuf checks ===================================================
 655
 656 dnl ================== comic book checks ===================================================
 657
 658 AC_ARG_ENABLE(comics,
 659         [AS_HELP_STRING([--enable-comics],
 660                         [Compile with support for comic book archives])],
 661         [enable_comics=$enableval],
 662         [enable_comics=yes])
 663
 664 if test "x$enable_comics" = "xyes"; then
 665         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 666 fi
 667 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 668
 669 dnl ================== End of comic book checks ============================================
 670
 671 dnl ================== impress book checks ===================================================
 672
 673 AC_ARG_ENABLE(impress,
 674         [AS_HELP_STRING([--enable-impress],
 675                         [Compile with support for impress presentations])],
 676         [enable_impress=$enableval],
 677         [enable_impress=no])
 678
 679 if test "x$enable_impress" = "xyes"; then
 680         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 681 fi
 682 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 683
 684 dnl ================== End of impress book checks ============================================
 685
 686 dnl =================== Mime types list ====================================================
 687
 688 if test "x$enable_pdf" = "xyes" ; then
 689         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 690 fi
 691 if test "x$enable_ps" = "xyes" ; then
 692         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 693 fi
 694 if test "x$enable_dvi" = "xyes"; then
 695         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 696 fi
 697 if test "x$enable_djvu" = "xyes"; then
 698         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 699 fi
 700 if test "x$enable_tiff" = "xyes"; then
 701         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 702 fi
 703 if test "x$enable_comics" = "xyes"; then
 704         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;application/x-cbt;"
 705 fi
 706 if test "x$enable_pixbuf" = "xyes"; then
 707         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 708 fi
 709 if test "x$enable_impress" = "xyes"; then
 710         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 711 fi
 712 AC_SUBST(EVINCE_MIME_TYPES)
 713
 714 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 715
 716 # *****************
 717 # Help files
 718 # *****************
 719
 720 GNOME_DOC_INIT([], gnome_doc_utils=yes, gnome_doc_utils=no)
 721
 722 AC_ARG_ENABLE(help,
 723     [AS_HELP_STRING([--disable-help], [Disable offline help files])],
 724     [enable_help=$enableval],
 725     [enable_help=yes])
 726
 727 if test "x$enable_help" = "xyes" && test "x$os_win32" = "xyes" ; then
 728     AC_MSG_WARN([Offline help is disabled (not implemented on Windows).])
 729     enable_help=no
 730 fi
 731
 732 if test "x$enable_help" = "xyes" && test "x$gnome_doc_utils" == "xno"; then
 733     AC_MSG_ERROR(
 734        [gnome-doc-utils not found; use --disable-help to disable help files]
 735     )
 736 fi
 737
 738 if test "x$enable_help" = "xyes"; then
 739     AC_DEFINE([OFFLINE_HELP_ENABLED], [1], [Enable offline help])
 740 fi
 741
 742 AM_CONDITIONAL(ENABLE_HELP, test "x$enable_help" = "xyes")
 743
 744 # *****************
 745 # API documentation
 746 # *****************
 747
 748 GTK_DOC_CHECK([1.13],[--flavour no-tmpl])
 749
 750 AC_SUBST([GLIB_PREFIX],[$($PKG_CONFIG --variable=prefix glib-2.0)])
 751 AC_SUBST([GTK_PREFIX],[$($PKG_CONFIG --variable=prefix gtk+-2.0)])
 752
 753 # ******************
 754 # Backends directory
 755 # ******************
 756
 757 AC_SUBST([backenddir],"\$(libdir)/evince/ev_binary_version/backends")
 758 AC_SUBST([backend_binary_version],"ev_binary_version")
 759
 760 # **********
 761 # Versioning
 762 # **********
 763
 764 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
 765 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
 766 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
 767
 768 AC_SUBST([EV_API_VERSION],[ev_api_version])
 769 AC_SUBST([EV_BINARY_VERSION],[ev_binary_version])
 770
 771 AC_SUBST([EV_DOCUMENT_LT_VERSION_INFO],[ev_document_lt_version_info])
 772 AC_SUBST([EV_DOCUMENT_LT_CURRENT_MINUS_AGE],[ev_document_lt_current_minus_age])
 773 AC_SUBST([EV_VIEW_LT_VERSION_INFO],[ev_view_lt_version_info])
 774 AC_SUBST([EV_VIEW_LT_CURRENT_MINUS_AGE],[ev_view_lt_current_minus_age])
 775
 776 # *****************************************************************************
 777 # *****************************************************************************
 778
 779 AC_CONFIG_FILES([
 780 backend/Makefile
 781 backend/comics/Makefile
 782 backend/djvu/Makefile
 783 backend/dvi/Makefile
 784 backend/dvi/mdvi-lib/Makefile
 785 backend/impress/Makefile
 786 backend/pdf/Makefile
 787 backend/pixbuf/Makefile
 788 backend/ps/Makefile
 789 backend/tiff/Makefile
 790 cut-n-paste/Makefile
 791 cut-n-paste/gimpcellrenderertoggle/Makefile
 792 cut-n-paste/smclient/Makefile
 793 cut-n-paste/toolbar-editor/Makefile
 794 cut-n-paste/zoom-control/Makefile
 795 cut-n-paste/totem-screensaver/Makefile
 796 data/evince.desktop.in
 797 data/Makefile
 798 data/icons/Makefile
 799 data/icons/16x16/Makefile
 800 data/icons/16x16/apps/Makefile
 801 data/icons/16x16/actions/Makefile
 802 data/icons/16x16/mimetypes/Makefile
 803 data/icons/22x22/Makefile
 804 data/icons/22x22/apps/Makefile
 805 data/icons/22x22/actions/Makefile
 806 data/icons/22x22/mimetypes/Makefile
 807 data/icons/24x24/Makefile
 808 data/icons/24x24/apps/Makefile
 809 data/icons/24x24/actions/Makefile
 810 data/icons/24x24/mimetypes/Makefile
 811 data/icons/32x32/Makefile
 812 data/icons/32x32/actions/Makefile
 813 data/icons/32x32/mimetypes/Makefile
 814 data/icons/48x48/Makefile
 815 data/icons/48x48/apps/Makefile
 816 data/icons/48x48/actions/Makefile
 817 data/icons/scalable/Makefile
 818 data/icons/scalable/apps/Makefile
 819 data/icons/scalable/actions/Makefile
 820 data/icons/scalable/mimetypes/Makefile
 821 help/Makefile
 822 help/reference/Makefile
 823 help/reference/libdocument/Makefile
 824 help/reference/libdocument/version.xml
 825 help/reference/libview/Makefile
 826 help/reference/libview/version.xml
 827 help/reference/shell/Makefile
 828 help/reference/shell/version.xml
 829 libdocument/Makefile
 830 libdocument/ev-version.h
 831 libmisc/Makefile
 832 libview/Makefile
 833 Makefile
 834 po/Makefile.in
 835 previewer/Makefile
 836 properties/Makefile
 837 shell/Makefile
 838 test/Makefile
 839 thumbnailer/Makefile
 840 ])
 841
 842 AC_CONFIG_FILES(evince-document-[]ev_api_version[].pc:evince-document.pc.in)
 843 AC_CONFIG_FILES(evince-view-[]ev_api_version[].pc:evince-view.pc.in)
 844
 845 AC_OUTPUT
 846
 847 echo "
 848 Configure summary:
 849         Platform...........:  $with_platform
 850         GConf Support......:  $with_gconf
 851         GTK+ Unix Print....:  $with_gtk_unix_print
 852         Keyring Support....:  $with_keyring
 853         DBUS Support.......:  $enable_dbus
 854         SM client support..:  $with_smclient
 855         Help files.........:  $enable_help
 856         Nautilus Plugin....:  $enable_nautilus
 857         Thumbnailer........:  $enable_thumbnailer
 858         Previewer..........:  $enable_previewer
 859         Gtk-Doc Support....:  $enable_gtk_doc
 860         Debug mode.........:  $enable_debug
 861         GObj. Introspection:  $enable_introspection
 862         Tests..............:  $enable_tests
 863
 864         PDF Backend........:  $enable_pdf
 865         PostScript Backend.:  $enable_ps
 866         TIFF Backend.......:  $enable_tiff
 867         DJVU Backend.......:  $enable_djvu
 868         DVI Backend........:  $enable_dvi
 869         Pixbuf Backend.....:  $enable_pixbuf
 870         Comics Backend.....:  $enable_comics
 871         Impress Backend....:  $enable_impress
 872 "