configure.ac

   1 # *****************************************************************************
   2 # Versioning
   3 # *****************************************************************************
   4
   5 m4_define([ev_major_version],[2])
   6 m4_define([ev_minor_version],[31])
   7 m4_define([ev_micro_version],[5])
   8 m4_define([ev_extra_version],[])
   9 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version()ev_extra_version])
  10
  11 # The evince API version
  12 m4_define([ev_api_version], [2.30])
  13
  14 # Libtool versioning. The backend and view libraries have separate versions.
  15 # Before making a release, the libtool version should be modified.
  16 # The string is of the form C:R:A.
  17 # - If interfaces have been changed or added, but binary compatibility has
  18 #   been preserved, change to C+1:0:A+1
  19 # - If binary compatibility has been broken (eg removed or changed interfaces)
  20 #   change to C+1:0:0
  21 # - If the interface is the same as the previous version, change to C:R+1:A
  22
  23 # Libtool version of the backend library
  24 m4_define([ev_document_lt_current],[2])
  25 m4_define([ev_document_lt_revision],[0])
  26 m4_define([ev_document_lt_age],[0])
  27 m4_define([ev_document_lt_version_info],[ev_document_lt_current:ev_document_lt_revision:ev_document_lt_age])
  28 m4_define([ev_document_lt_current_minus_age],[m4_eval(ev_document_lt_current - ev_document_lt_age)])
  29
  30 # Libtool version of the view library
  31 m4_define([ev_view_lt_current],[2])
  32 m4_define([ev_view_lt_revision],[0])
  33 m4_define([ev_view_lt_age],[0])
  34 m4_define([ev_view_lt_version_info],[ev_view_lt_current:ev_view_lt_revision:ev_view_lt_age])
  35 m4_define([ev_view_lt_current_minus_age],[m4_eval(ev_view_lt_current - ev_view_lt_age)])
  36
  37 # Binary version for the document backends
  38 m4_define([ev_binary_version],[ev_document_lt_current])
  39
  40 # *****************************************************************************
  41
  42 AC_PREREQ([2.57])
  43 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
  44 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2 no-dist-gzip])
  45
  46 AC_CONFIG_HEADERS([config.h])
  47 AC_CONFIG_MACRO_DIR([m4])
  48
  49 if test -z "$enable_maintainer_mode"; then
  50   enable_maintainer_mode=yes
  51 fi
  52 AM_MAINTAINER_MODE([enable])
  53
  54 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  55
  56 AM_PROG_LIBTOOL
  57
  58 AC_ISC_POSIX
  59 AC_PROG_CC
  60 AM_PROG_CC_STDC
  61 AM_PROG_CC_C_O
  62 AC_PROG_CXX
  63 AC_STDC_HEADERS
  64
  65 AC_PROG_SED
  66 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  67 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  68
  69 GNOME_MAINTAINER_MODE_DEFINES
  70 GNOME_COMPILE_WARNINGS
  71 GNOME_CXX_WARNINGS
  72
  73 dnl FIXME: remove this when required gtk+ >= 2.19.7
  74 DISABLE_DEPRECATED=
  75 AC_SUBST([DISABLE_DEPRECATED])
  76
  77 IT_PROG_INTLTOOL([0.35.0])
  78
  79 GETTEXT_PACKAGE=evince
  80 AC_SUBST(GETTEXT_PACKAGE)
  81 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  82 AM_GLIB_GNU_GETTEXT
  83
  84 m4_pattern_allow([AM_V_GEN])dnl Make autoconf not complain about the rule below
  85 EV_INTLTOOL_EVINCE_BACKEND_RULE='%.evince-backend:   %.evince-backend.in   $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; $(AM_V_GEN) LC_ALL=C $(INTLTOOL_MERGE) -d -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@'
  86 AC_SUBST([EV_INTLTOOL_EVINCE_BACKEND_RULE])
  87
  88 GLIB_GSETTINGS
  89
  90 # Check which platform to use
  91
  92 AC_MSG_CHECKING([for which platform to build])
  93 AC_ARG_WITH([platform],
  94   [AS_HELP_STRING([--with-platform=gnome|win32|hildon],
  95                   [Setting platform (default: gnome)])],
  96   [case "$withval" in
  97     gnome|win32|hildon) ;;
  98     *) AC_MSG_ERROR([invalid argument "$withval" for --with-platform]) ;;
  99    esac],
 100   [case "$host" in
 101      *-*-mingw*|*-*-cygwin*) with_platform="win32" ;;
 102      *) with_platform=gnome ;;
 103    esac])
 104
 105 AC_MSG_RESULT([$with_platform])
 106
 107 if test "$with_platform" = "win32"; then
 108   AC_CHECK_TOOL([WINDRES],[windres])
 109   AC_MSG_CHECKING([for native Win32])
 110   case "$host" in
 111     *-*-mingw*)
 112       os_win32=yes
 113       ;;
 114     *)
 115       os_win32=no
 116       ;;
 117   esac
 118   AC_MSG_RESULT([$os_win32])
 119 fi
 120
 121 AM_CONDITIONAL([PLATFORM_HILDON],[test "$with_platform" = "hildon"])
 122 AM_CONDITIONAL([PLATFORM_WIN32],[test "$with_platform" = "win32"])
 123
 124 dnl Specify required versions of dependencies
 125 GTK_REQUIRED=2.90.5
 126 GLIB_REQUIRED=2.25.11
 127 KEYRING_REQUIRED=2.22.0
 128 AC_SUBST([GLIB_REQUIRED])
 129 AC_SUBST([GTK_REQUIRED])
 130
 131 GNOME_ICON_THEME_REQUIRED=2.17.1
 132 LIBXML_REQUIRED=2.5.0
 133
 134 dnl Check dependencies
 135
 136 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
 137 # BACKEND_CFLAGS   for backend implementations.
 138 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
 139 # FRONTEND_LIBS
 140 # SHELL_CFLAGS     for shell implementation.
 141 # SHELL_LIBS
 142
 143
 144 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-3.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
 145 PKG_CHECK_MODULES(LIBVIEW, gtk+-3.0 >= $GTK_REQUIRED gail-3.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 146 PKG_CHECK_MODULES(BACKEND, gtk+-3.0 >= $GTK_REQUIRED)
 147 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-3.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 148
 149 SHELL_PLATFORM_PKGS=
 150 case "$with_platform" in
 151   hildon) AC_DEFINE([PLATFORM_HILDON],[1],[Define if building for the hildon platform])
 152           SHELL_PLATFORM_PKGS="hildon-1 hildon-fm-2 libosso"
 153           ;;
 154   gnome)
 155         # Evince has a rather soft run-time dependency on hicolor-icon-theme.
 156         # If the hicolor theme is not available, Evince fails to display some
 157         # icons. Because we cannot check for it at run-time, we instead
 158         # would like to require the icon theme at compile-time. But, because
 159         # the hicolor-icon-theme does not have a pkgconfig file, on gnome we
 160         # require the gnome icon theme instead.
 161         SHELL_PLATFORM_PKGS="gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED"
 162         # The totem-screensaver and egg_smclient code use x11 directly.
 163         SHELL_PLATFORM_PKGS="$SHELL_PLATFORM_PKGS x11"
 164         ;;
 165   *)
 166         # On all other platforms we issue a warning about the runtime
 167         # dependency.
 168         AC_MSG_WARN([Evince has a soft run-time dependency on hicolor-icon-theme. You are advised to have this theme installed when running Evince.]);
 169         SHELL_PLATFORM_PKGS=""
 170         ;;
 171 esac
 172
 173 PKG_CHECK_MODULES([SHELL_CORE],[libxml-2.0 >= $LIBXML_REQUIRED gtk+-3.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gthread-2.0 $SHELL_PLATFORM_PKGS])
 174
 175 # *********
 176 # SM client
 177 # *********
 178
 179 GDK_TARGET="$($PKG_CONFIG --variable target gdk-3.0)"
 180
 181 AC_MSG_CHECKING([which smclient backend to use])
 182 AC_ARG_WITH([smclient],
 183   [AS_HELP_STRING([--with-smclient-backend=no|xsmp|win32|quartz],
 184                   [Setting smclient backend (default:auto)])],
 185   [],
 186   [case "$GDK_TARGET" in
 187     x11) case "$with_platform" in
 188            gnome) with_smclient=xsmp ;;
 189            *) with_smclient=no ;;
 190          esac ;;
 191     win32|quartz) with_smclient=$GDK_TARGET ;;
 192     *) with_smclient=no ;;
 193    esac])
 194
 195 AC_MSG_RESULT([$with_smclient])
 196
 197 if test "$with_smclient" != "no"; then
 198   AC_DEFINE([WITH_SMCLIENT],[1],[Define if smclient is enabled])
 199
 200   case "$with_smclient" in
 201     xsmp) SMCLIENT_PKGS="sm >= 1.0.0" ;;
 202     *) SMCLIENT_PKGS="" ;;
 203   esac
 204
 205   PKG_CHECK_MODULES([SMCLIENT],[gtk+-3.0 gthread-2.0 $SMCLIENT_PKGS])
 206   AC_SUBST([SMCLIENT_CFLAGS])
 207   AC_SUBST([SMCLIENT_LIBS])
 208 fi
 209
 210 AM_CONDITIONAL([WITH_SMCLIENT],[test "$with_smclient" != "no"])
 211 AM_CONDITIONAL([WITH_SMCLIENT_XSMP],[test "$with_smclient" = "xsmp"])
 212 AM_CONDITIONAL([WITH_SMCLIENT_WIN32],[test "$with_smclient" = "win32"])
 213 AM_CONDITIONAL([WITH_SMCLIENT_QUARTZ],[test "$with_smclient" = "quartz"])
 214
 215 # ***
 216
 217 BACKEND_LIBTOOL_FLAGS="-module -avoid-version -no-undefined -export-symbols \$(top_srcdir)/backend/backend.symbols"
 218 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
 219
 220 dnl ===== Check special functions
 221 evince_save_LIBS=$LIBS
 222 LIBS="$LIBS $BACKEND_LIBS"
 223 AC_CHECK_FUNCS(cairo_format_stride_for_width)
 224 LIBS=$evince_save_LIBS
 225
 226 # ******************
 227 # GKT+ Unix Printing
 228 # ******************
 229
 230 AC_MSG_CHECKING([whether gtk+-unix-print support is requested])
 231 AC_ARG_WITH([gtk-unix-print],
 232   [AS_HELP_STRING([--without-gtk-unix-print],
 233                   [Disable the use of gtk-unix-print])],
 234   [],[case "$os_win32" in
 235         yes) with_gtk_unix_print=no ;;
 236         *) with_gtk_unix_print=yes ;;
 237       esac])
 238
 239 AC_MSG_RESULT([$with_gtk_unix_print])
 240
 241 if test "$with_gtk_unix_print" = "yes"; then
 242    PKG_CHECK_MODULES(GTKUNIXPRINT, [gtk+-unix-print-3.0 >= $GTK_REQUIRED])
 243    AC_DEFINE([GTKUNIXPRINT_ENABLED], [1], [Define if gtk+-unix-print is enabled.])
 244 fi
 245
 246 # *********************
 247 # GNOME Keyring support
 248 # *********************
 249
 250 AC_ARG_WITH(keyring,
 251         [AS_HELP_STRING([--without-keyring],
 252                         [Disable the use of gnome-keyring])],
 253         [],
 254         [case "$with_platform" in
 255            gnome) with_keyring=yes ;;
 256            hildon|win32) with_keyring=no ;;
 257          esac])
 258
 259 AM_CONDITIONAL([WITH_KEYRING],[test "$with_keyring" = "yes"])
 260
 261 if test "$with_keyring" = "yes"; then
 262         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
 263         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
 264 fi
 265
 266 # ****
 267 # DBUS
 268 # ****
 269
 270 AC_ARG_ENABLE([dbus],
 271   [AS_HELP_STRING([--disable-dbus], [Disable support for dbus])],
 272   [],
 273   [case "$with_platform" in
 274       gnome) enable_dbus=yes ;;
 275       hildon) enable_dbus=no ;;
 276     esac])
 277
 278 if test "$enable_dbus" = "yes"; then
 279   AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 280
 281    PKG_CHECK_MODULES([EV_DAEMON], [gio-2.0 >= $GLIB_REQUIRED])
 282 fi
 283
 284 AM_CONDITIONAL([ENABLE_DBUS], [test "$enable_dbus" = "yes"])
 285
 286 dnl ========= Check for Desktop Schemas
 287 PKG_CHECK_MODULES([DESKTOP_SCHEMAS], [gsettings-desktop-schemas],
 288                   has_desktop_schemas=yes, has_desktop_schemas=no)
 289 if test x$has_desktop_schemas = xyes; then
 290    AC_DEFINE([HAVE_DESKTOP_SCHEMAS], [1], [Whether GSettings Desktop Schemas are available])
 291 fi
 292
 293 dnl ========= Check for GConf
 294
 295 AC_MSG_CHECKING([whether GConf support is requested])
 296 AC_ARG_WITH([gconf],
 297   [AS_HELP_STRING([--without-gconf],
 298                   [Disable the use of gconf])],
 299   [],
 300   [case "$os_win32" in
 301      yes) with_gconf=no ;;
 302      *) with_gconf=yes ;;
 303    esac])
 304 AC_MSG_RESULT([$with_gconf])
 305
 306 AM_CONDITIONAL([WITH_GCONF],[test "$with_gconf" = "yes"])
 307
 308 if test "$with_gconf" = "yes"; then
 309    PKG_CHECK_MODULES([GCONF],[gconf-2.0])
 310    AC_DEFINE([WITH_GCONF],[1],[Define if GConf support is enabled])
 311
 312    AM_GCONF_SOURCE_2
 313
 314    AC_PATH_PROG([GCONFTOOL], [gconftool-2], [false])
 315    if test "$GCONFTOOL" = "false"; then
 316       AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 317    fi
 318 else
 319    AM_CONDITIONAL([GCONF_SCHEMAS_INSTALL],false)
 320 fi
 321
 322 dnl Debug mode
 323
 324 AC_ARG_ENABLE([debug],
 325         AS_HELP_STRING([--enable-debug],
 326                        [Turn on evince debug mode]),
 327         [enable_debug=$enableval],
 328         [enable_debug=no])
 329
 330 if test "x$enable_debug" = "xyes"; then
 331    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 332 fi
 333
 334 AC_ARG_ENABLE([tests],
 335         AS_HELP_STRING([--enable-tests], [Enable the tests]),
 336         [enable_tests=$enableval],
 337         [enable_tests=yes])
 338
 339 AM_CONDITIONAL(ENABLE_TESTS, test x$enable_tests = xyes)
 340
 341 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 342 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 343 AC_SUBST(LIBDOCUMENT_CFLAGS)
 344 AC_SUBST(LIBDOCUMENT_LIBS)
 345
 346 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 347 LIBVIEW_LIBS="$LIBVIEW_LIBS $GTKUNIXPRINT_LIBS -lm"
 348 AC_SUBST(LIBVIEW_CFLAGS)
 349 AC_SUBST(LIBVIEW_LIBS)
 350
 351 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 352 BACKEND_LIBS="$BACKEND_LIBS -lm"
 353 AC_SUBST(BACKEND_CFLAGS)
 354 AC_SUBST(BACKEND_LIBS)
 355
 356 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $KEYRING_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 357 SHELL_LIBS="$SHELL_CORE_LIBS $KEYRING_LIBS -lz -lm"
 358 AC_SUBST(SHELL_CFLAGS)
 359 AC_SUBST(SHELL_LIBS)
 360
 361 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 362 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 363 AC_SUBST(FRONTEND_CFLAGS)
 364 AC_SUBST(FRONTEND_LIBS)
 365
 366 EV_DAEMON_CFLAGS="$EV_DAEMON_CFLAGS $DEBUG_FLAGS"
 367 AC_SUBST([EV_DAEMON_CFLAGS])
 368 AC_SUBST([EV_DAEMON_LIBS])
 369
 370 # Check for Nautilus property page build
 371 AC_ARG_ENABLE([nautilus],
 372   [AS_HELP_STRING([--disable-nautilus],
 373                   [Disable build of nautilus extensions])],
 374   [],
 375   [case "$with_platform" in
 376      gnome) enable_nautilus=yes ;;
 377      *) enable_nautilus=no ;;
 378     esac])
 379
 380 if test "$enable_nautilus" = "yes" ; then
 381   PKG_CHECK_MODULES([NAUTILUS],[gtk+-x11-3.0 $MM gthread-2.0 libnautilus-extension],
 382                     [],[AC_MSG_ERROR([libnautilus-extension not found; use --disable-nautilus to disable the nautilus extensions])])
 383   NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 384   AC_SUBST([nautilusextensiondir],[$NAUTILUS_EXTENSION_DIR])
 385   AC_SUBST(NAUTILUS_CFLAGS)
 386   AC_SUBST(NAUTILUS_LIBS)
 387
 388   AC_DEFINE([HAVE_NAUTILUS],[1], [defined if you build the nautilus plugin])
 389 fi
 390
 391 AM_CONDITIONAL([ENABLE_NAUTILUS],[test "$enable_nautilus" = "yes"])
 392
 393 # Check for thumbnailer build
 394
 395 AC_ARG_ENABLE([thumbnailer],
 396   [AS_HELP_STRING([--disable-thumbnailer],
 397                   [Disable GNOME thumbnailer])],
 398   [],
 399   [case "$with_platform" in
 400      gnome) enable_thumbnailer=yes ;;
 401      *) enable_thumbnailer=no ;;
 402     esac])
 403
 404 AM_CONDITIONAL([ENABLE_THUMBNAILER],[test "$enable_thumbnailer" = "yes"])
 405
 406 # ***************
 407 # Print Previewer
 408 # ***************
 409
 410 AC_ARG_ENABLE([previewer],
 411   [AS_HELP_STRING([--disable-previewer],
 412                   [Disable the GNOME Document Previewer])],
 413   [],
 414   [case "$with_platform" in
 415       gnome) enable_previewer=yes ;;
 416       *) enable_previewer=no ;;
 417     esac])
 418
 419 if test x$enable_previewer = "xyes" ; then
 420   PKG_CHECK_MODULES([PREVIEWER],[gtk+-3.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED])
 421 fi
 422
 423 AM_CONDITIONAL([ENABLE_PREVIEWER],[test "$enable_previewer" = "yes"])
 424 PREVIEWER_CFLAGS="$PREVIEWER_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 425 PREVIEWER_LIBS="$PREVIEWER_LIBS $GTKUNIXPRINT_LIBS -lz"
 426 AC_SUBST(PREVIEWER_CFLAGS)
 427 AC_SUBST(PREVIEWER_LIBS)
 428
 429 # ***
 430 # GIR
 431 # ***
 432
 433 AC_MSG_CHECKING([whether GObject introspection is requested])
 434 AC_ARG_ENABLE([introspection],
 435         AS_HELP_STRING([--enable-introspection],
 436                        [Enable GObject introspection]),
 437         [enable_introspection=$enableval],
 438         [enable_introspection=no])
 439 AC_MSG_RESULT([$enable_introspection])
 440
 441 G_IR_SCANNER=
 442 G_IR_COMPILER=
 443 G_IR_GENERATE=
 444 GIRDIR=
 445 GIRTYPELIBDIR=
 446
 447 if test "$enable_introspection" = "yes"; then
 448   GOBJECT_INTROSPECTION_REQUIRED=0.6
 449   PKG_CHECK_MODULES([GOBJECT_INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
 450
 451   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
 452   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
 453   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
 454   GIRDIR="$($PKG_CONFIG --variable=girdir gobject-introspection-1.0)"
 455   GIRTYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
 456 fi
 457
 458 AC_SUBST([G_IR_SCANNER])
 459 AC_SUBST([G_IR_COMPILER])
 460 AC_SUBST([G_IR_GENERATE])
 461 AC_SUBST([GIRDIR])
 462 AC_SUBST([GIRTYPELIBDIR])
 463
 464 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
 465
 466 dnl ================== portability checks ===========================================
 467
 468 dnl for backtrace()
 469 AC_CHECK_HEADERS([execinfo.h])
 470
 471 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 472   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 473   ],[],[#include <langinfo.h>])
 474
 475 dnl ================== pdf checks ===================================================
 476 AC_ARG_ENABLE([pdf],
 477   [AS_HELP_STRING([--disable-pdf],
 478                   [Disable the PDF support])],
 479   [enable_pdf=$enableval],
 480   [enable_pdf=yes])
 481
 482 if test "x$enable_pdf" = "xyes"; then
 483     POPPLER_REQUIRED=0.14.0
 484     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED,enable_pdf=yes,enable_pdf=no)
 485
 486     if test "x$enable_pdf" = "xyes"; then
 487             evince_save_LIBS=$LIBS
 488             LIBS="$LIBS $POPPLER_LIBS"
 489             AC_CHECK_FUNCS(poppler_page_get_text_layout)
 490             AC_CHECK_FUNCS(poppler_page_get_selected_text)
 491             AC_CHECK_FUNCS(poppler_page_add_annot)
 492             LIBS=$evince_save_LIBS
 493             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 494             if test x$enable_cairo_pdf = xyes; then
 495                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 496             fi
 497
 498             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 499             if test x$enable_cairo_ps = xyes; then
 500                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 501             fi
 502     else
 503             AC_MSG_ERROR("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 504     fi
 505 fi
 506
 507 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 508 dnl ================== end of pdf checks ============================================
 509
 510 dnl libspectre (used by ps and dvi backends)
 511 SPECTRE_REQUIRED=0.2.0
 512 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 513 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 514 if test "x$have_spectre" = "xyes"; then
 515    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 516 fi
 517
 518 dnl ================== ps checks ====================================================
 519 AC_ARG_ENABLE(ps,
 520         [AS_HELP_STRING([--disable-ps],
 521                         [Disable the PostScript backend])],
 522         [enable_ps=$enableval],
 523         [enable_ps=yes])
 524
 525 if test "x$enable_ps" = "xyes"; then
 526    if test "x$have_spectre" = "xyes"; then
 527       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 528    else
 529       enable_ps="no"
 530       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 531    fi
 532 fi
 533 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 534 dnl ======================== End of ps checks ===================================
 535
 536 dnl ================== tiff checks ===================================================
 537 AC_ARG_ENABLE(tiff,
 538             [AS_HELP_STRING([--disable-tiff],
 539                             [Disable the support of multipage tiff])],
 540             [enable_tiff=$enableval],
 541             [enable_tiff=yes])
 542
 543 if test "x$enable_tiff" = "xyes"; then
 544     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 545     if test "x$enable_tiff" = "xyes"; then
 546         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 547         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 548     fi
 549     if test "x$enable_tiff" = "xyes"; then
 550             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 551     else
 552             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 553     fi
 554 fi
 555
 556 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 557 dnl ================== end of tiff checks ============================================
 558
 559 dnl ================== djvu checks ===================================================
 560
 561 AC_ARG_ENABLE(djvu,
 562             [AS_HELP_STRING([--disable-djvu],
 563                             [Disable the support of djvu viewer])],
 564             [enable_djvu=$enableval],
 565             [enable_djvu=yes])
 566
 567 if test "x$enable_djvu" = "xyes"; then
 568     DJVULIBRE_REQUIRED=3.5.17
 569     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 570
 571     if test "x$enable_djvu" = "xyes"; then
 572         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 573     else
 574         AC_MSG_WARN([
 575 ** Djvu support is disabled since a recent version of the djvulibre
 576 ** library was not found. You need at least djvulibre-3.5.17 which
 577 ** can be found on http://djvulibre.djvuzone.org
 578 ])
 579     fi
 580 fi
 581
 582 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 583
 584 dnl ================== End of djvu checks ===================================================
 585
 586 dnl ================== dvi checks ===================================================
 587
 588 AC_ARG_ENABLE(dvi,
 589             [AS_HELP_STRING([--disable-dvi],
 590             [Disable the support of dvi viewer])],
 591             [enable_dvi=$enableval],
 592             [enable_dvi=yes])
 593
 594 AC_ARG_ENABLE(t1lib,
 595             [AS_HELP_STRING([--enable-t1lib],
 596                             [Compile with support of t1lib for type1 fonts in dvi])],
 597             [enable_type1_fonts=$enableval],
 598             [enable_type1_fonts=no])
 599
 600 if test "x$enable_dvi" = "xyes"; then
 601     AC_C_CONST
 602     AC_C_INLINE
 603     AC_TYPE_SIZE_T
 604     AC_CHECK_SIZEOF(long, 4)
 605     AC_CHECK_SIZEOF(int, 4)
 606     AC_CHECK_SIZEOF(short, 2)
 607     AC_CHECK_SIZEOF(void *, 4)
 608     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 609
 610     if test "x$enable_dvi" = "xyes"; then
 611         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 612     else
 613         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 614     fi
 615 fi
 616 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 617
 618 if test "x$enable_dvi" = "xyes"; then
 619     if test "x$enable_type1_fonts" = "xyes"; then
 620         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 621     fi
 622
 623     if test "x$enable_type1_fonts" = xyes; then
 624         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 625     fi
 626 else
 627     enable_type1_fonts=no
 628 fi
 629 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 630
 631 dnl ================== End of dvi checks ===================================================
 632
 633 dnl ================== pixbuf checks ===================================================
 634
 635 AC_ARG_ENABLE(pixbuf,
 636             [AS_HELP_STRING([--enable-pixbuf],
 637                             [Compile with support of pixbuf])],
 638             [enable_pixbuf=$enableval],
 639             [enable_pixbuf=no])
 640
 641 if test "x$enable_pixbuf" = "xyes"; then
 642         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 643 fi
 644
 645 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 646
 647 dnl ================== End of pixbuf checks ===================================================
 648
 649 dnl ================== comic book checks ===================================================
 650
 651 AC_ARG_ENABLE(comics,
 652         [AS_HELP_STRING([--enable-comics],
 653                         [Compile with support for comic book archives])],
 654         [enable_comics=$enableval],
 655         [enable_comics=yes])
 656
 657 if test "x$enable_comics" = "xyes"; then
 658         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 659 fi
 660 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 661
 662 dnl ================== End of comic book checks ============================================
 663
 664 dnl ================== impress book checks ===================================================
 665
 666 AC_ARG_ENABLE(impress,
 667         [AS_HELP_STRING([--enable-impress],
 668                         [Compile with support for impress presentations])],
 669         [enable_impress=$enableval],
 670         [enable_impress=no])
 671
 672 if test "x$enable_impress" = "xyes"; then
 673         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 674 fi
 675 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 676
 677 dnl ================== End of impress book checks ============================================
 678
 679 dnl =================== Mime types list ====================================================
 680
 681 if test "x$enable_pdf" = "xyes" ; then
 682         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 683 fi
 684 if test "x$enable_ps" = "xyes" ; then
 685         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 686 fi
 687 if test "x$enable_dvi" = "xyes"; then
 688         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 689 fi
 690 if test "x$enable_djvu" = "xyes"; then
 691         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 692 fi
 693 if test "x$enable_tiff" = "xyes"; then
 694         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 695 fi
 696 if test "x$enable_comics" = "xyes"; then
 697         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;application/x-cbt;"
 698 fi
 699 if test "x$enable_pixbuf" = "xyes"; then
 700         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 701 fi
 702 if test "x$enable_impress" = "xyes"; then
 703         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 704 fi
 705 AC_SUBST(EVINCE_MIME_TYPES)
 706
 707 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 708
 709 # *****************
 710 # Help files
 711 # *****************
 712
 713 GNOME_DOC_INIT([], gnome_doc_utils=yes, gnome_doc_utils=no)
 714
 715 AC_ARG_ENABLE(help,
 716     [AS_HELP_STRING([--disable-help], [Disable offline help files])],
 717     [enable_help=$enableval],
 718     [enable_help=yes])
 719
 720 if test "x$enable_help" = "xyes" && test "x$os_win32" = "xyes" ; then
 721     AC_MSG_WARN([Offline help is disabled (not implemented on Windows).])
 722     enable_help=no
 723 fi
 724
 725 if test "x$enable_help" = "xyes" && test "x$gnome_doc_utils" == "xno"; then
 726     AC_MSG_ERROR(
 727        [gnome-doc-utils not found; use --disable-help to disable help files]
 728     )
 729 fi
 730
 731 if test "x$enable_help" = "xyes"; then
 732     AC_DEFINE([OFFLINE_HELP_ENABLED], [1], [Enable offline help])
 733 fi
 734
 735 AM_CONDITIONAL(ENABLE_HELP, test "x$enable_help" = "xyes")
 736
 737 # *****************
 738 # API documentation
 739 # *****************
 740
 741 GTK_DOC_CHECK([1.13],[--flavour no-tmpl])
 742
 743 AC_SUBST([GLIB_PREFIX],[$($PKG_CONFIG --variable=prefix glib-2.0)])
 744 AC_SUBST([GTK_PREFIX],[$($PKG_CONFIG --variable=prefix gtk+-3.0)])
 745
 746 # ******************
 747 # Backends directory
 748 # ******************
 749
 750 AC_SUBST([backenddir],"\$(libdir)/evince/ev_binary_version/backends")
 751 AC_SUBST([backend_binary_version],"ev_binary_version")
 752
 753 # **********
 754 # Versioning
 755 # **********
 756
 757 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
 758 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
 759 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
 760
 761 AC_SUBST([EV_API_VERSION],[ev_api_version])
 762 AC_SUBST([EV_API_VERSION_U],[AS_TR_SH([ev_api_version])])
 763 AC_SUBST([EV_BINARY_VERSION],[ev_binary_version])
 764
 765 AC_SUBST([EV_DOCUMENT_LT_VERSION_INFO],[ev_document_lt_version_info])
 766 AC_SUBST([EV_DOCUMENT_LT_CURRENT_MINUS_AGE],[ev_document_lt_current_minus_age])
 767 AC_SUBST([EV_VIEW_LT_VERSION_INFO],[ev_view_lt_version_info])
 768 AC_SUBST([EV_VIEW_LT_CURRENT_MINUS_AGE],[ev_view_lt_current_minus_age])
 769
 770 # *****************************************************************************
 771 # *****************************************************************************
 772
 773 AC_CONFIG_FILES([
 774 backend/Makefile
 775 backend/comics/Makefile
 776 backend/djvu/Makefile
 777 backend/dvi/Makefile
 778 backend/dvi/mdvi-lib/Makefile
 779 backend/impress/Makefile
 780 backend/pdf/Makefile
 781 backend/pixbuf/Makefile
 782 backend/ps/Makefile
 783 backend/tiff/Makefile
 784 cut-n-paste/Makefile
 785 cut-n-paste/gimpcellrenderertoggle/Makefile
 786 cut-n-paste/smclient/Makefile
 787 cut-n-paste/toolbar-editor/Makefile
 788 cut-n-paste/zoom-control/Makefile
 789 cut-n-paste/totem-screensaver/Makefile
 790 cut-n-paste/synctex/Makefile
 791 data/evince.desktop.in
 792 data/Makefile
 793 data/icons/Makefile
 794 data/icons/16x16/Makefile
 795 data/icons/16x16/apps/Makefile
 796 data/icons/16x16/actions/Makefile
 797 data/icons/16x16/mimetypes/Makefile
 798 data/icons/22x22/Makefile
 799 data/icons/22x22/apps/Makefile
 800 data/icons/22x22/actions/Makefile
 801 data/icons/22x22/mimetypes/Makefile
 802 data/icons/24x24/Makefile
 803 data/icons/24x24/apps/Makefile
 804 data/icons/24x24/actions/Makefile
 805 data/icons/24x24/mimetypes/Makefile
 806 data/icons/32x32/Makefile
 807 data/icons/32x32/actions/Makefile
 808 data/icons/32x32/mimetypes/Makefile
 809 data/icons/48x48/Makefile
 810 data/icons/48x48/apps/Makefile
 811 data/icons/48x48/actions/Makefile
 812 data/icons/scalable/Makefile
 813 data/icons/scalable/apps/Makefile
 814 data/icons/scalable/actions/Makefile
 815 data/icons/scalable/mimetypes/Makefile
 816 help/Makefile
 817 help/reference/Makefile
 818 help/reference/libdocument/Makefile
 819 help/reference/libdocument/version.xml
 820 help/reference/libview/Makefile
 821 help/reference/libview/version.xml
 822 help/reference/shell/Makefile
 823 help/reference/shell/version.xml
 824 libdocument/Makefile
 825 libdocument/ev-version.h
 826 libmisc/Makefile
 827 libview/Makefile
 828 Makefile
 829 po/Makefile.in
 830 previewer/Makefile
 831 properties/Makefile
 832 shell/Makefile
 833 test/Makefile
 834 thumbnailer/Makefile
 835 ])
 836
 837 AC_CONFIG_FILES(evince-document-[]ev_api_version[].pc:evince-document.pc.in)
 838 AC_CONFIG_FILES(evince-view-[]ev_api_version[].pc:evince-view.pc.in)
 839
 840 AC_OUTPUT
 841
 842 echo "
 843 Configure summary:
 844         Platform...........:  $with_platform
 845         GConf Support......:  $with_gconf
 846         GTK+ Unix Print....:  $with_gtk_unix_print
 847         Keyring Support....:  $with_keyring
 848         DBUS Support.......:  $enable_dbus
 849         SM client support..:  $with_smclient
 850         Help files.........:  $enable_help
 851         Nautilus Plugin....:  $enable_nautilus
 852         Thumbnailer........:  $enable_thumbnailer
 853         Previewer..........:  $enable_previewer
 854         Gtk-Doc Support....:  $enable_gtk_doc
 855         Debug mode.........:  $enable_debug
 856         GObj. Introspection:  $enable_introspection
 857         Tests..............:  $enable_tests
 858
 859         PDF Backend........:  $enable_pdf
 860         PostScript Backend.:  $enable_ps
 861         TIFF Backend.......:  $enable_tiff
 862         DJVU Backend.......:  $enable_djvu
 863         DVI Backend........:  $enable_dvi
 864         Pixbuf Backend.....:  $enable_pixbuf
 865         Comics Backend.....:  $enable_comics
 866         Impress Backend....:  $enable_impress
 867 "