configure.ac

   1 # *****************************************************************************
   2 # Versioning
   3 # *****************************************************************************
   4
   5 m4_define([ev_major_version],[2])
   6 m4_define([ev_minor_version],[91])
   7 m4_define([ev_micro_version],[5])
   8 m4_define([ev_extra_version],[])
   9 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version()ev_extra_version])
  10
  11 # The evince API version
  12 m4_define([ev_api_version], [3.0])
  13
  14 # Libtool versioning. The backend and view libraries have separate versions.
  15 # Before making a release, the libtool version should be modified.
  16 # The string is of the form C:R:A.
  17 # - If interfaces have been changed or added, but binary compatibility has
  18 #   been preserved, change to C+1:0:A+1
  19 # - If binary compatibility has been broken (eg removed or changed interfaces)
  20 #   change to C+1:0:0
  21 # - If the interface is the same as the previous version, change to C:R+1:A
  22
  23 # Libtool version of the backend library
  24 m4_define([ev_document_lt_current],[3])
  25 m4_define([ev_document_lt_revision],[0])
  26 m4_define([ev_document_lt_age],[0])
  27 m4_define([ev_document_lt_version_info],[ev_document_lt_current:ev_document_lt_revision:ev_document_lt_age])
  28 m4_define([ev_document_lt_current_minus_age],[m4_eval(ev_document_lt_current - ev_document_lt_age)])
  29
  30 # Libtool version of the view library
  31 m4_define([ev_view_lt_current],[3])
  32 m4_define([ev_view_lt_revision],[0])
  33 m4_define([ev_view_lt_age],[0])
  34 m4_define([ev_view_lt_version_info],[ev_view_lt_current:ev_view_lt_revision:ev_view_lt_age])
  35 m4_define([ev_view_lt_current_minus_age],[m4_eval(ev_view_lt_current - ev_view_lt_age)])
  36
  37 # Binary version for the document backends
  38 m4_define([ev_binary_version],[ev_document_lt_current])
  39
  40 # *****************************************************************************
  41
  42 AC_PREREQ([2.57])
  43 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
  44 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2 no-dist-gzip])
  45
  46 AC_CONFIG_HEADERS([config.h])
  47 AC_CONFIG_MACRO_DIR([m4])
  48
  49 if test -z "$enable_maintainer_mode"; then
  50   enable_maintainer_mode=yes
  51 fi
  52 AM_MAINTAINER_MODE([enable])
  53
  54 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  55
  56 AM_PROG_LIBTOOL
  57
  58 AC_ISC_POSIX
  59 AC_PROG_CC
  60 AM_PROG_CC_STDC
  61 AM_PROG_CC_C_O
  62 AC_PROG_CXX
  63 AC_STDC_HEADERS
  64
  65 AC_PROG_SED
  66 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  67 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  68
  69 GNOME_MAINTAINER_MODE_DEFINES
  70 GNOME_COMPILE_WARNINGS
  71 GNOME_CXX_WARNINGS
  72
  73 dnl FIXME: remove this when required gtk+ >= 2.19.7
  74 DISABLE_DEPRECATED=
  75 AC_SUBST([DISABLE_DEPRECATED])
  76
  77 IT_PROG_INTLTOOL([0.35.0])
  78
  79 GETTEXT_PACKAGE=evince
  80 AC_SUBST(GETTEXT_PACKAGE)
  81 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  82 AM_GLIB_GNU_GETTEXT
  83
  84 m4_pattern_allow([AM_V_GEN])dnl Make autoconf not complain about the rule below
  85 EV_INTLTOOL_EVINCE_BACKEND_RULE='%.evince-backend:   %.evince-backend.in   $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; $(AM_V_GEN) LC_ALL=C $(INTLTOOL_MERGE) -d -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@'
  86 AC_SUBST([EV_INTLTOOL_EVINCE_BACKEND_RULE])
  87
  88 GLIB_GSETTINGS
  89
  90 # Check which platform to use
  91
  92 AC_MSG_CHECKING([for which platform to build])
  93 AC_ARG_WITH([platform],
  94   [AS_HELP_STRING([--with-platform=gnome|win32|hildon],
  95                   [Setting platform (default: gnome)])],
  96   [case "$withval" in
  97     gnome|win32|hildon) ;;
  98     *) AC_MSG_ERROR([invalid argument "$withval" for --with-platform]) ;;
  99    esac],
 100   [case "$host" in
 101      *-*-mingw*|*-*-cygwin*) with_platform="win32" ;;
 102      *) with_platform=gnome ;;
 103    esac])
 104
 105 AC_MSG_RESULT([$with_platform])
 106
 107 if test "$with_platform" = "win32"; then
 108   AC_CHECK_TOOL([WINDRES],[windres])
 109   AC_MSG_CHECKING([for native Win32])
 110   case "$host" in
 111     *-*-mingw*)
 112       os_win32=yes
 113       ;;
 114     *)
 115       os_win32=no
 116       ;;
 117   esac
 118   AC_MSG_RESULT([$os_win32])
 119 fi
 120
 121 AM_CONDITIONAL([PLATFORM_HILDON],[test "$with_platform" = "hildon"])
 122 AM_CONDITIONAL([PLATFORM_WIN32],[test "$with_platform" = "win32"])
 123
 124 dnl Specify required versions of dependencies
 125 CAIRO_REQUIRED=1.10.0
 126 GLIB_REQUIRED=2.25.11
 127 KEYRING_REQUIRED=2.22.0
 128 GTK_REQUIRED=2.91.7
 129
 130 AC_SUBST([GLIB_REQUIRED])
 131 AC_SUBST([GTK_REQUIRED])
 132
 133 GNOME_ICON_THEME_REQUIRED=2.17.1
 134 LIBXML_REQUIRED=2.5.0
 135
 136 dnl Check dependencies
 137
 138 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
 139 # BACKEND_CFLAGS   for backend implementations.
 140 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
 141 # FRONTEND_LIBS
 142 # SHELL_CFLAGS     for shell implementation.
 143 # SHELL_LIBS
 144
 145
 146 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-3.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
 147 PKG_CHECK_MODULES(LIBVIEW, gtk+-3.0 >= $GTK_REQUIRED gail-3.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 148 PKG_CHECK_MODULES(BACKEND, cairo >= $CAIRO_REQUIRED gtk+-3.0 >= $GTK_REQUIRED)
 149 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-3.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 150
 151 SHELL_PLATFORM_PKGS=
 152 case "$with_platform" in
 153   hildon) AC_DEFINE([PLATFORM_HILDON],[1],[Define if building for the hildon platform])
 154           SHELL_PLATFORM_PKGS="hildon-1 hildon-fm-2 libosso"
 155           ;;
 156   gnome)
 157         # Evince has a rather soft run-time dependency on hicolor-icon-theme.
 158         # If the hicolor theme is not available, Evince fails to display some
 159         # icons. Because we cannot check for it at run-time, we instead
 160         # would like to require the icon theme at compile-time. But, because
 161         # the hicolor-icon-theme does not have a pkgconfig file, on gnome we
 162         # require the gnome icon theme instead.
 163         SHELL_PLATFORM_PKGS="gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED"
 164         # The totem-screensaver and egg_smclient code use x11 directly.
 165         SHELL_PLATFORM_PKGS="$SHELL_PLATFORM_PKGS x11"
 166         ;;
 167   *)
 168         # On all other platforms we issue a warning about the runtime
 169         # dependency.
 170         AC_MSG_WARN([Evince has a soft run-time dependency on hicolor-icon-theme. You are advised to have this theme installed when running Evince.]);
 171         SHELL_PLATFORM_PKGS=""
 172         ;;
 173 esac
 174
 175 PKG_CHECK_MODULES([SHELL_CORE],[libxml-2.0 >= $LIBXML_REQUIRED gtk+-3.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gthread-2.0 $SHELL_PLATFORM_PKGS])
 176
 177 # *********
 178 # SM client
 179 # *********
 180
 181 GDK_TARGET="$($PKG_CONFIG --variable target gdk-3.0)"
 182
 183 AC_MSG_CHECKING([which smclient backend to use])
 184 AC_ARG_WITH([smclient],
 185   [AS_HELP_STRING([--with-smclient-backend=no|xsmp|win32|quartz],
 186                   [Setting smclient backend (default:auto)])],
 187   [],
 188   [case "$GDK_TARGET" in
 189     x11) case "$with_platform" in
 190            gnome) with_smclient=xsmp ;;
 191            *) with_smclient=no ;;
 192          esac ;;
 193     win32|quartz) with_smclient=$GDK_TARGET ;;
 194     *) with_smclient=no ;;
 195    esac])
 196
 197 AC_MSG_RESULT([$with_smclient])
 198
 199 if test "$with_smclient" != "no"; then
 200   AC_DEFINE([WITH_SMCLIENT],[1],[Define if smclient is enabled])
 201
 202   case "$with_smclient" in
 203     xsmp) SMCLIENT_PKGS="sm >= 1.0.0" ;;
 204     *) SMCLIENT_PKGS="" ;;
 205   esac
 206
 207   PKG_CHECK_MODULES([SMCLIENT],[gtk+-3.0 gthread-2.0 $SMCLIENT_PKGS])
 208   AC_SUBST([SMCLIENT_CFLAGS])
 209   AC_SUBST([SMCLIENT_LIBS])
 210 fi
 211
 212 AM_CONDITIONAL([WITH_SMCLIENT],[test "$with_smclient" != "no"])
 213 AM_CONDITIONAL([WITH_SMCLIENT_XSMP],[test "$with_smclient" = "xsmp"])
 214 AM_CONDITIONAL([WITH_SMCLIENT_WIN32],[test "$with_smclient" = "win32"])
 215 AM_CONDITIONAL([WITH_SMCLIENT_QUARTZ],[test "$with_smclient" = "quartz"])
 216
 217 # ***
 218
 219 BACKEND_LIBTOOL_FLAGS="-module -avoid-version -no-undefined -export-symbols \$(top_srcdir)/backend/backend.symbols"
 220 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
 221
 222 dnl ===== Check special functions
 223 evince_save_LIBS=$LIBS
 224 LIBS="$LIBS $BACKEND_LIBS"
 225 AC_CHECK_FUNCS(cairo_format_stride_for_width)
 226 LIBS=$evince_save_LIBS
 227
 228 # ******************
 229 # GKT+ Unix Printing
 230 # ******************
 231
 232 AC_MSG_CHECKING([whether gtk+-unix-print support is requested])
 233 AC_ARG_WITH([gtk-unix-print],
 234   [AS_HELP_STRING([--without-gtk-unix-print],
 235                   [Disable the use of gtk-unix-print])],
 236   [],[case "$os_win32" in
 237         yes) with_gtk_unix_print=no ;;
 238         *) with_gtk_unix_print=yes ;;
 239       esac])
 240
 241 AC_MSG_RESULT([$with_gtk_unix_print])
 242
 243 if test "$with_gtk_unix_print" = "yes"; then
 244    PKG_CHECK_MODULES(GTKUNIXPRINT, [gtk+-unix-print-3.0 >= $GTK_REQUIRED])
 245    AC_DEFINE([GTKUNIXPRINT_ENABLED], [1], [Define if gtk+-unix-print is enabled.])
 246 fi
 247
 248 # *********************
 249 # GNOME Keyring support
 250 # *********************
 251
 252 AC_ARG_WITH(keyring,
 253         [AS_HELP_STRING([--without-keyring],
 254                         [Disable the use of gnome-keyring])],
 255         [],
 256         [case "$with_platform" in
 257            gnome) with_keyring=yes ;;
 258            hildon|win32) with_keyring=no ;;
 259          esac])
 260
 261 AM_CONDITIONAL([WITH_KEYRING],[test "$with_keyring" = "yes"])
 262
 263 if test "$with_keyring" = "yes"; then
 264         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
 265         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
 266 fi
 267
 268 # ****
 269 # DBUS
 270 # ****
 271
 272 AC_ARG_ENABLE([dbus],
 273   [AS_HELP_STRING([--disable-dbus], [Disable support for dbus])],
 274   [],
 275   [case "$with_platform" in
 276       gnome) enable_dbus=yes ;;
 277       hildon) enable_dbus=no ;;
 278     esac])
 279
 280 if test "$enable_dbus" = "yes"; then
 281   AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 282
 283    PKG_CHECK_MODULES([EV_DAEMON], [gio-2.0 >= $GLIB_REQUIRED])
 284 fi
 285
 286 AM_CONDITIONAL([ENABLE_DBUS], [test "$enable_dbus" = "yes"])
 287
 288 dnl ========= Check for Desktop Schemas
 289 PKG_CHECK_MODULES([DESKTOP_SCHEMAS], [gsettings-desktop-schemas],
 290                   has_desktop_schemas=yes, has_desktop_schemas=no)
 291 if test x$has_desktop_schemas = xyes; then
 292    AC_DEFINE([HAVE_DESKTOP_SCHEMAS], [1], [Whether GSettings Desktop Schemas are available])
 293 fi
 294
 295 dnl Debug mode
 296
 297 AC_ARG_ENABLE([debug],
 298         AS_HELP_STRING([--enable-debug],
 299                        [Turn on evince debug mode]),
 300         [enable_debug=$enableval],
 301         [enable_debug=no])
 302
 303 if test "x$enable_debug" = "xyes"; then
 304    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 305 fi
 306
 307 AC_ARG_ENABLE([tests],
 308         AS_HELP_STRING([--enable-tests], [Enable the tests]),
 309         [enable_tests=$enableval],
 310         [enable_tests=yes])
 311
 312 AM_CONDITIONAL(ENABLE_TESTS, test x$enable_tests = xyes)
 313
 314 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 315 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 316 AC_SUBST(LIBDOCUMENT_CFLAGS)
 317 AC_SUBST(LIBDOCUMENT_LIBS)
 318
 319 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 320 LIBVIEW_LIBS="$LIBVIEW_LIBS $GTKUNIXPRINT_LIBS -lm"
 321 AC_SUBST(LIBVIEW_CFLAGS)
 322 AC_SUBST(LIBVIEW_LIBS)
 323
 324 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 325 BACKEND_LIBS="$BACKEND_LIBS -lm"
 326 AC_SUBST(BACKEND_CFLAGS)
 327 AC_SUBST(BACKEND_LIBS)
 328
 329 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $KEYRING_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 330 SHELL_LIBS="$SHELL_CORE_LIBS $KEYRING_LIBS -lz -lm"
 331 AC_SUBST(SHELL_CFLAGS)
 332 AC_SUBST(SHELL_LIBS)
 333
 334 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 335 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 336 AC_SUBST(FRONTEND_CFLAGS)
 337 AC_SUBST(FRONTEND_LIBS)
 338
 339 EV_DAEMON_CFLAGS="$EV_DAEMON_CFLAGS $DEBUG_FLAGS"
 340 AC_SUBST([EV_DAEMON_CFLAGS])
 341 AC_SUBST([EV_DAEMON_LIBS])
 342
 343 # Check for Nautilus property page build
 344 AC_ARG_ENABLE([nautilus],
 345   [AS_HELP_STRING([--disable-nautilus],
 346                   [Disable build of nautilus extensions])],
 347   [],
 348   [case "$with_platform" in
 349      gnome) enable_nautilus=yes ;;
 350      *) enable_nautilus=no ;;
 351     esac])
 352
 353 if test "$enable_nautilus" = "yes" ; then
 354   PKG_CHECK_MODULES([NAUTILUS],[gtk+-x11-3.0 $MM gthread-2.0 libnautilus-extension],
 355                     [],[AC_MSG_ERROR([libnautilus-extension not found; use --disable-nautilus to disable the nautilus extensions])])
 356   NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 357   AC_SUBST([nautilusextensiondir],[$NAUTILUS_EXTENSION_DIR])
 358   AC_SUBST(NAUTILUS_CFLAGS)
 359   AC_SUBST(NAUTILUS_LIBS)
 360
 361   AC_DEFINE([HAVE_NAUTILUS],[1], [defined if you build the nautilus plugin])
 362 fi
 363
 364 AM_CONDITIONAL([ENABLE_NAUTILUS],[test "$enable_nautilus" = "yes"])
 365
 366 # Check for thumbnailer build
 367
 368 AC_ARG_ENABLE([thumbnailer],
 369   [AS_HELP_STRING([--disable-thumbnailer],
 370                   [Disable GNOME thumbnailer])],
 371   [],
 372   [case "$with_platform" in
 373      hildon) enable_thumbnailer=no ;;
 374      *) enable_thumbnailer=yes ;;
 375     esac])
 376
 377 AM_CONDITIONAL([ENABLE_THUMBNAILER],[test "$enable_thumbnailer" = "yes"])
 378
 379 # ***************
 380 # Print Previewer
 381 # ***************
 382
 383 AC_ARG_ENABLE([previewer],
 384   [AS_HELP_STRING([--disable-previewer],
 385                   [Disable the GNOME Document Previewer])],
 386   [],
 387   [case "$with_platform" in
 388       hildon) enable_previewer=no ;;
 389       *) enable_previewer=yes ;;
 390     esac])
 391
 392 if test x$enable_previewer = "xyes" ; then
 393   PKG_CHECK_MODULES([PREVIEWER],[gtk+-3.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED])
 394 fi
 395
 396 AM_CONDITIONAL([ENABLE_PREVIEWER],[test "$enable_previewer" = "yes"])
 397 PREVIEWER_CFLAGS="$PREVIEWER_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 398 PREVIEWER_LIBS="$PREVIEWER_LIBS $GTKUNIXPRINT_LIBS -lz"
 399 AC_SUBST(PREVIEWER_CFLAGS)
 400 AC_SUBST(PREVIEWER_LIBS)
 401
 402 # ***
 403 # GIR
 404 # ***
 405
 406 AC_MSG_CHECKING([whether GObject introspection is requested])
 407 AC_ARG_ENABLE([introspection],
 408         AS_HELP_STRING([--enable-introspection],
 409                        [Enable GObject introspection]),
 410         [enable_introspection=$enableval],
 411         [enable_introspection=no])
 412 AC_MSG_RESULT([$enable_introspection])
 413
 414 G_IR_SCANNER=
 415 G_IR_COMPILER=
 416 G_IR_GENERATE=
 417 GIRDIR=
 418 GIRTYPELIBDIR=
 419
 420 if test "$enable_introspection" = "yes"; then
 421   GOBJECT_INTROSPECTION_REQUIRED=0.6
 422   PKG_CHECK_MODULES([GOBJECT_INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
 423
 424   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
 425   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
 426   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
 427   GIRDIR="$($PKG_CONFIG --variable=girdir gobject-introspection-1.0)"
 428   GIRTYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
 429 fi
 430
 431 AC_SUBST([G_IR_SCANNER])
 432 AC_SUBST([G_IR_COMPILER])
 433 AC_SUBST([G_IR_GENERATE])
 434 AC_SUBST([GIRDIR])
 435 AC_SUBST([GIRTYPELIBDIR])
 436
 437 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
 438
 439 dnl ================== portability checks ===========================================
 440
 441 dnl for backtrace()
 442 AC_CHECK_HEADERS([execinfo.h])
 443
 444 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 445   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 446   ],[],[#include <langinfo.h>])
 447
 448 dnl ================== pdf checks ===================================================
 449 AC_ARG_ENABLE([pdf],
 450   [AS_HELP_STRING([--disable-pdf],
 451                   [Disable the PDF support])],
 452   [enable_pdf=$enableval],
 453   [enable_pdf=yes])
 454
 455 if test "x$enable_pdf" = "xyes"; then
 456     POPPLER_REQUIRED=0.16.0
 457     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED,enable_pdf=yes,enable_pdf=no)
 458
 459     if test "x$enable_pdf" = "xyes"; then
 460             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 461             if test x$enable_cairo_pdf = xyes; then
 462                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 463             fi
 464
 465             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 466             if test x$enable_cairo_ps = xyes; then
 467                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 468             fi
 469     else
 470             AC_MSG_ERROR("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 471     fi
 472 fi
 473
 474 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 475 dnl ================== end of pdf checks ============================================
 476
 477 dnl libspectre (used by ps and dvi backends)
 478 SPECTRE_REQUIRED=0.2.0
 479 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 480 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 481 if test "x$have_spectre" = "xyes"; then
 482    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 483 fi
 484
 485 dnl ================== ps checks ====================================================
 486 AC_ARG_ENABLE(ps,
 487         [AS_HELP_STRING([--disable-ps],
 488                         [Disable the PostScript backend])],
 489         [enable_ps=$enableval],
 490         [enable_ps=yes])
 491
 492 if test "x$enable_ps" = "xyes"; then
 493    if test "x$have_spectre" = "xyes"; then
 494       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 495    else
 496       enable_ps="no"
 497       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 498    fi
 499 fi
 500 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 501 dnl ======================== End of ps checks ===================================
 502
 503 dnl ================== tiff checks ===================================================
 504 AC_ARG_ENABLE(tiff,
 505             [AS_HELP_STRING([--disable-tiff],
 506                             [Disable the support of multipage tiff])],
 507             [enable_tiff=$enableval],
 508             [enable_tiff=yes])
 509
 510 if test "x$enable_tiff" = "xyes"; then
 511     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 512     if test "x$enable_tiff" = "xyes"; then
 513         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 514         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 515     fi
 516     if test "x$enable_tiff" = "xyes"; then
 517             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 518     else
 519             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 520     fi
 521 fi
 522
 523 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 524 dnl ================== end of tiff checks ============================================
 525
 526 dnl ================== djvu checks ===================================================
 527
 528 AC_ARG_ENABLE(djvu,
 529             [AS_HELP_STRING([--disable-djvu],
 530                             [Disable the support of djvu viewer])],
 531             [enable_djvu=$enableval],
 532             [enable_djvu=yes])
 533
 534 if test "x$enable_djvu" = "xyes"; then
 535     DJVULIBRE_REQUIRED=3.5.17
 536     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 537
 538     if test "x$enable_djvu" = "xyes"; then
 539         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 540     else
 541         AC_MSG_WARN([
 542 ** Djvu support is disabled since a recent version of the djvulibre
 543 ** library was not found. You need at least djvulibre-3.5.17 which
 544 ** can be found on http://djvulibre.djvuzone.org
 545 ])
 546     fi
 547 fi
 548
 549 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 550
 551 dnl ================== End of djvu checks ===================================================
 552
 553 dnl ================== dvi checks ===================================================
 554
 555 AC_ARG_ENABLE(dvi,
 556             [AS_HELP_STRING([--disable-dvi],
 557             [Disable the support of dvi viewer])],
 558             [enable_dvi=$enableval],
 559             [enable_dvi=yes])
 560
 561 AC_ARG_ENABLE(t1lib,
 562             [AS_HELP_STRING([--enable-t1lib],
 563                             [Compile with support of t1lib for type1 fonts in dvi])],
 564             [enable_type1_fonts=$enableval],
 565             [enable_type1_fonts=no])
 566
 567 if test "x$enable_dvi" = "xyes"; then
 568     AC_C_CONST
 569     AC_C_INLINE
 570     AC_TYPE_SIZE_T
 571     AC_CHECK_SIZEOF(long, 4)
 572     AC_CHECK_SIZEOF(int, 4)
 573     AC_CHECK_SIZEOF(short, 2)
 574     AC_CHECK_SIZEOF(void *, 4)
 575     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 576
 577     if test "x$enable_dvi" = "xyes"; then
 578         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 579     else
 580         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 581     fi
 582 fi
 583 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 584
 585 if test "x$enable_dvi" = "xyes"; then
 586     if test "x$enable_type1_fonts" = "xyes"; then
 587         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 588     fi
 589
 590     if test "x$enable_type1_fonts" = xyes; then
 591         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 592     fi
 593 else
 594     enable_type1_fonts=no
 595 fi
 596 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 597
 598 dnl ================== End of dvi checks ===================================================
 599
 600 dnl ================== comic book checks ===================================================
 601
 602 AC_ARG_ENABLE(comics,
 603         [AS_HELP_STRING([--enable-comics],
 604                         [Compile with support for comic book archives])],
 605         [enable_comics=$enableval],
 606         [enable_comics=yes])
 607
 608 if test "x$enable_comics" = "xyes"; then
 609         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 610 fi
 611 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 612
 613 dnl ================== End of comic book checks ============================================
 614
 615 dnl ================== XPS checks ===================================================
 616
 617 AC_ARG_ENABLE(xps,
 618         [AS_HELP_STRING([--enable-xps],
 619                         [Compile with support for XPS documents.])],
 620         [enable_xps=$enableval],
 621         [enable_xps=yes])
 622
 623 if test "x$enable_xps" = "xyes"; then
 624    GXPS_REQUIRED=0.0.1
 625    PKG_CHECK_MODULES(GXPS, libgxps >= $GXPS_REQUIRED,enable_xps=yes,enable_xps=no)
 626
 627    if test "x$enable_xps" = "xyes"; then
 628       AC_DEFINE([ENABLE_XPS], [1], [Enable support for XPS documents.])
 629    else
 630       enable_xps="no"
 631       AC_MSG_WARN(["XPS support is disabled since libgxps (version >= $GXPS_REQUIRED) is needed])
 632    fi
 633 fi
 634
 635 AM_CONDITIONAL(ENABLE_XPS, test x$enable_xps = xyes)
 636
 637 dnl ================== End of XPS checks ===================================================
 638
 639 dnl =================== Mime types list ====================================================
 640
 641 if test "x$enable_pdf" = "xyes" ; then
 642         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;application/x-xzpdf;"
 643 fi
 644 if test "x$enable_ps" = "xyes" ; then
 645         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 646 fi
 647 if test "x$enable_dvi" = "xyes"; then
 648         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 649 fi
 650 if test "x$enable_djvu" = "xyes"; then
 651         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 652 fi
 653 if test "x$enable_tiff" = "xyes"; then
 654         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 655 fi
 656 if test "x$enable_comics" = "xyes"; then
 657         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;application/x-cbt;"
 658 fi
 659 if test "x$enable_xps" = "xyes"; then
 660         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/oxps;application/vnd.ms-xpsdocument;"
 661 fi
 662 AC_SUBST(EVINCE_MIME_TYPES)
 663
 664 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 665
 666 # *****************
 667 # Help files
 668 # *****************
 669
 670 GNOME_DOC_INIT([], gnome_doc_utils=yes, gnome_doc_utils=no)
 671
 672 AC_ARG_ENABLE(help,
 673     [AS_HELP_STRING([--disable-help], [Disable offline help files])],
 674     [enable_help=$enableval],
 675     [enable_help=yes])
 676
 677 if test "x$enable_help" = "xyes" && test "x$os_win32" = "xyes" ; then
 678     AC_MSG_WARN([Offline help is disabled (not implemented on Windows).])
 679     enable_help=no
 680 fi
 681
 682 if test "x$enable_help" = "xyes" && test "x$gnome_doc_utils" == "xno"; then
 683     AC_MSG_ERROR(
 684        [gnome-doc-utils not found; use --disable-help to disable help files]
 685     )
 686 fi
 687
 688 if test "x$enable_help" = "xyes"; then
 689     AC_DEFINE([OFFLINE_HELP_ENABLED], [1], [Enable offline help])
 690 fi
 691
 692 AM_CONDITIONAL(ENABLE_HELP, test "x$enable_help" = "xyes")
 693
 694 # *****************
 695 # API documentation
 696 # *****************
 697
 698 GTK_DOC_CHECK([1.13],[--flavour no-tmpl])
 699
 700 AC_SUBST([GLIB_PREFIX],[$($PKG_CONFIG --variable=prefix glib-2.0)])
 701 AC_SUBST([GTK_PREFIX],[$($PKG_CONFIG --variable=prefix gtk+-3.0)])
 702
 703 # ******************
 704 # Backends directory
 705 # ******************
 706
 707 AC_SUBST([backenddir],"\$(libdir)/evince/ev_binary_version/backends")
 708 AC_SUBST([backend_binary_version],"ev_binary_version")
 709
 710 # **********
 711 # Versioning
 712 # **********
 713
 714 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
 715 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
 716 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
 717
 718 AC_SUBST([EV_API_VERSION],[ev_api_version])
 719 AC_SUBST([EV_API_VERSION_U],[AS_TR_SH([ev_api_version])])
 720 AC_SUBST([EV_BINARY_VERSION],[ev_binary_version])
 721
 722 AC_SUBST([EV_DOCUMENT_LT_VERSION_INFO],[ev_document_lt_version_info])
 723 AC_SUBST([EV_DOCUMENT_LT_CURRENT_MINUS_AGE],[ev_document_lt_current_minus_age])
 724 AC_SUBST([EV_VIEW_LT_VERSION_INFO],[ev_view_lt_version_info])
 725 AC_SUBST([EV_VIEW_LT_CURRENT_MINUS_AGE],[ev_view_lt_current_minus_age])
 726
 727 # *****************************************************************************
 728 # *****************************************************************************
 729
 730 AC_CONFIG_FILES([
 731 backend/Makefile
 732 backend/comics/Makefile
 733 backend/djvu/Makefile
 734 backend/dvi/Makefile
 735 backend/dvi/mdvi-lib/Makefile
 736 backend/pdf/Makefile
 737 backend/ps/Makefile
 738 backend/tiff/Makefile
 739 backend/xps/Makefile
 740 cut-n-paste/Makefile
 741 cut-n-paste/gimpcellrenderertoggle/Makefile
 742 cut-n-paste/smclient/Makefile
 743 cut-n-paste/toolbar-editor/Makefile
 744 cut-n-paste/zoom-control/Makefile
 745 cut-n-paste/totem-screensaver/Makefile
 746 cut-n-paste/synctex/Makefile
 747 data/evince.desktop.in
 748 data/Makefile
 749 data/icons/Makefile
 750 data/icons/16x16/Makefile
 751 data/icons/16x16/apps/Makefile
 752 data/icons/16x16/actions/Makefile
 753 data/icons/16x16/mimetypes/Makefile
 754 data/icons/22x22/Makefile
 755 data/icons/22x22/apps/Makefile
 756 data/icons/22x22/actions/Makefile
 757 data/icons/22x22/mimetypes/Makefile
 758 data/icons/24x24/Makefile
 759 data/icons/24x24/apps/Makefile
 760 data/icons/24x24/actions/Makefile
 761 data/icons/24x24/mimetypes/Makefile
 762 data/icons/32x32/Makefile
 763 data/icons/32x32/actions/Makefile
 764 data/icons/32x32/mimetypes/Makefile
 765 data/icons/48x48/Makefile
 766 data/icons/48x48/apps/Makefile
 767 data/icons/48x48/actions/Makefile
 768 data/icons/scalable/Makefile
 769 data/icons/scalable/apps/Makefile
 770 data/icons/scalable/actions/Makefile
 771 data/icons/scalable/mimetypes/Makefile
 772 help/Makefile
 773 help/reference/Makefile
 774 help/reference/libdocument/Makefile
 775 help/reference/libdocument/version.xml
 776 help/reference/libview/Makefile
 777 help/reference/libview/version.xml
 778 help/reference/shell/Makefile
 779 help/reference/shell/version.xml
 780 libdocument/Makefile
 781 libdocument/ev-version.h
 782 libmisc/Makefile
 783 libview/Makefile
 784 Makefile
 785 po/Makefile.in
 786 previewer/Makefile
 787 properties/Makefile
 788 shell/Makefile
 789 test/Makefile
 790 thumbnailer/Makefile
 791 ])
 792
 793 AC_CONFIG_FILES(evince-document-[]ev_api_version[].pc:evince-document.pc.in)
 794 AC_CONFIG_FILES(evince-view-[]ev_api_version[].pc:evince-view.pc.in)
 795
 796 AC_OUTPUT
 797
 798 echo "
 799 Configure summary:
 800         Platform...........:  $with_platform
 801         GTK+ Unix Print....:  $with_gtk_unix_print
 802         Keyring Support....:  $with_keyring
 803         DBUS Support.......:  $enable_dbus
 804         SM client support..:  $with_smclient
 805         Help files.........:  $enable_help
 806         Nautilus Plugin....:  $enable_nautilus
 807         Thumbnailer........:  $enable_thumbnailer
 808         Previewer..........:  $enable_previewer
 809         Gtk-Doc Support....:  $enable_gtk_doc
 810         Debug mode.........:  $enable_debug
 811         GObj. Introspection:  $enable_introspection
 812         Tests..............:  $enable_tests
 813
 814         PDF Backend........:  $enable_pdf
 815         PostScript Backend.:  $enable_ps
 816         TIFF Backend.......:  $enable_tiff
 817         DJVU Backend.......:  $enable_djvu
 818         DVI Backend........:  $enable_dvi
 819         Comics Backend.....:  $enable_comics
 820         XPS Backend........:  $enable_xps
 821 "