configure.ac

   1 # *****************************************************************************
   2 # Versioning
   3 # *****************************************************************************
   4
   5 m4_define([ev_major_version],[2])
   6 m4_define([ev_minor_version],[91])
   7 m4_define([ev_micro_version],[2])
   8 m4_define([ev_extra_version],[])
   9 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version()ev_extra_version])
  10
  11 # The evince API version
  12 m4_define([ev_api_version], [3.0])
  13
  14 # Libtool versioning. The backend and view libraries have separate versions.
  15 # Before making a release, the libtool version should be modified.
  16 # The string is of the form C:R:A.
  17 # - If interfaces have been changed or added, but binary compatibility has
  18 #   been preserved, change to C+1:0:A+1
  19 # - If binary compatibility has been broken (eg removed or changed interfaces)
  20 #   change to C+1:0:0
  21 # - If the interface is the same as the previous version, change to C:R+1:A
  22
  23 # Libtool version of the backend library
  24 m4_define([ev_document_lt_current],[3])
  25 m4_define([ev_document_lt_revision],[0])
  26 m4_define([ev_document_lt_age],[0])
  27 m4_define([ev_document_lt_version_info],[ev_document_lt_current:ev_document_lt_revision:ev_document_lt_age])
  28 m4_define([ev_document_lt_current_minus_age],[m4_eval(ev_document_lt_current - ev_document_lt_age)])
  29
  30 # Libtool version of the view library
  31 m4_define([ev_view_lt_current],[3])
  32 m4_define([ev_view_lt_revision],[0])
  33 m4_define([ev_view_lt_age],[0])
  34 m4_define([ev_view_lt_version_info],[ev_view_lt_current:ev_view_lt_revision:ev_view_lt_age])
  35 m4_define([ev_view_lt_current_minus_age],[m4_eval(ev_view_lt_current - ev_view_lt_age)])
  36
  37 # Binary version for the document backends
  38 m4_define([ev_binary_version],[ev_document_lt_current])
  39
  40 # *****************************************************************************
  41
  42 AC_PREREQ([2.57])
  43 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
  44 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2 no-dist-gzip])
  45
  46 AC_CONFIG_HEADERS([config.h])
  47 AC_CONFIG_MACRO_DIR([m4])
  48
  49 if test -z "$enable_maintainer_mode"; then
  50   enable_maintainer_mode=yes
  51 fi
  52 AM_MAINTAINER_MODE([enable])
  53
  54 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  55
  56 AM_PROG_LIBTOOL
  57
  58 AC_ISC_POSIX
  59 AC_PROG_CC
  60 AM_PROG_CC_STDC
  61 AM_PROG_CC_C_O
  62 AC_PROG_CXX
  63 AC_STDC_HEADERS
  64
  65 AC_PROG_SED
  66 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  67 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  68
  69 GNOME_MAINTAINER_MODE_DEFINES
  70 GNOME_COMPILE_WARNINGS
  71 GNOME_CXX_WARNINGS
  72
  73 dnl FIXME: remove this when required gtk+ >= 2.19.7
  74 DISABLE_DEPRECATED=
  75 AC_SUBST([DISABLE_DEPRECATED])
  76
  77 IT_PROG_INTLTOOL([0.35.0])
  78
  79 GETTEXT_PACKAGE=evince
  80 AC_SUBST(GETTEXT_PACKAGE)
  81 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  82 AM_GLIB_GNU_GETTEXT
  83
  84 m4_pattern_allow([AM_V_GEN])dnl Make autoconf not complain about the rule below
  85 EV_INTLTOOL_EVINCE_BACKEND_RULE='%.evince-backend:   %.evince-backend.in   $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; $(AM_V_GEN) LC_ALL=C $(INTLTOOL_MERGE) -d -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@'
  86 AC_SUBST([EV_INTLTOOL_EVINCE_BACKEND_RULE])
  87
  88 GLIB_GSETTINGS
  89
  90 # Check which platform to use
  91
  92 AC_MSG_CHECKING([for which platform to build])
  93 AC_ARG_WITH([platform],
  94   [AS_HELP_STRING([--with-platform=gnome|win32|hildon],
  95                   [Setting platform (default: gnome)])],
  96   [case "$withval" in
  97     gnome|win32|hildon) ;;
  98     *) AC_MSG_ERROR([invalid argument "$withval" for --with-platform]) ;;
  99    esac],
 100   [case "$host" in
 101      *-*-mingw*|*-*-cygwin*) with_platform="win32" ;;
 102      *) with_platform=gnome ;;
 103    esac])
 104
 105 AC_MSG_RESULT([$with_platform])
 106
 107 if test "$with_platform" = "win32"; then
 108   AC_CHECK_TOOL([WINDRES],[windres])
 109   AC_MSG_CHECKING([for native Win32])
 110   case "$host" in
 111     *-*-mingw*)
 112       os_win32=yes
 113       ;;
 114     *)
 115       os_win32=no
 116       ;;
 117   esac
 118   AC_MSG_RESULT([$os_win32])
 119 fi
 120
 121 AM_CONDITIONAL([PLATFORM_HILDON],[test "$with_platform" = "hildon"])
 122 AM_CONDITIONAL([PLATFORM_WIN32],[test "$with_platform" = "win32"])
 123
 124 dnl Specify required versions of dependencies
 125 CAIRO_REQUIRED=1.10.0
 126 GLIB_REQUIRED=2.25.11
 127 KEYRING_REQUIRED=2.22.0
 128 GTK_REQUIRED=2.91.3
 129
 130 AC_SUBST([GLIB_REQUIRED])
 131 AC_SUBST([GTK_REQUIRED])
 132
 133 GNOME_ICON_THEME_REQUIRED=2.17.1
 134 LIBXML_REQUIRED=2.5.0
 135
 136 dnl Check dependencies
 137
 138 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
 139 # BACKEND_CFLAGS   for backend implementations.
 140 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
 141 # FRONTEND_LIBS
 142 # SHELL_CFLAGS     for shell implementation.
 143 # SHELL_LIBS
 144
 145
 146 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-3.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
 147 PKG_CHECK_MODULES(LIBVIEW, gtk+-3.0 >= $GTK_REQUIRED gail-3.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 148 PKG_CHECK_MODULES(BACKEND, cairo >= $CAIRO_REQUIRED gtk+-3.0 >= $GTK_REQUIRED)
 149 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-3.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 150
 151 SHELL_PLATFORM_PKGS=
 152 case "$with_platform" in
 153   hildon) AC_DEFINE([PLATFORM_HILDON],[1],[Define if building for the hildon platform])
 154           SHELL_PLATFORM_PKGS="hildon-1 hildon-fm-2 libosso"
 155           ;;
 156   gnome)
 157         # Evince has a rather soft run-time dependency on hicolor-icon-theme.
 158         # If the hicolor theme is not available, Evince fails to display some
 159         # icons. Because we cannot check for it at run-time, we instead
 160         # would like to require the icon theme at compile-time. But, because
 161         # the hicolor-icon-theme does not have a pkgconfig file, on gnome we
 162         # require the gnome icon theme instead.
 163         SHELL_PLATFORM_PKGS="gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED"
 164         # The totem-screensaver and egg_smclient code use x11 directly.
 165         SHELL_PLATFORM_PKGS="$SHELL_PLATFORM_PKGS x11"
 166         ;;
 167   *)
 168         # On all other platforms we issue a warning about the runtime
 169         # dependency.
 170         AC_MSG_WARN([Evince has a soft run-time dependency on hicolor-icon-theme. You are advised to have this theme installed when running Evince.]);
 171         SHELL_PLATFORM_PKGS=""
 172         ;;
 173 esac
 174
 175 PKG_CHECK_MODULES([SHELL_CORE],[libxml-2.0 >= $LIBXML_REQUIRED gtk+-3.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gthread-2.0 $SHELL_PLATFORM_PKGS])
 176
 177 # *********
 178 # SM client
 179 # *********
 180
 181 GDK_TARGET="$($PKG_CONFIG --variable target gdk-3.0)"
 182
 183 AC_MSG_CHECKING([which smclient backend to use])
 184 AC_ARG_WITH([smclient],
 185   [AS_HELP_STRING([--with-smclient-backend=no|xsmp|win32|quartz],
 186                   [Setting smclient backend (default:auto)])],
 187   [],
 188   [case "$GDK_TARGET" in
 189     x11) case "$with_platform" in
 190            gnome) with_smclient=xsmp ;;
 191            *) with_smclient=no ;;
 192          esac ;;
 193     win32|quartz) with_smclient=$GDK_TARGET ;;
 194     *) with_smclient=no ;;
 195    esac])
 196
 197 AC_MSG_RESULT([$with_smclient])
 198
 199 if test "$with_smclient" != "no"; then
 200   AC_DEFINE([WITH_SMCLIENT],[1],[Define if smclient is enabled])
 201
 202   case "$with_smclient" in
 203     xsmp) SMCLIENT_PKGS="sm >= 1.0.0" ;;
 204     *) SMCLIENT_PKGS="" ;;
 205   esac
 206
 207   PKG_CHECK_MODULES([SMCLIENT],[gtk+-3.0 gthread-2.0 $SMCLIENT_PKGS])
 208   AC_SUBST([SMCLIENT_CFLAGS])
 209   AC_SUBST([SMCLIENT_LIBS])
 210 fi
 211
 212 AM_CONDITIONAL([WITH_SMCLIENT],[test "$with_smclient" != "no"])
 213 AM_CONDITIONAL([WITH_SMCLIENT_XSMP],[test "$with_smclient" = "xsmp"])
 214 AM_CONDITIONAL([WITH_SMCLIENT_WIN32],[test "$with_smclient" = "win32"])
 215 AM_CONDITIONAL([WITH_SMCLIENT_QUARTZ],[test "$with_smclient" = "quartz"])
 216
 217 # ***
 218
 219 BACKEND_LIBTOOL_FLAGS="-module -avoid-version -no-undefined -export-symbols \$(top_srcdir)/backend/backend.symbols"
 220 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
 221
 222 dnl ===== Check special functions
 223 evince_save_LIBS=$LIBS
 224 LIBS="$LIBS $BACKEND_LIBS"
 225 AC_CHECK_FUNCS(cairo_format_stride_for_width)
 226 LIBS=$evince_save_LIBS
 227
 228 # ******************
 229 # GKT+ Unix Printing
 230 # ******************
 231
 232 AC_MSG_CHECKING([whether gtk+-unix-print support is requested])
 233 AC_ARG_WITH([gtk-unix-print],
 234   [AS_HELP_STRING([--without-gtk-unix-print],
 235                   [Disable the use of gtk-unix-print])],
 236   [],[case "$os_win32" in
 237         yes) with_gtk_unix_print=no ;;
 238         *) with_gtk_unix_print=yes ;;
 239       esac])
 240
 241 AC_MSG_RESULT([$with_gtk_unix_print])
 242
 243 if test "$with_gtk_unix_print" = "yes"; then
 244    PKG_CHECK_MODULES(GTKUNIXPRINT, [gtk+-unix-print-3.0 >= $GTK_REQUIRED])
 245    AC_DEFINE([GTKUNIXPRINT_ENABLED], [1], [Define if gtk+-unix-print is enabled.])
 246 fi
 247
 248 # *********************
 249 # GNOME Keyring support
 250 # *********************
 251
 252 AC_ARG_WITH(keyring,
 253         [AS_HELP_STRING([--without-keyring],
 254                         [Disable the use of gnome-keyring])],
 255         [],
 256         [case "$with_platform" in
 257            gnome) with_keyring=yes ;;
 258            hildon|win32) with_keyring=no ;;
 259          esac])
 260
 261 AM_CONDITIONAL([WITH_KEYRING],[test "$with_keyring" = "yes"])
 262
 263 if test "$with_keyring" = "yes"; then
 264         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
 265         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
 266 fi
 267
 268 # ****
 269 # DBUS
 270 # ****
 271
 272 AC_ARG_ENABLE([dbus],
 273   [AS_HELP_STRING([--disable-dbus], [Disable support for dbus])],
 274   [],
 275   [case "$with_platform" in
 276       gnome) enable_dbus=yes ;;
 277       hildon) enable_dbus=no ;;
 278     esac])
 279
 280 if test "$enable_dbus" = "yes"; then
 281   AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 282
 283    PKG_CHECK_MODULES([EV_DAEMON], [gio-2.0 >= $GLIB_REQUIRED])
 284 fi
 285
 286 AM_CONDITIONAL([ENABLE_DBUS], [test "$enable_dbus" = "yes"])
 287
 288 dnl ========= Check for Desktop Schemas
 289 PKG_CHECK_MODULES([DESKTOP_SCHEMAS], [gsettings-desktop-schemas],
 290                   has_desktop_schemas=yes, has_desktop_schemas=no)
 291 if test x$has_desktop_schemas = xyes; then
 292    AC_DEFINE([HAVE_DESKTOP_SCHEMAS], [1], [Whether GSettings Desktop Schemas are available])
 293 fi
 294
 295 dnl ========= Check for GConf
 296
 297 AC_MSG_CHECKING([whether GConf support is requested])
 298 AC_ARG_WITH([gconf],
 299   [AS_HELP_STRING([--without-gconf],
 300                   [Disable the use of gconf])],
 301   [],
 302   [case "$os_win32" in
 303      yes) with_gconf=no ;;
 304      *) with_gconf=yes ;;
 305    esac])
 306 AC_MSG_RESULT([$with_gconf])
 307
 308 AM_CONDITIONAL([WITH_GCONF],[test "$with_gconf" = "yes"])
 309
 310 if test "$with_gconf" = "yes"; then
 311    PKG_CHECK_MODULES([GCONF],[gconf-2.0])
 312    AC_DEFINE([WITH_GCONF],[1],[Define if GConf support is enabled])
 313
 314    AM_GCONF_SOURCE_2
 315
 316    AC_PATH_PROG([GCONFTOOL], [gconftool-2], [false])
 317    if test "$GCONFTOOL" = "false"; then
 318       AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 319    fi
 320 else
 321    AM_CONDITIONAL([GCONF_SCHEMAS_INSTALL],false)
 322 fi
 323
 324 dnl Debug mode
 325
 326 AC_ARG_ENABLE([debug],
 327         AS_HELP_STRING([--enable-debug],
 328                        [Turn on evince debug mode]),
 329         [enable_debug=$enableval],
 330         [enable_debug=no])
 331
 332 if test "x$enable_debug" = "xyes"; then
 333    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 334 fi
 335
 336 AC_ARG_ENABLE([tests],
 337         AS_HELP_STRING([--enable-tests], [Enable the tests]),
 338         [enable_tests=$enableval],
 339         [enable_tests=yes])
 340
 341 AM_CONDITIONAL(ENABLE_TESTS, test x$enable_tests = xyes)
 342
 343 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 344 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 345 AC_SUBST(LIBDOCUMENT_CFLAGS)
 346 AC_SUBST(LIBDOCUMENT_LIBS)
 347
 348 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 349 LIBVIEW_LIBS="$LIBVIEW_LIBS $GTKUNIXPRINT_LIBS -lm"
 350 AC_SUBST(LIBVIEW_CFLAGS)
 351 AC_SUBST(LIBVIEW_LIBS)
 352
 353 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 354 BACKEND_LIBS="$BACKEND_LIBS -lm"
 355 AC_SUBST(BACKEND_CFLAGS)
 356 AC_SUBST(BACKEND_LIBS)
 357
 358 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $KEYRING_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 359 SHELL_LIBS="$SHELL_CORE_LIBS $KEYRING_LIBS -lz -lm"
 360 AC_SUBST(SHELL_CFLAGS)
 361 AC_SUBST(SHELL_LIBS)
 362
 363 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 364 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 365 AC_SUBST(FRONTEND_CFLAGS)
 366 AC_SUBST(FRONTEND_LIBS)
 367
 368 EV_DAEMON_CFLAGS="$EV_DAEMON_CFLAGS $DEBUG_FLAGS"
 369 AC_SUBST([EV_DAEMON_CFLAGS])
 370 AC_SUBST([EV_DAEMON_LIBS])
 371
 372 # Check for Nautilus property page build
 373 AC_ARG_ENABLE([nautilus],
 374   [AS_HELP_STRING([--disable-nautilus],
 375                   [Disable build of nautilus extensions])],
 376   [],
 377   [case "$with_platform" in
 378      gnome) enable_nautilus=yes ;;
 379      *) enable_nautilus=no ;;
 380     esac])
 381
 382 if test "$enable_nautilus" = "yes" ; then
 383   PKG_CHECK_MODULES([NAUTILUS],[gtk+-x11-3.0 $MM gthread-2.0 libnautilus-extension],
 384                     [],[AC_MSG_ERROR([libnautilus-extension not found; use --disable-nautilus to disable the nautilus extensions])])
 385   NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 386   AC_SUBST([nautilusextensiondir],[$NAUTILUS_EXTENSION_DIR])
 387   AC_SUBST(NAUTILUS_CFLAGS)
 388   AC_SUBST(NAUTILUS_LIBS)
 389
 390   AC_DEFINE([HAVE_NAUTILUS],[1], [defined if you build the nautilus plugin])
 391 fi
 392
 393 AM_CONDITIONAL([ENABLE_NAUTILUS],[test "$enable_nautilus" = "yes"])
 394
 395 # Check for thumbnailer build
 396
 397 AC_ARG_ENABLE([thumbnailer],
 398   [AS_HELP_STRING([--disable-thumbnailer],
 399                   [Disable GNOME thumbnailer])],
 400   [],
 401   [case "$with_platform" in
 402      hildon) enable_thumbnailer=no ;;
 403      *) enable_thumbnailer=yes ;;
 404     esac])
 405
 406 AM_CONDITIONAL([ENABLE_THUMBNAILER],[test "$enable_thumbnailer" = "yes"])
 407
 408 # ***************
 409 # Print Previewer
 410 # ***************
 411
 412 AC_ARG_ENABLE([previewer],
 413   [AS_HELP_STRING([--disable-previewer],
 414                   [Disable the GNOME Document Previewer])],
 415   [],
 416   [case "$with_platform" in
 417       hildon) enable_previewer=no ;;
 418       *) enable_previewer=yes ;;
 419     esac])
 420
 421 if test x$enable_previewer = "xyes" ; then
 422   PKG_CHECK_MODULES([PREVIEWER],[gtk+-3.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED])
 423 fi
 424
 425 AM_CONDITIONAL([ENABLE_PREVIEWER],[test "$enable_previewer" = "yes"])
 426 PREVIEWER_CFLAGS="$PREVIEWER_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 427 PREVIEWER_LIBS="$PREVIEWER_LIBS $GTKUNIXPRINT_LIBS -lz"
 428 AC_SUBST(PREVIEWER_CFLAGS)
 429 AC_SUBST(PREVIEWER_LIBS)
 430
 431 # ***
 432 # GIR
 433 # ***
 434
 435 AC_MSG_CHECKING([whether GObject introspection is requested])
 436 AC_ARG_ENABLE([introspection],
 437         AS_HELP_STRING([--enable-introspection],
 438                        [Enable GObject introspection]),
 439         [enable_introspection=$enableval],
 440         [enable_introspection=no])
 441 AC_MSG_RESULT([$enable_introspection])
 442
 443 G_IR_SCANNER=
 444 G_IR_COMPILER=
 445 G_IR_GENERATE=
 446 GIRDIR=
 447 GIRTYPELIBDIR=
 448
 449 if test "$enable_introspection" = "yes"; then
 450   GOBJECT_INTROSPECTION_REQUIRED=0.6
 451   PKG_CHECK_MODULES([GOBJECT_INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
 452
 453   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
 454   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
 455   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
 456   GIRDIR="$($PKG_CONFIG --variable=girdir gobject-introspection-1.0)"
 457   GIRTYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
 458 fi
 459
 460 AC_SUBST([G_IR_SCANNER])
 461 AC_SUBST([G_IR_COMPILER])
 462 AC_SUBST([G_IR_GENERATE])
 463 AC_SUBST([GIRDIR])
 464 AC_SUBST([GIRTYPELIBDIR])
 465
 466 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
 467
 468 dnl ================== portability checks ===========================================
 469
 470 dnl for backtrace()
 471 AC_CHECK_HEADERS([execinfo.h])
 472
 473 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 474   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 475   ],[],[#include <langinfo.h>])
 476
 477 dnl ================== pdf checks ===================================================
 478 AC_ARG_ENABLE([pdf],
 479   [AS_HELP_STRING([--disable-pdf],
 480                   [Disable the PDF support])],
 481   [enable_pdf=$enableval],
 482   [enable_pdf=yes])
 483
 484 if test "x$enable_pdf" = "xyes"; then
 485     POPPLER_REQUIRED=0.14.0
 486     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED,enable_pdf=yes,enable_pdf=no)
 487
 488     if test "x$enable_pdf" = "xyes"; then
 489             evince_save_LIBS=$LIBS
 490             LIBS="$LIBS $POPPLER_LIBS"
 491             AC_CHECK_FUNCS(poppler_page_get_text_layout)
 492             AC_CHECK_FUNCS(poppler_page_get_selected_text)
 493             AC_CHECK_FUNCS(poppler_page_add_annot)
 494             AC_CHECK_FUNCS(poppler_document_is_linearized)
 495             LIBS=$evince_save_LIBS
 496             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 497             if test x$enable_cairo_pdf = xyes; then
 498                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 499             fi
 500
 501             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 502             if test x$enable_cairo_ps = xyes; then
 503                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 504             fi
 505     else
 506             AC_MSG_ERROR("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 507     fi
 508 fi
 509
 510 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 511 dnl ================== end of pdf checks ============================================
 512
 513 dnl libspectre (used by ps and dvi backends)
 514 SPECTRE_REQUIRED=0.2.0
 515 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 516 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 517 if test "x$have_spectre" = "xyes"; then
 518    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 519 fi
 520
 521 dnl ================== ps checks ====================================================
 522 AC_ARG_ENABLE(ps,
 523         [AS_HELP_STRING([--disable-ps],
 524                         [Disable the PostScript backend])],
 525         [enable_ps=$enableval],
 526         [enable_ps=yes])
 527
 528 if test "x$enable_ps" = "xyes"; then
 529    if test "x$have_spectre" = "xyes"; then
 530       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 531    else
 532       enable_ps="no"
 533       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 534    fi
 535 fi
 536 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 537 dnl ======================== End of ps checks ===================================
 538
 539 dnl ================== tiff checks ===================================================
 540 AC_ARG_ENABLE(tiff,
 541             [AS_HELP_STRING([--disable-tiff],
 542                             [Disable the support of multipage tiff])],
 543             [enable_tiff=$enableval],
 544             [enable_tiff=yes])
 545
 546 if test "x$enable_tiff" = "xyes"; then
 547     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 548     if test "x$enable_tiff" = "xyes"; then
 549         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 550         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 551     fi
 552     if test "x$enable_tiff" = "xyes"; then
 553             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 554     else
 555             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 556     fi
 557 fi
 558
 559 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 560 dnl ================== end of tiff checks ============================================
 561
 562 dnl ================== djvu checks ===================================================
 563
 564 AC_ARG_ENABLE(djvu,
 565             [AS_HELP_STRING([--disable-djvu],
 566                             [Disable the support of djvu viewer])],
 567             [enable_djvu=$enableval],
 568             [enable_djvu=yes])
 569
 570 if test "x$enable_djvu" = "xyes"; then
 571     DJVULIBRE_REQUIRED=3.5.17
 572     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 573
 574     if test "x$enable_djvu" = "xyes"; then
 575         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 576     else
 577         AC_MSG_WARN([
 578 ** Djvu support is disabled since a recent version of the djvulibre
 579 ** library was not found. You need at least djvulibre-3.5.17 which
 580 ** can be found on http://djvulibre.djvuzone.org
 581 ])
 582     fi
 583 fi
 584
 585 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 586
 587 dnl ================== End of djvu checks ===================================================
 588
 589 dnl ================== dvi checks ===================================================
 590
 591 AC_ARG_ENABLE(dvi,
 592             [AS_HELP_STRING([--disable-dvi],
 593             [Disable the support of dvi viewer])],
 594             [enable_dvi=$enableval],
 595             [enable_dvi=yes])
 596
 597 AC_ARG_ENABLE(t1lib,
 598             [AS_HELP_STRING([--enable-t1lib],
 599                             [Compile with support of t1lib for type1 fonts in dvi])],
 600             [enable_type1_fonts=$enableval],
 601             [enable_type1_fonts=no])
 602
 603 if test "x$enable_dvi" = "xyes"; then
 604     AC_C_CONST
 605     AC_C_INLINE
 606     AC_TYPE_SIZE_T
 607     AC_CHECK_SIZEOF(long, 4)
 608     AC_CHECK_SIZEOF(int, 4)
 609     AC_CHECK_SIZEOF(short, 2)
 610     AC_CHECK_SIZEOF(void *, 4)
 611     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 612
 613     if test "x$enable_dvi" = "xyes"; then
 614         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 615     else
 616         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 617     fi
 618 fi
 619 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 620
 621 if test "x$enable_dvi" = "xyes"; then
 622     if test "x$enable_type1_fonts" = "xyes"; then
 623         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 624     fi
 625
 626     if test "x$enable_type1_fonts" = xyes; then
 627         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 628     fi
 629 else
 630     enable_type1_fonts=no
 631 fi
 632 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 633
 634 dnl ================== End of dvi checks ===================================================
 635
 636 dnl ================== pixbuf checks ===================================================
 637
 638 AC_ARG_ENABLE(pixbuf,
 639             [AS_HELP_STRING([--enable-pixbuf],
 640                             [Compile with support of pixbuf])],
 641             [enable_pixbuf=$enableval],
 642             [enable_pixbuf=no])
 643
 644 if test "x$enable_pixbuf" = "xyes"; then
 645         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 646 fi
 647
 648 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 649
 650 dnl ================== End of pixbuf checks ===================================================
 651
 652 dnl ================== comic book checks ===================================================
 653
 654 AC_ARG_ENABLE(comics,
 655         [AS_HELP_STRING([--enable-comics],
 656                         [Compile with support for comic book archives])],
 657         [enable_comics=$enableval],
 658         [enable_comics=yes])
 659
 660 if test "x$enable_comics" = "xyes"; then
 661         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 662 fi
 663 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 664
 665 dnl ================== End of comic book checks ============================================
 666
 667 dnl ================== XPS checks ===================================================
 668
 669 AC_ARG_ENABLE(xps,
 670         [AS_HELP_STRING([--enable-xps],
 671                         [Compile with support for XPS documents.])],
 672         [enable_xps=$enableval],
 673         [enable_xps=yes])
 674
 675 if test "x$enable_xps" = "xyes"; then
 676    GXPS_REQUIRED=0.0.1
 677    PKG_CHECK_MODULES(GXPS, libgxps >= $GXPS_REQUIRED,enable_xps=yes,enable_xps=no)
 678
 679    if test "x$enable_xps" = "xyes"; then
 680       AC_DEFINE([ENABLE_XPS], [1], [Enable support for XPS documents.])
 681    else
 682       enable_xps="no"
 683       AC_MSG_WARN(["XPS support is disabled since libgxps (version >= $GXPS_REQUIRED) is needed])
 684    fi
 685 fi
 686
 687 AM_CONDITIONAL(ENABLE_XPS, test x$enable_xps = xyes)
 688
 689 dnl ================== End of XPS checks ===================================================
 690
 691 dnl =================== Mime types list ====================================================
 692
 693 if test "x$enable_pdf" = "xyes" ; then
 694         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 695 fi
 696 if test "x$enable_ps" = "xyes" ; then
 697         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 698 fi
 699 if test "x$enable_dvi" = "xyes"; then
 700         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 701 fi
 702 if test "x$enable_djvu" = "xyes"; then
 703         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 704 fi
 705 if test "x$enable_tiff" = "xyes"; then
 706         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 707 fi
 708 if test "x$enable_comics" = "xyes"; then
 709         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;application/x-cbt;"
 710 fi
 711 if test "x$enable_pixbuf" = "xyes"; then
 712         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 713 fi
 714 if test "x$enable_xps" = "xyes"; then
 715         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/oxps;application/vnd.ms-xpsdocument;"
 716 fi
 717 AC_SUBST(EVINCE_MIME_TYPES)
 718
 719 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 720
 721 # *****************
 722 # Help files
 723 # *****************
 724
 725 GNOME_DOC_INIT([], gnome_doc_utils=yes, gnome_doc_utils=no)
 726
 727 AC_ARG_ENABLE(help,
 728     [AS_HELP_STRING([--disable-help], [Disable offline help files])],
 729     [enable_help=$enableval],
 730     [enable_help=yes])
 731
 732 if test "x$enable_help" = "xyes" && test "x$os_win32" = "xyes" ; then
 733     AC_MSG_WARN([Offline help is disabled (not implemented on Windows).])
 734     enable_help=no
 735 fi
 736
 737 if test "x$enable_help" = "xyes" && test "x$gnome_doc_utils" == "xno"; then
 738     AC_MSG_ERROR(
 739        [gnome-doc-utils not found; use --disable-help to disable help files]
 740     )
 741 fi
 742
 743 if test "x$enable_help" = "xyes"; then
 744     AC_DEFINE([OFFLINE_HELP_ENABLED], [1], [Enable offline help])
 745 fi
 746
 747 AM_CONDITIONAL(ENABLE_HELP, test "x$enable_help" = "xyes")
 748
 749 # *****************
 750 # API documentation
 751 # *****************
 752
 753 GTK_DOC_CHECK([1.13],[--flavour no-tmpl])
 754
 755 AC_SUBST([GLIB_PREFIX],[$($PKG_CONFIG --variable=prefix glib-2.0)])
 756 AC_SUBST([GTK_PREFIX],[$($PKG_CONFIG --variable=prefix gtk+-3.0)])
 757
 758 # ******************
 759 # Backends directory
 760 # ******************
 761
 762 AC_SUBST([backenddir],"\$(libdir)/evince/ev_binary_version/backends")
 763 AC_SUBST([backend_binary_version],"ev_binary_version")
 764
 765 # **********
 766 # Versioning
 767 # **********
 768
 769 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
 770 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
 771 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
 772
 773 AC_SUBST([EV_API_VERSION],[ev_api_version])
 774 AC_SUBST([EV_API_VERSION_U],[AS_TR_SH([ev_api_version])])
 775 AC_SUBST([EV_BINARY_VERSION],[ev_binary_version])
 776
 777 AC_SUBST([EV_DOCUMENT_LT_VERSION_INFO],[ev_document_lt_version_info])
 778 AC_SUBST([EV_DOCUMENT_LT_CURRENT_MINUS_AGE],[ev_document_lt_current_minus_age])
 779 AC_SUBST([EV_VIEW_LT_VERSION_INFO],[ev_view_lt_version_info])
 780 AC_SUBST([EV_VIEW_LT_CURRENT_MINUS_AGE],[ev_view_lt_current_minus_age])
 781
 782 # *****************************************************************************
 783 # *****************************************************************************
 784
 785 AC_CONFIG_FILES([
 786 backend/Makefile
 787 backend/comics/Makefile
 788 backend/djvu/Makefile
 789 backend/dvi/Makefile
 790 backend/dvi/mdvi-lib/Makefile
 791 backend/pdf/Makefile
 792 backend/pixbuf/Makefile
 793 backend/ps/Makefile
 794 backend/tiff/Makefile
 795 backend/xps/Makefile
 796 cut-n-paste/Makefile
 797 cut-n-paste/gimpcellrenderertoggle/Makefile
 798 cut-n-paste/smclient/Makefile
 799 cut-n-paste/toolbar-editor/Makefile
 800 cut-n-paste/zoom-control/Makefile
 801 cut-n-paste/totem-screensaver/Makefile
 802 cut-n-paste/synctex/Makefile
 803 data/evince.desktop.in
 804 data/Makefile
 805 data/icons/Makefile
 806 data/icons/16x16/Makefile
 807 data/icons/16x16/apps/Makefile
 808 data/icons/16x16/actions/Makefile
 809 data/icons/16x16/mimetypes/Makefile
 810 data/icons/22x22/Makefile
 811 data/icons/22x22/apps/Makefile
 812 data/icons/22x22/actions/Makefile
 813 data/icons/22x22/mimetypes/Makefile
 814 data/icons/24x24/Makefile
 815 data/icons/24x24/apps/Makefile
 816 data/icons/24x24/actions/Makefile
 817 data/icons/24x24/mimetypes/Makefile
 818 data/icons/32x32/Makefile
 819 data/icons/32x32/actions/Makefile
 820 data/icons/32x32/mimetypes/Makefile
 821 data/icons/48x48/Makefile
 822 data/icons/48x48/apps/Makefile
 823 data/icons/48x48/actions/Makefile
 824 data/icons/scalable/Makefile
 825 data/icons/scalable/apps/Makefile
 826 data/icons/scalable/actions/Makefile
 827 data/icons/scalable/mimetypes/Makefile
 828 help/Makefile
 829 help/reference/Makefile
 830 help/reference/libdocument/Makefile
 831 help/reference/libdocument/version.xml
 832 help/reference/libview/Makefile
 833 help/reference/libview/version.xml
 834 help/reference/shell/Makefile
 835 help/reference/shell/version.xml
 836 libdocument/Makefile
 837 libdocument/ev-version.h
 838 libmisc/Makefile
 839 libview/Makefile
 840 Makefile
 841 po/Makefile.in
 842 previewer/Makefile
 843 properties/Makefile
 844 shell/Makefile
 845 test/Makefile
 846 thumbnailer/Makefile
 847 ])
 848
 849 AC_CONFIG_FILES(evince-document-[]ev_api_version[].pc:evince-document.pc.in)
 850 AC_CONFIG_FILES(evince-view-[]ev_api_version[].pc:evince-view.pc.in)
 851
 852 AC_OUTPUT
 853
 854 echo "
 855 Configure summary:
 856         Platform...........:  $with_platform
 857         GConf Support......:  $with_gconf
 858         GTK+ Unix Print....:  $with_gtk_unix_print
 859         Keyring Support....:  $with_keyring
 860         DBUS Support.......:  $enable_dbus
 861         SM client support..:  $with_smclient
 862         Help files.........:  $enable_help
 863         Nautilus Plugin....:  $enable_nautilus
 864         Thumbnailer........:  $enable_thumbnailer
 865         Previewer..........:  $enable_previewer
 866         Gtk-Doc Support....:  $enable_gtk_doc
 867         Debug mode.........:  $enable_debug
 868         GObj. Introspection:  $enable_introspection
 869         Tests..............:  $enable_tests
 870
 871         PDF Backend........:  $enable_pdf
 872         PostScript Backend.:  $enable_ps
 873         TIFF Backend.......:  $enable_tiff
 874         DJVU Backend.......:  $enable_djvu
 875         DVI Backend........:  $enable_dvi
 876         Pixbuf Backend.....:  $enable_pixbuf
 877         Comics Backend.....:  $enable_comics
 878         XPS Backend........:  $enable_xps
 879 "