configure.ac

   1 # *****************************************************************************
   2 # Versioning
   3 # *****************************************************************************
   4
   5 m4_define([ev_major_version],[2])
   6 m4_define([ev_minor_version],[26])
   7 m4_define([ev_micro_version],[0])
   8 m4_define([ev_extra_version],[])
   9 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version()ev_extra_version])
  10
  11 # The evince API version
  12 m4_define([ev_api_version], [2.25])
  13
  14 # Libtool versioning. The backend and view libraries have separate versions.
  15 # Before making a release, the libtool version should be modified.
  16 # The string is of the form C:R:A.
  17 # - If interfaces have been changed or added, but binary compatibility has
  18 #   been preserved, change to C+1:0:A+1
  19 # - If binary compatibility has been broken (eg removed or changed interfaces)
  20 #   change to C+1:0:0
  21 # - If the interface is the same as the previous version, change to C:R+1:A
  22
  23 # Libtool version of the backend library
  24 m4_define([ev_document_lt_current],[1])
  25 m4_define([ev_document_lt_revision],[0])
  26 m4_define([ev_document_lt_age],[0])
  27 m4_define([ev_document_lt_version_info],[ev_document_lt_current:ev_document_lt_revision:ev_document_lt_age])
  28 m4_define([ev_document_lt_current_minus_age],[m4_eval(ev_document_lt_current - ev_document_lt_age)])
  29
  30 # Libtool version of the view library
  31 m4_define([ev_view_lt_current],[1])
  32 m4_define([ev_view_lt_revision],[0])
  33 m4_define([ev_view_lt_age],[0])
  34 m4_define([ev_view_lt_version_info],[ev_view_lt_current:ev_view_lt_revision:ev_view_lt_age])
  35 m4_define([ev_view_lt_current_minus_age],[m4_eval(ev_view_lt_current - ev_view_lt_age)])
  36
  37 # Binary version for the document backends
  38 m4_define([ev_binary_version],[ev_document_lt_current])
  39
  40 # *****************************************************************************
  41
  42 AC_PREREQ([2.57])
  43 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
  44 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-dist-gzip])
  45
  46 AM_CONFIG_HEADER(config.h)
  47
  48 AM_MAINTAINER_MODE
  49
  50 AM_PROG_LIBTOOL
  51
  52 AC_ISC_POSIX
  53 AC_PROG_CC
  54 AM_PROG_CC_STDC
  55 AM_PROG_CC_C_O
  56 AC_PROG_CXX
  57 AC_STDC_HEADERS
  58 IT_PROG_INTLTOOL([0.35.0])
  59 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  60 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  61
  62 GNOME_COMMON_INIT
  63 GNOME_DOC_INIT
  64 GNOME_MAINTAINER_MODE_DEFINES
  65 GNOME_COMPILE_WARNINGS
  66 GNOME_CXX_WARNINGS
  67
  68 GTK_DOC_CHECK(1.0)
  69
  70 GETTEXT_PACKAGE=evince
  71 AC_SUBST(GETTEXT_PACKAGE)
  72 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  73 AM_GLIB_GNU_GETTEXT
  74
  75 dnl check for win32 platform
  76 AC_MSG_CHECKING([for Win32 platform])
  77 case "$host" in
  78   *-*-mingw*|*-*-cygwin*)
  79     platform_win32=yes
  80     AC_CHECK_TOOL(WINDRES, windres)
  81     ;;
  82   *)
  83     platform_win32=no
  84     ;;
  85 esac
  86 AC_MSG_RESULT([$platform_win32])
  87 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
  88
  89 AC_MSG_CHECKING([for native Win32])
  90 case "$host" in
  91   *-*-mingw*)
  92     os_win32=yes
  93     ;;
  94   *)
  95     os_win32=no
  96     ;;
  97 esac
  98 AC_MSG_RESULT([$os_win32])
  99 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 100
 101 dnl Check dependencies
 102
 103 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
 104 # BACKEND_CFLAGS   for backend implementations.
 105 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
 106 # FRONTEND_LIBS
 107 # SHELL_CFLAGS     for shell implementation.
 108 # SHELL_LIBS
 109
 110 DBUS_GLIB_REQUIRED=0.70
 111 GTK_REQUIRED=2.14.0
 112 GLIB_REQUIRED=2.18.0
 113 KEYRING_REQUIRED=2.22.0
 114 AC_SUBST([GLIB_REQUIRED])
 115 AC_SUBST([GTK_REQUIRED])
 116
 117 GNOME_ICON_THEME_REQUIRED=2.17.1
 118 LIBXML_REQUIRED=2.5.0
 119
 120 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
 121 PKG_CHECK_MODULES(LIBVIEW, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 122 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
 123 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 124 PKG_CHECK_MODULES(PREVIEWER, gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 125 PKG_CHECK_MODULES(SHELL_CORE, libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED gthread-2.0)
 126
 127 if test "$os_win32" = no; then
 128         PKG_CHECK_MODULES(SMCLIENT, gtk+-2.0 gthread-2.0 sm >= 1.0.0)
 129 else
 130         PKG_CHECK_MODULES(SMCLIENT, gtk+-2.0 gthread-2.0)
 131 fi
 132
 133 AC_SUBST(SMCLIENT_CFLAGS)
 134 AC_SUBST(SMCLIENT_LIBS)
 135
 136 BACKEND_LIBTOOL_FLAGS="-module -avoid-version -no-undefined -export-symbols \$(top_srcdir)/backend/backend.symbols"
 137 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
 138
 139 dnl ===== Check special functions
 140 evince_save_LIBS=$LIBS
 141 LIBS="$LIBS $BACKEND_LIBS"
 142 AC_CHECK_FUNCS(cairo_format_stride_for_width)
 143 LIBS=$evince_save_LIBS
 144
 145 dnl ========= Check for Keyring
 146 AC_ARG_WITH(keyring,
 147         AC_HELP_STRING([--without-keyring],[disable the use of gnome-keyring]),
 148         [case "${withval}" in
 149         yes) WITH_KEYRING=yes ;;
 150         no) WITH_KEYRING=no ;;
 151         *) AC_MSG_ERROR(bad value ${withval} for --with-keyring) ;;
 152         esac],
 153         [WITH_KEYRING=yes]) dnl Default value
 154 AM_CONDITIONAL(WITH_KEYRING, test x$WITH_KEYRING = "xyes")
 155
 156 if test x$WITH_KEYRING = "xyes"; then
 157         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
 158         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
 159 fi
 160
 161 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
 162 AC_SUBST(GLIB_GENMARSHAL)
 163
 164 dnl ========= Check for DBUS
 165 AC_ARG_ENABLE(dbus,
 166         [AC_HELP_STRING([--enable-dbus], [Compile with support for dbus])],
 167         enable_dbus="$enableval",enable_dbus=yes)
 168 if test "x$enable_dbus" != "xno"; then
 169         PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
 170         [enable_dbus=yes],[enable_dbus=no])
 171
 172         if test "x$enable_dbus" = "xno"; then
 173            AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
 174         fi
 175
 176         if test "x$enable_dbus" = "xyes" ; then
 177                 AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 178
 179                 if test x$DBUS_BINDING_TOOL = "xno" ; then
 180                         AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 181                 fi
 182
 183                 AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 184         fi
 185 fi
 186
 187 AC_SUBST([DBUS_CFLAGS])
 188 AC_SUBST([DBUS_LIBS])
 189
 190 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
 191 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
 192
 193 dnl ========= Check for GConf
 194 AC_ARG_WITH(gconf,
 195         AC_HELP_STRING([--without-gconf],[disable the use of gconf]),
 196         [case "${withval}" in
 197         yes) WITH_GCONF=yes ;;
 198         no) WITH_GCONF=no ;;
 199         *) AC_MSG_ERROR(bad value ${withval} for --with-gconf) ;;
 200         esac],
 201         [WITH_GCONF=yes]) dnl Default value
 202 AM_CONDITIONAL(WITH_GCONF, test x$WITH_GCONF = "xyes")
 203
 204 if test x$WITH_GCONF = "xyes"; then
 205    PKG_CHECK_MODULES(GCONF, gconf-2.0)
 206    AC_DEFINE([WITH_GCONF],[1],[Define if GConf support is enabled])
 207 fi
 208
 209 dnl Debug mode
 210 AC_ARG_ENABLE([debug],
 211         AC_HELP_STRING([--enable-debug],
 212                         [Turn on evince debug mode]),,
 213                 [enable_debug=no])
 214
 215 if test "x$enable_debug" = "xyes"; then
 216    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 217 fi
 218
 219
 220 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 221 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 222 AC_SUBST(LIBDOCUMENT_CFLAGS)
 223 AC_SUBST(LIBDOCUMENT_LIBS)
 224
 225 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $DEBUG_FLAGS"
 226 LIBVIEW_LIBS="$LIBVIEW_LIBS"
 227 AC_SUBST(LIBVIEW_CFLAGS)
 228 AC_SUBST(LIBVIEW_LIBS)
 229
 230 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 231 AC_SUBST(BACKEND_CFLAGS)
 232 AC_SUBST(BACKEND_LIBS)
 233
 234 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS $KEYRING_CFLAGS $GCONF_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 235 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS $KEYRING_LIBS $GCONF_LIBS -lz"
 236 AC_SUBST(SHELL_CFLAGS)
 237 AC_SUBST(SHELL_LIBS)
 238
 239 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 240 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 241 AC_SUBST(FRONTEND_CFLAGS)
 242 AC_SUBST(FRONTEND_LIBS)
 243
 244 dnl Check for Nautilus property page build
 245 AC_ARG_ENABLE(nautilus,
 246         AC_HELP_STRING([--enable-nautilus],[compile the nautilus plugin]),
 247         [case "${enableval}" in
 248         yes) ENABLE_NAUTILUS=yes ;;
 249         no) ENABLE_NAUTILUS=no ;;
 250         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nautilus) ;;
 251         esac],
 252         [ENABLE_NAUTILUS=yes]) dnl Default value
 253
 254 if test x$ENABLE_NAUTILUS = "xyes" ; then
 255         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
 256                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
 257         NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 258         AC_SUBST(NAUTILUS_EXTENSION_DIR)
 259 fi
 260
 261 AC_SUBST(NAUTILUS_CFLAGS)
 262 AC_SUBST(NAUTILUS_LIBS)
 263 if test x$HAVE_NAUTILUS = "xyes"; then
 264         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
 265 fi
 266 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
 267
 268
 269 dnl Check for thumbnailer build
 270 AC_ARG_ENABLE(thumbnailer,
 271         AC_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer]),
 272         [case "${enableval}" in
 273         yes) ENABLE_THUMBNAILER=yes ;;
 274         no) ENABLE_THUMBNAILER=no ;;
 275         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thumbnailer) ;;
 276         esac],
 277         [ENABLE_THUMBNAILER=yes]) dnl Default value
 278 AM_CONDITIONAL(ENABLE_THUMBNAILER, test x$ENABLE_THUMBNAILER = "xyes")
 279
 280 dnl Check for previewer build
 281 AC_ARG_ENABLE(previewer,
 282         AC_HELP_STRING([--disable-previewer],[disable the GNOME Document Previewer]),
 283         [case "${enableval}" in
 284         yes) ENABLE_PREVIEWER=yes ;;
 285         no) ENABLE_PREVIEWER=no ;;
 286         *) AC_MSG_ERROR(bad value ${enableval} for --enable-previewer) ;;
 287         esac],
 288         [ENABLE_PREVIEWER=yes]) dnl Default value
 289 if test x$ENABLE_PREVIEWER = "xyes" ; then
 290    PKG_CHECK_MODULES(PREVIEWER, gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED,
 291                      [ENABLE_PREVIEWER=yes],[ENABLE_PREVIEWER=no])
 292    if test x$ENABLE_PREVIEWER = "xno" ; then
 293       AC_MSG_WARN([Previewer support is disabled since gtk+-unix-print $GTK_REQUIRED or higher was not found])
 294    fi
 295 fi
 296 AM_CONDITIONAL(ENABLE_PREVIEWER, test x$ENABLE_PREVIEWER = "xyes")
 297 PREVIEWER_CFLAGS="$PREVIEWER_CFLAGS $DEBUG_FLAGS"
 298 PREVIEWER_LIBS="$PREVIEWER_LIBS -lz"
 299 AC_SUBST(PREVIEWER_CFLAGS)
 300 AC_SUBST(PREVIEWER_LIBS)
 301
 302 dnl GConf configuration
 303 AM_GCONF_SOURCE_2
 304
 305 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
 306 if test "x$GCONFTOOL" = "xno"; then
 307         AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 308 fi
 309
 310 # ***
 311 # GIR
 312 # ***
 313
 314 AC_MSG_CHECKING([whether GObject introspection is requested])
 315 AC_ARG_ENABLE([introspection],
 316         AS_HELP_STRING([--enable-introspection],[Enable GObject introspection]),
 317         [],[enable_introspection=no])
 318 AC_MSG_RESULT([$enable_introspection])
 319
 320 G_IR_SCANNER=
 321 G_IR_COMPILER=
 322 G_IR_GENERATE=
 323 GIRDIR=
 324 GIRTYPELIBDIR=
 325
 326 if test "$enable_introspection" = "yes"; then
 327   GOBJECT_INTROSPECTION_REQUIRED=0.6
 328   PKG_CHECK_MODULES([GOBJECT_INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
 329
 330   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
 331   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
 332   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
 333   GIRDIR="$($PKG_CONFIG --variable=girdir gobject-introspection-1.0)"
 334   GIRTYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
 335 fi
 336
 337 AC_SUBST([G_IR_SCANNER])
 338 AC_SUBST([G_IR_COMPILER])
 339 AC_SUBST([G_IR_GENERATE])
 340 AC_SUBST([GIRDIR])
 341 AC_SUBST([GIRTYPELIBDIR])
 342
 343 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
 344
 345 dnl ================== portability checks ===========================================
 346
 347 dnl for backtrace()
 348 AC_CHECK_HEADERS([execinfo.h])
 349
 350 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 351   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 352   ],[],[#include <langinfo.h>])
 353
 354 dnl ================== pdf checks ===================================================
 355 AC_ARG_ENABLE(pdf,
 356               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 357
 358 if test "x$enable_pdf" = "xyes"; then
 359     POPPLER_REQUIRED=0.8.0
 360     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED,enable_pdf=yes,enable_pdf=no)
 361
 362     if test "x$enable_pdf" = "xyes"; then
 363             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 364             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 365             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 366
 367             evince_save_LIBS=$LIBS
 368             LIBS="$LIBS $POPPLER_LIBS"
 369             AC_CHECK_FUNCS(poppler_page_render)
 370             AC_CHECK_FUNCS(poppler_layers_iter_new)
 371             LIBS=$evince_save_LIBS
 372
 373             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 374             if test x$enable_cairo_pdf = xyes; then
 375                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 376             fi
 377
 378             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 379             if test x$enable_cairo_ps = xyes; then
 380                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 381             fi
 382     else
 383             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 384     fi
 385 fi
 386
 387 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 388 dnl ================== end of pdf checks ============================================
 389
 390 dnl libspectre (used by ps and dvi backends)
 391 SPECTRE_REQUIRED=0.2.0
 392 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 393 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 394 if test "x$have_spectre" = "xyes"; then
 395    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 396 fi
 397
 398 dnl ================== ps checks ====================================================
 399 AC_ARG_ENABLE(ps,
 400         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 401
 402 if test "x$enable_ps" = "xyes"; then
 403    if test "x$have_spectre" = "xyes"; then
 404       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 405    else
 406       enable_ps="no"
 407       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 408    fi
 409 fi
 410 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 411 dnl ======================== End of ps checks ===================================
 412
 413 dnl ================== tiff checks ===================================================
 414 AC_ARG_ENABLE(tiff,
 415             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 416
 417 if test "x$enable_tiff" = "xyes"; then
 418     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 419     if test "x$enable_tiff" = "xyes"; then
 420         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 421         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 422     fi
 423     if test "x$enable_tiff" = "xyes"; then
 424             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 425     else
 426             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 427     fi
 428 fi
 429
 430 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 431 dnl ================== end of tiff checks ============================================
 432
 433 dnl ================== djvu checks ===================================================
 434
 435 AC_ARG_ENABLE(djvu,
 436             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=yes)
 437
 438 if test "x$enable_djvu" = "xyes"; then
 439     DJVULIBRE_REQUIRED=3.5.17
 440     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 441
 442     if test "x$enable_djvu" = "xyes"; then
 443         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 444     else
 445         AC_MSG_WARN([
 446 ** Djvu support is disabled since a recent version of the djvulibre
 447 ** library was not found. You need at least djvulibre-3.5.17 which
 448 ** can be found on http://djvulibre.djvuzone.org
 449 ])
 450     fi
 451 fi
 452
 453 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 454
 455 dnl ================== End of djvu checks ===================================================
 456
 457 dnl ================== dvi checks ===================================================
 458
 459 AC_ARG_ENABLE(dvi,
 460             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=yes)
 461
 462 AC_ARG_ENABLE(t1lib,
 463             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 464
 465 if test "x$enable_dvi" = "xyes"; then
 466     AC_C_CONST
 467     AC_C_INLINE
 468     AC_TYPE_SIZE_T
 469     AC_CHECK_SIZEOF(long, 4)
 470     AC_CHECK_SIZEOF(int, 4)
 471     AC_CHECK_SIZEOF(short, 2)
 472     AC_CHECK_SIZEOF(void *, 4)
 473     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 474
 475     if test "x$enable_dvi" = "xyes"; then
 476         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 477     else
 478         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 479     fi
 480 fi
 481 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 482
 483 if test "x$enable_dvi" = "xyes"; then
 484     if test "x$enable_type1_fonts" = "xyes"; then
 485         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 486     fi
 487
 488     if test "x$enable_type1_fonts" = xyes; then
 489         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 490     fi
 491 else
 492     enable_type1_fonts=no
 493 fi
 494 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 495
 496 dnl ================== End of dvi checks ===================================================
 497
 498 dnl ================== pixbuf checks ===================================================
 499
 500 AC_ARG_ENABLE(pixbuf,
 501             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 502 if test "x$enable_pixbuf" = "xyes"; then
 503         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 504 fi
 505 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 506
 507 dnl ================== End of pixbuf checks ===================================================
 508
 509 dnl ================== comic book checks ===================================================
 510
 511 AC_ARG_ENABLE(comics,
 512         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=yes)
 513 if test "x$enable_comics" = "xyes"; then
 514         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 515 fi
 516 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 517
 518 dnl ================== End of comic book checks ============================================
 519
 520 dnl ================== impress book checks ===================================================
 521
 522 AC_ARG_ENABLE(impress,
 523         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 524 if test "x$enable_impress" = "xyes"; then
 525         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 526 fi
 527 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 528
 529 dnl ================== End of impress book checks ============================================
 530
 531 dnl =================== Mime types list ====================================================
 532
 533 if test "x$enable_pdf" = "xyes" ; then
 534         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 535 fi
 536 if test "x$enable_ps" = "xyes" ; then
 537         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 538 fi
 539 if test "x$enable_dvi" = "xyes"; then
 540         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 541 fi
 542 if test "x$enable_djvu" = "xyes"; then
 543         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 544 fi
 545 if test "x$enable_tiff" = "xyes"; then
 546         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 547 fi
 548 if test "x$enable_comics" = "xyes"; then
 549         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;"
 550 fi
 551 if test "x$enable_pixbuf" = "xyes"; then
 552         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 553 fi
 554 if test "x$enable_impress" = "xyes"; then
 555         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 556 fi
 557 AC_SUBST(EVINCE_MIME_TYPES)
 558
 559 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 560
 561 # Backends directory
 562
 563 AC_SUBST([backenddir],"\$(libdir)/evince/ev_binary_version/backends")
 564
 565 # Versioning
 566
 567 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
 568 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
 569 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
 570
 571 AC_SUBST([EV_API_VERSION],[ev_api_version])
 572 AC_SUBST([EV_BINARY_VERSION],[ev_binary_version])
 573
 574 AC_SUBST([EV_DOCUMENT_LT_VERSION_INFO],[ev_document_lt_version_info])
 575 AC_SUBST([EV_DOCUMENT_LT_CURRENT_MINUS_AGE],[ev_document_lt_current_minus_age])
 576 AC_SUBST([EV_VIEW_LT_VERSION_INFO],[ev_view_lt_version_info])
 577 AC_SUBST([EV_VIEW_LT_CURRENT_MINUS_AGE],[ev_view_lt_current_minus_age])
 578
 579 # *****************************************************************************
 580
 581 AC_CONFIG_FILES([
 582 backend/Makefile
 583 backend/comics/Makefile
 584 backend/djvu/Makefile
 585 backend/dvi/Makefile
 586 backend/dvi/mdvi-lib/Makefile
 587 backend/impress/Makefile
 588 backend/pdf/Makefile
 589 backend/pixbuf/Makefile
 590 backend/ps/Makefile
 591 backend/tiff/Makefile
 592 cut-n-paste/Makefile
 593 cut-n-paste/gedit-message-area/Makefile
 594 cut-n-paste/gimpcellrenderertoggle/Makefile
 595 cut-n-paste/smclient/Makefile
 596 cut-n-paste/toolbar-editor/Makefile
 597 cut-n-paste/zoom-control/Makefile
 598 cut-n-paste/totem-screensaver/Makefile
 599 data/evince.desktop.in
 600 data/Makefile
 601 data/icons/Makefile
 602 data/icons/16x16/Makefile
 603 data/icons/16x16/apps/Makefile
 604 data/icons/16x16/actions/Makefile
 605 data/icons/22x22/Makefile
 606 data/icons/22x22/apps/Makefile
 607 data/icons/22x22/actions/Makefile
 608 data/icons/24x24/Makefile
 609 data/icons/24x24/apps/Makefile
 610 data/icons/24x24/actions/Makefile
 611 data/icons/32x32/Makefile
 612 data/icons/32x32/actions/Makefile
 613 data/icons/48x48/Makefile
 614 data/icons/48x48/apps/Makefile
 615 data/icons/48x48/actions/Makefile
 616 data/icons/scalable/Makefile
 617 data/icons/scalable/apps/Makefile
 618 help/Makefile
 619 help/reference/Makefile
 620 help/reference/libdocument/Makefile
 621 help/reference/libdocument/version.xml
 622 help/reference/libview/Makefile
 623 help/reference/libview/version.xml
 624 help/reference/shell/Makefile
 625 help/reference/shell/version.xml
 626 libdocument/Makefile
 627 libdocument/ev-version.h
 628 libmisc/Makefile
 629 libview/Makefile
 630 Makefile
 631 po/Makefile.in
 632 previewer/Makefile
 633 properties/Makefile
 634 shell/Makefile
 635 test/Makefile
 636 thumbnailer/Makefile
 637 ])
 638
 639 AC_CONFIG_FILES(evince-document-[]ev_api_version[].pc:evince-document.pc.in)
 640 AC_CONFIG_FILES(evince-view-[]ev_api_version[].pc:evince-view.pc.in)
 641
 642 AC_OUTPUT
 643
 644 echo "
 645 Configure summary:
 646         GConf Support......:  $WITH_GCONF
 647         Keyring Support....:  $WITH_KEYRING
 648         DBUS Support.......:  $enable_dbus
 649         Nautilus Plugin....:  $HAVE_NAUTILUS
 650         Thumbnailer........:  $ENABLE_THUMBNAILER
 651         Previewer..........:  $ENABLE_PREVIEWER
 652         Gtk-Doc Support....:  $enable_gtk_doc
 653         Debug mode.........:  $enable_debug
 654         GObj. Introspection:  $enable_introspection
 655
 656         PDF Backend........:  $enable_pdf
 657         PostScript Backend.:  $enable_ps
 658         TIFF Backend.......:  $enable_tiff
 659         DJVU Backend.......:  $enable_djvu
 660         DVI Backend........:  $enable_dvi
 661         Pixbuf Backend.....:  $enable_pixbuf
 662         Comics Backend.....:  $enable_comics
 663         Impress Backend....:  $enable_impress
 664 "