configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.57)
   4 AC_INIT([Evince],[2.24.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
   5 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-dist-gzip])
   6
   7 EV_API_VERSION=2.20
   8 AC_SUBST(EV_API_VERSION)
   9
  10 AM_CONFIG_HEADER(config.h)
  11
  12 AM_MAINTAINER_MODE
  13
  14 AM_PROG_LIBTOOL
  15
  16 AC_ISC_POSIX
  17 AC_PROG_CC
  18 AM_PROG_CC_STDC
  19 AC_PROG_CXX
  20 AC_STDC_HEADERS
  21 IT_PROG_INTLTOOL([0.35.0])
  22 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  23 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  24
  25 GNOME_COMMON_INIT
  26 GNOME_DOC_INIT
  27 GNOME_MAINTAINER_MODE_DEFINES
  28 GNOME_COMPILE_WARNINGS
  29 GNOME_CXX_WARNINGS
  30
  31 GTK_DOC_CHECK(1.0)
  32
  33 GETTEXT_PACKAGE=evince
  34 AC_SUBST(GETTEXT_PACKAGE)
  35 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  36 AM_GLIB_GNU_GETTEXT
  37
  38 dnl Check dependencies
  39
  40 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
  41 # BACKEND_CFLAGS   for backend implementations.
  42 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
  43 # FRONTEND_LIBS
  44 # SHELL_CFLAGS     for shell implementation.
  45 # SHELL_LIBS
  46
  47 DBUS_GLIB_REQUIRED=0.70
  48 GTK_REQUIRED=2.12.0
  49 GLIB_REQUIRED=2.15.6
  50 KEYRING_REQUIRED=0.4.0
  51
  52 GNOME_ICON_THEME_REQUIRED=2.17.1
  53 LIBXML_REQUIRED=2.5.0
  54
  55 PKG_CHECK_MODULES(LIB, gtk+-2.0 >= $GTK_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
  56 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
  57 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED libglade-2.0 gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
  58 PKG_CHECK_MODULES(SHELL_CORE, libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED gthread-2.0 libglade-2.0 gconf-2.0)
  59
  60 PKG_CHECK_MODULES(SMCLIENT, gtk+-2.0 gthread-2.0)
  61 AC_SUBST(SMCLIENT_CFLAGS)
  62 AC_SUBST(SMCLIENT_LIBS)
  63
  64 BACKEND_LIBTOOL_FLAGS="-module -avoid-version"
  65 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
  66
  67 dnl ===== Check special functions
  68 evince_save_LIBS=$LIBS
  69 LIBS="$LIBS $BACKEND_LIBS"
  70 AC_CHECK_FUNCS(cairo_format_stride_for_width)
  71 LIBS=$evince_save_LIBS
  72
  73 AC_ARG_WITH(keyring,
  74         AC_HELP_STRING([--without-keyring],[disable the use of gnome-keyring]),
  75         [case "${withval}" in
  76         yes) WITH_KEYRING=yes ;;
  77         no) WITH_KEYRING=no ;;
  78         *) AC_MSG_ERROR(bad value ${withval} for --with-keyring) ;;
  79         esac],
  80         [WITH_KEYRING=yes]) dnl Default value
  81 AM_CONDITIONAL(WITH_KEYRING, test x$WITH_KEYRING = "xyes")
  82
  83 if test x$WITH_KEYRING = "xyes"; then
  84         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
  85         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
  86 fi
  87
  88 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
  89 AC_SUBST(GLIB_GENMARSHAL)
  90
  91 dnl ========= Check for DBUS
  92 AC_ARG_ENABLE(dbus,
  93         [AC_HELP_STRING([--enable-dbus], [Compile with support for dbus])],
  94         enable_dbus="$enableval",enable_dbus=yes)
  95 if test "x$enable_dbus" != "xno"; then
  96         PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
  97         [enable_dbus=yes],[enable_dbus=no])
  98
  99         if test "x$enable_dbus" = "xno"; then
 100            AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
 101         fi
 102
 103         if test "x$enable_dbus" = "xyes" ; then
 104                 AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 105
 106                 if test x$DBUS_BINDING_TOOL = "xno" ; then
 107                         AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 108                 fi
 109
 110                 AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 111         fi
 112 fi
 113
 114 AC_SUBST([DBUS_CFLAGS])
 115 AC_SUBST([DBUS_LIBS])
 116
 117 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
 118 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
 119
 120 dnl Debug mode
 121 AC_ARG_ENABLE([debug],
 122         AC_HELP_STRING([--enable-debug],
 123                         [Turn on evince debug mode]),,
 124                 [enable_debug=no])
 125
 126 if test "x$enable_debug" = "xyes"; then
 127    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 128 fi
 129
 130
 131 LIB_CFLAGS="$LIB_CFLAGS $DEBUG_FLAGS"
 132 LIB_LIBS="$LIB_LIBS"
 133 AC_SUBST(LIB_CFLAGS)
 134 AC_SUBST(LIB_LIBS)
 135
 136 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 137 AC_SUBST(BACKEND_CFLAGS)
 138 AC_SUBST(BACKEND_LIBS)
 139
 140 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS $KEYRING_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 141 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS $KEYRING_LIBS -lz"
 142 AC_SUBST(SHELL_CFLAGS)
 143 AC_SUBST(SHELL_LIBS)
 144
 145 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 146 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 147 AC_SUBST(FRONTEND_CFLAGS)
 148 AC_SUBST(FRONTEND_LIBS)
 149
 150 dnl Check for Nautilus property page build
 151 AC_ARG_ENABLE(nautilus,
 152         AC_HELP_STRING([--enable-nautilus],[compile the nautilus plugin]),
 153         [case "${enableval}" in
 154         yes) ENABLE_NAUTILUS=yes ;;
 155         no) ENABLE_NAUTILUS=no ;;
 156         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nautilus) ;;
 157         esac],
 158         [ENABLE_NAUTILUS=yes]) dnl Default value
 159
 160 if test x$ENABLE_NAUTILUS = "xyes" ; then
 161         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
 162                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
 163         NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 164         AC_SUBST(NAUTILUS_EXTENSION_DIR)
 165 fi
 166
 167 AC_SUBST(NAUTILUS_CFLAGS)
 168 AC_SUBST(NAUTILUS_LIBS)
 169 if test x$HAVE_NAUTILUS = "xyes"; then
 170         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
 171 fi
 172 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
 173
 174
 175 dnl Check for thumbnailer build
 176 AC_ARG_ENABLE(thumbnailer,
 177         AC_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer]),
 178         [case "${enableval}" in
 179         yes) ENABLE_THUMBNAILER=yes ;;
 180         no) ENABLE_THUMBNAILER=no ;;
 181         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thumbnailer) ;;
 182         esac],
 183         [ENABLE_THUMBNAILER=yes]) dnl Default value
 184 AM_CONDITIONAL(ENABLE_THUMBNAILER, test x$ENABLE_THUMBNAILER = "xyes")
 185
 186 dnl GConf configuration
 187 AM_GCONF_SOURCE_2
 188
 189 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
 190 if test "x$GCONFTOOL" = "xno"; then
 191         AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 192 fi
 193
 194 dnl ================== portability checks ===========================================
 195
 196 dnl for backtrace()
 197 AC_CHECK_HEADERS([execinfo.h])
 198
 199 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 200   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 201   ],[],[#include <langinfo.h>])
 202
 203 dnl ================== pdf checks ===================================================
 204 AC_ARG_ENABLE(pdf,
 205               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 206
 207 if test "x$enable_pdf" = "xyes"; then
 208     POPPLER_REQUIRED=0.8.0
 209     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED,enable_pdf=yes,enable_pdf=no)
 210
 211     if test "x$enable_pdf" = "xyes"; then
 212             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 213             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 214             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 215
 216             evince_save_LIBS=$LIBS
 217             LIBS="$LIBS $POPPLER_LIBS"
 218             AC_CHECK_FUNCS(poppler_page_render)
 219             LIBS=$evince_save_LIBS
 220
 221             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 222             if test x$enable_cairo_pdf = xyes; then
 223                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 224             fi
 225
 226             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 227             if test x$enable_cairo_ps = xyes; then
 228                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 229             fi
 230     else
 231             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 232     fi
 233 fi
 234
 235 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 236 dnl ================== end of pdf checks ============================================
 237
 238 dnl libspectre (used by ps and dvi backends)
 239 SPECTRE_REQUIRED=0.2.0
 240 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 241 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 242 if test "x$have_spectre" = "xyes"; then
 243    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 244 fi
 245
 246 dnl ================== ps checks ====================================================
 247 AC_ARG_ENABLE(ps,
 248         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 249
 250 if test "x$enable_ps" = "xyes"; then
 251    if test "x$have_spectre" = "xyes"; then
 252       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 253    else
 254       enable_ps="no"
 255       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 256    fi
 257 fi
 258 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 259 dnl ======================== End of ps checks ===================================
 260
 261 dnl ================== tiff checks ===================================================
 262 AC_ARG_ENABLE(tiff,
 263             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 264
 265 if test "x$enable_tiff" = "xyes"; then
 266     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 267     if test "x$enable_tiff" = "xyes"; then
 268         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 269         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 270     fi
 271     if test "x$enable_tiff" = "xyes"; then
 272             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 273     else
 274             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 275     fi
 276 fi
 277
 278 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 279 dnl ================== end of tiff checks ============================================
 280
 281 dnl ================== djvu checks ===================================================
 282
 283 AC_ARG_ENABLE(djvu,
 284             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=yes)
 285
 286 if test "x$enable_djvu" = "xyes"; then
 287     DJVULIBRE_REQUIRED=3.5.17
 288     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 289
 290     if test "x$enable_djvu" = "xyes"; then
 291         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 292     else
 293         AC_MSG_WARN([
 294 ** Djvu support is disabled since a recent version of the djvulibre
 295 ** library was not found. You need at least djvulibre-3.5.17 which
 296 ** can be found on http://djvulibre.djvuzone.org
 297 ])
 298     fi
 299 fi
 300
 301 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 302
 303 dnl ================== End of djvu checks ===================================================
 304
 305 dnl ================== dvi checks ===================================================
 306
 307 AC_ARG_ENABLE(dvi,
 308             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=yes)
 309
 310 AC_ARG_ENABLE(t1lib,
 311             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 312
 313 if test "x$enable_dvi" = "xyes"; then
 314     AC_C_CONST
 315     AC_C_INLINE
 316     AC_TYPE_SIZE_T
 317     AC_CHECK_SIZEOF(long, 4)
 318     AC_CHECK_SIZEOF(int, 4)
 319     AC_CHECK_SIZEOF(short, 2)
 320     AC_CHECK_SIZEOF(void *, 4)
 321     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 322
 323     if test "x$enable_dvi" = "xyes"; then
 324         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 325     else
 326         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 327     fi
 328 fi
 329 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 330
 331 if test "x$enable_dvi" = "xyes"; then
 332     if test "x$enable_type1_fonts" = "xyes"; then
 333         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 334     fi
 335
 336     if test "x$enable_type1_fonts" = xyes; then
 337         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 338     fi
 339 else
 340     enable_type1_fonts=no
 341 fi
 342 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 343
 344 dnl ================== End of dvi checks ===================================================
 345
 346 dnl ================== pixbuf checks ===================================================
 347
 348 AC_ARG_ENABLE(pixbuf,
 349             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 350 if test "x$enable_pixbuf" = "xyes"; then
 351         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 352 fi
 353 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 354
 355 dnl ================== End of pixbuf checks ===================================================
 356
 357 dnl ================== comic book checks ===================================================
 358
 359 AC_ARG_ENABLE(comics,
 360         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=yes)
 361 if test "x$enable_comics" = "xyes"; then
 362         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 363 fi
 364 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 365
 366 dnl ================== End of comic book checks ============================================
 367
 368 dnl ================== impress book checks ===================================================
 369
 370 AC_ARG_ENABLE(impress,
 371         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 372 if test "x$enable_impress" = "xyes"; then
 373         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 374 fi
 375 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 376
 377 dnl ================== End of impress book checks ============================================
 378
 379 dnl =================== Mime types list ====================================================
 380
 381 if test "x$enable_pdf" = "xyes" ; then
 382         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 383 fi
 384 if test "x$enable_ps" = "xyes" ; then
 385         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 386 fi
 387 if test "x$enable_dvi" = "xyes"; then
 388         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 389 fi
 390 if test "x$enable_djvu" = "xyes"; then
 391         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 392 fi
 393 if test "x$enable_tiff" = "xyes"; then
 394         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 395 fi
 396 if test "x$enable_comics" = "xyes"; then
 397         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;"
 398 fi
 399 if test "x$enable_pixbuf" = "xyes"; then
 400         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 401 fi
 402 if test "x$enable_impress" = "xyes"; then
 403         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 404 fi
 405 AC_SUBST(EVINCE_MIME_TYPES)
 406
 407 AC_CONFIG_FILES([
 408 backend/Makefile
 409 backend/comics/Makefile
 410 backend/djvu/Makefile
 411 backend/dvi/Makefile
 412 backend/dvi/mdvi-lib/Makefile
 413 backend/impress/Makefile
 414 backend/pdf/Makefile
 415 backend/pixbuf/Makefile
 416 backend/ps/Makefile
 417 backend/tiff/Makefile
 418 cut-n-paste/Makefile
 419 cut-n-paste/evmountoperation/Makefile
 420 cut-n-paste/gedit-message-area/Makefile
 421 cut-n-paste/smclient/Makefile
 422 cut-n-paste/toolbar-editor/Makefile
 423 cut-n-paste/zoom-control/Makefile
 424 cut-n-paste/totem-screensaver/Makefile
 425 data/evince.desktop.in
 426 data/Makefile
 427 data/icons/Makefile
 428 data/icons/16x16/Makefile
 429 data/icons/16x16/apps/Makefile
 430 data/icons/16x16/actions/Makefile
 431 data/icons/22x22/Makefile
 432 data/icons/22x22/apps/Makefile
 433 data/icons/22x22/actions/Makefile
 434 data/icons/24x24/Makefile
 435 data/icons/24x24/apps/Makefile
 436 data/icons/24x24/actions/Makefile
 437 data/icons/32x32/Makefile
 438 data/icons/32x32/actions/Makefile
 439 data/icons/48x48/Makefile
 440 data/icons/48x48/apps/Makefile
 441 data/icons/48x48/actions/Makefile
 442 data/icons/scalable/Makefile
 443 data/icons/scalable/apps/Makefile
 444 help/Makefile
 445 help/reference/Makefile
 446 help/reference/version.xml
 447 libdocument/Makefile
 448 Makefile
 449 po/Makefile.in
 450 properties/Makefile
 451 shell/Makefile
 452 test/Makefile
 453 thumbnailer/Makefile
 454 ])
 455
 456 AC_OUTPUT
 457
 458 echo "
 459 Configure summary:
 460         Keyring Support....:  $WITH_KEYRING
 461         DBUS Support.......:  $enable_dbus
 462         Nautilus Plugin....:  $HAVE_NAUTILUS
 463         Thumbnailer........:  $ENABLE_THUMBNAILER
 464         Gtk-Doc Support....:  $enable_gtk_doc
 465         Debug mode.........:  $enable_debug
 466
 467         PDF Backend........:  $enable_pdf
 468         PostScript Backend.:  $enable_ps
 469         TIFF Backend.......:  $enable_tiff
 470         DJVU Backend.......:  $enable_djvu
 471         DVI Backend........:  $enable_dvi
 472         Pixbuf Backend.....:  $enable_pixbuf
 473         Comics Backend.....:  $enable_comics
 474         Impress Backend....:  $enable_impress
 475 "