configure.ac

   1 # *****************************************************************************
   2 # Versioning
   3 # *****************************************************************************
   4
   5 m4_define([ev_major_version],[2])
   6 m4_define([ev_minor_version],[25])
   7 m4_define([ev_micro_version],[90])
   8 m4_define([ev_extra_version],[])
   9 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version()ev_extra_version])
  10
  11 # The evince API version
  12 m4_define([ev_api_version], [2.25])
  13
  14 # Libtool versioning. The backend and view libraries have separate versions.
  15 # Before making a release, the libtool version should be modified.
  16 # The string is of the form C:R:A.
  17 # - If interfaces have been changed or added, but binary compatibility has
  18 #   been preserved, change to C+1:0:A+1
  19 # - If binary compatibility has been broken (eg removed or changed interfaces)
  20 #   change to C+1:0:0
  21 # - If the interface is the same as the previous version, change to C:R+1:A
  22
  23 # Libtool version of the backend library
  24 m4_define([ev_document_lt_current],[1])
  25 m4_define([ev_document_lt_revision],[0])
  26 m4_define([ev_document_lt_age],[0])
  27 m4_define([ev_document_lt_version_info],[ev_document_lt_current:ev_document_lt_revision:ev_document_lt_age])
  28 m4_define([ev_document_lt_current_minus_age],[m4_eval(ev_document_lt_current - ev_document_lt_age)])
  29
  30 # Libtool version of the view library
  31 m4_define([ev_view_lt_current],[1])
  32 m4_define([ev_view_lt_revision],[0])
  33 m4_define([ev_view_lt_age],[0])
  34 m4_define([ev_view_lt_version_info],[ev_view_lt_current:ev_view_lt_revision:ev_view_lt_age])
  35 m4_define([ev_view_lt_current_minus_age],[m4_eval(ev_view_lt_current - ev_view_lt_age)])
  36
  37 # Binary version for the document backends
  38 m4_define([ev_binary_version],[ev_document_lt_current])
  39
  40 # *****************************************************************************
  41
  42 AC_PREREQ([2.57])
  43 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
  44 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-dist-gzip])
  45
  46 AM_CONFIG_HEADER(config.h)
  47
  48 AM_MAINTAINER_MODE
  49
  50 AM_PROG_LIBTOOL
  51
  52 AC_ISC_POSIX
  53 AC_PROG_CC
  54 AM_PROG_CC_STDC
  55 AM_PROG_CC_C_O
  56 AC_PROG_CXX
  57 AC_STDC_HEADERS
  58 IT_PROG_INTLTOOL([0.35.0])
  59 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  60 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  61
  62 GNOME_COMMON_INIT
  63 GNOME_DOC_INIT
  64 GNOME_MAINTAINER_MODE_DEFINES
  65 GNOME_COMPILE_WARNINGS
  66 GNOME_CXX_WARNINGS
  67
  68 GTK_DOC_CHECK(1.0)
  69
  70 GETTEXT_PACKAGE=evince
  71 AC_SUBST(GETTEXT_PACKAGE)
  72 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  73 AM_GLIB_GNU_GETTEXT
  74
  75 dnl check for win32 platform
  76 AC_MSG_CHECKING([for Win32 platform])
  77 case "$host" in
  78   *-*-mingw*|*-*-cygwin*)
  79     platform_win32=yes
  80     AC_CHECK_TOOL(WINDRES, windres)
  81     ;;
  82   *)
  83     platform_win32=no
  84     ;;
  85 esac
  86 AC_MSG_RESULT([$platform_win32])
  87 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
  88
  89 AC_MSG_CHECKING([for native Win32])
  90 case "$host" in
  91   *-*-mingw*)
  92     os_win32=yes
  93     ;;
  94   *)
  95     os_win32=no
  96     ;;
  97 esac
  98 AC_MSG_RESULT([$os_win32])
  99 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 100
 101 dnl Check dependencies
 102
 103 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
 104 # BACKEND_CFLAGS   for backend implementations.
 105 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
 106 # FRONTEND_LIBS
 107 # SHELL_CFLAGS     for shell implementation.
 108 # SHELL_LIBS
 109
 110 DBUS_GLIB_REQUIRED=0.70
 111 GTK_REQUIRED=2.12.0
 112 GLIB_REQUIRED=2.18.0
 113 KEYRING_REQUIRED=2.22.0
 114 AC_SUBST([GLIB_REQUIRED])
 115 AC_SUBST([GTK_REQUIRED])
 116
 117 GNOME_ICON_THEME_REQUIRED=2.17.1
 118 LIBXML_REQUIRED=2.5.0
 119
 120 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
 121 PKG_CHECK_MODULES(LIBVIEW, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 122 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
 123 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 124 PKG_CHECK_MODULES(SHELL_CORE, libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED gthread-2.0)
 125
 126 if test "$os_win32" = no; then
 127         PKG_CHECK_MODULES(SMCLIENT, gtk+-2.0 gthread-2.0 sm >= 1.0.0)
 128 else
 129         PKG_CHECK_MODULES(SMCLIENT, gtk+-2.0 gthread-2.0)
 130 fi
 131
 132 AC_SUBST(SMCLIENT_CFLAGS)
 133 AC_SUBST(SMCLIENT_LIBS)
 134
 135 BACKEND_LIBTOOL_FLAGS="-module -avoid-version -export-symbols \$(top_srcdir)/backend/backend.symbols"
 136 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
 137
 138 dnl ===== Check special functions
 139 evince_save_LIBS=$LIBS
 140 LIBS="$LIBS $BACKEND_LIBS"
 141 AC_CHECK_FUNCS(cairo_format_stride_for_width)
 142 LIBS=$evince_save_LIBS
 143
 144 dnl ========= Check for Keyring
 145 AC_ARG_WITH(keyring,
 146         AC_HELP_STRING([--without-keyring],[disable the use of gnome-keyring]),
 147         [case "${withval}" in
 148         yes) WITH_KEYRING=yes ;;
 149         no) WITH_KEYRING=no ;;
 150         *) AC_MSG_ERROR(bad value ${withval} for --with-keyring) ;;
 151         esac],
 152         [WITH_KEYRING=yes]) dnl Default value
 153 AM_CONDITIONAL(WITH_KEYRING, test x$WITH_KEYRING = "xyes")
 154
 155 if test x$WITH_KEYRING = "xyes"; then
 156         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
 157         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
 158 fi
 159
 160 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
 161 AC_SUBST(GLIB_GENMARSHAL)
 162
 163 dnl ========= Check for DBUS
 164 AC_ARG_ENABLE(dbus,
 165         [AC_HELP_STRING([--enable-dbus], [Compile with support for dbus])],
 166         enable_dbus="$enableval",enable_dbus=yes)
 167 if test "x$enable_dbus" != "xno"; then
 168         PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
 169         [enable_dbus=yes],[enable_dbus=no])
 170
 171         if test "x$enable_dbus" = "xno"; then
 172            AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
 173         fi
 174
 175         if test "x$enable_dbus" = "xyes" ; then
 176                 AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 177
 178                 if test x$DBUS_BINDING_TOOL = "xno" ; then
 179                         AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 180                 fi
 181
 182                 AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 183         fi
 184 fi
 185
 186 AC_SUBST([DBUS_CFLAGS])
 187 AC_SUBST([DBUS_LIBS])
 188
 189 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
 190 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
 191
 192 dnl ========= Check for GConf
 193 AC_ARG_WITH(gconf,
 194         AC_HELP_STRING([--without-gconf],[disable the use of gconf]),
 195         [case "${withval}" in
 196         yes) WITH_GCONF=yes ;;
 197         no) WITH_GCONF=no ;;
 198         *) AC_MSG_ERROR(bad value ${withval} for --with-gconf) ;;
 199         esac],
 200         [WITH_GCONF=yes]) dnl Default value
 201 AM_CONDITIONAL(WITH_GCONF, test x$WITH_GCONF = "xyes")
 202
 203 if test x$WITH_GCONF = "xyes"; then
 204    PKG_CHECK_MODULES(GCONF, gconf-2.0)
 205    AC_DEFINE([WITH_GCONF],[1],[Define if GConf support is enabled])
 206 fi
 207
 208 dnl Debug mode
 209 AC_ARG_ENABLE([debug],
 210         AC_HELP_STRING([--enable-debug],
 211                         [Turn on evince debug mode]),,
 212                 [enable_debug=no])
 213
 214 if test "x$enable_debug" = "xyes"; then
 215    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 216 fi
 217
 218
 219 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 220 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 221 AC_SUBST(LIBDOCUMENT_CFLAGS)
 222 AC_SUBST(LIBDOCUMENT_LIBS)
 223
 224 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $DEBUG_FLAGS"
 225 LIBVIEW_LIBS="$LIBVIEW_LIBS"
 226 AC_SUBST(LIBVIEW_CFLAGS)
 227 AC_SUBST(LIBVIEW_LIBS)
 228
 229 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 230 AC_SUBST(BACKEND_CFLAGS)
 231 AC_SUBST(BACKEND_LIBS)
 232
 233 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS $KEYRING_CFLAGS $GCONF_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 234 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS $KEYRING_LIBS $GCONF_LIBS -lz"
 235 AC_SUBST(SHELL_CFLAGS)
 236 AC_SUBST(SHELL_LIBS)
 237
 238 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 239 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 240 AC_SUBST(FRONTEND_CFLAGS)
 241 AC_SUBST(FRONTEND_LIBS)
 242
 243 dnl Check for Nautilus property page build
 244 AC_ARG_ENABLE(nautilus,
 245         AC_HELP_STRING([--enable-nautilus],[compile the nautilus plugin]),
 246         [case "${enableval}" in
 247         yes) ENABLE_NAUTILUS=yes ;;
 248         no) ENABLE_NAUTILUS=no ;;
 249         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nautilus) ;;
 250         esac],
 251         [ENABLE_NAUTILUS=yes]) dnl Default value
 252
 253 if test x$ENABLE_NAUTILUS = "xyes" ; then
 254         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
 255                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
 256         NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 257         AC_SUBST(NAUTILUS_EXTENSION_DIR)
 258 fi
 259
 260 AC_SUBST(NAUTILUS_CFLAGS)
 261 AC_SUBST(NAUTILUS_LIBS)
 262 if test x$HAVE_NAUTILUS = "xyes"; then
 263         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
 264 fi
 265 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
 266
 267
 268 dnl Check for thumbnailer build
 269 AC_ARG_ENABLE(thumbnailer,
 270         AC_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer]),
 271         [case "${enableval}" in
 272         yes) ENABLE_THUMBNAILER=yes ;;
 273         no) ENABLE_THUMBNAILER=no ;;
 274         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thumbnailer) ;;
 275         esac],
 276         [ENABLE_THUMBNAILER=yes]) dnl Default value
 277 AM_CONDITIONAL(ENABLE_THUMBNAILER, test x$ENABLE_THUMBNAILER = "xyes")
 278
 279 dnl GConf configuration
 280 AM_GCONF_SOURCE_2
 281
 282 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
 283 if test "x$GCONFTOOL" = "xno"; then
 284         AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 285 fi
 286
 287 # ***
 288 # GIR
 289 # ***
 290
 291 AC_MSG_CHECKING([whether GObject introspection is requested])
 292 AC_ARG_ENABLE([introspection],
 293         AS_HELP_STRING([--enable-introspection],[Enable GObject introspection]),
 294         [],[enable_introspection=no])
 295 AC_MSG_RESULT([$enable_introspection])
 296
 297 G_IR_SCANNER=
 298 G_IR_COMPILER=
 299 G_IR_GENERATE=
 300 GIRDIR=
 301 GIRTYPELIBDIR=
 302
 303 if test "$enable_introspection" = "yes"; then
 304   GOBJECT_INTROSPECTION_REQUIRED=0.6
 305   PKG_CHECK_MODULES([GOBJECT_INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
 306
 307   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
 308   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
 309   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
 310   GIRDIR="$($PKG_CONFIG --variable=girdir gobject-introspection-1.0)"
 311   GIRTYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
 312 fi
 313
 314 AC_SUBST([G_IR_SCANNER])
 315 AC_SUBST([G_IR_COMPILER])
 316 AC_SUBST([G_IR_GENERATE])
 317 AC_SUBST([GIRDIR])
 318 AC_SUBST([GIRTYPELIBDIR])
 319
 320 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
 321
 322 dnl ================== portability checks ===========================================
 323
 324 dnl for backtrace()
 325 AC_CHECK_HEADERS([execinfo.h])
 326
 327 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 328   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 329   ],[],[#include <langinfo.h>])
 330
 331 dnl ================== pdf checks ===================================================
 332 AC_ARG_ENABLE(pdf,
 333               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 334
 335 if test "x$enable_pdf" = "xyes"; then
 336     POPPLER_REQUIRED=0.8.0
 337     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED,enable_pdf=yes,enable_pdf=no)
 338
 339     if test "x$enable_pdf" = "xyes"; then
 340             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 341             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 342             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 343
 344             evince_save_LIBS=$LIBS
 345             LIBS="$LIBS $POPPLER_LIBS"
 346             AC_CHECK_FUNCS(poppler_page_render)
 347             AC_CHECK_FUNCS(poppler_layers_iter_new)
 348             LIBS=$evince_save_LIBS
 349
 350             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 351             if test x$enable_cairo_pdf = xyes; then
 352                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 353             fi
 354
 355             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 356             if test x$enable_cairo_ps = xyes; then
 357                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 358             fi
 359     else
 360             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 361     fi
 362 fi
 363
 364 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 365 dnl ================== end of pdf checks ============================================
 366
 367 dnl libspectre (used by ps and dvi backends)
 368 SPECTRE_REQUIRED=0.2.0
 369 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 370 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 371 if test "x$have_spectre" = "xyes"; then
 372    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 373 fi
 374
 375 dnl ================== ps checks ====================================================
 376 AC_ARG_ENABLE(ps,
 377         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 378
 379 if test "x$enable_ps" = "xyes"; then
 380    if test "x$have_spectre" = "xyes"; then
 381       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 382    else
 383       enable_ps="no"
 384       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 385    fi
 386 fi
 387 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 388 dnl ======================== End of ps checks ===================================
 389
 390 dnl ================== tiff checks ===================================================
 391 AC_ARG_ENABLE(tiff,
 392             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 393
 394 if test "x$enable_tiff" = "xyes"; then
 395     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 396     if test "x$enable_tiff" = "xyes"; then
 397         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 398         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 399     fi
 400     if test "x$enable_tiff" = "xyes"; then
 401             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 402     else
 403             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 404     fi
 405 fi
 406
 407 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 408 dnl ================== end of tiff checks ============================================
 409
 410 dnl ================== djvu checks ===================================================
 411
 412 AC_ARG_ENABLE(djvu,
 413             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=yes)
 414
 415 if test "x$enable_djvu" = "xyes"; then
 416     DJVULIBRE_REQUIRED=3.5.17
 417     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 418
 419     if test "x$enable_djvu" = "xyes"; then
 420         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 421     else
 422         AC_MSG_WARN([
 423 ** Djvu support is disabled since a recent version of the djvulibre
 424 ** library was not found. You need at least djvulibre-3.5.17 which
 425 ** can be found on http://djvulibre.djvuzone.org
 426 ])
 427     fi
 428 fi
 429
 430 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 431
 432 dnl ================== End of djvu checks ===================================================
 433
 434 dnl ================== dvi checks ===================================================
 435
 436 AC_ARG_ENABLE(dvi,
 437             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=yes)
 438
 439 AC_ARG_ENABLE(t1lib,
 440             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 441
 442 if test "x$enable_dvi" = "xyes"; then
 443     AC_C_CONST
 444     AC_C_INLINE
 445     AC_TYPE_SIZE_T
 446     AC_CHECK_SIZEOF(long, 4)
 447     AC_CHECK_SIZEOF(int, 4)
 448     AC_CHECK_SIZEOF(short, 2)
 449     AC_CHECK_SIZEOF(void *, 4)
 450     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 451
 452     if test "x$enable_dvi" = "xyes"; then
 453         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 454     else
 455         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 456     fi
 457 fi
 458 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 459
 460 if test "x$enable_dvi" = "xyes"; then
 461     if test "x$enable_type1_fonts" = "xyes"; then
 462         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 463     fi
 464
 465     if test "x$enable_type1_fonts" = xyes; then
 466         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 467     fi
 468 else
 469     enable_type1_fonts=no
 470 fi
 471 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 472
 473 dnl ================== End of dvi checks ===================================================
 474
 475 dnl ================== pixbuf checks ===================================================
 476
 477 AC_ARG_ENABLE(pixbuf,
 478             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 479 if test "x$enable_pixbuf" = "xyes"; then
 480         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 481 fi
 482 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 483
 484 dnl ================== End of pixbuf checks ===================================================
 485
 486 dnl ================== comic book checks ===================================================
 487
 488 AC_ARG_ENABLE(comics,
 489         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=yes)
 490 if test "x$enable_comics" = "xyes"; then
 491         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 492 fi
 493 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 494
 495 dnl ================== End of comic book checks ============================================
 496
 497 dnl ================== impress book checks ===================================================
 498
 499 AC_ARG_ENABLE(impress,
 500         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 501 if test "x$enable_impress" = "xyes"; then
 502         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 503 fi
 504 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 505
 506 dnl ================== End of impress book checks ============================================
 507
 508 dnl =================== Mime types list ====================================================
 509
 510 if test "x$enable_pdf" = "xyes" ; then
 511         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 512 fi
 513 if test "x$enable_ps" = "xyes" ; then
 514         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 515 fi
 516 if test "x$enable_dvi" = "xyes"; then
 517         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 518 fi
 519 if test "x$enable_djvu" = "xyes"; then
 520         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 521 fi
 522 if test "x$enable_tiff" = "xyes"; then
 523         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 524 fi
 525 if test "x$enable_comics" = "xyes"; then
 526         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;"
 527 fi
 528 if test "x$enable_pixbuf" = "xyes"; then
 529         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 530 fi
 531 if test "x$enable_impress" = "xyes"; then
 532         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 533 fi
 534 AC_SUBST(EVINCE_MIME_TYPES)
 535
 536 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 537
 538 # Backends directory
 539
 540 AC_SUBST([backenddir],"\$(libdir)/evince/ev_binary_version/backends")
 541
 542 # Versioning
 543
 544 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
 545 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
 546 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
 547
 548 AC_SUBST([EV_API_VERSION],[ev_api_version])
 549 AC_SUBST([EV_BINARY_VERSION],[ev_binary_version])
 550
 551 AC_SUBST([EV_DOCUMENT_LT_VERSION_INFO],[ev_document_lt_version_info])
 552 AC_SUBST([EV_DOCUMENT_LT_CURRENT_MINUS_AGE],[ev_document_lt_current_minus_age])
 553 AC_SUBST([EV_VIEW_LT_VERSION_INFO],[ev_view_lt_version_info])
 554 AC_SUBST([EV_VIEW_LT_CURRENT_MINUS_AGE],[ev_view_lt_current_minus_age])
 555
 556 # *****************************************************************************
 557
 558 AC_CONFIG_FILES([
 559 backend/Makefile
 560 backend/comics/Makefile
 561 backend/djvu/Makefile
 562 backend/dvi/Makefile
 563 backend/dvi/mdvi-lib/Makefile
 564 backend/impress/Makefile
 565 backend/pdf/Makefile
 566 backend/pixbuf/Makefile
 567 backend/ps/Makefile
 568 backend/tiff/Makefile
 569 cut-n-paste/Makefile
 570 cut-n-paste/evmountoperation/Makefile
 571 cut-n-paste/gedit-message-area/Makefile
 572 cut-n-paste/gimpcellrenderertoggle/Makefile
 573 cut-n-paste/smclient/Makefile
 574 cut-n-paste/toolbar-editor/Makefile
 575 cut-n-paste/zoom-control/Makefile
 576 cut-n-paste/totem-screensaver/Makefile
 577 data/evince.desktop.in
 578 data/Makefile
 579 data/icons/Makefile
 580 data/icons/16x16/Makefile
 581 data/icons/16x16/apps/Makefile
 582 data/icons/16x16/actions/Makefile
 583 data/icons/22x22/Makefile
 584 data/icons/22x22/apps/Makefile
 585 data/icons/22x22/actions/Makefile
 586 data/icons/24x24/Makefile
 587 data/icons/24x24/apps/Makefile
 588 data/icons/24x24/actions/Makefile
 589 data/icons/32x32/Makefile
 590 data/icons/32x32/actions/Makefile
 591 data/icons/48x48/Makefile
 592 data/icons/48x48/apps/Makefile
 593 data/icons/48x48/actions/Makefile
 594 data/icons/scalable/Makefile
 595 data/icons/scalable/apps/Makefile
 596 help/Makefile
 597 help/reference/Makefile
 598 help/reference/libdocument/Makefile
 599 help/reference/libdocument/version.xml
 600 help/reference/libview/Makefile
 601 help/reference/libview/version.xml
 602 help/reference/shell/Makefile
 603 help/reference/shell/version.xml
 604 libdocument/Makefile
 605 libdocument/ev-version.h
 606 libview/Makefile
 607 Makefile
 608 po/Makefile.in
 609 properties/Makefile
 610 shell/Makefile
 611 test/Makefile
 612 thumbnailer/Makefile
 613 ])
 614
 615 AC_CONFIG_FILES(evince-document-[]ev_api_version[].pc:evince-document.pc.in)
 616 AC_CONFIG_FILES(evince-view-[]ev_api_version[].pc:evince-view.pc.in)
 617
 618 AC_OUTPUT
 619
 620 echo "
 621 Configure summary:
 622         GConf Support......:  $WITH_GCONF
 623         Keyring Support....:  $WITH_KEYRING
 624         DBUS Support.......:  $enable_dbus
 625         Nautilus Plugin....:  $HAVE_NAUTILUS
 626         Thumbnailer........:  $ENABLE_THUMBNAILER
 627         Gtk-Doc Support....:  $enable_gtk_doc
 628         Debug mode.........:  $enable_debug
 629         GObj. Introspection:  $enable_introspection
 630
 631         PDF Backend........:  $enable_pdf
 632         PostScript Backend.:  $enable_ps
 633         TIFF Backend.......:  $enable_tiff
 634         DJVU Backend.......:  $enable_djvu
 635         DVI Backend........:  $enable_dvi
 636         Pixbuf Backend.....:  $enable_pixbuf
 637         Comics Backend.....:  $enable_comics
 638         Impress Backend....:  $enable_impress
 639 "