configure.ac

   1 # *****************************************************************************
   2 # Versioning
   3 # *****************************************************************************
   4
   5 m4_define([ev_major_version],[2])
   6 m4_define([ev_minor_version],[25])
   7 m4_define([ev_micro_version],[5])
   8 m4_define([ev_extra_version],[])
   9 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version()ev_extra_version])
  10
  11 # The evince API version
  12 m4_define([ev_api_version], [2.25])
  13
  14 # Libtool versioning. The backend and view libraries have separate versions.
  15 # Before making a release, the libtool version should be modified.
  16 # The string is of the form C:R:A.
  17 # - If interfaces have been changed or added, but binary compatibility has
  18 #   been preserved, change to C+1:0:A+1
  19 # - If binary compatibility has been broken (eg removed or changed interfaces)
  20 #   change to C+1:0:0
  21 # - If the interface is the same as the previous version, change to C:R+1:A
  22
  23 # Libtool version of the backend library
  24 m4_define([ev_document_lt_current],[1])
  25 m4_define([ev_document_lt_revision],[0])
  26 m4_define([ev_document_lt_age],[0])
  27 m4_define([ev_document_lt_version_info],[ev_document_lt_current:ev_document_lt_revision:ev_document_lt_age])
  28 m4_define([ev_document_lt_current_minus_age],[m4_eval(ev_document_lt_current - ev_document_lt_age)])
  29
  30 # Libtool version of the view library
  31 m4_define([ev_view_lt_current],[1])
  32 m4_define([ev_view_lt_revision],[0])
  33 m4_define([ev_view_lt_age],[0])
  34 m4_define([ev_view_lt_version_info],[ev_view_lt_current:ev_view_lt_revision:ev_view_lt_age])
  35 m4_define([ev_view_lt_current_minus_age],[m4_eval(ev_view_lt_current - ev_view_lt_age)])
  36
  37 # Binary version for the document backends
  38 m4_define([ev_binary_version],[ev_document_lt_current])
  39
  40 # *****************************************************************************
  41
  42 AC_PREREQ([2.57])
  43 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
  44 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-dist-gzip])
  45
  46 AM_CONFIG_HEADER(config.h)
  47
  48 AM_MAINTAINER_MODE
  49
  50 AM_PROG_LIBTOOL
  51
  52 AC_ISC_POSIX
  53 AC_PROG_CC
  54 AM_PROG_CC_STDC
  55 AM_PROG_CC_C_O
  56 AC_PROG_CXX
  57 AC_STDC_HEADERS
  58 IT_PROG_INTLTOOL([0.35.0])
  59 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  60 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  61
  62 GNOME_COMMON_INIT
  63 GNOME_DOC_INIT
  64 GNOME_MAINTAINER_MODE_DEFINES
  65 GNOME_COMPILE_WARNINGS
  66 GNOME_CXX_WARNINGS
  67
  68 GTK_DOC_CHECK(1.0)
  69
  70 GETTEXT_PACKAGE=evince
  71 AC_SUBST(GETTEXT_PACKAGE)
  72 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  73 AM_GLIB_GNU_GETTEXT
  74
  75 dnl Check dependencies
  76
  77 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
  78 # BACKEND_CFLAGS   for backend implementations.
  79 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
  80 # FRONTEND_LIBS
  81 # SHELL_CFLAGS     for shell implementation.
  82 # SHELL_LIBS
  83
  84 DBUS_GLIB_REQUIRED=0.70
  85 GTK_REQUIRED=2.12.0
  86 GLIB_REQUIRED=2.18.0
  87 KEYRING_REQUIRED=2.22.0
  88 AC_SUBST([GLIB_REQUIRED])
  89 AC_SUBST([GTK_REQUIRED])
  90
  91 GNOME_ICON_THEME_REQUIRED=2.17.1
  92 LIBXML_REQUIRED=2.5.0
  93
  94 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
  95 PKG_CHECK_MODULES(LIBVIEW, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
  96 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
  97 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
  98 PKG_CHECK_MODULES(SHELL_CORE, libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED gthread-2.0 gconf-2.0)
  99
 100 PKG_CHECK_MODULES(SMCLIENT, gtk+-2.0 gthread-2.0)
 101 AC_SUBST(SMCLIENT_CFLAGS)
 102 AC_SUBST(SMCLIENT_LIBS)
 103
 104 BACKEND_LIBTOOL_FLAGS="-module -avoid-version"
 105 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
 106
 107 dnl ===== Check special functions
 108 evince_save_LIBS=$LIBS
 109 LIBS="$LIBS $BACKEND_LIBS"
 110 AC_CHECK_FUNCS(cairo_format_stride_for_width)
 111 LIBS=$evince_save_LIBS
 112
 113 AC_ARG_WITH(keyring,
 114         AC_HELP_STRING([--without-keyring],[disable the use of gnome-keyring]),
 115         [case "${withval}" in
 116         yes) WITH_KEYRING=yes ;;
 117         no) WITH_KEYRING=no ;;
 118         *) AC_MSG_ERROR(bad value ${withval} for --with-keyring) ;;
 119         esac],
 120         [WITH_KEYRING=yes]) dnl Default value
 121 AM_CONDITIONAL(WITH_KEYRING, test x$WITH_KEYRING = "xyes")
 122
 123 if test x$WITH_KEYRING = "xyes"; then
 124         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
 125         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
 126 fi
 127
 128 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
 129 AC_SUBST(GLIB_GENMARSHAL)
 130
 131 dnl ========= Check for DBUS
 132 AC_ARG_ENABLE(dbus,
 133         [AC_HELP_STRING([--enable-dbus], [Compile with support for dbus])],
 134         enable_dbus="$enableval",enable_dbus=yes)
 135 if test "x$enable_dbus" != "xno"; then
 136         PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
 137         [enable_dbus=yes],[enable_dbus=no])
 138
 139         if test "x$enable_dbus" = "xno"; then
 140            AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
 141         fi
 142
 143         if test "x$enable_dbus" = "xyes" ; then
 144                 AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 145
 146                 if test x$DBUS_BINDING_TOOL = "xno" ; then
 147                         AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 148                 fi
 149
 150                 AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 151         fi
 152 fi
 153
 154 AC_SUBST([DBUS_CFLAGS])
 155 AC_SUBST([DBUS_LIBS])
 156
 157 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
 158 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
 159
 160 dnl Debug mode
 161 AC_ARG_ENABLE([debug],
 162         AC_HELP_STRING([--enable-debug],
 163                         [Turn on evince debug mode]),,
 164                 [enable_debug=no])
 165
 166 if test "x$enable_debug" = "xyes"; then
 167    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 168 fi
 169
 170
 171 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 172 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 173 AC_SUBST(LIBDOCUMENT_CFLAGS)
 174 AC_SUBST(LIBDOCUMENT_LIBS)
 175
 176 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $DEBUG_FLAGS"
 177 LIBVIEW_LIBS="$LIBVIEW_LIBS"
 178 AC_SUBST(LIBVIEW_CFLAGS)
 179 AC_SUBST(LIBVIEW_LIBS)
 180
 181 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 182 AC_SUBST(BACKEND_CFLAGS)
 183 AC_SUBST(BACKEND_LIBS)
 184
 185 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS $KEYRING_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 186 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS $KEYRING_LIBS -lz"
 187 AC_SUBST(SHELL_CFLAGS)
 188 AC_SUBST(SHELL_LIBS)
 189
 190 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 191 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 192 AC_SUBST(FRONTEND_CFLAGS)
 193 AC_SUBST(FRONTEND_LIBS)
 194
 195 dnl Check for Nautilus property page build
 196 AC_ARG_ENABLE(nautilus,
 197         AC_HELP_STRING([--enable-nautilus],[compile the nautilus plugin]),
 198         [case "${enableval}" in
 199         yes) ENABLE_NAUTILUS=yes ;;
 200         no) ENABLE_NAUTILUS=no ;;
 201         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nautilus) ;;
 202         esac],
 203         [ENABLE_NAUTILUS=yes]) dnl Default value
 204
 205 if test x$ENABLE_NAUTILUS = "xyes" ; then
 206         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
 207                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
 208         NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 209         AC_SUBST(NAUTILUS_EXTENSION_DIR)
 210 fi
 211
 212 AC_SUBST(NAUTILUS_CFLAGS)
 213 AC_SUBST(NAUTILUS_LIBS)
 214 if test x$HAVE_NAUTILUS = "xyes"; then
 215         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
 216 fi
 217 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
 218
 219
 220 dnl Check for thumbnailer build
 221 AC_ARG_ENABLE(thumbnailer,
 222         AC_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer]),
 223         [case "${enableval}" in
 224         yes) ENABLE_THUMBNAILER=yes ;;
 225         no) ENABLE_THUMBNAILER=no ;;
 226         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thumbnailer) ;;
 227         esac],
 228         [ENABLE_THUMBNAILER=yes]) dnl Default value
 229 AM_CONDITIONAL(ENABLE_THUMBNAILER, test x$ENABLE_THUMBNAILER = "xyes")
 230
 231 dnl GConf configuration
 232 AM_GCONF_SOURCE_2
 233
 234 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
 235 if test "x$GCONFTOOL" = "xno"; then
 236         AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 237 fi
 238
 239 dnl ================== portability checks ===========================================
 240
 241 dnl for backtrace()
 242 AC_CHECK_HEADERS([execinfo.h])
 243
 244 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 245   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 246   ],[],[#include <langinfo.h>])
 247
 248 dnl ================== pdf checks ===================================================
 249 AC_ARG_ENABLE(pdf,
 250               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 251
 252 if test "x$enable_pdf" = "xyes"; then
 253     POPPLER_REQUIRED=0.8.0
 254     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED,enable_pdf=yes,enable_pdf=no)
 255
 256     if test "x$enable_pdf" = "xyes"; then
 257             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 258             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 259             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 260
 261             evince_save_LIBS=$LIBS
 262             LIBS="$LIBS $POPPLER_LIBS"
 263             AC_CHECK_FUNCS(poppler_page_render)
 264             AC_CHECK_FUNCS(poppler_layers_iter_new)
 265             LIBS=$evince_save_LIBS
 266
 267             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 268             if test x$enable_cairo_pdf = xyes; then
 269                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 270             fi
 271
 272             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 273             if test x$enable_cairo_ps = xyes; then
 274                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 275             fi
 276     else
 277             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 278     fi
 279 fi
 280
 281 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 282 dnl ================== end of pdf checks ============================================
 283
 284 dnl libspectre (used by ps and dvi backends)
 285 SPECTRE_REQUIRED=0.2.0
 286 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 287 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 288 if test "x$have_spectre" = "xyes"; then
 289    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 290 fi
 291
 292 dnl ================== ps checks ====================================================
 293 AC_ARG_ENABLE(ps,
 294         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 295
 296 if test "x$enable_ps" = "xyes"; then
 297    if test "x$have_spectre" = "xyes"; then
 298       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 299    else
 300       enable_ps="no"
 301       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 302    fi
 303 fi
 304 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 305 dnl ======================== End of ps checks ===================================
 306
 307 dnl ================== tiff checks ===================================================
 308 AC_ARG_ENABLE(tiff,
 309             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 310
 311 if test "x$enable_tiff" = "xyes"; then
 312     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 313     if test "x$enable_tiff" = "xyes"; then
 314         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 315         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 316     fi
 317     if test "x$enable_tiff" = "xyes"; then
 318             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 319     else
 320             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 321     fi
 322 fi
 323
 324 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 325 dnl ================== end of tiff checks ============================================
 326
 327 dnl ================== djvu checks ===================================================
 328
 329 AC_ARG_ENABLE(djvu,
 330             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=yes)
 331
 332 if test "x$enable_djvu" = "xyes"; then
 333     DJVULIBRE_REQUIRED=3.5.17
 334     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 335
 336     if test "x$enable_djvu" = "xyes"; then
 337         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 338     else
 339         AC_MSG_WARN([
 340 ** Djvu support is disabled since a recent version of the djvulibre
 341 ** library was not found. You need at least djvulibre-3.5.17 which
 342 ** can be found on http://djvulibre.djvuzone.org
 343 ])
 344     fi
 345 fi
 346
 347 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 348
 349 dnl ================== End of djvu checks ===================================================
 350
 351 dnl ================== dvi checks ===================================================
 352
 353 AC_ARG_ENABLE(dvi,
 354             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=yes)
 355
 356 AC_ARG_ENABLE(t1lib,
 357             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 358
 359 if test "x$enable_dvi" = "xyes"; then
 360     AC_C_CONST
 361     AC_C_INLINE
 362     AC_TYPE_SIZE_T
 363     AC_CHECK_SIZEOF(long, 4)
 364     AC_CHECK_SIZEOF(int, 4)
 365     AC_CHECK_SIZEOF(short, 2)
 366     AC_CHECK_SIZEOF(void *, 4)
 367     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 368
 369     if test "x$enable_dvi" = "xyes"; then
 370         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 371     else
 372         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 373     fi
 374 fi
 375 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 376
 377 if test "x$enable_dvi" = "xyes"; then
 378     if test "x$enable_type1_fonts" = "xyes"; then
 379         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 380     fi
 381
 382     if test "x$enable_type1_fonts" = xyes; then
 383         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 384     fi
 385 else
 386     enable_type1_fonts=no
 387 fi
 388 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 389
 390 dnl ================== End of dvi checks ===================================================
 391
 392 dnl ================== pixbuf checks ===================================================
 393
 394 AC_ARG_ENABLE(pixbuf,
 395             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 396 if test "x$enable_pixbuf" = "xyes"; then
 397         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 398 fi
 399 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 400
 401 dnl ================== End of pixbuf checks ===================================================
 402
 403 dnl ================== comic book checks ===================================================
 404
 405 AC_ARG_ENABLE(comics,
 406         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=yes)
 407 if test "x$enable_comics" = "xyes"; then
 408         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 409 fi
 410 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 411
 412 dnl ================== End of comic book checks ============================================
 413
 414 dnl ================== impress book checks ===================================================
 415
 416 AC_ARG_ENABLE(impress,
 417         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 418 if test "x$enable_impress" = "xyes"; then
 419         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 420 fi
 421 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 422
 423 dnl ================== End of impress book checks ============================================
 424
 425 dnl =================== Mime types list ====================================================
 426
 427 if test "x$enable_pdf" = "xyes" ; then
 428         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 429 fi
 430 if test "x$enable_ps" = "xyes" ; then
 431         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 432 fi
 433 if test "x$enable_dvi" = "xyes"; then
 434         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 435 fi
 436 if test "x$enable_djvu" = "xyes"; then
 437         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 438 fi
 439 if test "x$enable_tiff" = "xyes"; then
 440         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 441 fi
 442 if test "x$enable_comics" = "xyes"; then
 443         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;"
 444 fi
 445 if test "x$enable_pixbuf" = "xyes"; then
 446         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 447 fi
 448 if test "x$enable_impress" = "xyes"; then
 449         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 450 fi
 451 AC_SUBST(EVINCE_MIME_TYPES)
 452
 453 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 454
 455 # Backends directory
 456
 457 AC_SUBST([backenddir],"\$(libdir)/evince/ev_binary_version/backends")
 458
 459 # Versioning
 460
 461 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
 462 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
 463 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
 464
 465 AC_SUBST([EV_API_VERSION],[ev_api_version])
 466 AC_SUBST([EV_BINARY_VERSION],[ev_binary_version])
 467
 468 AC_SUBST([EV_DOCUMENT_LT_VERSION_INFO],[ev_document_lt_version_info])
 469 AC_SUBST([EV_DOCUMENT_LT_CURRENT_MINUS_AGE],[ev_document_lt_current_minus_age])
 470 AC_SUBST([EV_VIEW_LT_VERSION_INFO],[ev_view_lt_version_info])
 471 AC_SUBST([EV_VIEW_LT_CURRENT_MINUS_AGE],[ev_view_lt_current_minus_age])
 472
 473 # *****************************************************************************
 474
 475 AC_CONFIG_FILES([
 476 backend/Makefile
 477 backend/comics/Makefile
 478 backend/djvu/Makefile
 479 backend/dvi/Makefile
 480 backend/dvi/mdvi-lib/Makefile
 481 backend/impress/Makefile
 482 backend/pdf/Makefile
 483 backend/pixbuf/Makefile
 484 backend/ps/Makefile
 485 backend/tiff/Makefile
 486 cut-n-paste/Makefile
 487 cut-n-paste/evmountoperation/Makefile
 488 cut-n-paste/gedit-message-area/Makefile
 489 cut-n-paste/gimpcellrenderertoggle/Makefile
 490 cut-n-paste/smclient/Makefile
 491 cut-n-paste/toolbar-editor/Makefile
 492 cut-n-paste/zoom-control/Makefile
 493 cut-n-paste/totem-screensaver/Makefile
 494 data/evince.desktop.in
 495 data/Makefile
 496 data/icons/Makefile
 497 data/icons/16x16/Makefile
 498 data/icons/16x16/apps/Makefile
 499 data/icons/16x16/actions/Makefile
 500 data/icons/22x22/Makefile
 501 data/icons/22x22/apps/Makefile
 502 data/icons/22x22/actions/Makefile
 503 data/icons/24x24/Makefile
 504 data/icons/24x24/apps/Makefile
 505 data/icons/24x24/actions/Makefile
 506 data/icons/32x32/Makefile
 507 data/icons/32x32/actions/Makefile
 508 data/icons/48x48/Makefile
 509 data/icons/48x48/apps/Makefile
 510 data/icons/48x48/actions/Makefile
 511 data/icons/scalable/Makefile
 512 data/icons/scalable/apps/Makefile
 513 help/Makefile
 514 help/reference/Makefile
 515 help/reference/version.xml
 516 libdocument/Makefile
 517 libdocument/ev-version.h
 518 libview/Makefile
 519 Makefile
 520 po/Makefile.in
 521 properties/Makefile
 522 shell/Makefile
 523 test/Makefile
 524 thumbnailer/Makefile
 525 ])
 526
 527 AC_CONFIG_FILES(evince-document-[]ev_api_version[].pc:evince-document.pc.in)
 528 AC_CONFIG_FILES(evince-view-[]ev_api_version[].pc:evince-view.pc.in)
 529
 530 AC_OUTPUT
 531
 532 echo "
 533 Configure summary:
 534         Keyring Support....:  $WITH_KEYRING
 535         DBUS Support.......:  $enable_dbus
 536         Nautilus Plugin....:  $HAVE_NAUTILUS
 537         Thumbnailer........:  $ENABLE_THUMBNAILER
 538         Gtk-Doc Support....:  $enable_gtk_doc
 539         Debug mode.........:  $enable_debug
 540
 541         PDF Backend........:  $enable_pdf
 542         PostScript Backend.:  $enable_ps
 543         TIFF Backend.......:  $enable_tiff
 544         DJVU Backend.......:  $enable_djvu
 545         DVI Backend........:  $enable_dvi
 546         Pixbuf Backend.....:  $enable_pixbuf
 547         Comics Backend.....:  $enable_comics
 548         Impress Backend....:  $enable_impress
 549 "