configure.ac

   1 # *****************************************************************************
   2 # Versioning
   3 # *****************************************************************************
   4
   5 m4_define([ev_major_version],[2])
   6 m4_define([ev_minor_version],[27])
   7 m4_define([ev_micro_version],[90])
   8 m4_define([ev_extra_version],[])
   9 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version()ev_extra_version])
  10
  11 # The evince API version
  12 m4_define([ev_api_version], [2.25])
  13
  14 # Libtool versioning. The backend and view libraries have separate versions.
  15 # Before making a release, the libtool version should be modified.
  16 # The string is of the form C:R:A.
  17 # - If interfaces have been changed or added, but binary compatibility has
  18 #   been preserved, change to C+1:0:A+1
  19 # - If binary compatibility has been broken (eg removed or changed interfaces)
  20 #   change to C+1:0:0
  21 # - If the interface is the same as the previous version, change to C:R+1:A
  22
  23 # Libtool version of the backend library
  24 m4_define([ev_document_lt_current],[1])
  25 m4_define([ev_document_lt_revision],[0])
  26 m4_define([ev_document_lt_age],[0])
  27 m4_define([ev_document_lt_version_info],[ev_document_lt_current:ev_document_lt_revision:ev_document_lt_age])
  28 m4_define([ev_document_lt_current_minus_age],[m4_eval(ev_document_lt_current - ev_document_lt_age)])
  29
  30 # Libtool version of the view library
  31 m4_define([ev_view_lt_current],[1])
  32 m4_define([ev_view_lt_revision],[0])
  33 m4_define([ev_view_lt_age],[0])
  34 m4_define([ev_view_lt_version_info],[ev_view_lt_current:ev_view_lt_revision:ev_view_lt_age])
  35 m4_define([ev_view_lt_current_minus_age],[m4_eval(ev_view_lt_current - ev_view_lt_age)])
  36
  37 # Binary version for the document backends
  38 m4_define([ev_binary_version],[ev_document_lt_current])
  39
  40 # *****************************************************************************
  41
  42 AC_PREREQ([2.57])
  43 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
  44 AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip])
  45
  46 AC_CONFIG_HEADERS([config.h])
  47 AC_CONFIG_MACRO_DIR([m4])
  48
  49 if test -z "$enable_maintainer_mode"; then
  50   enable_maintainer_mode=yes
  51 fi
  52 AM_MAINTAINER_MODE([enable])
  53
  54 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  55
  56 AM_PROG_LIBTOOL
  57
  58 AC_ISC_POSIX
  59 AC_PROG_CC
  60 AM_PROG_CC_STDC
  61 AM_PROG_CC_C_O
  62 AC_PROG_CXX
  63 AC_STDC_HEADERS
  64
  65 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  66 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  67
  68 GNOME_COMMON_INIT
  69 GNOME_DOC_INIT
  70 GNOME_MAINTAINER_MODE_DEFINES
  71 GNOME_COMPILE_WARNINGS
  72 GNOME_CXX_WARNINGS
  73
  74 GTK_DOC_CHECK(1.0)
  75
  76 IT_PROG_INTLTOOL([0.35.0])
  77
  78 GETTEXT_PACKAGE=evince
  79 AC_SUBST(GETTEXT_PACKAGE)
  80 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  81 AM_GLIB_GNU_GETTEXT
  82
  83 m4_pattern_allow([AM_V_GEN])dnl Make autoconf not complain about the rule below
  84 EV_INTLTOOL_EVINCE_BACKEND_RULE='%.evince-backend:   %.evince-backend.in   $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; $(AM_V_GEN) LC_ALL=C $(INTLTOOL_MERGE) -d -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@'
  85 AC_SUBST([EV_INTLTOOL_EVINCE_BACKEND_RULE])
  86
  87 # Check which platform to use
  88
  89 AC_MSG_CHECKING([for which platform to build])
  90 AC_ARG_WITH([platform],
  91   [AS_HELP_STRING([--with-platform=gnome|win32|hildon (default: gnome)])],
  92   [case "$withval" in
  93     gnome|win32|hildon) ;;
  94     *) AC_MSG_ERROR([invalid argument "$withval" for --with-platform]) ;;
  95    esac],
  96   [case "$host" in
  97      *-*-mingw*|*-*-cygwin*) with_platform="win32" ;;
  98      *) with_platform=gnome ;;
  99    esac])
 100
 101 AC_MSG_RESULT([$with_platform])
 102
 103 if test "$with_platform" = "win32"; then
 104   AC_CHECK_TOOL([WINDRES],[windres])
 105   AC_MSG_CHECKING([for native Win32])
 106   case "$host" in
 107     *-*-mingw*)
 108       os_win32=yes
 109       ;;
 110     *)
 111       os_win32=no
 112       ;;
 113   esac
 114   AC_MSG_RESULT([$os_win32])
 115 fi
 116
 117 AM_CONDITIONAL([PLATFORM_HILDON],[test "$with_platform" = "hildon"])
 118 AM_CONDITIONAL([PLATFORM_WIN32],[test "$with_platform" = "win32"])
 119
 120 dnl Specify required versions of dependencies
 121 DBUS_GLIB_REQUIRED=0.70
 122 GTK_REQUIRED=2.14.0
 123 GLIB_REQUIRED=2.18.0
 124 KEYRING_REQUIRED=2.22.0
 125 AC_SUBST([GLIB_REQUIRED])
 126 AC_SUBST([GTK_REQUIRED])
 127
 128 GNOME_ICON_THEME_REQUIRED=2.17.1
 129 LIBXML_REQUIRED=2.5.0
 130
 131 dnl Check dependencies
 132
 133 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
 134 # BACKEND_CFLAGS   for backend implementations.
 135 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
 136 # FRONTEND_LIBS
 137 # SHELL_CFLAGS     for shell implementation.
 138 # SHELL_LIBS
 139
 140 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
 141 PKG_CHECK_MODULES(LIBVIEW, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 142 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
 143 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 144 PKG_CHECK_MODULES(PREVIEWER, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 145
 146 SHELL_PLATFORM_PKGS=
 147 case "$with_platform" in
 148   hildon) AC_DEFINE([PLATFORM_HILDON],[1],[Define if building for the hildon platform])
 149           SHELL_PLATFORM_PKGS="hildon-1 hildon-fm-2 libosso"
 150           ;;
 151   *) SHELL_PLATFORM_PKGS="gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED"
 152      ;;
 153 esac
 154
 155 PKG_CHECK_MODULES([SHELL_CORE],[libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gthread-2.0 $SHELL_PLATFORM_PKGS])
 156
 157 # *********
 158 # SM client
 159 # *********
 160
 161 GDK_TARGET="$($PKG_CONFIG --variable target gdk-2.0)"
 162
 163 SMCLIENT_PKGS=
 164 AC_MSG_CHECKING([which smclient backend to use])
 165 AC_ARG_WITH([smclient],
 166   [AS_HELP_STRING([--with-smclient-backend],[which smclient backend to use (no|xsmp|win32|quartz)])],
 167   [],
 168   [case "$GDK_TARGET" in
 169     x11) case "$with_platform" in
 170            gnome) with_smclient=xsmp SMCLIENT_PKGS="sm >= 1.0.0" ;;
 171            *) with_smclient=no ;;
 172          esac ;;
 173     win32|quartz) with_smclient=$GDK_TARGET ;;
 174     *) with_smclient=no ;;
 175    esac])
 176 AC_MSG_RESULT([$with_smclient])
 177
 178 if test "$with_smclient" != "no"; then
 179   AC_DEFINE([WITH_SMCLIENT],[1],[Define if smclient is enabled])
 180
 181   PKG_CHECK_MODULES([SMCLIENT],[gtk+-2.0 gthread-2.0 $SMCLIENT_PKGS])
 182   AC_SUBST([SMCLIENT_CFLAGS])
 183   AC_SUBST([SMCLIENT_LIBS])
 184 fi
 185
 186 AM_CONDITIONAL([WITH_SMCLIENT],[test "$with_smclient" != "no"])
 187 AM_CONDITIONAL([WITH_SMCLIENT_XSMP],[test "$with_smclient" = "xsmp"])
 188 AM_CONDITIONAL([WITH_SMCLIENT_WIN32],[test "$with_smclient" = "win32"])
 189 AM_CONDITIONAL([WITH_SMCLIENT_QUARTZ],[test "$with_smclient" = "quartz"])
 190
 191 # ***
 192
 193 BACKEND_LIBTOOL_FLAGS="-module -avoid-version -no-undefined -export-symbols \$(top_srcdir)/backend/backend.symbols"
 194 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
 195
 196 dnl ===== Check special functions
 197 evince_save_LIBS=$LIBS
 198 LIBS="$LIBS $BACKEND_LIBS"
 199 AC_CHECK_FUNCS(cairo_format_stride_for_width)
 200 AC_CHECK_FUNCS(gtk_print_operation_get_n_pages_to_print)
 201 LIBS=$evince_save_LIBS
 202
 203 # ******************
 204 # GKT+ Unix Printing
 205 # ******************
 206
 207 AC_MSG_CHECKING([whether gtk+-unix-print support is requested])
 208 AC_ARG_WITH([gtk-unix-print],
 209   [AS_HELP_STRING([--without-gtk-unix-print],[disable the use of gtk-unix-print])],
 210   [],[case "$os_win32" in
 211         yes) with_gtk_unix_print=no ;;
 212         *) with_gtk_unix_print=yes ;;
 213       esac])
 214 AC_MSG_RESULT([$with_gtk_unix_print])
 215
 216 if test "$with_gtk_unix_print" = "yes"; then
 217    PKG_CHECK_MODULES(GTKUNIXPRINT, [gtk+-unix-print-2.0 >= $GTK_REQUIRED])
 218    AC_DEFINE([GTKUNIXPRINT_ENABLED], [1], [Define if gtk+-unix-print is enabled.])
 219 fi
 220
 221 # *********************
 222 # GNOME Keyring support
 223 # *********************
 224
 225 AC_ARG_WITH(keyring,
 226         [AS_HELP_STRING([--without-keyring],[disable the use of gnome-keyring])],
 227         [],
 228         [case "$with_platform" in
 229            gnome) with_keyring=yes ;;
 230            hildon|win32) with_keyring=no ;;
 231          esac])
 232
 233 AM_CONDITIONAL([WITH_KEYRING],[test "$with_keyring" = "yes"])
 234
 235 if test "$with_keyring" = "yes"; then
 236         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
 237         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
 238 fi
 239
 240 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
 241 AC_SUBST(GLIB_GENMARSHAL)
 242
 243 # ****
 244 # DBUS
 245 # ****
 246
 247 AC_ARG_ENABLE([dbus],
 248   [AS_HELP_STRING([--enable-dbus], [Compile with support for dbus])],
 249   [],
 250   [case "$with_platform" in
 251       gnome) enable_dbus=yes ;;
 252       hildon) enable_dbus=no ;;
 253     esac])
 254
 255 if test "$enable_dbus" = "yes"; then
 256   PKG_CHECK_MODULES([DBUS],[dbus-glib-1 >= $DBUS_GLIB_REQUIRED],[],
 257                     [AC_MSG_ERROR([DBUS not found; use --disable-dbus to disable DBUS support])])
 258
 259   AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 260   if test x$DBUS_BINDING_TOOL = "xno" ; then
 261           AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 262   fi
 263
 264   AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 265 fi
 266
 267 AC_SUBST([DBUS_CFLAGS])
 268 AC_SUBST([DBUS_LIBS])
 269
 270 AM_CONDITIONAL([ENABLE_DBUS], [test "$enable_dbus" = "yes"])
 271
 272 dnl ========= Check for GConf
 273
 274 AC_MSG_CHECKING([whether GConf support is requested])
 275 AC_ARG_WITH([gconf],
 276   [AS_HELP_STRING([--without-gconf],[disable the use of gconf])],
 277   [],
 278   [case "$os_win32" in
 279      yes) with_gconf=no ;;
 280      *) with_gconf=yes ;;
 281    esac])
 282 AC_MSG_RESULT([$with_gconf])
 283
 284 AM_CONDITIONAL([WITH_GCONF],[test "$with_gconf" = "yes"])
 285
 286 if test "$with_gconf" = "yes"; then
 287    PKG_CHECK_MODULES([GCONF],[gconf-2.0])
 288    AC_DEFINE([WITH_GCONF],[1],[Define if GConf support is enabled])
 289
 290    AM_GCONF_SOURCE_2
 291
 292    AC_PATH_PROG([GCONFTOOL], [gconftool-2], [false])
 293    if test "$GCONFTOOL" = "false"; then
 294       AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 295    fi
 296 else
 297    AM_CONDITIONAL([GCONF_SCHEMAS_INSTALL],false)
 298 fi
 299
 300 dnl Debug mode
 301
 302 AC_ARG_ENABLE([debug],
 303         AC_HELP_STRING([--enable-debug],
 304                         [Turn on evince debug mode]),,
 305                 [enable_debug=no])
 306
 307 if test "x$enable_debug" = "xyes"; then
 308    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 309 fi
 310
 311 AC_ARG_ENABLE([tests],
 312         AC_HELP_STRING([--enable-tests], [Disable tests]),
 313         enable_tests="$enableval",
 314         enable_tests=yes)
 315
 316 AM_CONDITIONAL(ENABLE_TESTS, test x$enable_tests = xyes)
 317
 318 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 319 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 320 AC_SUBST(LIBDOCUMENT_CFLAGS)
 321 AC_SUBST(LIBDOCUMENT_LIBS)
 322
 323 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $DEBUG_FLAGS"
 324 LIBVIEW_LIBS="$LIBVIEW_LIBS"
 325 AC_SUBST(LIBVIEW_CFLAGS)
 326 AC_SUBST(LIBVIEW_LIBS)
 327
 328 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 329 AC_SUBST(BACKEND_CFLAGS)
 330 AC_SUBST(BACKEND_LIBS)
 331
 332 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $GTKUNIXPRINT_CFLAGS $DBUS_CFLAGS $KEYRING_CFLAGS $GCONF_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 333 SHELL_LIBS="$SHELL_CORE_LIBS $GTKUNIXPRINT_CFLAGS $DBUS_LIBS $KEYRING_LIBS $GCONF_LIBS -lz"
 334 AC_SUBST(SHELL_CFLAGS)
 335 AC_SUBST(SHELL_LIBS)
 336
 337 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 338 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 339 AC_SUBST(FRONTEND_CFLAGS)
 340 AC_SUBST(FRONTEND_LIBS)
 341
 342 # Check for Nautilus property page build
 343 AC_ARG_ENABLE([nautilus],
 344   [AS_HELP_STRING([--disable-nautilus],[Build the nautilus extensions])],
 345   [],
 346   [case "$with_platform" in
 347      gnome) enable_nautilus=yes ;;
 348      *) enable_nautilus=no ;;
 349     esac])
 350
 351 if test "$enable_nautilus" = "yes" ; then
 352   PKG_CHECK_MODULES([NAUTILUS],[gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension],
 353                     [],[AC_MSG_ERROR([libnautilus-extension not found; use --disable-nautilus to disable the nautilus extensions])])
 354   NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 355   AC_SUBST([nautilusextensiondir],[$NAUTILUS_EXTENSION_DIR])
 356   AC_SUBST(NAUTILUS_CFLAGS)
 357   AC_SUBST(NAUTILUS_LIBS)
 358
 359   AC_DEFINE([HAVE_NAUTILUS],[1], [defined if you build the nautilus plugin])
 360 fi
 361
 362 AM_CONDITIONAL([ENABLE_NAUTILUS],[test "$enable_nautilus" = "yes"])
 363
 364 # Check for thumbnailer build
 365
 366 AC_ARG_ENABLE([thumbnailer],
 367   [AS_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer])],
 368   [],
 369   [case "$with_platform" in
 370      gnome) enable_thumbnailer=yes ;;
 371      *) enable_thumbnailer=no ;;
 372     esac])
 373
 374 AM_CONDITIONAL([ENABLE_THUMBNAILER],[test "$enable_thumbnailer" = "yes"])
 375
 376 # ***************
 377 # Print Previewer
 378 # ***************
 379
 380 AC_ARG_ENABLE([previewer],
 381   [AS_HELP_STRING([--disable-previewer],[disable the GNOME Document Previewer])],
 382   [],
 383   [case "$with_platform" in
 384       gnome) enable_previewer=yes ;;
 385       *) enable_previewer=no ;;
 386     esac])
 387
 388 if test x$enable_previewer = "xyes" ; then
 389   PKG_CHECK_MODULES([PREVIEWER],[gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED])
 390 fi
 391
 392 AM_CONDITIONAL([ENABLE_PREVIEWER],[test "$enable_previewer" = "yes"])
 393 PREVIEWER_CFLAGS="$PREVIEWER_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 394 PREVIEWER_LIBS="$PREVIEWER_LIBS $GTKUNIXPRINT_LIBS -lz"
 395 AC_SUBST(PREVIEWER_CFLAGS)
 396 AC_SUBST(PREVIEWER_LIBS)
 397
 398 # ***
 399 # GIR
 400 # ***
 401
 402 AC_MSG_CHECKING([whether GObject introspection is requested])
 403 AC_ARG_ENABLE([introspection],
 404         AS_HELP_STRING([--enable-introspection],[Enable GObject introspection]),
 405         [],[enable_introspection=no])
 406 AC_MSG_RESULT([$enable_introspection])
 407
 408 G_IR_SCANNER=
 409 G_IR_COMPILER=
 410 G_IR_GENERATE=
 411 GIRDIR=
 412 GIRTYPELIBDIR=
 413
 414 if test "$enable_introspection" = "yes"; then
 415   GOBJECT_INTROSPECTION_REQUIRED=0.6
 416   PKG_CHECK_MODULES([GOBJECT_INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
 417
 418   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
 419   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
 420   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
 421   GIRDIR="$($PKG_CONFIG --variable=girdir gobject-introspection-1.0)"
 422   GIRTYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
 423 fi
 424
 425 AC_SUBST([G_IR_SCANNER])
 426 AC_SUBST([G_IR_COMPILER])
 427 AC_SUBST([G_IR_GENERATE])
 428 AC_SUBST([GIRDIR])
 429 AC_SUBST([GIRTYPELIBDIR])
 430
 431 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
 432
 433 dnl ================== portability checks ===========================================
 434
 435 dnl for backtrace()
 436 AC_CHECK_HEADERS([execinfo.h])
 437
 438 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 439   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 440   ],[],[#include <langinfo.h>])
 441
 442 dnl ================== pdf checks ===================================================
 443 AC_ARG_ENABLE(pdf,
 444               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 445
 446 if test "x$enable_pdf" = "xyes"; then
 447     POPPLER_REQUIRED=0.11.0
 448     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED,enable_pdf=yes,enable_pdf=no)
 449
 450     if test "x$enable_pdf" = "xyes"; then
 451             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 452             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 453             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 454
 455             evince_save_LIBS=$LIBS
 456             LIBS="$LIBS $POPPLER_LIBS"
 457             AC_CHECK_FUNCS(poppler_page_render)
 458             AC_CHECK_FUNCS(poppler_page_get_image)
 459             LIBS=$evince_save_LIBS
 460
 461             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 462             if test x$enable_cairo_pdf = xyes; then
 463                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 464             fi
 465
 466             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 467             if test x$enable_cairo_ps = xyes; then
 468                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 469             fi
 470     else
 471             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 472     fi
 473 fi
 474
 475 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 476 dnl ================== end of pdf checks ============================================
 477
 478 dnl libspectre (used by ps and dvi backends)
 479 SPECTRE_REQUIRED=0.2.0
 480 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 481 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 482 if test "x$have_spectre" = "xyes"; then
 483    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 484 fi
 485
 486 dnl ================== ps checks ====================================================
 487 AC_ARG_ENABLE(ps,
 488         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 489
 490 if test "x$enable_ps" = "xyes"; then
 491    if test "x$have_spectre" = "xyes"; then
 492       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 493    else
 494       enable_ps="no"
 495       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 496    fi
 497 fi
 498 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 499 dnl ======================== End of ps checks ===================================
 500
 501 dnl ================== tiff checks ===================================================
 502 AC_ARG_ENABLE(tiff,
 503             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 504
 505 if test "x$enable_tiff" = "xyes"; then
 506     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 507     if test "x$enable_tiff" = "xyes"; then
 508         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 509         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 510     fi
 511     if test "x$enable_tiff" = "xyes"; then
 512             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 513     else
 514             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 515     fi
 516 fi
 517
 518 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 519 dnl ================== end of tiff checks ============================================
 520
 521 dnl ================== djvu checks ===================================================
 522
 523 AC_ARG_ENABLE(djvu,
 524             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=yes)
 525
 526 if test "x$enable_djvu" = "xyes"; then
 527     DJVULIBRE_REQUIRED=3.5.17
 528     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 529
 530     if test "x$enable_djvu" = "xyes"; then
 531         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 532     else
 533         AC_MSG_WARN([
 534 ** Djvu support is disabled since a recent version of the djvulibre
 535 ** library was not found. You need at least djvulibre-3.5.17 which
 536 ** can be found on http://djvulibre.djvuzone.org
 537 ])
 538     fi
 539 fi
 540
 541 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 542
 543 dnl ================== End of djvu checks ===================================================
 544
 545 dnl ================== dvi checks ===================================================
 546
 547 AC_ARG_ENABLE(dvi,
 548             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=yes)
 549
 550 AC_ARG_ENABLE(t1lib,
 551             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 552
 553 if test "x$enable_dvi" = "xyes"; then
 554     AC_C_CONST
 555     AC_C_INLINE
 556     AC_TYPE_SIZE_T
 557     AC_CHECK_SIZEOF(long, 4)
 558     AC_CHECK_SIZEOF(int, 4)
 559     AC_CHECK_SIZEOF(short, 2)
 560     AC_CHECK_SIZEOF(void *, 4)
 561     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 562
 563     if test "x$enable_dvi" = "xyes"; then
 564         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 565     else
 566         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 567     fi
 568 fi
 569 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 570
 571 if test "x$enable_dvi" = "xyes"; then
 572     if test "x$enable_type1_fonts" = "xyes"; then
 573         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 574     fi
 575
 576     if test "x$enable_type1_fonts" = xyes; then
 577         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 578     fi
 579 else
 580     enable_type1_fonts=no
 581 fi
 582 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 583
 584 dnl ================== End of dvi checks ===================================================
 585
 586 dnl ================== pixbuf checks ===================================================
 587
 588 AC_ARG_ENABLE(pixbuf,
 589             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 590 if test "x$enable_pixbuf" = "xyes"; then
 591         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 592 fi
 593 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 594
 595 dnl ================== End of pixbuf checks ===================================================
 596
 597 dnl ================== comic book checks ===================================================
 598
 599 AC_ARG_ENABLE(comics,
 600         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=yes)
 601 if test "x$enable_comics" = "xyes"; then
 602         if test "x$os_win32" = "xyes"; then
 603                 # The comics backend is disabled on windows because:
 604                 # 1) it uses unix functions from sys/wait.h.
 605                 # 2) it uses external decompression tools not generally available on windows.
 606                 enable_comics=no
 607                 AC_MSG_WARN(The comics backend is not supported on windows.)
 608         else
 609                 AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 610         fi
 611 fi
 612 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 613
 614 dnl ================== End of comic book checks ============================================
 615
 616 dnl ================== impress book checks ===================================================
 617
 618 AC_ARG_ENABLE(impress,
 619         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 620 if test "x$enable_impress" = "xyes"; then
 621         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 622 fi
 623 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 624
 625 dnl ================== End of impress book checks ============================================
 626
 627 dnl =================== Mime types list ====================================================
 628
 629 if test "x$enable_pdf" = "xyes" ; then
 630         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 631 fi
 632 if test "x$enable_ps" = "xyes" ; then
 633         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 634 fi
 635 if test "x$enable_dvi" = "xyes"; then
 636         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 637 fi
 638 if test "x$enable_djvu" = "xyes"; then
 639         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 640 fi
 641 if test "x$enable_tiff" = "xyes"; then
 642         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 643 fi
 644 if test "x$enable_comics" = "xyes"; then
 645         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;"
 646 fi
 647 if test "x$enable_pixbuf" = "xyes"; then
 648         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 649 fi
 650 if test "x$enable_impress" = "xyes"; then
 651         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 652 fi
 653 AC_SUBST(EVINCE_MIME_TYPES)
 654
 655 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 656
 657 # Backends directory
 658
 659 AC_SUBST([backenddir],"\$(libdir)/evince/ev_binary_version/backends")
 660 AC_SUBST([backend_binary_version],"ev_binary_version")
 661
 662 # Versioning
 663
 664 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
 665 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
 666 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
 667
 668 AC_SUBST([EV_API_VERSION],[ev_api_version])
 669 AC_SUBST([EV_BINARY_VERSION],[ev_binary_version])
 670
 671 AC_SUBST([EV_DOCUMENT_LT_VERSION_INFO],[ev_document_lt_version_info])
 672 AC_SUBST([EV_DOCUMENT_LT_CURRENT_MINUS_AGE],[ev_document_lt_current_minus_age])
 673 AC_SUBST([EV_VIEW_LT_VERSION_INFO],[ev_view_lt_version_info])
 674 AC_SUBST([EV_VIEW_LT_CURRENT_MINUS_AGE],[ev_view_lt_current_minus_age])
 675
 676 # *****************************************************************************
 677
 678 AC_CONFIG_FILES([
 679 backend/Makefile
 680 backend/comics/Makefile
 681 backend/djvu/Makefile
 682 backend/dvi/Makefile
 683 backend/dvi/mdvi-lib/Makefile
 684 backend/impress/Makefile
 685 backend/pdf/Makefile
 686 backend/pixbuf/Makefile
 687 backend/ps/Makefile
 688 backend/tiff/Makefile
 689 cut-n-paste/Makefile
 690 cut-n-paste/evinfobar/Makefile
 691 cut-n-paste/gimpcellrenderertoggle/Makefile
 692 cut-n-paste/smclient/Makefile
 693 cut-n-paste/toolbar-editor/Makefile
 694 cut-n-paste/zoom-control/Makefile
 695 cut-n-paste/totem-screensaver/Makefile
 696 data/evince.desktop.in
 697 data/Makefile
 698 data/icons/Makefile
 699 data/icons/16x16/Makefile
 700 data/icons/16x16/apps/Makefile
 701 data/icons/16x16/actions/Makefile
 702 data/icons/22x22/Makefile
 703 data/icons/22x22/apps/Makefile
 704 data/icons/22x22/actions/Makefile
 705 data/icons/24x24/Makefile
 706 data/icons/24x24/apps/Makefile
 707 data/icons/24x24/actions/Makefile
 708 data/icons/32x32/Makefile
 709 data/icons/32x32/actions/Makefile
 710 data/icons/48x48/Makefile
 711 data/icons/48x48/apps/Makefile
 712 data/icons/48x48/actions/Makefile
 713 data/icons/scalable/Makefile
 714 data/icons/scalable/apps/Makefile
 715 help/Makefile
 716 help/reference/Makefile
 717 help/reference/libdocument/Makefile
 718 help/reference/libdocument/version.xml
 719 help/reference/libview/Makefile
 720 help/reference/libview/version.xml
 721 help/reference/shell/Makefile
 722 help/reference/shell/version.xml
 723 libdocument/Makefile
 724 libdocument/ev-version.h
 725 libmisc/Makefile
 726 libview/Makefile
 727 Makefile
 728 po/Makefile.in
 729 previewer/Makefile
 730 properties/Makefile
 731 shell/Makefile
 732 test/Makefile
 733 thumbnailer/Makefile
 734 ])
 735
 736 AC_CONFIG_FILES(evince-document-[]ev_api_version[].pc:evince-document.pc.in)
 737 AC_CONFIG_FILES(evince-view-[]ev_api_version[].pc:evince-view.pc.in)
 738
 739 AC_OUTPUT
 740
 741 echo "
 742 Configure summary:
 743         Platform...........:  $with_platform
 744         GConf Support......:  $with_gconf
 745         GTK+ Unix Print....:  $with_gtk_unix_print
 746         Keyring Support....:  $with_keyring
 747         DBUS Support.......:  $enable_dbus
 748         SM client support..:  $with_smclient
 749         Nautilus Plugin....:  $enable_nautilus
 750         Thumbnailer........:  $enable_thumbnailer
 751         Previewer..........:  $enable_previewer
 752         Gtk-Doc Support....:  $enable_gtk_doc
 753         Debug mode.........:  $enable_debug
 754         GObj. Introspection:  $enable_introspection
 755         Tests..............:  $enable_tests
 756
 757         PDF Backend........:  $enable_pdf
 758         PostScript Backend.:  $enable_ps
 759         TIFF Backend.......:  $enable_tiff
 760         DJVU Backend.......:  $enable_djvu
 761         DVI Backend........:  $enable_dvi
 762         Pixbuf Backend.....:  $enable_pixbuf
 763         Comics Backend.....:  $enable_comics
 764         Impress Backend....:  $enable_impress
 765 "