configure.ac

   1 # *****************************************************************************
   2 # Versioning
   3 # *****************************************************************************
   4
   5 m4_define([ev_major_version],[2])
   6 m4_define([ev_minor_version],[29])
   7 m4_define([ev_micro_version],[5])
   8 m4_define([ev_extra_version],[])
   9 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version()ev_extra_version])
  10
  11 # The evince API version
  12 m4_define([ev_api_version], [2.29])
  13
  14 # Libtool versioning. The backend and view libraries have separate versions.
  15 # Before making a release, the libtool version should be modified.
  16 # The string is of the form C:R:A.
  17 # - If interfaces have been changed or added, but binary compatibility has
  18 #   been preserved, change to C+1:0:A+1
  19 # - If binary compatibility has been broken (eg removed or changed interfaces)
  20 #   change to C+1:0:0
  21 # - If the interface is the same as the previous version, change to C:R+1:A
  22
  23 # Libtool version of the backend library
  24 m4_define([ev_document_lt_current],[2])
  25 m4_define([ev_document_lt_revision],[0])
  26 m4_define([ev_document_lt_age],[0])
  27 m4_define([ev_document_lt_version_info],[ev_document_lt_current:ev_document_lt_revision:ev_document_lt_age])
  28 m4_define([ev_document_lt_current_minus_age],[m4_eval(ev_document_lt_current - ev_document_lt_age)])
  29
  30 # Libtool version of the view library
  31 m4_define([ev_view_lt_current],[2])
  32 m4_define([ev_view_lt_revision],[0])
  33 m4_define([ev_view_lt_age],[0])
  34 m4_define([ev_view_lt_version_info],[ev_view_lt_current:ev_view_lt_revision:ev_view_lt_age])
  35 m4_define([ev_view_lt_current_minus_age],[m4_eval(ev_view_lt_current - ev_view_lt_age)])
  36
  37 # Binary version for the document backends
  38 m4_define([ev_binary_version],[ev_document_lt_current])
  39
  40 # *****************************************************************************
  41
  42 AC_PREREQ([2.57])
  43 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
  44 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2 no-dist-gzip])
  45
  46 AC_CONFIG_HEADERS([config.h])
  47 AC_CONFIG_MACRO_DIR([m4])
  48
  49 if test -z "$enable_maintainer_mode"; then
  50   enable_maintainer_mode=yes
  51 fi
  52 AM_MAINTAINER_MODE([enable])
  53
  54 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  55
  56 AM_PROG_LIBTOOL
  57
  58 AC_ISC_POSIX
  59 AC_PROG_CC
  60 AM_PROG_CC_STDC
  61 AM_PROG_CC_C_O
  62 AC_PROG_CXX
  63 AC_STDC_HEADERS
  64
  65 AC_PROG_SED
  66 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  67 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  68
  69 GNOME_DOC_INIT
  70 GNOME_MAINTAINER_MODE_DEFINES
  71 GNOME_COMPILE_WARNINGS
  72 GNOME_CXX_WARNINGS
  73
  74 IT_PROG_INTLTOOL([0.35.0])
  75
  76 GETTEXT_PACKAGE=evince
  77 AC_SUBST(GETTEXT_PACKAGE)
  78 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  79 AM_GLIB_GNU_GETTEXT
  80
  81 m4_pattern_allow([AM_V_GEN])dnl Make autoconf not complain about the rule below
  82 EV_INTLTOOL_EVINCE_BACKEND_RULE='%.evince-backend:   %.evince-backend.in   $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; $(AM_V_GEN) LC_ALL=C $(INTLTOOL_MERGE) -d -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@'
  83 AC_SUBST([EV_INTLTOOL_EVINCE_BACKEND_RULE])
  84
  85 # Check which platform to use
  86
  87 AC_MSG_CHECKING([for which platform to build])
  88 AC_ARG_WITH([platform],
  89   [AS_HELP_STRING([--with-platform=gnome|win32|hildon],
  90                   [Setting platform (default: gnome)])],
  91   [case "$withval" in
  92     gnome|win32|hildon) ;;
  93     *) AC_MSG_ERROR([invalid argument "$withval" for --with-platform]) ;;
  94    esac],
  95   [case "$host" in
  96      *-*-mingw*|*-*-cygwin*) with_platform="win32" ;;
  97      *) with_platform=gnome ;;
  98    esac])
  99
 100 AC_MSG_RESULT([$with_platform])
 101
 102 if test "$with_platform" = "win32"; then
 103   AC_CHECK_TOOL([WINDRES],[windres])
 104   AC_MSG_CHECKING([for native Win32])
 105   case "$host" in
 106     *-*-mingw*)
 107       os_win32=yes
 108       ;;
 109     *)
 110       os_win32=no
 111       ;;
 112   esac
 113   AC_MSG_RESULT([$os_win32])
 114 fi
 115
 116 AM_CONDITIONAL([PLATFORM_HILDON],[test "$with_platform" = "hildon"])
 117 AM_CONDITIONAL([PLATFORM_WIN32],[test "$with_platform" = "win32"])
 118
 119 dnl Specify required versions of dependencies
 120 DBUS_GLIB_REQUIRED=0.70
 121 GTK_REQUIRED=2.14.0
 122 GLIB_REQUIRED=2.18.0
 123 KEYRING_REQUIRED=2.22.0
 124 AC_SUBST([GLIB_REQUIRED])
 125 AC_SUBST([GTK_REQUIRED])
 126
 127 GNOME_ICON_THEME_REQUIRED=2.17.1
 128 LIBXML_REQUIRED=2.5.0
 129
 130 dnl Check dependencies
 131
 132 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
 133 # BACKEND_CFLAGS   for backend implementations.
 134 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
 135 # FRONTEND_LIBS
 136 # SHELL_CFLAGS     for shell implementation.
 137 # SHELL_LIBS
 138
 139 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
 140 PKG_CHECK_MODULES(LIBVIEW, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 141 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
 142 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 143 PKG_CHECK_MODULES(PREVIEWER, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 144
 145 SHELL_PLATFORM_PKGS=
 146 case "$with_platform" in
 147   hildon) AC_DEFINE([PLATFORM_HILDON],[1],[Define if building for the hildon platform])
 148           SHELL_PLATFORM_PKGS="hildon-1 hildon-fm-2 libosso"
 149           ;;
 150   gnome)
 151         # Evince has a rather soft run-time dependency on hicolor-icon-theme.
 152         # If the hicolor theme is not available, Evince fails to display some
 153         # icons. Because we cannot check for it at run-time, we instead
 154         # would like to require the icon theme at compile-time. But, because
 155         # the hicolor-icon-theme does not have a pkgconfig file, on gnome we
 156         # require the gnome icon theme instead.
 157         SHELL_PLATFORM_PKGS="gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED"
 158         ;;
 159   *)
 160         # On all other platforms we issue a warning about the runtime
 161         # dependency.
 162         AC_MSG_WARN([Evince has a soft run-time dependency on hicolor-icon-theme. You are advised to have this theme installed when running Evince.]);
 163         SHELL_PLATFORM_PKGS=""
 164         ;;
 165 esac
 166
 167 PKG_CHECK_MODULES([SHELL_CORE],[libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gthread-2.0 $SHELL_PLATFORM_PKGS])
 168
 169 # *********
 170 # SM client
 171 # *********
 172
 173 GDK_TARGET="$($PKG_CONFIG --variable target gdk-2.0)"
 174
 175 AC_MSG_CHECKING([which smclient backend to use])
 176 AC_ARG_WITH([smclient],
 177   [AS_HELP_STRING([--with-smclient-backend=no|xsmp|win32|quartz],
 178                   [Setting smclient backend (default:auto)])],
 179   [],
 180   [case "$GDK_TARGET" in
 181     x11) case "$with_platform" in
 182            gnome) with_smclient=xsmp ;;
 183            *) with_smclient=no ;;
 184          esac ;;
 185     win32|quartz) with_smclient=$GDK_TARGET ;;
 186     *) with_smclient=no ;;
 187    esac])
 188
 189 AC_MSG_RESULT([$with_smclient])
 190
 191 if test "$with_smclient" != "no"; then
 192   AC_DEFINE([WITH_SMCLIENT],[1],[Define if smclient is enabled])
 193
 194   case "$with_smclient" in
 195     xsmp) SMCLIENT_PKGS="sm >= 1.0.0" ;;
 196     *) SMCLIENT_PKGS="" ;;
 197   esac
 198
 199   PKG_CHECK_MODULES([SMCLIENT],[gtk+-2.0 gthread-2.0 $SMCLIENT_PKGS])
 200   AC_SUBST([SMCLIENT_CFLAGS])
 201   AC_SUBST([SMCLIENT_LIBS])
 202 fi
 203
 204 AM_CONDITIONAL([WITH_SMCLIENT],[test "$with_smclient" != "no"])
 205 AM_CONDITIONAL([WITH_SMCLIENT_XSMP],[test "$with_smclient" = "xsmp"])
 206 AM_CONDITIONAL([WITH_SMCLIENT_WIN32],[test "$with_smclient" = "win32"])
 207 AM_CONDITIONAL([WITH_SMCLIENT_QUARTZ],[test "$with_smclient" = "quartz"])
 208
 209 # ***
 210
 211 BACKEND_LIBTOOL_FLAGS="-module -avoid-version -no-undefined -export-symbols \$(top_srcdir)/backend/backend.symbols"
 212 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
 213
 214 dnl ===== Check special functions
 215 evince_save_LIBS=$LIBS
 216 LIBS="$LIBS $BACKEND_LIBS"
 217 AC_CHECK_FUNCS(cairo_format_stride_for_width)
 218 AC_CHECK_FUNCS(gtk_print_operation_get_n_pages_to_print)
 219 LIBS=$evince_save_LIBS
 220
 221 # ******************
 222 # GKT+ Unix Printing
 223 # ******************
 224
 225 AC_MSG_CHECKING([whether gtk+-unix-print support is requested])
 226 AC_ARG_WITH([gtk-unix-print],
 227   [AS_HELP_STRING([--without-gtk-unix-print],
 228                   [Disable the use of gtk-unix-print])],
 229   [],[case "$os_win32" in
 230         yes) with_gtk_unix_print=no ;;
 231         *) with_gtk_unix_print=yes ;;
 232       esac])
 233
 234 AC_MSG_RESULT([$with_gtk_unix_print])
 235
 236 if test "$with_gtk_unix_print" = "yes"; then
 237    PKG_CHECK_MODULES(GTKUNIXPRINT, [gtk+-unix-print-2.0 >= $GTK_REQUIRED])
 238    AC_DEFINE([GTKUNIXPRINT_ENABLED], [1], [Define if gtk+-unix-print is enabled.])
 239 fi
 240
 241 # *********************
 242 # GNOME Keyring support
 243 # *********************
 244
 245 AC_ARG_WITH(keyring,
 246         [AS_HELP_STRING([--without-keyring],
 247                         [Disable the use of gnome-keyring])],
 248         [],
 249         [case "$with_platform" in
 250            gnome) with_keyring=yes ;;
 251            hildon|win32) with_keyring=no ;;
 252          esac])
 253
 254 AM_CONDITIONAL([WITH_KEYRING],[test "$with_keyring" = "yes"])
 255
 256 if test "$with_keyring" = "yes"; then
 257         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
 258         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
 259 fi
 260
 261 # ****
 262 # DBUS
 263 # ****
 264
 265 AC_ARG_ENABLE([dbus],
 266   [AS_HELP_STRING([--disable-dbus], [Disable support for dbus])],
 267   [],
 268   [case "$with_platform" in
 269       gnome) enable_dbus=yes ;;
 270       hildon) enable_dbus=no ;;
 271     esac])
 272
 273 if test "$enable_dbus" = "yes"; then
 274   PKG_CHECK_MODULES([DBUS],[dbus-glib-1 >= $DBUS_GLIB_REQUIRED],[],
 275                     [AC_MSG_ERROR([DBUS not found; use --disable-dbus to disable DBUS support])])
 276
 277   AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 278   if test x$DBUS_BINDING_TOOL = "xno" ; then
 279           AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 280   fi
 281
 282   AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 283 fi
 284
 285 AC_SUBST([DBUS_CFLAGS])
 286 AC_SUBST([DBUS_LIBS])
 287
 288 AM_CONDITIONAL([ENABLE_DBUS], [test "$enable_dbus" = "yes"])
 289
 290 if test "$enable_dbus" = "yes"; then
 291    PKG_CHECK_MODULES([EV_DAEMON], [gthread-2.0 gio-2.0 >= $GLIB_REQUIRED dbus-glib-1 >= $DBUS_GLIB_REQUIRED])
 292 fi
 293
 294 dnl ========= Check for GConf
 295
 296 AC_MSG_CHECKING([whether GConf support is requested])
 297 AC_ARG_WITH([gconf],
 298   [AS_HELP_STRING([--without-gconf],
 299                   [Disable the use of gconf])],
 300   [],
 301   [case "$os_win32" in
 302      yes) with_gconf=no ;;
 303      *) with_gconf=yes ;;
 304    esac])
 305 AC_MSG_RESULT([$with_gconf])
 306
 307 AM_CONDITIONAL([WITH_GCONF],[test "$with_gconf" = "yes"])
 308
 309 if test "$with_gconf" = "yes"; then
 310    PKG_CHECK_MODULES([GCONF],[gconf-2.0])
 311    AC_DEFINE([WITH_GCONF],[1],[Define if GConf support is enabled])
 312
 313    AM_GCONF_SOURCE_2
 314
 315    AC_PATH_PROG([GCONFTOOL], [gconftool-2], [false])
 316    if test "$GCONFTOOL" = "false"; then
 317       AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 318    fi
 319 else
 320    AM_CONDITIONAL([GCONF_SCHEMAS_INSTALL],false)
 321 fi
 322
 323 dnl Debug mode
 324
 325 AC_ARG_ENABLE([debug],
 326         AS_HELP_STRING([--enable-debug],
 327                        [Turn on evince debug mode]),
 328         [enable_debug=$enableval],
 329         [enable_debug=no])
 330
 331 if test "x$enable_debug" = "xyes"; then
 332    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 333 fi
 334
 335 AC_ARG_ENABLE([tests],
 336         AS_HELP_STRING([--enable-tests], [Enable the tests]),
 337         [enable_tests=$enableval],
 338         [enable_tests=yes])
 339
 340 AM_CONDITIONAL(ENABLE_TESTS, test x$enable_tests = xyes)
 341
 342 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 343 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 344 AC_SUBST(LIBDOCUMENT_CFLAGS)
 345 AC_SUBST(LIBDOCUMENT_LIBS)
 346
 347 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 348 LIBVIEW_LIBS="$LIBVIEW_LIBS $GTKUNIXPRINT_LIBS"
 349 AC_SUBST(LIBVIEW_CFLAGS)
 350 AC_SUBST(LIBVIEW_LIBS)
 351
 352 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 353 AC_SUBST(BACKEND_CFLAGS)
 354 AC_SUBST(BACKEND_LIBS)
 355
 356 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS $KEYRING_CFLAGS $GCONF_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 357 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS $KEYRING_LIBS $GCONF_LIBS -lz"
 358 AC_SUBST(SHELL_CFLAGS)
 359 AC_SUBST(SHELL_LIBS)
 360
 361 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 362 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 363 AC_SUBST(FRONTEND_CFLAGS)
 364 AC_SUBST(FRONTEND_LIBS)
 365
 366 EV_DAEMON_CFLAGS="$EV_DAEMON_CFLAGS $DEBUG_FLAGS"
 367 AC_SUBST([EV_DAEMON_CFLAGS])
 368 AC_SUBST([EV_DAEMON_LIBS])
 369
 370 # Check for Nautilus property page build
 371 AC_ARG_ENABLE([nautilus],
 372   [AS_HELP_STRING([--disable-nautilus],
 373                   [Disable build of nautilus extensions])],
 374   [],
 375   [case "$with_platform" in
 376      gnome) enable_nautilus=yes ;;
 377      *) enable_nautilus=no ;;
 378     esac])
 379
 380 if test "$enable_nautilus" = "yes" ; then
 381   PKG_CHECK_MODULES([NAUTILUS],[gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension],
 382                     [],[AC_MSG_ERROR([libnautilus-extension not found; use --disable-nautilus to disable the nautilus extensions])])
 383   NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 384   AC_SUBST([nautilusextensiondir],[$NAUTILUS_EXTENSION_DIR])
 385   AC_SUBST(NAUTILUS_CFLAGS)
 386   AC_SUBST(NAUTILUS_LIBS)
 387
 388   AC_DEFINE([HAVE_NAUTILUS],[1], [defined if you build the nautilus plugin])
 389 fi
 390
 391 AM_CONDITIONAL([ENABLE_NAUTILUS],[test "$enable_nautilus" = "yes"])
 392
 393 # Check for thumbnailer build
 394
 395 AC_ARG_ENABLE([thumbnailer],
 396   [AS_HELP_STRING([--disable-thumbnailer],
 397                   [Disable GNOME thumbnailer])],
 398   [],
 399   [case "$with_platform" in
 400      gnome) enable_thumbnailer=yes ;;
 401      *) enable_thumbnailer=no ;;
 402     esac])
 403
 404 AM_CONDITIONAL([ENABLE_THUMBNAILER],[test "$enable_thumbnailer" = "yes"])
 405
 406 # ***************
 407 # Print Previewer
 408 # ***************
 409
 410 AC_ARG_ENABLE([previewer],
 411   [AS_HELP_STRING([--disable-previewer],
 412                   [Disable the GNOME Document Previewer])],
 413   [],
 414   [case "$with_platform" in
 415       gnome) enable_previewer=yes ;;
 416       *) enable_previewer=no ;;
 417     esac])
 418
 419 if test x$enable_previewer = "xyes" ; then
 420   PKG_CHECK_MODULES([PREVIEWER],[gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED])
 421 fi
 422
 423 AM_CONDITIONAL([ENABLE_PREVIEWER],[test "$enable_previewer" = "yes"])
 424 PREVIEWER_CFLAGS="$PREVIEWER_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 425 PREVIEWER_LIBS="$PREVIEWER_LIBS $GTKUNIXPRINT_LIBS -lz"
 426 AC_SUBST(PREVIEWER_CFLAGS)
 427 AC_SUBST(PREVIEWER_LIBS)
 428
 429 # ***
 430 # GIR
 431 # ***
 432
 433 AC_MSG_CHECKING([whether GObject introspection is requested])
 434 AC_ARG_ENABLE([introspection],
 435         AS_HELP_STRING([--enable-introspection],
 436                        [Enable GObject introspection]),
 437         [enable_introspection=$enableval],
 438         [enable_introspection=no])
 439 AC_MSG_RESULT([$enable_introspection])
 440
 441 G_IR_SCANNER=
 442 G_IR_COMPILER=
 443 G_IR_GENERATE=
 444 GIRDIR=
 445 GIRTYPELIBDIR=
 446
 447 if test "$enable_introspection" = "yes"; then
 448   GOBJECT_INTROSPECTION_REQUIRED=0.6
 449   PKG_CHECK_MODULES([GOBJECT_INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
 450
 451   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
 452   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
 453   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
 454   GIRDIR="$($PKG_CONFIG --variable=girdir gobject-introspection-1.0)"
 455   GIRTYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
 456 fi
 457
 458 AC_SUBST([G_IR_SCANNER])
 459 AC_SUBST([G_IR_COMPILER])
 460 AC_SUBST([G_IR_GENERATE])
 461 AC_SUBST([GIRDIR])
 462 AC_SUBST([GIRTYPELIBDIR])
 463
 464 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
 465
 466 dnl ================== portability checks ===========================================
 467
 468 dnl for backtrace()
 469 AC_CHECK_HEADERS([execinfo.h])
 470
 471 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 472   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 473   ],[],[#include <langinfo.h>])
 474
 475 dnl ================== pdf checks ===================================================
 476 AC_ARG_ENABLE([pdf],
 477   [AS_HELP_STRING([--disable-pdf],
 478                   [Disable the PDF support])],
 479   [enable_pdf=$enableval],
 480   [enable_pdf=yes])
 481
 482 if test "x$enable_pdf" = "xyes"; then
 483     POPPLER_REQUIRED=0.12.0
 484     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED,enable_pdf=yes,enable_pdf=no)
 485
 486     if test "x$enable_pdf" = "xyes"; then
 487             evince_save_LIBS=$LIBS
 488             LIBS="$LIBS $POPPLER_LIBS"
 489             AC_CHECK_FUNCS(poppler_page_render)
 490             AC_CHECK_FUNCS(poppler_page_get_image)
 491             AC_CHECK_FUNCS(poppler_annot_file_attachment_get_attachment)
 492             LIBS=$evince_save_LIBS
 493
 494             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 495             if test x$enable_cairo_pdf = xyes; then
 496                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 497             fi
 498
 499             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 500             if test x$enable_cairo_ps = xyes; then
 501                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 502             fi
 503     else
 504             AC_MSG_ERROR("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 505     fi
 506 fi
 507
 508 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 509 dnl ================== end of pdf checks ============================================
 510
 511 dnl libspectre (used by ps and dvi backends)
 512 SPECTRE_REQUIRED=0.2.0
 513 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 514 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 515 if test "x$have_spectre" = "xyes"; then
 516    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 517 fi
 518
 519 dnl ================== ps checks ====================================================
 520 AC_ARG_ENABLE(ps,
 521         [AS_HELP_STRING([--disable-ps],
 522                         [Disable the PostScript backend])],
 523         [enable_ps=$enableval],
 524         [enable_ps=yes])
 525
 526 if test "x$enable_ps" = "xyes"; then
 527    if test "x$have_spectre" = "xyes"; then
 528       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 529    else
 530       enable_ps="no"
 531       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 532    fi
 533 fi
 534 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 535 dnl ======================== End of ps checks ===================================
 536
 537 dnl ================== tiff checks ===================================================
 538 AC_ARG_ENABLE(tiff,
 539             [AS_HELP_STRING([--disable-tiff],
 540                             [Disable the support of multipage tiff])],
 541             [enable_tiff=$enableval],
 542             [enable_tiff=yes])
 543
 544 if test "x$enable_tiff" = "xyes"; then
 545     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 546     if test "x$enable_tiff" = "xyes"; then
 547         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 548         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 549     fi
 550     if test "x$enable_tiff" = "xyes"; then
 551             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 552     else
 553             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 554     fi
 555 fi
 556
 557 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 558 dnl ================== end of tiff checks ============================================
 559
 560 dnl ================== djvu checks ===================================================
 561
 562 AC_ARG_ENABLE(djvu,
 563             [AS_HELP_STRING([--disable-djvu],
 564                             [Disable the support of djvu viewer])],
 565             [enable_djvu=$enableval],
 566             [enable_djvu=yes])
 567
 568 if test "x$enable_djvu" = "xyes"; then
 569     DJVULIBRE_REQUIRED=3.5.17
 570     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 571
 572     if test "x$enable_djvu" = "xyes"; then
 573         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 574     else
 575         AC_MSG_WARN([
 576 ** Djvu support is disabled since a recent version of the djvulibre
 577 ** library was not found. You need at least djvulibre-3.5.17 which
 578 ** can be found on http://djvulibre.djvuzone.org
 579 ])
 580     fi
 581 fi
 582
 583 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 584
 585 dnl ================== End of djvu checks ===================================================
 586
 587 dnl ================== dvi checks ===================================================
 588
 589 AC_ARG_ENABLE(dvi,
 590             [AS_HELP_STRING([--disable-dvi],
 591             [Disable the support of dvi viewer])],
 592             [enable_dvi=$enableval],
 593             [enable_dvi=yes])
 594
 595 AC_ARG_ENABLE(t1lib,
 596             [AS_HELP_STRING([--enable-t1lib],
 597                             [Compile with support of t1lib for type1 fonts in dvi])],
 598             [enable_type1_fonts=$enableval],
 599             [enable_type1_fonts=no])
 600
 601 if test "x$enable_dvi" = "xyes"; then
 602     AC_C_CONST
 603     AC_C_INLINE
 604     AC_TYPE_SIZE_T
 605     AC_CHECK_SIZEOF(long, 4)
 606     AC_CHECK_SIZEOF(int, 4)
 607     AC_CHECK_SIZEOF(short, 2)
 608     AC_CHECK_SIZEOF(void *, 4)
 609     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 610
 611     if test "x$enable_dvi" = "xyes"; then
 612         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 613     else
 614         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 615     fi
 616 fi
 617 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 618
 619 if test "x$enable_dvi" = "xyes"; then
 620     if test "x$enable_type1_fonts" = "xyes"; then
 621         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 622     fi
 623
 624     if test "x$enable_type1_fonts" = xyes; then
 625         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 626     fi
 627 else
 628     enable_type1_fonts=no
 629 fi
 630 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 631
 632 dnl ================== End of dvi checks ===================================================
 633
 634 dnl ================== pixbuf checks ===================================================
 635
 636 AC_ARG_ENABLE(pixbuf,
 637             [AS_HELP_STRING([--enable-pixbuf],
 638                             [Compile with support of pixbuf])],
 639             [enable_pixbuf=$enableval],
 640             [enable_pixbuf=no])
 641
 642 if test "x$enable_pixbuf" = "xyes"; then
 643         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 644 fi
 645
 646 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 647
 648 dnl ================== End of pixbuf checks ===================================================
 649
 650 dnl ================== comic book checks ===================================================
 651
 652 AC_ARG_ENABLE(comics,
 653         [AS_HELP_STRING([--enable-comics],
 654                         [Compile with support for comic book archives])],
 655         [enable_comics=$enableval],
 656         [enable_comics=yes])
 657
 658 if test "x$enable_comics" = "xyes"; then
 659         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 660 fi
 661 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 662
 663 dnl ================== End of comic book checks ============================================
 664
 665 dnl ================== impress book checks ===================================================
 666
 667 AC_ARG_ENABLE(impress,
 668         [AS_HELP_STRING([--enable-impress],
 669                         [Compile with support for impress presentations])],
 670         [enable_impress=$enableval],
 671         [enable_impress=no])
 672
 673 if test "x$enable_impress" = "xyes"; then
 674         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 675 fi
 676 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 677
 678 dnl ================== End of impress book checks ============================================
 679
 680 dnl =================== Mime types list ====================================================
 681
 682 if test "x$enable_pdf" = "xyes" ; then
 683         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 684 fi
 685 if test "x$enable_ps" = "xyes" ; then
 686         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 687 fi
 688 if test "x$enable_dvi" = "xyes"; then
 689         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 690 fi
 691 if test "x$enable_djvu" = "xyes"; then
 692         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 693 fi
 694 if test "x$enable_tiff" = "xyes"; then
 695         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 696 fi
 697 if test "x$enable_comics" = "xyes"; then
 698         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;application/x-cbt;"
 699 fi
 700 if test "x$enable_pixbuf" = "xyes"; then
 701         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 702 fi
 703 if test "x$enable_impress" = "xyes"; then
 704         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 705 fi
 706 AC_SUBST(EVINCE_MIME_TYPES)
 707
 708 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 709
 710 # *****************
 711 # API documentation
 712 # *****************
 713
 714 GTK_DOC_CHECK([1.13],[--flavour no-tmpl])
 715
 716 AC_SUBST([GLIB_PREFIX],[$($PKG_CONFIG --variable=prefix glib-2.0)])
 717 AC_SUBST([GTK_PREFIX],[$($PKG_CONFIG --variable=prefix gtk+-2.0)])
 718
 719 # ******************
 720 # Backends directory
 721 # ******************
 722
 723 AC_SUBST([backenddir],"\$(libdir)/evince/ev_binary_version/backends")
 724 AC_SUBST([backend_binary_version],"ev_binary_version")
 725
 726 # **********
 727 # Versioning
 728 # **********
 729
 730 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
 731 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
 732 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
 733
 734 AC_SUBST([EV_API_VERSION],[ev_api_version])
 735 AC_SUBST([EV_BINARY_VERSION],[ev_binary_version])
 736
 737 AC_SUBST([EV_DOCUMENT_LT_VERSION_INFO],[ev_document_lt_version_info])
 738 AC_SUBST([EV_DOCUMENT_LT_CURRENT_MINUS_AGE],[ev_document_lt_current_minus_age])
 739 AC_SUBST([EV_VIEW_LT_VERSION_INFO],[ev_view_lt_version_info])
 740 AC_SUBST([EV_VIEW_LT_CURRENT_MINUS_AGE],[ev_view_lt_current_minus_age])
 741
 742 # *****************************************************************************
 743 # *****************************************************************************
 744
 745 AC_CONFIG_FILES([
 746 backend/Makefile
 747 backend/comics/Makefile
 748 backend/djvu/Makefile
 749 backend/dvi/Makefile
 750 backend/dvi/mdvi-lib/Makefile
 751 backend/impress/Makefile
 752 backend/pdf/Makefile
 753 backend/pixbuf/Makefile
 754 backend/ps/Makefile
 755 backend/tiff/Makefile
 756 cut-n-paste/Makefile
 757 cut-n-paste/evinfobar/Makefile
 758 cut-n-paste/gimpcellrenderertoggle/Makefile
 759 cut-n-paste/smclient/Makefile
 760 cut-n-paste/toolbar-editor/Makefile
 761 cut-n-paste/zoom-control/Makefile
 762 cut-n-paste/totem-screensaver/Makefile
 763 data/evince.desktop.in
 764 data/Makefile
 765 data/icons/Makefile
 766 data/icons/16x16/Makefile
 767 data/icons/16x16/apps/Makefile
 768 data/icons/16x16/actions/Makefile
 769 data/icons/16x16/mimetypes/Makefile
 770 data/icons/22x22/Makefile
 771 data/icons/22x22/apps/Makefile
 772 data/icons/22x22/actions/Makefile
 773 data/icons/22x22/mimetypes/Makefile
 774 data/icons/24x24/Makefile
 775 data/icons/24x24/apps/Makefile
 776 data/icons/24x24/actions/Makefile
 777 data/icons/24x24/mimetypes/Makefile
 778 data/icons/32x32/Makefile
 779 data/icons/32x32/actions/Makefile
 780 data/icons/32x32/mimetypes/Makefile
 781 data/icons/48x48/Makefile
 782 data/icons/48x48/apps/Makefile
 783 data/icons/48x48/actions/Makefile
 784 data/icons/scalable/Makefile
 785 data/icons/scalable/apps/Makefile
 786 data/icons/scalable/actions/Makefile
 787 data/icons/scalable/mimetypes/Makefile
 788 help/Makefile
 789 help/reference/Makefile
 790 help/reference/libdocument/Makefile
 791 help/reference/libdocument/version.xml
 792 help/reference/libview/Makefile
 793 help/reference/libview/version.xml
 794 help/reference/shell/Makefile
 795 help/reference/shell/version.xml
 796 libdocument/Makefile
 797 libdocument/ev-version.h
 798 libmisc/Makefile
 799 libview/Makefile
 800 Makefile
 801 po/Makefile.in
 802 previewer/Makefile
 803 properties/Makefile
 804 shell/Makefile
 805 test/Makefile
 806 thumbnailer/Makefile
 807 ])
 808
 809 AC_CONFIG_FILES(evince-document-[]ev_api_version[].pc:evince-document.pc.in)
 810 AC_CONFIG_FILES(evince-view-[]ev_api_version[].pc:evince-view.pc.in)
 811
 812 AC_OUTPUT
 813
 814 echo "
 815 Configure summary:
 816         Platform...........:  $with_platform
 817         GConf Support......:  $with_gconf
 818         GTK+ Unix Print....:  $with_gtk_unix_print
 819         Keyring Support....:  $with_keyring
 820         DBUS Support.......:  $enable_dbus
 821         SM client support..:  $with_smclient
 822         Nautilus Plugin....:  $enable_nautilus
 823         Thumbnailer........:  $enable_thumbnailer
 824         Previewer..........:  $enable_previewer
 825         Gtk-Doc Support....:  $enable_gtk_doc
 826         Debug mode.........:  $enable_debug
 827         GObj. Introspection:  $enable_introspection
 828         Tests..............:  $enable_tests
 829
 830         PDF Backend........:  $enable_pdf
 831         PostScript Backend.:  $enable_ps
 832         TIFF Backend.......:  $enable_tiff
 833         DJVU Backend.......:  $enable_djvu
 834         DVI Backend........:  $enable_dvi
 835         Pixbuf Backend.....:  $enable_pixbuf
 836         Comics Backend.....:  $enable_comics
 837         Impress Backend....:  $enable_impress
 838 "