configure.ac

   1 # *****************************************************************************
   2 # Versioning
   3 # *****************************************************************************
   4
   5 m4_define([ev_major_version],[2])
   6 m4_define([ev_minor_version],[31])
   7 m4_define([ev_micro_version],[92])
   8 m4_define([ev_extra_version],[])
   9 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version()ev_extra_version])
  10
  11 # The evince API version
  12 m4_define([ev_api_version], [2.32])
  13
  14 # Libtool versioning. The backend and view libraries have separate versions.
  15 # Before making a release, the libtool version should be modified.
  16 # The string is of the form C:R:A.
  17 # - If interfaces have been changed or added, but binary compatibility has
  18 #   been preserved, change to C+1:0:A+1
  19 # - If binary compatibility has been broken (eg removed or changed interfaces)
  20 #   change to C+1:0:0
  21 # - If the interface is the same as the previous version, change to C:R+1:A
  22
  23 # Libtool version of the backend library
  24 m4_define([ev_document_lt_current],[3])
  25 m4_define([ev_document_lt_revision],[0])
  26 m4_define([ev_document_lt_age],[0])
  27 m4_define([ev_document_lt_version_info],[ev_document_lt_current:ev_document_lt_revision:ev_document_lt_age])
  28 m4_define([ev_document_lt_current_minus_age],[m4_eval(ev_document_lt_current - ev_document_lt_age)])
  29
  30 # Libtool version of the view library
  31 m4_define([ev_view_lt_current],[3])
  32 m4_define([ev_view_lt_revision],[0])
  33 m4_define([ev_view_lt_age],[0])
  34 m4_define([ev_view_lt_version_info],[ev_view_lt_current:ev_view_lt_revision:ev_view_lt_age])
  35 m4_define([ev_view_lt_current_minus_age],[m4_eval(ev_view_lt_current - ev_view_lt_age)])
  36
  37 # Binary version for the document backends
  38 m4_define([ev_binary_version],[ev_document_lt_current])
  39
  40 # *****************************************************************************
  41
  42 AC_PREREQ([2.57])
  43 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
  44 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2 no-dist-gzip])
  45
  46 AC_CONFIG_HEADERS([config.h])
  47 AC_CONFIG_MACRO_DIR([m4])
  48
  49 if test -z "$enable_maintainer_mode"; then
  50   enable_maintainer_mode=yes
  51 fi
  52 AM_MAINTAINER_MODE([enable])
  53
  54 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  55
  56 AM_PROG_LIBTOOL
  57
  58 AC_ISC_POSIX
  59 AC_PROG_CC
  60 AM_PROG_CC_STDC
  61 AM_PROG_CC_C_O
  62 AC_PROG_CXX
  63 AC_STDC_HEADERS
  64
  65 AC_PROG_SED
  66 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  67 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  68
  69 GNOME_MAINTAINER_MODE_DEFINES
  70 GNOME_COMPILE_WARNINGS
  71 GNOME_CXX_WARNINGS
  72
  73 dnl FIXME: remove this when required gtk+ >= 2.19.7
  74 DISABLE_DEPRECATED=
  75 AC_SUBST([DISABLE_DEPRECATED])
  76
  77 IT_PROG_INTLTOOL([0.35.0])
  78
  79 GETTEXT_PACKAGE=evince
  80 AC_SUBST(GETTEXT_PACKAGE)
  81 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  82 AM_GLIB_GNU_GETTEXT
  83
  84 m4_pattern_allow([AM_V_GEN])dnl Make autoconf not complain about the rule below
  85 EV_INTLTOOL_EVINCE_BACKEND_RULE='%.evince-backend:   %.evince-backend.in   $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; $(AM_V_GEN) LC_ALL=C $(INTLTOOL_MERGE) -d -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@'
  86 AC_SUBST([EV_INTLTOOL_EVINCE_BACKEND_RULE])
  87
  88 GLIB_GSETTINGS
  89
  90 # Check which platform to use
  91
  92 AC_MSG_CHECKING([for which platform to build])
  93 AC_ARG_WITH([platform],
  94   [AS_HELP_STRING([--with-platform=gnome|win32|hildon],
  95                   [Setting platform (default: gnome)])],
  96   [case "$withval" in
  97     gnome|win32|hildon) ;;
  98     *) AC_MSG_ERROR([invalid argument "$withval" for --with-platform]) ;;
  99    esac],
 100   [case "$host" in
 101      *-*-mingw*|*-*-cygwin*) with_platform="win32" ;;
 102      *) with_platform=gnome ;;
 103    esac])
 104
 105 AC_MSG_RESULT([$with_platform])
 106
 107 if test "$with_platform" = "win32"; then
 108   AC_CHECK_TOOL([WINDRES],[windres])
 109   AC_MSG_CHECKING([for native Win32])
 110   case "$host" in
 111     *-*-mingw*)
 112       os_win32=yes
 113       ;;
 114     *)
 115       os_win32=no
 116       ;;
 117   esac
 118   AC_MSG_RESULT([$os_win32])
 119 fi
 120
 121 AM_CONDITIONAL([PLATFORM_HILDON],[test "$with_platform" = "hildon"])
 122 AM_CONDITIONAL([PLATFORM_WIN32],[test "$with_platform" = "win32"])
 123
 124 AC_MSG_CHECKING([which gtk+ version to compile against])
 125 AC_ARG_WITH([gtk],
 126   [AS_HELP_STRING([--with-gtk=2.0|3.0],[which gtk+ version to compile against (default: 2.0)])],
 127   [case "$with_gtk" in
 128      2.0|3.0) ;;
 129      *) AC_MSG_ERROR([invalid gtk version specified]) ;;
 130    esac],
 131   [with_gtk=2.0])
 132 AC_MSG_RESULT([$with_gtk])
 133
 134 dnl Specify required versions of dependencies
 135 CAIRO_REQUIRED=1.9.10
 136 GLIB_REQUIRED=2.25.11
 137 KEYRING_REQUIRED=2.22.0
 138
 139 case "$with_gtk" in
 140   2.0) GTK_API_VERSION=2.0
 141        GAIL_API_VERSION=
 142        GTK_REQUIRED=2.21.5
 143        ;;
 144   3.0) GTK_API_VERSION=3.0
 145        GAIL_API_VERSION=-3.0
 146        GTK_REQUIRED=2.90.5
 147        ;;
 148 esac
 149
 150 AC_SUBST([GLIB_REQUIRED])
 151 AC_SUBST([GTK_REQUIRED])
 152 AC_SUBST([GTK_API_VERSION])
 153
 154 GNOME_ICON_THEME_REQUIRED=2.17.1
 155 LIBXML_REQUIRED=2.5.0
 156
 157 dnl Check dependencies
 158
 159 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
 160 # BACKEND_CFLAGS   for backend implementations.
 161 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
 162 # FRONTEND_LIBS
 163 # SHELL_CFLAGS     for shell implementation.
 164 # SHELL_LIBS
 165
 166
 167 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-$GTK_API_VERSION >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
 168 PKG_CHECK_MODULES(LIBVIEW, gtk+-$GTK_API_VERSION >= $GTK_REQUIRED gail$GAIL_API_VERSION >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 169 PKG_CHECK_MODULES(BACKEND, cairo >= $CAIRO_REQUIRED gtk+-$GTK_API_VERSION >= $GTK_REQUIRED)
 170 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-$GTK_API_VERSION >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 171
 172 SHELL_PLATFORM_PKGS=
 173 case "$with_platform" in
 174   hildon) AC_DEFINE([PLATFORM_HILDON],[1],[Define if building for the hildon platform])
 175           SHELL_PLATFORM_PKGS="hildon-1 hildon-fm-2 libosso"
 176           ;;
 177   gnome)
 178         # Evince has a rather soft run-time dependency on hicolor-icon-theme.
 179         # If the hicolor theme is not available, Evince fails to display some
 180         # icons. Because we cannot check for it at run-time, we instead
 181         # would like to require the icon theme at compile-time. But, because
 182         # the hicolor-icon-theme does not have a pkgconfig file, on gnome we
 183         # require the gnome icon theme instead.
 184         SHELL_PLATFORM_PKGS="gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED"
 185         # The totem-screensaver and egg_smclient code use x11 directly.
 186         SHELL_PLATFORM_PKGS="$SHELL_PLATFORM_PKGS x11"
 187         ;;
 188   *)
 189         # On all other platforms we issue a warning about the runtime
 190         # dependency.
 191         AC_MSG_WARN([Evince has a soft run-time dependency on hicolor-icon-theme. You are advised to have this theme installed when running Evince.]);
 192         SHELL_PLATFORM_PKGS=""
 193         ;;
 194 esac
 195
 196 PKG_CHECK_MODULES([SHELL_CORE],[libxml-2.0 >= $LIBXML_REQUIRED gtk+-$GTK_API_VERSION >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gthread-2.0 $SHELL_PLATFORM_PKGS])
 197
 198 # *********
 199 # SM client
 200 # *********
 201
 202 GDK_TARGET="$($PKG_CONFIG --variable target gdk-$GTK_API_VERSION)"
 203
 204 AC_MSG_CHECKING([which smclient backend to use])
 205 AC_ARG_WITH([smclient],
 206   [AS_HELP_STRING([--with-smclient-backend=no|xsmp|win32|quartz],
 207                   [Setting smclient backend (default:auto)])],
 208   [],
 209   [case "$GDK_TARGET" in
 210     x11) case "$with_platform" in
 211            gnome) with_smclient=xsmp ;;
 212            *) with_smclient=no ;;
 213          esac ;;
 214     win32|quartz) with_smclient=$GDK_TARGET ;;
 215     *) with_smclient=no ;;
 216    esac])
 217
 218 AC_MSG_RESULT([$with_smclient])
 219
 220 if test "$with_smclient" != "no"; then
 221   AC_DEFINE([WITH_SMCLIENT],[1],[Define if smclient is enabled])
 222
 223   case "$with_smclient" in
 224     xsmp) SMCLIENT_PKGS="sm >= 1.0.0" ;;
 225     *) SMCLIENT_PKGS="" ;;
 226   esac
 227
 228   PKG_CHECK_MODULES([SMCLIENT],[gtk+-$GTK_API_VERSION gthread-2.0 $SMCLIENT_PKGS])
 229   AC_SUBST([SMCLIENT_CFLAGS])
 230   AC_SUBST([SMCLIENT_LIBS])
 231 fi
 232
 233 AM_CONDITIONAL([WITH_SMCLIENT],[test "$with_smclient" != "no"])
 234 AM_CONDITIONAL([WITH_SMCLIENT_XSMP],[test "$with_smclient" = "xsmp"])
 235 AM_CONDITIONAL([WITH_SMCLIENT_WIN32],[test "$with_smclient" = "win32"])
 236 AM_CONDITIONAL([WITH_SMCLIENT_QUARTZ],[test "$with_smclient" = "quartz"])
 237
 238 # ***
 239
 240 BACKEND_LIBTOOL_FLAGS="-module -avoid-version -no-undefined -export-symbols \$(top_srcdir)/backend/backend.symbols"
 241 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
 242
 243 dnl ===== Check special functions
 244 evince_save_LIBS=$LIBS
 245 LIBS="$LIBS $BACKEND_LIBS"
 246 AC_CHECK_FUNCS(cairo_format_stride_for_width)
 247 LIBS=$evince_save_LIBS
 248
 249 # ******************
 250 # GKT+ Unix Printing
 251 # ******************
 252
 253 AC_MSG_CHECKING([whether gtk+-unix-print support is requested])
 254 AC_ARG_WITH([gtk-unix-print],
 255   [AS_HELP_STRING([--without-gtk-unix-print],
 256                   [Disable the use of gtk-unix-print])],
 257   [],[case "$os_win32" in
 258         yes) with_gtk_unix_print=no ;;
 259         *) with_gtk_unix_print=yes ;;
 260       esac])
 261
 262 AC_MSG_RESULT([$with_gtk_unix_print])
 263
 264 if test "$with_gtk_unix_print" = "yes"; then
 265    PKG_CHECK_MODULES(GTKUNIXPRINT, [gtk+-unix-print-$GTK_API_VERSION >= $GTK_REQUIRED])
 266    AC_DEFINE([GTKUNIXPRINT_ENABLED], [1], [Define if gtk+-unix-print is enabled.])
 267 fi
 268
 269 # *********************
 270 # GNOME Keyring support
 271 # *********************
 272
 273 AC_ARG_WITH(keyring,
 274         [AS_HELP_STRING([--without-keyring],
 275                         [Disable the use of gnome-keyring])],
 276         [],
 277         [case "$with_platform" in
 278            gnome) with_keyring=yes ;;
 279            hildon|win32) with_keyring=no ;;
 280          esac])
 281
 282 AM_CONDITIONAL([WITH_KEYRING],[test "$with_keyring" = "yes"])
 283
 284 if test "$with_keyring" = "yes"; then
 285         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
 286         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
 287 fi
 288
 289 # ****
 290 # DBUS
 291 # ****
 292
 293 AC_ARG_ENABLE([dbus],
 294   [AS_HELP_STRING([--disable-dbus], [Disable support for dbus])],
 295   [],
 296   [case "$with_platform" in
 297       gnome) enable_dbus=yes ;;
 298       hildon) enable_dbus=no ;;
 299     esac])
 300
 301 if test "$enable_dbus" = "yes"; then
 302   AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 303
 304    PKG_CHECK_MODULES([EV_DAEMON], [gio-2.0 >= $GLIB_REQUIRED])
 305 fi
 306
 307 AM_CONDITIONAL([ENABLE_DBUS], [test "$enable_dbus" = "yes"])
 308
 309 dnl ========= Check for GConf
 310
 311 AC_MSG_CHECKING([whether GConf support is requested])
 312 AC_ARG_WITH([gconf],
 313   [AS_HELP_STRING([--without-gconf],
 314                   [Disable the use of gconf])],
 315   [],
 316   [case "$os_win32" in
 317      yes) with_gconf=no ;;
 318      *) with_gconf=yes ;;
 319    esac])
 320 AC_MSG_RESULT([$with_gconf])
 321
 322 AM_CONDITIONAL([WITH_GCONF],[test "$with_gconf" = "yes"])
 323
 324 if test "$with_gconf" = "yes"; then
 325    PKG_CHECK_MODULES([GCONF],[gconf-2.0])
 326    AC_DEFINE([WITH_GCONF],[1],[Define if GConf support is enabled])
 327
 328    AM_GCONF_SOURCE_2
 329
 330    AC_PATH_PROG([GCONFTOOL], [gconftool-2], [false])
 331    if test "$GCONFTOOL" = "false"; then
 332       AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 333    fi
 334 else
 335    AM_CONDITIONAL([GCONF_SCHEMAS_INSTALL],false)
 336 fi
 337
 338 dnl Debug mode
 339
 340 AC_ARG_ENABLE([debug],
 341         AS_HELP_STRING([--enable-debug],
 342                        [Turn on evince debug mode]),
 343         [enable_debug=$enableval],
 344         [enable_debug=no])
 345
 346 if test "x$enable_debug" = "xyes"; then
 347    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 348 fi
 349
 350 AC_ARG_ENABLE([tests],
 351         AS_HELP_STRING([--enable-tests], [Enable the tests]),
 352         [enable_tests=$enableval],
 353         [enable_tests=yes])
 354
 355 AM_CONDITIONAL(ENABLE_TESTS, test x$enable_tests = xyes)
 356
 357 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 358 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 359 AC_SUBST(LIBDOCUMENT_CFLAGS)
 360 AC_SUBST(LIBDOCUMENT_LIBS)
 361
 362 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 363 LIBVIEW_LIBS="$LIBVIEW_LIBS $GTKUNIXPRINT_LIBS -lm"
 364 AC_SUBST(LIBVIEW_CFLAGS)
 365 AC_SUBST(LIBVIEW_LIBS)
 366
 367 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 368 BACKEND_LIBS="$BACKEND_LIBS -lm"
 369 AC_SUBST(BACKEND_CFLAGS)
 370 AC_SUBST(BACKEND_LIBS)
 371
 372 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $KEYRING_CFLAGS $GCONF_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 373 SHELL_LIBS="$SHELL_CORE_LIBS $KEYRING_LIBS $GCONF_LIBS -lz -lm"
 374 AC_SUBST(SHELL_CFLAGS)
 375 AC_SUBST(SHELL_LIBS)
 376
 377 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 378 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 379 AC_SUBST(FRONTEND_CFLAGS)
 380 AC_SUBST(FRONTEND_LIBS)
 381
 382 EV_DAEMON_CFLAGS="$EV_DAEMON_CFLAGS $DEBUG_FLAGS"
 383 AC_SUBST([EV_DAEMON_CFLAGS])
 384 AC_SUBST([EV_DAEMON_LIBS])
 385
 386 # Check for Nautilus property page build
 387 AC_ARG_ENABLE([nautilus],
 388   [AS_HELP_STRING([--disable-nautilus],
 389                   [Disable build of nautilus extensions])],
 390   [],
 391   [case "$with_platform" in
 392      gnome) enable_nautilus=yes ;;
 393      *) enable_nautilus=no ;;
 394     esac])
 395
 396 if test "$enable_nautilus" = "yes" ; then
 397   PKG_CHECK_MODULES([NAUTILUS],[gtk+-x11-$GTK_API_VERSION $MM gthread-2.0 libnautilus-extension],
 398                     [],[AC_MSG_ERROR([libnautilus-extension not found; use --disable-nautilus to disable the nautilus extensions])])
 399   NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 400   AC_SUBST([nautilusextensiondir],[$NAUTILUS_EXTENSION_DIR])
 401   AC_SUBST(NAUTILUS_CFLAGS)
 402   AC_SUBST(NAUTILUS_LIBS)
 403
 404   AC_DEFINE([HAVE_NAUTILUS],[1], [defined if you build the nautilus plugin])
 405 fi
 406
 407 AM_CONDITIONAL([ENABLE_NAUTILUS],[test "$enable_nautilus" = "yes"])
 408
 409 # Check for thumbnailer build
 410
 411 AC_ARG_ENABLE([thumbnailer],
 412   [AS_HELP_STRING([--disable-thumbnailer],
 413                   [Disable GNOME thumbnailer])],
 414   [],
 415   [case "$with_platform" in
 416      hildon) enable_thumbnailer=no ;;
 417      *) enable_thumbnailer=yes ;;
 418     esac])
 419
 420 AM_CONDITIONAL([ENABLE_THUMBNAILER],[test "$enable_thumbnailer" = "yes"])
 421
 422 # ***************
 423 # Print Previewer
 424 # ***************
 425
 426 AC_ARG_ENABLE([previewer],
 427   [AS_HELP_STRING([--disable-previewer],
 428                   [Disable the GNOME Document Previewer])],
 429   [],
 430   [case "$with_platform" in
 431       hildon) enable_previewer=no ;;
 432       *) enable_previewer=yes ;;
 433     esac])
 434
 435 if test x$enable_previewer = "xyes" ; then
 436   PKG_CHECK_MODULES([PREVIEWER],[gtk+-$GTK_API_VERSION >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED])
 437 fi
 438
 439 AM_CONDITIONAL([ENABLE_PREVIEWER],[test "$enable_previewer" = "yes"])
 440 PREVIEWER_CFLAGS="$PREVIEWER_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 441 PREVIEWER_LIBS="$PREVIEWER_LIBS $GTKUNIXPRINT_LIBS -lz"
 442 AC_SUBST(PREVIEWER_CFLAGS)
 443 AC_SUBST(PREVIEWER_LIBS)
 444
 445 # ***
 446 # GIR
 447 # ***
 448
 449 AC_MSG_CHECKING([whether GObject introspection is requested])
 450 AC_ARG_ENABLE([introspection],
 451         AS_HELP_STRING([--enable-introspection],
 452                        [Enable GObject introspection]),
 453         [enable_introspection=$enableval],
 454         [enable_introspection=no])
 455 AC_MSG_RESULT([$enable_introspection])
 456
 457 G_IR_SCANNER=
 458 G_IR_COMPILER=
 459 G_IR_GENERATE=
 460 GIRDIR=
 461 GIRTYPELIBDIR=
 462
 463 if test "$enable_introspection" = "yes"; then
 464   GOBJECT_INTROSPECTION_REQUIRED=0.6
 465   PKG_CHECK_MODULES([GOBJECT_INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
 466
 467   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
 468   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
 469   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
 470   GIRDIR="$($PKG_CONFIG --variable=girdir gobject-introspection-1.0)"
 471   GIRTYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
 472 fi
 473
 474 AC_SUBST([G_IR_SCANNER])
 475 AC_SUBST([G_IR_COMPILER])
 476 AC_SUBST([G_IR_GENERATE])
 477 AC_SUBST([GIRDIR])
 478 AC_SUBST([GIRTYPELIBDIR])
 479
 480 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
 481
 482 dnl ================== portability checks ===========================================
 483
 484 dnl for backtrace()
 485 AC_CHECK_HEADERS([execinfo.h])
 486
 487 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 488   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 489   ],[],[#include <langinfo.h>])
 490
 491 dnl ================== pdf checks ===================================================
 492 AC_ARG_ENABLE([pdf],
 493   [AS_HELP_STRING([--disable-pdf],
 494                   [Disable the PDF support])],
 495   [enable_pdf=$enableval],
 496   [enable_pdf=yes])
 497
 498 if test "x$enable_pdf" = "xyes"; then
 499     POPPLER_REQUIRED=0.14.0
 500     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED,enable_pdf=yes,enable_pdf=no)
 501
 502     if test "x$enable_pdf" = "xyes"; then
 503             evince_save_LIBS=$LIBS
 504             LIBS="$LIBS $POPPLER_LIBS"
 505             AC_CHECK_FUNCS(poppler_page_get_text_layout)
 506             AC_CHECK_FUNCS(poppler_page_get_selected_text)
 507             AC_CHECK_FUNCS(poppler_page_add_annot)
 508             LIBS=$evince_save_LIBS
 509             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 510             if test x$enable_cairo_pdf = xyes; then
 511                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 512             fi
 513
 514             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 515             if test x$enable_cairo_ps = xyes; then
 516                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 517             fi
 518     else
 519             AC_MSG_ERROR("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 520     fi
 521 fi
 522
 523 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 524 dnl ================== end of pdf checks ============================================
 525
 526 dnl libspectre (used by ps and dvi backends)
 527 SPECTRE_REQUIRED=0.2.0
 528 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 529 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 530 if test "x$have_spectre" = "xyes"; then
 531    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 532 fi
 533
 534 dnl ================== ps checks ====================================================
 535 AC_ARG_ENABLE(ps,
 536         [AS_HELP_STRING([--disable-ps],
 537                         [Disable the PostScript backend])],
 538         [enable_ps=$enableval],
 539         [enable_ps=yes])
 540
 541 if test "x$enable_ps" = "xyes"; then
 542    if test "x$have_spectre" = "xyes"; then
 543       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 544    else
 545       enable_ps="no"
 546       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 547    fi
 548 fi
 549 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 550 dnl ======================== End of ps checks ===================================
 551
 552 dnl ================== tiff checks ===================================================
 553 AC_ARG_ENABLE(tiff,
 554             [AS_HELP_STRING([--disable-tiff],
 555                             [Disable the support of multipage tiff])],
 556             [enable_tiff=$enableval],
 557             [enable_tiff=yes])
 558
 559 if test "x$enable_tiff" = "xyes"; then
 560     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 561     if test "x$enable_tiff" = "xyes"; then
 562         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 563         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 564     fi
 565     if test "x$enable_tiff" = "xyes"; then
 566             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 567     else
 568             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 569     fi
 570 fi
 571
 572 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 573 dnl ================== end of tiff checks ============================================
 574
 575 dnl ================== djvu checks ===================================================
 576
 577 AC_ARG_ENABLE(djvu,
 578             [AS_HELP_STRING([--disable-djvu],
 579                             [Disable the support of djvu viewer])],
 580             [enable_djvu=$enableval],
 581             [enable_djvu=yes])
 582
 583 if test "x$enable_djvu" = "xyes"; then
 584     DJVULIBRE_REQUIRED=3.5.17
 585     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 586
 587     if test "x$enable_djvu" = "xyes"; then
 588         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 589     else
 590         AC_MSG_WARN([
 591 ** Djvu support is disabled since a recent version of the djvulibre
 592 ** library was not found. You need at least djvulibre-3.5.17 which
 593 ** can be found on http://djvulibre.djvuzone.org
 594 ])
 595     fi
 596 fi
 597
 598 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 599
 600 dnl ================== End of djvu checks ===================================================
 601
 602 dnl ================== dvi checks ===================================================
 603
 604 AC_ARG_ENABLE(dvi,
 605             [AS_HELP_STRING([--disable-dvi],
 606             [Disable the support of dvi viewer])],
 607             [enable_dvi=$enableval],
 608             [enable_dvi=yes])
 609
 610 AC_ARG_ENABLE(t1lib,
 611             [AS_HELP_STRING([--enable-t1lib],
 612                             [Compile with support of t1lib for type1 fonts in dvi])],
 613             [enable_type1_fonts=$enableval],
 614             [enable_type1_fonts=no])
 615
 616 if test "x$enable_dvi" = "xyes"; then
 617     AC_C_CONST
 618     AC_C_INLINE
 619     AC_TYPE_SIZE_T
 620     AC_CHECK_SIZEOF(long, 4)
 621     AC_CHECK_SIZEOF(int, 4)
 622     AC_CHECK_SIZEOF(short, 2)
 623     AC_CHECK_SIZEOF(void *, 4)
 624     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 625
 626     if test "x$enable_dvi" = "xyes"; then
 627         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 628     else
 629         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 630     fi
 631 fi
 632 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 633
 634 if test "x$enable_dvi" = "xyes"; then
 635     if test "x$enable_type1_fonts" = "xyes"; then
 636         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 637     fi
 638
 639     if test "x$enable_type1_fonts" = xyes; then
 640         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 641     fi
 642 else
 643     enable_type1_fonts=no
 644 fi
 645 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 646
 647 dnl ================== End of dvi checks ===================================================
 648
 649 dnl ================== pixbuf checks ===================================================
 650
 651 AC_ARG_ENABLE(pixbuf,
 652             [AS_HELP_STRING([--enable-pixbuf],
 653                             [Compile with support of pixbuf])],
 654             [enable_pixbuf=$enableval],
 655             [enable_pixbuf=no])
 656
 657 if test "x$enable_pixbuf" = "xyes"; then
 658         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 659 fi
 660
 661 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 662
 663 dnl ================== End of pixbuf checks ===================================================
 664
 665 dnl ================== comic book checks ===================================================
 666
 667 AC_ARG_ENABLE(comics,
 668         [AS_HELP_STRING([--enable-comics],
 669                         [Compile with support for comic book archives])],
 670         [enable_comics=$enableval],
 671         [enable_comics=yes])
 672
 673 if test "x$enable_comics" = "xyes"; then
 674         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 675 fi
 676 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 677
 678 dnl ================== End of comic book checks ============================================
 679
 680 dnl ================== impress book checks ===================================================
 681
 682 AC_ARG_ENABLE(impress,
 683         [AS_HELP_STRING([--enable-impress],
 684                         [Compile with support for impress presentations])],
 685         [enable_impress=$enableval],
 686         [enable_impress=no])
 687
 688 if test "x$enable_impress" = "xyes"; then
 689         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 690 fi
 691 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 692
 693 dnl ================== End of impress book checks ============================================
 694
 695 dnl =================== Mime types list ====================================================
 696
 697 if test "x$enable_pdf" = "xyes" ; then
 698         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 699 fi
 700 if test "x$enable_ps" = "xyes" ; then
 701         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 702 fi
 703 if test "x$enable_dvi" = "xyes"; then
 704         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 705 fi
 706 if test "x$enable_djvu" = "xyes"; then
 707         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 708 fi
 709 if test "x$enable_tiff" = "xyes"; then
 710         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 711 fi
 712 if test "x$enable_comics" = "xyes"; then
 713         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;application/x-cbt;"
 714 fi
 715 if test "x$enable_pixbuf" = "xyes"; then
 716         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 717 fi
 718 if test "x$enable_impress" = "xyes"; then
 719         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 720 fi
 721 AC_SUBST(EVINCE_MIME_TYPES)
 722
 723 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 724
 725 # *****************
 726 # Help files
 727 # *****************
 728
 729 GNOME_DOC_INIT([], gnome_doc_utils=yes, gnome_doc_utils=no)
 730
 731 AC_ARG_ENABLE(help,
 732     [AS_HELP_STRING([--disable-help], [Disable offline help files])],
 733     [enable_help=$enableval],
 734     [enable_help=yes])
 735
 736 if test "x$enable_help" = "xyes" && test "x$os_win32" = "xyes" ; then
 737     AC_MSG_WARN([Offline help is disabled (not implemented on Windows).])
 738     enable_help=no
 739 fi
 740
 741 if test "x$enable_help" = "xyes" && test "x$gnome_doc_utils" == "xno"; then
 742     AC_MSG_ERROR(
 743        [gnome-doc-utils not found; use --disable-help to disable help files]
 744     )
 745 fi
 746
 747 if test "x$enable_help" = "xyes"; then
 748     AC_DEFINE([OFFLINE_HELP_ENABLED], [1], [Enable offline help])
 749 fi
 750
 751 AM_CONDITIONAL(ENABLE_HELP, test "x$enable_help" = "xyes")
 752
 753 # *****************
 754 # API documentation
 755 # *****************
 756
 757 GTK_DOC_CHECK([1.13],[--flavour no-tmpl])
 758
 759 AC_SUBST([GLIB_PREFIX],[$($PKG_CONFIG --variable=prefix glib-2.0)])
 760 AC_SUBST([GTK_PREFIX],[$($PKG_CONFIG --variable=prefix gtk+-$GTK_API_VERSION)])
 761
 762 # ******************
 763 # Backends directory
 764 # ******************
 765
 766 AC_SUBST([backenddir],"\$(libdir)/evince/ev_binary_version/backends")
 767 AC_SUBST([backend_binary_version],"ev_binary_version")
 768
 769 # **********
 770 # Versioning
 771 # **********
 772
 773 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
 774 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
 775 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
 776
 777 AC_SUBST([EV_API_VERSION],[ev_api_version])
 778 AC_SUBST([EV_API_VERSION_U],[AS_TR_SH([ev_api_version])])
 779 AC_SUBST([EV_BINARY_VERSION],[ev_binary_version])
 780
 781 AC_SUBST([EV_DOCUMENT_LT_VERSION_INFO],[ev_document_lt_version_info])
 782 AC_SUBST([EV_DOCUMENT_LT_CURRENT_MINUS_AGE],[ev_document_lt_current_minus_age])
 783 AC_SUBST([EV_VIEW_LT_VERSION_INFO],[ev_view_lt_version_info])
 784 AC_SUBST([EV_VIEW_LT_CURRENT_MINUS_AGE],[ev_view_lt_current_minus_age])
 785
 786 # *****************************************************************************
 787 # *****************************************************************************
 788
 789 AC_CONFIG_FILES([
 790 backend/Makefile
 791 backend/comics/Makefile
 792 backend/djvu/Makefile
 793 backend/dvi/Makefile
 794 backend/dvi/mdvi-lib/Makefile
 795 backend/impress/Makefile
 796 backend/pdf/Makefile
 797 backend/pixbuf/Makefile
 798 backend/ps/Makefile
 799 backend/tiff/Makefile
 800 cut-n-paste/Makefile
 801 cut-n-paste/gimpcellrenderertoggle/Makefile
 802 cut-n-paste/smclient/Makefile
 803 cut-n-paste/toolbar-editor/Makefile
 804 cut-n-paste/zoom-control/Makefile
 805 cut-n-paste/totem-screensaver/Makefile
 806 cut-n-paste/synctex/Makefile
 807 data/evince.desktop.in
 808 data/Makefile
 809 data/icons/Makefile
 810 data/icons/16x16/Makefile
 811 data/icons/16x16/apps/Makefile
 812 data/icons/16x16/actions/Makefile
 813 data/icons/16x16/mimetypes/Makefile
 814 data/icons/22x22/Makefile
 815 data/icons/22x22/apps/Makefile
 816 data/icons/22x22/actions/Makefile
 817 data/icons/22x22/mimetypes/Makefile
 818 data/icons/24x24/Makefile
 819 data/icons/24x24/apps/Makefile
 820 data/icons/24x24/actions/Makefile
 821 data/icons/24x24/mimetypes/Makefile
 822 data/icons/32x32/Makefile
 823 data/icons/32x32/actions/Makefile
 824 data/icons/32x32/mimetypes/Makefile
 825 data/icons/48x48/Makefile
 826 data/icons/48x48/apps/Makefile
 827 data/icons/48x48/actions/Makefile
 828 data/icons/scalable/Makefile
 829 data/icons/scalable/apps/Makefile
 830 data/icons/scalable/actions/Makefile
 831 data/icons/scalable/mimetypes/Makefile
 832 help/Makefile
 833 help/reference/Makefile
 834 help/reference/libdocument/Makefile
 835 help/reference/libdocument/version.xml
 836 help/reference/libview/Makefile
 837 help/reference/libview/version.xml
 838 help/reference/shell/Makefile
 839 help/reference/shell/version.xml
 840 libdocument/Makefile
 841 libdocument/ev-version.h
 842 libmisc/Makefile
 843 libview/Makefile
 844 Makefile
 845 po/Makefile.in
 846 previewer/Makefile
 847 properties/Makefile
 848 shell/Makefile
 849 test/Makefile
 850 thumbnailer/Makefile
 851 ])
 852
 853 AC_CONFIG_FILES(evince-document-[]ev_api_version[].pc:evince-document.pc.in)
 854 AC_CONFIG_FILES(evince-view-[]ev_api_version[].pc:evince-view.pc.in)
 855
 856 AC_OUTPUT
 857
 858 echo "
 859 Configure summary:
 860         Platform...........:  $with_platform
 861         GTK+ version.......:  $with_gtk
 862         GConf Support......:  $with_gconf
 863         GTK+ Unix Print....:  $with_gtk_unix_print
 864         Keyring Support....:  $with_keyring
 865         DBUS Support.......:  $enable_dbus
 866         SM client support..:  $with_smclient
 867         Help files.........:  $enable_help
 868         Nautilus Plugin....:  $enable_nautilus
 869         Thumbnailer........:  $enable_thumbnailer
 870         Previewer..........:  $enable_previewer
 871         Gtk-Doc Support....:  $enable_gtk_doc
 872         Debug mode.........:  $enable_debug
 873         GObj. Introspection:  $enable_introspection
 874         Tests..............:  $enable_tests
 875
 876         PDF Backend........:  $enable_pdf
 877         PostScript Backend.:  $enable_ps
 878         TIFF Backend.......:  $enable_tiff
 879         DJVU Backend.......:  $enable_djvu
 880         DVI Backend........:  $enable_dvi
 881         Pixbuf Backend.....:  $enable_pixbuf
 882         Comics Backend.....:  $enable_comics
 883         Impress Backend....:  $enable_impress
 884 "