configure.ac

   1 # *****************************************************************************
   2 # Versioning
   3 # *****************************************************************************
   4
   5 m4_define([ev_major_version],[2])
   6 m4_define([ev_minor_version],[29])
   7 m4_define([ev_micro_version],[4])
   8 m4_define([ev_extra_version],[])
   9 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version()ev_extra_version])
  10
  11 # The evince API version
  12 m4_define([ev_api_version], [2.29])
  13
  14 # Libtool versioning. The backend and view libraries have separate versions.
  15 # Before making a release, the libtool version should be modified.
  16 # The string is of the form C:R:A.
  17 # - If interfaces have been changed or added, but binary compatibility has
  18 #   been preserved, change to C+1:0:A+1
  19 # - If binary compatibility has been broken (eg removed or changed interfaces)
  20 #   change to C+1:0:0
  21 # - If the interface is the same as the previous version, change to C:R+1:A
  22
  23 # Libtool version of the backend library
  24 m4_define([ev_document_lt_current],[2])
  25 m4_define([ev_document_lt_revision],[0])
  26 m4_define([ev_document_lt_age],[0])
  27 m4_define([ev_document_lt_version_info],[ev_document_lt_current:ev_document_lt_revision:ev_document_lt_age])
  28 m4_define([ev_document_lt_current_minus_age],[m4_eval(ev_document_lt_current - ev_document_lt_age)])
  29
  30 # Libtool version of the view library
  31 m4_define([ev_view_lt_current],[2])
  32 m4_define([ev_view_lt_revision],[0])
  33 m4_define([ev_view_lt_age],[0])
  34 m4_define([ev_view_lt_version_info],[ev_view_lt_current:ev_view_lt_revision:ev_view_lt_age])
  35 m4_define([ev_view_lt_current_minus_age],[m4_eval(ev_view_lt_current - ev_view_lt_age)])
  36
  37 # Binary version for the document backends
  38 m4_define([ev_binary_version],[ev_document_lt_current])
  39
  40 # *****************************************************************************
  41
  42 AC_PREREQ([2.57])
  43 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
  44 AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip])
  45
  46 AC_CONFIG_HEADERS([config.h])
  47 AC_CONFIG_MACRO_DIR([m4])
  48
  49 if test -z "$enable_maintainer_mode"; then
  50   enable_maintainer_mode=yes
  51 fi
  52 AM_MAINTAINER_MODE([enable])
  53
  54 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  55
  56 AM_PROG_LIBTOOL
  57
  58 AC_ISC_POSIX
  59 AC_PROG_CC
  60 AM_PROG_CC_STDC
  61 AM_PROG_CC_C_O
  62 AC_PROG_CXX
  63 AC_STDC_HEADERS
  64
  65 AC_PROG_SED
  66 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  67 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  68
  69 GNOME_COMMON_INIT
  70 GNOME_DOC_INIT
  71 GNOME_MAINTAINER_MODE_DEFINES
  72 GNOME_COMPILE_WARNINGS
  73 GNOME_CXX_WARNINGS
  74
  75 GTK_DOC_CHECK(1.0)
  76
  77 IT_PROG_INTLTOOL([0.35.0])
  78
  79 GETTEXT_PACKAGE=evince
  80 AC_SUBST(GETTEXT_PACKAGE)
  81 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  82 AM_GLIB_GNU_GETTEXT
  83
  84 m4_pattern_allow([AM_V_GEN])dnl Make autoconf not complain about the rule below
  85 EV_INTLTOOL_EVINCE_BACKEND_RULE='%.evince-backend:   %.evince-backend.in   $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; $(AM_V_GEN) LC_ALL=C $(INTLTOOL_MERGE) -d -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@'
  86 AC_SUBST([EV_INTLTOOL_EVINCE_BACKEND_RULE])
  87
  88 # Check which platform to use
  89
  90 AC_MSG_CHECKING([for which platform to build])
  91 AC_ARG_WITH([platform],
  92   [AS_HELP_STRING([--with-platform=gnome|win32|hildon],
  93                   [Setting platform (default: gnome)])],
  94   [case "$withval" in
  95     gnome|win32|hildon) ;;
  96     *) AC_MSG_ERROR([invalid argument "$withval" for --with-platform]) ;;
  97    esac],
  98   [case "$host" in
  99      *-*-mingw*|*-*-cygwin*) with_platform="win32" ;;
 100      *) with_platform=gnome ;;
 101    esac])
 102
 103 AC_MSG_RESULT([$with_platform])
 104
 105 if test "$with_platform" = "win32"; then
 106   AC_CHECK_TOOL([WINDRES],[windres])
 107   AC_MSG_CHECKING([for native Win32])
 108   case "$host" in
 109     *-*-mingw*)
 110       os_win32=yes
 111       ;;
 112     *)
 113       os_win32=no
 114       ;;
 115   esac
 116   AC_MSG_RESULT([$os_win32])
 117 fi
 118
 119 AM_CONDITIONAL([PLATFORM_HILDON],[test "$with_platform" = "hildon"])
 120 AM_CONDITIONAL([PLATFORM_WIN32],[test "$with_platform" = "win32"])
 121
 122 dnl Specify required versions of dependencies
 123 DBUS_GLIB_REQUIRED=0.70
 124 GTK_REQUIRED=2.14.0
 125 GLIB_REQUIRED=2.18.0
 126 KEYRING_REQUIRED=2.22.0
 127 AC_SUBST([GLIB_REQUIRED])
 128 AC_SUBST([GTK_REQUIRED])
 129
 130 GNOME_ICON_THEME_REQUIRED=2.17.1
 131 LIBXML_REQUIRED=2.5.0
 132
 133 dnl Check dependencies
 134
 135 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
 136 # BACKEND_CFLAGS   for backend implementations.
 137 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
 138 # FRONTEND_LIBS
 139 # SHELL_CFLAGS     for shell implementation.
 140 # SHELL_LIBS
 141
 142 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
 143 PKG_CHECK_MODULES(LIBVIEW, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 144 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
 145 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 146 PKG_CHECK_MODULES(PREVIEWER, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 147
 148 SHELL_PLATFORM_PKGS=
 149 case "$with_platform" in
 150   hildon) AC_DEFINE([PLATFORM_HILDON],[1],[Define if building for the hildon platform])
 151           SHELL_PLATFORM_PKGS="hildon-1 hildon-fm-2 libosso"
 152           ;;
 153   gnome)
 154         # Evince has a rather soft run-time dependency on hicolor-icon-theme.
 155         # If the hicolor theme is not available, Evince fails to display some
 156         # icons. Because we cannot check for it at run-time, we instead
 157         # would like to require the icon theme at compile-time. But, because
 158         # the hicolor-icon-theme does not have a pkgconfig file, on gnome we
 159         # require the gnome icon theme instead.
 160         SHELL_PLATFORM_PKGS="gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED"
 161         ;;
 162   *)
 163         # On all other platforms we issue a warning about the runtime
 164         # dependency.
 165         AC_MSG_WARN([Evince has a soft run-time dependency on hicolor-icon-theme. You are advised to have this theme installed when running Evince.]);
 166         SHELL_PLATFORM_PKGS=""
 167         ;;
 168 esac
 169
 170 PKG_CHECK_MODULES([SHELL_CORE],[libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gthread-2.0 $SHELL_PLATFORM_PKGS])
 171
 172 # *********
 173 # SM client
 174 # *********
 175
 176 GDK_TARGET="$($PKG_CONFIG --variable target gdk-2.0)"
 177
 178 AC_MSG_CHECKING([which smclient backend to use])
 179 AC_ARG_WITH([smclient],
 180   [AS_HELP_STRING([--with-smclient-backend=no|xsmp|win32|quartz],
 181                   [Setting smclient backend (default:auto)])],
 182   [],
 183   [case "$GDK_TARGET" in
 184     x11) case "$with_platform" in
 185            gnome) with_smclient=xsmp ;;
 186            *) with_smclient=no ;;
 187          esac ;;
 188     win32|quartz) with_smclient=$GDK_TARGET ;;
 189     *) with_smclient=no ;;
 190    esac])
 191
 192 AC_MSG_RESULT([$with_smclient])
 193
 194 if test "$with_smclient" != "no"; then
 195   AC_DEFINE([WITH_SMCLIENT],[1],[Define if smclient is enabled])
 196
 197   case "$with_smclient" in
 198     xsmp) SMCLIENT_PKGS="sm >= 1.0.0" ;;
 199     *) SMCLIENT_PKGS="" ;;
 200   esac
 201
 202   PKG_CHECK_MODULES([SMCLIENT],[gtk+-2.0 gthread-2.0 $SMCLIENT_PKGS])
 203   AC_SUBST([SMCLIENT_CFLAGS])
 204   AC_SUBST([SMCLIENT_LIBS])
 205 fi
 206
 207 AM_CONDITIONAL([WITH_SMCLIENT],[test "$with_smclient" != "no"])
 208 AM_CONDITIONAL([WITH_SMCLIENT_XSMP],[test "$with_smclient" = "xsmp"])
 209 AM_CONDITIONAL([WITH_SMCLIENT_WIN32],[test "$with_smclient" = "win32"])
 210 AM_CONDITIONAL([WITH_SMCLIENT_QUARTZ],[test "$with_smclient" = "quartz"])
 211
 212 # ***
 213
 214 BACKEND_LIBTOOL_FLAGS="-module -avoid-version -no-undefined -export-symbols \$(top_srcdir)/backend/backend.symbols"
 215 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
 216
 217 dnl ===== Check special functions
 218 evince_save_LIBS=$LIBS
 219 LIBS="$LIBS $BACKEND_LIBS"
 220 AC_CHECK_FUNCS(cairo_format_stride_for_width)
 221 AC_CHECK_FUNCS(gtk_print_operation_get_n_pages_to_print)
 222 LIBS=$evince_save_LIBS
 223
 224 # ******************
 225 # GKT+ Unix Printing
 226 # ******************
 227
 228 AC_MSG_CHECKING([whether gtk+-unix-print support is requested])
 229 AC_ARG_WITH([gtk-unix-print],
 230   [AS_HELP_STRING([--without-gtk-unix-print],
 231                   [Disable the use of gtk-unix-print])],
 232   [],[case "$os_win32" in
 233         yes) with_gtk_unix_print=no ;;
 234         *) with_gtk_unix_print=yes ;;
 235       esac])
 236
 237 AC_MSG_RESULT([$with_gtk_unix_print])
 238
 239 if test "$with_gtk_unix_print" = "yes"; then
 240    PKG_CHECK_MODULES(GTKUNIXPRINT, [gtk+-unix-print-2.0 >= $GTK_REQUIRED])
 241    AC_DEFINE([GTKUNIXPRINT_ENABLED], [1], [Define if gtk+-unix-print is enabled.])
 242 fi
 243
 244 # *********************
 245 # GNOME Keyring support
 246 # *********************
 247
 248 AC_ARG_WITH(keyring,
 249         [AS_HELP_STRING([--without-keyring],
 250                         [Disable the use of gnome-keyring])],
 251         [],
 252         [case "$with_platform" in
 253            gnome) with_keyring=yes ;;
 254            hildon|win32) with_keyring=no ;;
 255          esac])
 256
 257 AM_CONDITIONAL([WITH_KEYRING],[test "$with_keyring" = "yes"])
 258
 259 if test "$with_keyring" = "yes"; then
 260         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
 261         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
 262 fi
 263
 264 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
 265 AC_SUBST(GLIB_GENMARSHAL)
 266
 267 # ****
 268 # DBUS
 269 # ****
 270
 271 AC_ARG_ENABLE([dbus],
 272   [AS_HELP_STRING([--disable-dbus], [Disable support for dbus])],
 273   [],
 274   [case "$with_platform" in
 275       gnome) enable_dbus=yes ;;
 276       hildon) enable_dbus=no ;;
 277     esac])
 278
 279 if test "$enable_dbus" = "yes"; then
 280   PKG_CHECK_MODULES([DBUS],[dbus-glib-1 >= $DBUS_GLIB_REQUIRED],[],
 281                     [AC_MSG_ERROR([DBUS not found; use --disable-dbus to disable DBUS support])])
 282
 283   AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 284   if test x$DBUS_BINDING_TOOL = "xno" ; then
 285           AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 286   fi
 287
 288   AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 289 fi
 290
 291 AC_SUBST([DBUS_CFLAGS])
 292 AC_SUBST([DBUS_LIBS])
 293
 294 AM_CONDITIONAL([ENABLE_DBUS], [test "$enable_dbus" = "yes"])
 295
 296 if test "$enable_dbus" = "yes"; then
 297    PKG_CHECK_MODULES([EV_DAEMON], [gthread-2.0 gio-2.0 >= $GLIB_REQUIRED dbus-glib-1 >= $DBUS_GLIB_REQUIRED])
 298 fi
 299
 300 dnl ========= Check for GConf
 301
 302 AC_MSG_CHECKING([whether GConf support is requested])
 303 AC_ARG_WITH([gconf],
 304   [AS_HELP_STRING([--without-gconf],
 305                   [Disable the use of gconf])],
 306   [],
 307   [case "$os_win32" in
 308      yes) with_gconf=no ;;
 309      *) with_gconf=yes ;;
 310    esac])
 311 AC_MSG_RESULT([$with_gconf])
 312
 313 AM_CONDITIONAL([WITH_GCONF],[test "$with_gconf" = "yes"])
 314
 315 if test "$with_gconf" = "yes"; then
 316    PKG_CHECK_MODULES([GCONF],[gconf-2.0])
 317    AC_DEFINE([WITH_GCONF],[1],[Define if GConf support is enabled])
 318
 319    AM_GCONF_SOURCE_2
 320
 321    AC_PATH_PROG([GCONFTOOL], [gconftool-2], [false])
 322    if test "$GCONFTOOL" = "false"; then
 323       AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 324    fi
 325 else
 326    AM_CONDITIONAL([GCONF_SCHEMAS_INSTALL],false)
 327 fi
 328
 329 dnl Debug mode
 330
 331 AC_ARG_ENABLE([debug],
 332         AS_HELP_STRING([--enable-debug],
 333                        [Turn on evince debug mode]),
 334         [enable_debug=$enableval],
 335         [enable_debug=no])
 336
 337 if test "x$enable_debug" = "xyes"; then
 338    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 339 fi
 340
 341 AC_ARG_ENABLE([tests],
 342         AS_HELP_STRING([--enable-tests], [Enable the tests]),
 343         [enable_tests=$enableval],
 344         [enable_tests=yes])
 345
 346 AM_CONDITIONAL(ENABLE_TESTS, test x$enable_tests = xyes)
 347
 348 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 349 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 350 AC_SUBST(LIBDOCUMENT_CFLAGS)
 351 AC_SUBST(LIBDOCUMENT_LIBS)
 352
 353 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 354 LIBVIEW_LIBS="$LIBVIEW_LIBS $GTKUNIXPRINT_LIBS"
 355 AC_SUBST(LIBVIEW_CFLAGS)
 356 AC_SUBST(LIBVIEW_LIBS)
 357
 358 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 359 AC_SUBST(BACKEND_CFLAGS)
 360 AC_SUBST(BACKEND_LIBS)
 361
 362 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS $KEYRING_CFLAGS $GCONF_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 363 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS $KEYRING_LIBS $GCONF_LIBS -lz"
 364 AC_SUBST(SHELL_CFLAGS)
 365 AC_SUBST(SHELL_LIBS)
 366
 367 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 368 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 369 AC_SUBST(FRONTEND_CFLAGS)
 370 AC_SUBST(FRONTEND_LIBS)
 371
 372 EV_DAEMON_CFLAGS="$EV_DAEMON_CFLAGS $DEBUG_FLAGS"
 373 AC_SUBST([EV_DAEMON_CFLAGS])
 374 AC_SUBST([EV_DAEMON_LIBS])
 375
 376 # Check for Nautilus property page build
 377 AC_ARG_ENABLE([nautilus],
 378   [AS_HELP_STRING([--disable-nautilus],
 379                   [Disable build of nautilus extensions])],
 380   [],
 381   [case "$with_platform" in
 382      gnome) enable_nautilus=yes ;;
 383      *) enable_nautilus=no ;;
 384     esac])
 385
 386 if test "$enable_nautilus" = "yes" ; then
 387   PKG_CHECK_MODULES([NAUTILUS],[gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension],
 388                     [],[AC_MSG_ERROR([libnautilus-extension not found; use --disable-nautilus to disable the nautilus extensions])])
 389   NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 390   AC_SUBST([nautilusextensiondir],[$NAUTILUS_EXTENSION_DIR])
 391   AC_SUBST(NAUTILUS_CFLAGS)
 392   AC_SUBST(NAUTILUS_LIBS)
 393
 394   AC_DEFINE([HAVE_NAUTILUS],[1], [defined if you build the nautilus plugin])
 395 fi
 396
 397 AM_CONDITIONAL([ENABLE_NAUTILUS],[test "$enable_nautilus" = "yes"])
 398
 399 # Check for thumbnailer build
 400
 401 AC_ARG_ENABLE([thumbnailer],
 402   [AS_HELP_STRING([--disable-thumbnailer],
 403                   [Disable GNOME thumbnailer])],
 404   [],
 405   [case "$with_platform" in
 406      gnome) enable_thumbnailer=yes ;;
 407      *) enable_thumbnailer=no ;;
 408     esac])
 409
 410 AM_CONDITIONAL([ENABLE_THUMBNAILER],[test "$enable_thumbnailer" = "yes"])
 411
 412 # ***************
 413 # Print Previewer
 414 # ***************
 415
 416 AC_ARG_ENABLE([previewer],
 417   [AS_HELP_STRING([--disable-previewer],
 418                   [Disable the GNOME Document Previewer])],
 419   [],
 420   [case "$with_platform" in
 421       gnome) enable_previewer=yes ;;
 422       *) enable_previewer=no ;;
 423     esac])
 424
 425 if test x$enable_previewer = "xyes" ; then
 426   PKG_CHECK_MODULES([PREVIEWER],[gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED])
 427 fi
 428
 429 AM_CONDITIONAL([ENABLE_PREVIEWER],[test "$enable_previewer" = "yes"])
 430 PREVIEWER_CFLAGS="$PREVIEWER_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 431 PREVIEWER_LIBS="$PREVIEWER_LIBS $GTKUNIXPRINT_LIBS -lz"
 432 AC_SUBST(PREVIEWER_CFLAGS)
 433 AC_SUBST(PREVIEWER_LIBS)
 434
 435 # ***
 436 # GIR
 437 # ***
 438
 439 AC_MSG_CHECKING([whether GObject introspection is requested])
 440 AC_ARG_ENABLE([introspection],
 441         AS_HELP_STRING([--enable-introspection],
 442                        [Enable GObject introspection]),
 443         [enable_introspection=$enableval],
 444         [enable_introspection=no])
 445 AC_MSG_RESULT([$enable_introspection])
 446
 447 G_IR_SCANNER=
 448 G_IR_COMPILER=
 449 G_IR_GENERATE=
 450 GIRDIR=
 451 GIRTYPELIBDIR=
 452
 453 if test "$enable_introspection" = "yes"; then
 454   GOBJECT_INTROSPECTION_REQUIRED=0.6
 455   PKG_CHECK_MODULES([GOBJECT_INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
 456
 457   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
 458   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
 459   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
 460   GIRDIR="$($PKG_CONFIG --variable=girdir gobject-introspection-1.0)"
 461   GIRTYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
 462 fi
 463
 464 AC_SUBST([G_IR_SCANNER])
 465 AC_SUBST([G_IR_COMPILER])
 466 AC_SUBST([G_IR_GENERATE])
 467 AC_SUBST([GIRDIR])
 468 AC_SUBST([GIRTYPELIBDIR])
 469
 470 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
 471
 472 dnl ================== portability checks ===========================================
 473
 474 dnl for backtrace()
 475 AC_CHECK_HEADERS([execinfo.h])
 476
 477 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 478   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 479   ],[],[#include <langinfo.h>])
 480
 481 dnl ================== pdf checks ===================================================
 482 AC_ARG_ENABLE([pdf],
 483   [AS_HELP_STRING([--disable-pdf],
 484                   [Disable the PDF support])],
 485   [enable_pdf=$enableval],
 486   [enable_pdf=yes])
 487
 488 if test "x$enable_pdf" = "xyes"; then
 489     POPPLER_REQUIRED=0.12.0
 490     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED,enable_pdf=yes,enable_pdf=no)
 491
 492     if test "x$enable_pdf" = "xyes"; then
 493             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 494             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 495             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 496
 497             evince_save_LIBS=$LIBS
 498             LIBS="$LIBS $POPPLER_LIBS"
 499             AC_CHECK_FUNCS(poppler_page_render)
 500             AC_CHECK_FUNCS(poppler_page_get_image)
 501             AC_CHECK_FUNCS(poppler_annot_file_attachment_get_attachment)
 502             LIBS=$evince_save_LIBS
 503
 504             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 505             if test x$enable_cairo_pdf = xyes; then
 506                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 507             fi
 508
 509             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 510             if test x$enable_cairo_ps = xyes; then
 511                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 512             fi
 513     else
 514             AC_MSG_ERROR("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 515     fi
 516 fi
 517
 518 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 519 dnl ================== end of pdf checks ============================================
 520
 521 dnl libspectre (used by ps and dvi backends)
 522 SPECTRE_REQUIRED=0.2.0
 523 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 524 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 525 if test "x$have_spectre" = "xyes"; then
 526    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 527 fi
 528
 529 dnl ================== ps checks ====================================================
 530 AC_ARG_ENABLE(ps,
 531         [AS_HELP_STRING([--disable-ps],
 532                         [Disable the PostScript backend])],
 533         [enable_ps=$enableval],
 534         [enable_ps=yes])
 535
 536 if test "x$enable_ps" = "xyes"; then
 537    if test "x$have_spectre" = "xyes"; then
 538       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 539    else
 540       enable_ps="no"
 541       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 542    fi
 543 fi
 544 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 545 dnl ======================== End of ps checks ===================================
 546
 547 dnl ================== tiff checks ===================================================
 548 AC_ARG_ENABLE(tiff,
 549             [AS_HELP_STRING([--disable-tiff],
 550                             [Disable the support of multipage tiff])],
 551             [enable_tiff=$enableval],
 552             [enable_tiff=yes])
 553
 554 if test "x$enable_tiff" = "xyes"; then
 555     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 556     if test "x$enable_tiff" = "xyes"; then
 557         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 558         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 559     fi
 560     if test "x$enable_tiff" = "xyes"; then
 561             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 562     else
 563             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 564     fi
 565 fi
 566
 567 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 568 dnl ================== end of tiff checks ============================================
 569
 570 dnl ================== djvu checks ===================================================
 571
 572 AC_ARG_ENABLE(djvu,
 573             [AS_HELP_STRING([--disable-djvu],
 574                             [Disable the support of djvu viewer])],
 575             [enable_djvu=$enableval],
 576             [enable_djvu=yes])
 577
 578 if test "x$enable_djvu" = "xyes"; then
 579     DJVULIBRE_REQUIRED=3.5.17
 580     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 581
 582     if test "x$enable_djvu" = "xyes"; then
 583         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 584     else
 585         AC_MSG_WARN([
 586 ** Djvu support is disabled since a recent version of the djvulibre
 587 ** library was not found. You need at least djvulibre-3.5.17 which
 588 ** can be found on http://djvulibre.djvuzone.org
 589 ])
 590     fi
 591 fi
 592
 593 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 594
 595 dnl ================== End of djvu checks ===================================================
 596
 597 dnl ================== dvi checks ===================================================
 598
 599 AC_ARG_ENABLE(dvi,
 600             [AS_HELP_STRING([--disable-dvi],
 601             [Disable the support of dvi viewer])],
 602             [enable_dvi=$enableval],
 603             [enable_dvi=yes])
 604
 605 AC_ARG_ENABLE(t1lib,
 606             [AS_HELP_STRING([--enable-t1lib],
 607                             [Compile with support of t1lib for type1 fonts in dvi])],
 608             [enable_type1_fonts=$enableval],
 609             [enable_type1_fonts=no])
 610
 611 if test "x$enable_dvi" = "xyes"; then
 612     AC_C_CONST
 613     AC_C_INLINE
 614     AC_TYPE_SIZE_T
 615     AC_CHECK_SIZEOF(long, 4)
 616     AC_CHECK_SIZEOF(int, 4)
 617     AC_CHECK_SIZEOF(short, 2)
 618     AC_CHECK_SIZEOF(void *, 4)
 619     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 620
 621     if test "x$enable_dvi" = "xyes"; then
 622         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 623     else
 624         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 625     fi
 626 fi
 627 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 628
 629 if test "x$enable_dvi" = "xyes"; then
 630     if test "x$enable_type1_fonts" = "xyes"; then
 631         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 632     fi
 633
 634     if test "x$enable_type1_fonts" = xyes; then
 635         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 636     fi
 637 else
 638     enable_type1_fonts=no
 639 fi
 640 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 641
 642 dnl ================== End of dvi checks ===================================================
 643
 644 dnl ================== pixbuf checks ===================================================
 645
 646 AC_ARG_ENABLE(pixbuf,
 647             [AS_HELP_STRING([--enable-pixbuf],
 648                             [Compile with support of pixbuf])],
 649             [enable_pixbuf=$enableval],
 650             [enable_pixbuf=no])
 651
 652 if test "x$enable_pixbuf" = "xyes"; then
 653         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 654 fi
 655
 656 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 657
 658 dnl ================== End of pixbuf checks ===================================================
 659
 660 dnl ================== comic book checks ===================================================
 661
 662 AC_ARG_ENABLE(comics,
 663         [AS_HELP_STRING([--enable-comics],
 664                         [Compile with support for comic book archives])],
 665         [enable_comics=$enableval],
 666         [enable_comics=yes])
 667
 668 if test "x$enable_comics" = "xyes"; then
 669         if test "x$os_win32" = "xyes"; then
 670                 # The comics backend is disabled on windows because:
 671                 # 1) it uses unix functions from sys/wait.h.
 672                 # 2) it uses external decompression tools not generally available on windows.
 673                 enable_comics=no
 674                 AC_MSG_WARN(The comics backend is not supported on windows.)
 675         else
 676                 AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 677         fi
 678 fi
 679 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 680
 681 dnl ================== End of comic book checks ============================================
 682
 683 dnl ================== impress book checks ===================================================
 684
 685 AC_ARG_ENABLE(impress,
 686         [AS_HELP_STRING([--enable-impress],
 687                         [Compile with support for impress presentations])],
 688         [enable_impress=$enableval],
 689         [enable_impress=no])
 690
 691 if test "x$enable_impress" = "xyes"; then
 692         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 693 fi
 694 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 695
 696 dnl ================== End of impress book checks ============================================
 697
 698 dnl =================== Mime types list ====================================================
 699
 700 if test "x$enable_pdf" = "xyes" ; then
 701         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 702 fi
 703 if test "x$enable_ps" = "xyes" ; then
 704         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 705 fi
 706 if test "x$enable_dvi" = "xyes"; then
 707         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 708 fi
 709 if test "x$enable_djvu" = "xyes"; then
 710         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 711 fi
 712 if test "x$enable_tiff" = "xyes"; then
 713         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 714 fi
 715 if test "x$enable_comics" = "xyes"; then
 716         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;application/x-cbt;"
 717 fi
 718 if test "x$enable_pixbuf" = "xyes"; then
 719         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 720 fi
 721 if test "x$enable_impress" = "xyes"; then
 722         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 723 fi
 724 AC_SUBST(EVINCE_MIME_TYPES)
 725
 726 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 727
 728 # Backends directory
 729
 730 AC_SUBST([backenddir],"\$(libdir)/evince/ev_binary_version/backends")
 731 AC_SUBST([backend_binary_version],"ev_binary_version")
 732
 733 # Versioning
 734
 735 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
 736 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
 737 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
 738
 739 AC_SUBST([EV_API_VERSION],[ev_api_version])
 740 AC_SUBST([EV_BINARY_VERSION],[ev_binary_version])
 741
 742 AC_SUBST([EV_DOCUMENT_LT_VERSION_INFO],[ev_document_lt_version_info])
 743 AC_SUBST([EV_DOCUMENT_LT_CURRENT_MINUS_AGE],[ev_document_lt_current_minus_age])
 744 AC_SUBST([EV_VIEW_LT_VERSION_INFO],[ev_view_lt_version_info])
 745 AC_SUBST([EV_VIEW_LT_CURRENT_MINUS_AGE],[ev_view_lt_current_minus_age])
 746
 747 # *****************************************************************************
 748
 749 AC_CONFIG_FILES([
 750 backend/Makefile
 751 backend/comics/Makefile
 752 backend/djvu/Makefile
 753 backend/dvi/Makefile
 754 backend/dvi/mdvi-lib/Makefile
 755 backend/impress/Makefile
 756 backend/pdf/Makefile
 757 backend/pixbuf/Makefile
 758 backend/ps/Makefile
 759 backend/tiff/Makefile
 760 cut-n-paste/Makefile
 761 cut-n-paste/evinfobar/Makefile
 762 cut-n-paste/gimpcellrenderertoggle/Makefile
 763 cut-n-paste/smclient/Makefile
 764 cut-n-paste/toolbar-editor/Makefile
 765 cut-n-paste/zoom-control/Makefile
 766 cut-n-paste/totem-screensaver/Makefile
 767 data/evince.desktop.in
 768 data/Makefile
 769 data/icons/Makefile
 770 data/icons/16x16/Makefile
 771 data/icons/16x16/apps/Makefile
 772 data/icons/16x16/actions/Makefile
 773 data/icons/16x16/mimetypes/Makefile
 774 data/icons/22x22/Makefile
 775 data/icons/22x22/apps/Makefile
 776 data/icons/22x22/actions/Makefile
 777 data/icons/22x22/mimetypes/Makefile
 778 data/icons/24x24/Makefile
 779 data/icons/24x24/apps/Makefile
 780 data/icons/24x24/actions/Makefile
 781 data/icons/24x24/mimetypes/Makefile
 782 data/icons/32x32/Makefile
 783 data/icons/32x32/actions/Makefile
 784 data/icons/32x32/mimetypes/Makefile
 785 data/icons/48x48/Makefile
 786 data/icons/48x48/apps/Makefile
 787 data/icons/48x48/actions/Makefile
 788 data/icons/scalable/Makefile
 789 data/icons/scalable/apps/Makefile
 790 data/icons/scalable/actions/Makefile
 791 data/icons/scalable/mimetypes/Makefile
 792 help/Makefile
 793 help/reference/Makefile
 794 help/reference/libdocument/Makefile
 795 help/reference/libdocument/version.xml
 796 help/reference/libview/Makefile
 797 help/reference/libview/version.xml
 798 help/reference/shell/Makefile
 799 help/reference/shell/version.xml
 800 libdocument/Makefile
 801 libdocument/ev-version.h
 802 libmisc/Makefile
 803 libview/Makefile
 804 Makefile
 805 po/Makefile.in
 806 previewer/Makefile
 807 properties/Makefile
 808 shell/Makefile
 809 test/Makefile
 810 thumbnailer/Makefile
 811 ])
 812
 813 AC_CONFIG_FILES(evince-document-[]ev_api_version[].pc:evince-document.pc.in)
 814 AC_CONFIG_FILES(evince-view-[]ev_api_version[].pc:evince-view.pc.in)
 815
 816 AC_OUTPUT
 817
 818 echo "
 819 Configure summary:
 820         Platform...........:  $with_platform
 821         GConf Support......:  $with_gconf
 822         GTK+ Unix Print....:  $with_gtk_unix_print
 823         Keyring Support....:  $with_keyring
 824         DBUS Support.......:  $enable_dbus
 825         SM client support..:  $with_smclient
 826         Nautilus Plugin....:  $enable_nautilus
 827         Thumbnailer........:  $enable_thumbnailer
 828         Previewer..........:  $enable_previewer
 829         Gtk-Doc Support....:  $enable_gtk_doc
 830         Debug mode.........:  $enable_debug
 831         GObj. Introspection:  $enable_introspection
 832         Tests..............:  $enable_tests
 833
 834         PDF Backend........:  $enable_pdf
 835         PostScript Backend.:  $enable_ps
 836         TIFF Backend.......:  $enable_tiff
 837         DJVU Backend.......:  $enable_djvu
 838         DVI Backend........:  $enable_dvi
 839         Pixbuf Backend.....:  $enable_pixbuf
 840         Comics Backend.....:  $enable_comics
 841         Impress Backend....:  $enable_impress
 842 "