configure.ac

   1 # *****************************************************************************
   2 # Versioning
   3 # *****************************************************************************
   4
   5 m4_define([ev_major_version],[2])
   6 m4_define([ev_minor_version],[31])
   7 m4_define([ev_micro_version],[6])
   8 m4_define([ev_extra_version],[1])
   9 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version().ev_extra_version])
  10
  11 # The evince API version
  12 m4_define([ev_api_version], [2.30])
  13
  14 # Libtool versioning. The backend and view libraries have separate versions.
  15 # Before making a release, the libtool version should be modified.
  16 # The string is of the form C:R:A.
  17 # - If interfaces have been changed or added, but binary compatibility has
  18 #   been preserved, change to C+1:0:A+1
  19 # - If binary compatibility has been broken (eg removed or changed interfaces)
  20 #   change to C+1:0:0
  21 # - If the interface is the same as the previous version, change to C:R+1:A
  22
  23 # Libtool version of the backend library
  24 m4_define([ev_document_lt_current],[2])
  25 m4_define([ev_document_lt_revision],[0])
  26 m4_define([ev_document_lt_age],[0])
  27 m4_define([ev_document_lt_version_info],[ev_document_lt_current:ev_document_lt_revision:ev_document_lt_age])
  28 m4_define([ev_document_lt_current_minus_age],[m4_eval(ev_document_lt_current - ev_document_lt_age)])
  29
  30 # Libtool version of the view library
  31 m4_define([ev_view_lt_current],[2])
  32 m4_define([ev_view_lt_revision],[0])
  33 m4_define([ev_view_lt_age],[0])
  34 m4_define([ev_view_lt_version_info],[ev_view_lt_current:ev_view_lt_revision:ev_view_lt_age])
  35 m4_define([ev_view_lt_current_minus_age],[m4_eval(ev_view_lt_current - ev_view_lt_age)])
  36
  37 # Binary version for the document backends
  38 m4_define([ev_binary_version],[ev_document_lt_current])
  39
  40 # *****************************************************************************
  41
  42 AC_PREREQ([2.57])
  43 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
  44 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2 no-dist-gzip])
  45
  46 AC_CONFIG_HEADERS([config.h])
  47 AC_CONFIG_MACRO_DIR([m4])
  48
  49 if test -z "$enable_maintainer_mode"; then
  50   enable_maintainer_mode=yes
  51 fi
  52 AM_MAINTAINER_MODE([enable])
  53
  54 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  55
  56 AM_PROG_LIBTOOL
  57
  58 AC_ISC_POSIX
  59 AC_PROG_CC
  60 AM_PROG_CC_STDC
  61 AM_PROG_CC_C_O
  62 AC_PROG_CXX
  63 AC_STDC_HEADERS
  64
  65 AC_PROG_SED
  66 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  67 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  68
  69 GNOME_MAINTAINER_MODE_DEFINES
  70 GNOME_COMPILE_WARNINGS
  71 GNOME_CXX_WARNINGS
  72
  73 dnl FIXME: remove this when required gtk+ >= 2.19.7
  74 DISABLE_DEPRECATED=
  75 AC_SUBST([DISABLE_DEPRECATED])
  76
  77 IT_PROG_INTLTOOL([0.35.0])
  78
  79 GETTEXT_PACKAGE=evince
  80 AC_SUBST(GETTEXT_PACKAGE)
  81 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  82 AM_GLIB_GNU_GETTEXT
  83
  84 m4_pattern_allow([AM_V_GEN])dnl Make autoconf not complain about the rule below
  85 EV_INTLTOOL_EVINCE_BACKEND_RULE='%.evince-backend:   %.evince-backend.in   $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; $(AM_V_GEN) LC_ALL=C $(INTLTOOL_MERGE) -d -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@'
  86 AC_SUBST([EV_INTLTOOL_EVINCE_BACKEND_RULE])
  87
  88 GLIB_GSETTINGS
  89
  90 # Check which platform to use
  91
  92 AC_MSG_CHECKING([for which platform to build])
  93 AC_ARG_WITH([platform],
  94   [AS_HELP_STRING([--with-platform=gnome|win32|hildon],
  95                   [Setting platform (default: gnome)])],
  96   [case "$withval" in
  97     gnome|win32|hildon) ;;
  98     *) AC_MSG_ERROR([invalid argument "$withval" for --with-platform]) ;;
  99    esac],
 100   [case "$host" in
 101      *-*-mingw*|*-*-cygwin*) with_platform="win32" ;;
 102      *) with_platform=gnome ;;
 103    esac])
 104
 105 AC_MSG_RESULT([$with_platform])
 106
 107 if test "$with_platform" = "win32"; then
 108   AC_CHECK_TOOL([WINDRES],[windres])
 109   AC_MSG_CHECKING([for native Win32])
 110   case "$host" in
 111     *-*-mingw*)
 112       os_win32=yes
 113       ;;
 114     *)
 115       os_win32=no
 116       ;;
 117   esac
 118   AC_MSG_RESULT([$os_win32])
 119 fi
 120
 121 AM_CONDITIONAL([PLATFORM_HILDON],[test "$with_platform" = "hildon"])
 122 AM_CONDITIONAL([PLATFORM_WIN32],[test "$with_platform" = "win32"])
 123
 124 AC_MSG_CHECKING([which gtk+ version to compile against])
 125 AC_ARG_WITH([gtk],
 126   [AS_HELP_STRING([--with-gtk=2.0|3.0],[which gtk+ version to compile against (default: 2.0)])],
 127   [case "$with_gtk" in
 128      2.0|3.0) ;;
 129      *) AC_MSG_ERROR([invalid gtk version specified]) ;;
 130    esac],
 131   [with_gtk=2.0])
 132 AC_MSG_RESULT([$with_gtk])
 133
 134 dnl Specify required versions of dependencies
 135 CAIRO_REQUIRED=1.9.10
 136 GLIB_REQUIRED=2.25.11
 137 KEYRING_REQUIRED=2.22.0
 138
 139 case "$with_gtk" in
 140   2.0) GTK_API_VERSION=2.0
 141        GAIL_API_VERSION=
 142        GTK_REQUIRED=2.21.5
 143        ;;
 144   3.0) GTK_API_VERSION=3.0
 145        GAIL_API_VERSION=-3.0
 146        GTK_REQUIRED=2.90.5
 147        ;;
 148 esac
 149
 150 AC_SUBST([GLIB_REQUIRED])
 151 AC_SUBST([GTK_REQUIRED])
 152
 153 GNOME_ICON_THEME_REQUIRED=2.17.1
 154 LIBXML_REQUIRED=2.5.0
 155
 156 dnl Check dependencies
 157
 158 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
 159 # BACKEND_CFLAGS   for backend implementations.
 160 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
 161 # FRONTEND_LIBS
 162 # SHELL_CFLAGS     for shell implementation.
 163 # SHELL_LIBS
 164
 165
 166 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-$GTK_API_VERSION >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
 167 PKG_CHECK_MODULES(LIBVIEW, gtk+-$GTK_API_VERSION >= $GTK_REQUIRED gail$GAIL_API_VERSION >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 168 PKG_CHECK_MODULES(BACKEND, cairo >= $CAIRO_REQUIRED gtk+-$GTK_API_VERSION >= $GTK_REQUIRED)
 169 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-$GTK_API_VERSION >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 170
 171 SHELL_PLATFORM_PKGS=
 172 case "$with_platform" in
 173   hildon) AC_DEFINE([PLATFORM_HILDON],[1],[Define if building for the hildon platform])
 174           SHELL_PLATFORM_PKGS="hildon-1 hildon-fm-2 libosso"
 175           ;;
 176   gnome)
 177         # Evince has a rather soft run-time dependency on hicolor-icon-theme.
 178         # If the hicolor theme is not available, Evince fails to display some
 179         # icons. Because we cannot check for it at run-time, we instead
 180         # would like to require the icon theme at compile-time. But, because
 181         # the hicolor-icon-theme does not have a pkgconfig file, on gnome we
 182         # require the gnome icon theme instead.
 183         SHELL_PLATFORM_PKGS="gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED"
 184         # The totem-screensaver and egg_smclient code use x11 directly.
 185         SHELL_PLATFORM_PKGS="$SHELL_PLATFORM_PKGS x11"
 186         ;;
 187   *)
 188         # On all other platforms we issue a warning about the runtime
 189         # dependency.
 190         AC_MSG_WARN([Evince has a soft run-time dependency on hicolor-icon-theme. You are advised to have this theme installed when running Evince.]);
 191         SHELL_PLATFORM_PKGS=""
 192         ;;
 193 esac
 194
 195 PKG_CHECK_MODULES([SHELL_CORE],[libxml-2.0 >= $LIBXML_REQUIRED gtk+-$GTK_API_VERSION >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gthread-2.0 $SHELL_PLATFORM_PKGS])
 196
 197 # *********
 198 # SM client
 199 # *********
 200
 201 GDK_TARGET="$($PKG_CONFIG --variable target gdk-$GTK_API_VERSION)"
 202
 203 AC_MSG_CHECKING([which smclient backend to use])
 204 AC_ARG_WITH([smclient],
 205   [AS_HELP_STRING([--with-smclient-backend=no|xsmp|win32|quartz],
 206                   [Setting smclient backend (default:auto)])],
 207   [],
 208   [case "$GDK_TARGET" in
 209     x11) case "$with_platform" in
 210            gnome) with_smclient=xsmp ;;
 211            *) with_smclient=no ;;
 212          esac ;;
 213     win32|quartz) with_smclient=$GDK_TARGET ;;
 214     *) with_smclient=no ;;
 215    esac])
 216
 217 AC_MSG_RESULT([$with_smclient])
 218
 219 if test "$with_smclient" != "no"; then
 220   AC_DEFINE([WITH_SMCLIENT],[1],[Define if smclient is enabled])
 221
 222   case "$with_smclient" in
 223     xsmp) SMCLIENT_PKGS="sm >= 1.0.0" ;;
 224     *) SMCLIENT_PKGS="" ;;
 225   esac
 226
 227   PKG_CHECK_MODULES([SMCLIENT],[gtk+-$GTK_API_VERSION gthread-2.0 $SMCLIENT_PKGS])
 228   AC_SUBST([SMCLIENT_CFLAGS])
 229   AC_SUBST([SMCLIENT_LIBS])
 230 fi
 231
 232 AM_CONDITIONAL([WITH_SMCLIENT],[test "$with_smclient" != "no"])
 233 AM_CONDITIONAL([WITH_SMCLIENT_XSMP],[test "$with_smclient" = "xsmp"])
 234 AM_CONDITIONAL([WITH_SMCLIENT_WIN32],[test "$with_smclient" = "win32"])
 235 AM_CONDITIONAL([WITH_SMCLIENT_QUARTZ],[test "$with_smclient" = "quartz"])
 236
 237 # ***
 238
 239 BACKEND_LIBTOOL_FLAGS="-module -avoid-version -no-undefined -export-symbols \$(top_srcdir)/backend/backend.symbols"
 240 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
 241
 242 dnl ===== Check special functions
 243 evince_save_LIBS=$LIBS
 244 LIBS="$LIBS $BACKEND_LIBS"
 245 AC_CHECK_FUNCS(cairo_format_stride_for_width)
 246 LIBS=$evince_save_LIBS
 247
 248 # ******************
 249 # GKT+ Unix Printing
 250 # ******************
 251
 252 AC_MSG_CHECKING([whether gtk+-unix-print support is requested])
 253 AC_ARG_WITH([gtk-unix-print],
 254   [AS_HELP_STRING([--without-gtk-unix-print],
 255                   [Disable the use of gtk-unix-print])],
 256   [],[case "$os_win32" in
 257         yes) with_gtk_unix_print=no ;;
 258         *) with_gtk_unix_print=yes ;;
 259       esac])
 260
 261 AC_MSG_RESULT([$with_gtk_unix_print])
 262
 263 if test "$with_gtk_unix_print" = "yes"; then
 264    PKG_CHECK_MODULES(GTKUNIXPRINT, [gtk+-unix-print-$GTK_API_VERSION >= $GTK_REQUIRED])
 265    AC_DEFINE([GTKUNIXPRINT_ENABLED], [1], [Define if gtk+-unix-print is enabled.])
 266 fi
 267
 268 # *********************
 269 # GNOME Keyring support
 270 # *********************
 271
 272 AC_ARG_WITH(keyring,
 273         [AS_HELP_STRING([--without-keyring],
 274                         [Disable the use of gnome-keyring])],
 275         [],
 276         [case "$with_platform" in
 277            gnome) with_keyring=yes ;;
 278            hildon|win32) with_keyring=no ;;
 279          esac])
 280
 281 AM_CONDITIONAL([WITH_KEYRING],[test "$with_keyring" = "yes"])
 282
 283 if test "$with_keyring" = "yes"; then
 284         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
 285         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
 286 fi
 287
 288 # ****
 289 # DBUS
 290 # ****
 291
 292 AC_ARG_ENABLE([dbus],
 293   [AS_HELP_STRING([--disable-dbus], [Disable support for dbus])],
 294   [],
 295   [case "$with_platform" in
 296       gnome) enable_dbus=yes ;;
 297       hildon) enable_dbus=no ;;
 298     esac])
 299
 300 if test "$enable_dbus" = "yes"; then
 301   AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 302
 303    PKG_CHECK_MODULES([EV_DAEMON], [gio-2.0 >= $GLIB_REQUIRED])
 304 fi
 305
 306 AM_CONDITIONAL([ENABLE_DBUS], [test "$enable_dbus" = "yes"])
 307
 308 dnl ========= Check for Desktop Schemas
 309 PKG_CHECK_MODULES([DESKTOP_SCHEMAS], [gsettings-desktop-schemas],
 310                   has_desktop_schemas=yes, has_desktop_schemas=no)
 311 if test x$has_desktop_schemas = xyes; then
 312    AC_DEFINE([HAVE_DESKTOP_SCHEMAS], [1], [Whether GSettings Desktop Schemas are available])
 313 fi
 314
 315 dnl ========= Check for GConf
 316
 317 AC_MSG_CHECKING([whether GConf support is requested])
 318 AC_ARG_WITH([gconf],
 319   [AS_HELP_STRING([--without-gconf],
 320                   [Disable the use of gconf])],
 321   [],
 322   [case "$os_win32" in
 323      yes) with_gconf=no ;;
 324      *) with_gconf=yes ;;
 325    esac])
 326 AC_MSG_RESULT([$with_gconf])
 327
 328 AM_CONDITIONAL([WITH_GCONF],[test "$with_gconf" = "yes"])
 329
 330 if test "$with_gconf" = "yes"; then
 331    PKG_CHECK_MODULES([GCONF],[gconf-2.0])
 332    AC_DEFINE([WITH_GCONF],[1],[Define if GConf support is enabled])
 333
 334    AM_GCONF_SOURCE_2
 335
 336    AC_PATH_PROG([GCONFTOOL], [gconftool-2], [false])
 337    if test "$GCONFTOOL" = "false"; then
 338       AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 339    fi
 340 else
 341    AM_CONDITIONAL([GCONF_SCHEMAS_INSTALL],false)
 342 fi
 343
 344 dnl Debug mode
 345
 346 AC_ARG_ENABLE([debug],
 347         AS_HELP_STRING([--enable-debug],
 348                        [Turn on evince debug mode]),
 349         [enable_debug=$enableval],
 350         [enable_debug=no])
 351
 352 if test "x$enable_debug" = "xyes"; then
 353    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 354 fi
 355
 356 AC_ARG_ENABLE([tests],
 357         AS_HELP_STRING([--enable-tests], [Enable the tests]),
 358         [enable_tests=$enableval],
 359         [enable_tests=yes])
 360
 361 AM_CONDITIONAL(ENABLE_TESTS, test x$enable_tests = xyes)
 362
 363 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 364 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 365 AC_SUBST(LIBDOCUMENT_CFLAGS)
 366 AC_SUBST(LIBDOCUMENT_LIBS)
 367
 368 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 369 LIBVIEW_LIBS="$LIBVIEW_LIBS $GTKUNIXPRINT_LIBS -lm"
 370 AC_SUBST(LIBVIEW_CFLAGS)
 371 AC_SUBST(LIBVIEW_LIBS)
 372
 373 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 374 BACKEND_LIBS="$BACKEND_LIBS -lm"
 375 AC_SUBST(BACKEND_CFLAGS)
 376 AC_SUBST(BACKEND_LIBS)
 377
 378 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $KEYRING_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 379 SHELL_LIBS="$SHELL_CORE_LIBS $KEYRING_LIBS -lz -lm"
 380 AC_SUBST(SHELL_CFLAGS)
 381 AC_SUBST(SHELL_LIBS)
 382
 383 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 384 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 385 AC_SUBST(FRONTEND_CFLAGS)
 386 AC_SUBST(FRONTEND_LIBS)
 387
 388 EV_DAEMON_CFLAGS="$EV_DAEMON_CFLAGS $DEBUG_FLAGS"
 389 AC_SUBST([EV_DAEMON_CFLAGS])
 390 AC_SUBST([EV_DAEMON_LIBS])
 391
 392 # Check for Nautilus property page build
 393 AC_ARG_ENABLE([nautilus],
 394   [AS_HELP_STRING([--disable-nautilus],
 395                   [Disable build of nautilus extensions])],
 396   [],
 397   [case "$with_platform" in
 398      gnome) enable_nautilus=yes ;;
 399      *) enable_nautilus=no ;;
 400     esac])
 401
 402 if test "$enable_nautilus" = "yes" ; then
 403   PKG_CHECK_MODULES([NAUTILUS],[gtk+-x11-$GTK_API_VERSION $MM gthread-2.0 libnautilus-extension],
 404                     [],[AC_MSG_ERROR([libnautilus-extension not found; use --disable-nautilus to disable the nautilus extensions])])
 405   NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 406   AC_SUBST([nautilusextensiondir],[$NAUTILUS_EXTENSION_DIR])
 407   AC_SUBST(NAUTILUS_CFLAGS)
 408   AC_SUBST(NAUTILUS_LIBS)
 409
 410   AC_DEFINE([HAVE_NAUTILUS],[1], [defined if you build the nautilus plugin])
 411 fi
 412
 413 AM_CONDITIONAL([ENABLE_NAUTILUS],[test "$enable_nautilus" = "yes"])
 414
 415 # Check for thumbnailer build
 416
 417 AC_ARG_ENABLE([thumbnailer],
 418   [AS_HELP_STRING([--disable-thumbnailer],
 419                   [Disable GNOME thumbnailer])],
 420   [],
 421   [case "$with_platform" in
 422      hildon) enable_thumbnailer=no ;;
 423      *) enable_thumbnailer=yes ;;
 424     esac])
 425
 426 AM_CONDITIONAL([ENABLE_THUMBNAILER],[test "$enable_thumbnailer" = "yes"])
 427
 428 # ***************
 429 # Print Previewer
 430 # ***************
 431
 432 AC_ARG_ENABLE([previewer],
 433   [AS_HELP_STRING([--disable-previewer],
 434                   [Disable the GNOME Document Previewer])],
 435   [],
 436   [case "$with_platform" in
 437       hildon) enable_previewer=no ;;
 438       *) enable_previewer=yes ;;
 439     esac])
 440
 441 if test x$enable_previewer = "xyes" ; then
 442   PKG_CHECK_MODULES([PREVIEWER],[gtk+-$GTK_API_VERSION >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED])
 443 fi
 444
 445 AM_CONDITIONAL([ENABLE_PREVIEWER],[test "$enable_previewer" = "yes"])
 446 PREVIEWER_CFLAGS="$PREVIEWER_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 447 PREVIEWER_LIBS="$PREVIEWER_LIBS $GTKUNIXPRINT_LIBS -lz"
 448 AC_SUBST(PREVIEWER_CFLAGS)
 449 AC_SUBST(PREVIEWER_LIBS)
 450
 451 # ***
 452 # GIR
 453 # ***
 454
 455 AC_MSG_CHECKING([whether GObject introspection is requested])
 456 AC_ARG_ENABLE([introspection],
 457         AS_HELP_STRING([--enable-introspection],
 458                        [Enable GObject introspection]),
 459         [enable_introspection=$enableval],
 460         [enable_introspection=no])
 461 AC_MSG_RESULT([$enable_introspection])
 462
 463 G_IR_SCANNER=
 464 G_IR_COMPILER=
 465 G_IR_GENERATE=
 466 GIRDIR=
 467 GIRTYPELIBDIR=
 468
 469 if test "$enable_introspection" = "yes"; then
 470   GOBJECT_INTROSPECTION_REQUIRED=0.6
 471   PKG_CHECK_MODULES([GOBJECT_INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
 472
 473   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
 474   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
 475   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
 476   GIRDIR="$($PKG_CONFIG --variable=girdir gobject-introspection-1.0)"
 477   GIRTYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
 478 fi
 479
 480 AC_SUBST([G_IR_SCANNER])
 481 AC_SUBST([G_IR_COMPILER])
 482 AC_SUBST([G_IR_GENERATE])
 483 AC_SUBST([GIRDIR])
 484 AC_SUBST([GIRTYPELIBDIR])
 485
 486 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
 487
 488 dnl ================== portability checks ===========================================
 489
 490 dnl for backtrace()
 491 AC_CHECK_HEADERS([execinfo.h])
 492
 493 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 494   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 495   ],[],[#include <langinfo.h>])
 496
 497 dnl ================== pdf checks ===================================================
 498 AC_ARG_ENABLE([pdf],
 499   [AS_HELP_STRING([--disable-pdf],
 500                   [Disable the PDF support])],
 501   [enable_pdf=$enableval],
 502   [enable_pdf=yes])
 503
 504 if test "x$enable_pdf" = "xyes"; then
 505     POPPLER_REQUIRED=0.14.0
 506     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED,enable_pdf=yes,enable_pdf=no)
 507
 508     if test "x$enable_pdf" = "xyes"; then
 509             evince_save_LIBS=$LIBS
 510             LIBS="$LIBS $POPPLER_LIBS"
 511             AC_CHECK_FUNCS(poppler_page_get_text_layout)
 512             AC_CHECK_FUNCS(poppler_page_get_selected_text)
 513             AC_CHECK_FUNCS(poppler_page_add_annot)
 514             LIBS=$evince_save_LIBS
 515             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 516             if test x$enable_cairo_pdf = xyes; then
 517                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 518             fi
 519
 520             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 521             if test x$enable_cairo_ps = xyes; then
 522                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 523             fi
 524     else
 525             AC_MSG_ERROR("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 526     fi
 527 fi
 528
 529 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 530 dnl ================== end of pdf checks ============================================
 531
 532 dnl libspectre (used by ps and dvi backends)
 533 SPECTRE_REQUIRED=0.2.0
 534 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 535 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 536 if test "x$have_spectre" = "xyes"; then
 537    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 538 fi
 539
 540 dnl ================== ps checks ====================================================
 541 AC_ARG_ENABLE(ps,
 542         [AS_HELP_STRING([--disable-ps],
 543                         [Disable the PostScript backend])],
 544         [enable_ps=$enableval],
 545         [enable_ps=yes])
 546
 547 if test "x$enable_ps" = "xyes"; then
 548    if test "x$have_spectre" = "xyes"; then
 549       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 550    else
 551       enable_ps="no"
 552       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 553    fi
 554 fi
 555 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 556 dnl ======================== End of ps checks ===================================
 557
 558 dnl ================== tiff checks ===================================================
 559 AC_ARG_ENABLE(tiff,
 560             [AS_HELP_STRING([--disable-tiff],
 561                             [Disable the support of multipage tiff])],
 562             [enable_tiff=$enableval],
 563             [enable_tiff=yes])
 564
 565 if test "x$enable_tiff" = "xyes"; then
 566     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 567     if test "x$enable_tiff" = "xyes"; then
 568         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 569         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 570     fi
 571     if test "x$enable_tiff" = "xyes"; then
 572             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 573     else
 574             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 575     fi
 576 fi
 577
 578 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 579 dnl ================== end of tiff checks ============================================
 580
 581 dnl ================== djvu checks ===================================================
 582
 583 AC_ARG_ENABLE(djvu,
 584             [AS_HELP_STRING([--disable-djvu],
 585                             [Disable the support of djvu viewer])],
 586             [enable_djvu=$enableval],
 587             [enable_djvu=yes])
 588
 589 if test "x$enable_djvu" = "xyes"; then
 590     DJVULIBRE_REQUIRED=3.5.17
 591     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 592
 593     if test "x$enable_djvu" = "xyes"; then
 594         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 595     else
 596         AC_MSG_WARN([
 597 ** Djvu support is disabled since a recent version of the djvulibre
 598 ** library was not found. You need at least djvulibre-3.5.17 which
 599 ** can be found on http://djvulibre.djvuzone.org
 600 ])
 601     fi
 602 fi
 603
 604 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 605
 606 dnl ================== End of djvu checks ===================================================
 607
 608 dnl ================== dvi checks ===================================================
 609
 610 AC_ARG_ENABLE(dvi,
 611             [AS_HELP_STRING([--disable-dvi],
 612             [Disable the support of dvi viewer])],
 613             [enable_dvi=$enableval],
 614             [enable_dvi=yes])
 615
 616 AC_ARG_ENABLE(t1lib,
 617             [AS_HELP_STRING([--enable-t1lib],
 618                             [Compile with support of t1lib for type1 fonts in dvi])],
 619             [enable_type1_fonts=$enableval],
 620             [enable_type1_fonts=no])
 621
 622 if test "x$enable_dvi" = "xyes"; then
 623     AC_C_CONST
 624     AC_C_INLINE
 625     AC_TYPE_SIZE_T
 626     AC_CHECK_SIZEOF(long, 4)
 627     AC_CHECK_SIZEOF(int, 4)
 628     AC_CHECK_SIZEOF(short, 2)
 629     AC_CHECK_SIZEOF(void *, 4)
 630     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 631
 632     if test "x$enable_dvi" = "xyes"; then
 633         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 634     else
 635         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 636     fi
 637 fi
 638 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 639
 640 if test "x$enable_dvi" = "xyes"; then
 641     if test "x$enable_type1_fonts" = "xyes"; then
 642         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 643     fi
 644
 645     if test "x$enable_type1_fonts" = xyes; then
 646         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 647     fi
 648 else
 649     enable_type1_fonts=no
 650 fi
 651 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 652
 653 dnl ================== End of dvi checks ===================================================
 654
 655 dnl ================== pixbuf checks ===================================================
 656
 657 AC_ARG_ENABLE(pixbuf,
 658             [AS_HELP_STRING([--enable-pixbuf],
 659                             [Compile with support of pixbuf])],
 660             [enable_pixbuf=$enableval],
 661             [enable_pixbuf=no])
 662
 663 if test "x$enable_pixbuf" = "xyes"; then
 664         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 665 fi
 666
 667 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 668
 669 dnl ================== End of pixbuf checks ===================================================
 670
 671 dnl ================== comic book checks ===================================================
 672
 673 AC_ARG_ENABLE(comics,
 674         [AS_HELP_STRING([--enable-comics],
 675                         [Compile with support for comic book archives])],
 676         [enable_comics=$enableval],
 677         [enable_comics=yes])
 678
 679 if test "x$enable_comics" = "xyes"; then
 680         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 681 fi
 682 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 683
 684 dnl ================== End of comic book checks ============================================
 685
 686 dnl ================== impress book checks ===================================================
 687
 688 AC_ARG_ENABLE(impress,
 689         [AS_HELP_STRING([--enable-impress],
 690                         [Compile with support for impress presentations])],
 691         [enable_impress=$enableval],
 692         [enable_impress=no])
 693
 694 if test "x$enable_impress" = "xyes"; then
 695         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 696 fi
 697 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 698
 699 dnl ================== End of impress book checks ============================================
 700
 701 dnl =================== Mime types list ====================================================
 702
 703 if test "x$enable_pdf" = "xyes" ; then
 704         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 705 fi
 706 if test "x$enable_ps" = "xyes" ; then
 707         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 708 fi
 709 if test "x$enable_dvi" = "xyes"; then
 710         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 711 fi
 712 if test "x$enable_djvu" = "xyes"; then
 713         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 714 fi
 715 if test "x$enable_tiff" = "xyes"; then
 716         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 717 fi
 718 if test "x$enable_comics" = "xyes"; then
 719         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;application/x-cbt;"
 720 fi
 721 if test "x$enable_pixbuf" = "xyes"; then
 722         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 723 fi
 724 if test "x$enable_impress" = "xyes"; then
 725         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 726 fi
 727 AC_SUBST(EVINCE_MIME_TYPES)
 728
 729 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 730
 731 # *****************
 732 # Help files
 733 # *****************
 734
 735 GNOME_DOC_INIT([], gnome_doc_utils=yes, gnome_doc_utils=no)
 736
 737 AC_ARG_ENABLE(help,
 738     [AS_HELP_STRING([--disable-help], [Disable offline help files])],
 739     [enable_help=$enableval],
 740     [enable_help=yes])
 741
 742 if test "x$enable_help" = "xyes" && test "x$os_win32" = "xyes" ; then
 743     AC_MSG_WARN([Offline help is disabled (not implemented on Windows).])
 744     enable_help=no
 745 fi
 746
 747 if test "x$enable_help" = "xyes" && test "x$gnome_doc_utils" == "xno"; then
 748     AC_MSG_ERROR(
 749        [gnome-doc-utils not found; use --disable-help to disable help files]
 750     )
 751 fi
 752
 753 if test "x$enable_help" = "xyes"; then
 754     AC_DEFINE([OFFLINE_HELP_ENABLED], [1], [Enable offline help])
 755 fi
 756
 757 AM_CONDITIONAL(ENABLE_HELP, test "x$enable_help" = "xyes")
 758
 759 # *****************
 760 # API documentation
 761 # *****************
 762
 763 GTK_DOC_CHECK([1.13],[--flavour no-tmpl])
 764
 765 AC_SUBST([GLIB_PREFIX],[$($PKG_CONFIG --variable=prefix glib-2.0)])
 766 AC_SUBST([GTK_PREFIX],[$($PKG_CONFIG --variable=prefix gtk+-$GTK_API_VERSION)])
 767
 768 # ******************
 769 # Backends directory
 770 # ******************
 771
 772 AC_SUBST([backenddir],"\$(libdir)/evince/ev_binary_version/backends")
 773 AC_SUBST([backend_binary_version],"ev_binary_version")
 774
 775 # **********
 776 # Versioning
 777 # **********
 778
 779 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
 780 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
 781 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
 782
 783 AC_SUBST([EV_API_VERSION],[ev_api_version])
 784 AC_SUBST([EV_API_VERSION_U],[AS_TR_SH([ev_api_version])])
 785 AC_SUBST([EV_BINARY_VERSION],[ev_binary_version])
 786
 787 AC_SUBST([EV_DOCUMENT_LT_VERSION_INFO],[ev_document_lt_version_info])
 788 AC_SUBST([EV_DOCUMENT_LT_CURRENT_MINUS_AGE],[ev_document_lt_current_minus_age])
 789 AC_SUBST([EV_VIEW_LT_VERSION_INFO],[ev_view_lt_version_info])
 790 AC_SUBST([EV_VIEW_LT_CURRENT_MINUS_AGE],[ev_view_lt_current_minus_age])
 791
 792 # *****************************************************************************
 793 # *****************************************************************************
 794
 795 AC_CONFIG_FILES([
 796 backend/Makefile
 797 backend/comics/Makefile
 798 backend/djvu/Makefile
 799 backend/dvi/Makefile
 800 backend/dvi/mdvi-lib/Makefile
 801 backend/impress/Makefile
 802 backend/pdf/Makefile
 803 backend/pixbuf/Makefile
 804 backend/ps/Makefile
 805 backend/tiff/Makefile
 806 cut-n-paste/Makefile
 807 cut-n-paste/gimpcellrenderertoggle/Makefile
 808 cut-n-paste/smclient/Makefile
 809 cut-n-paste/toolbar-editor/Makefile
 810 cut-n-paste/zoom-control/Makefile
 811 cut-n-paste/totem-screensaver/Makefile
 812 cut-n-paste/synctex/Makefile
 813 data/evince.desktop.in
 814 data/Makefile
 815 data/icons/Makefile
 816 data/icons/16x16/Makefile
 817 data/icons/16x16/apps/Makefile
 818 data/icons/16x16/actions/Makefile
 819 data/icons/16x16/mimetypes/Makefile
 820 data/icons/22x22/Makefile
 821 data/icons/22x22/apps/Makefile
 822 data/icons/22x22/actions/Makefile
 823 data/icons/22x22/mimetypes/Makefile
 824 data/icons/24x24/Makefile
 825 data/icons/24x24/apps/Makefile
 826 data/icons/24x24/actions/Makefile
 827 data/icons/24x24/mimetypes/Makefile
 828 data/icons/32x32/Makefile
 829 data/icons/32x32/actions/Makefile
 830 data/icons/32x32/mimetypes/Makefile
 831 data/icons/48x48/Makefile
 832 data/icons/48x48/apps/Makefile
 833 data/icons/48x48/actions/Makefile
 834 data/icons/scalable/Makefile
 835 data/icons/scalable/apps/Makefile
 836 data/icons/scalable/actions/Makefile
 837 data/icons/scalable/mimetypes/Makefile
 838 help/Makefile
 839 help/reference/Makefile
 840 help/reference/libdocument/Makefile
 841 help/reference/libdocument/version.xml
 842 help/reference/libview/Makefile
 843 help/reference/libview/version.xml
 844 help/reference/shell/Makefile
 845 help/reference/shell/version.xml
 846 libdocument/Makefile
 847 libdocument/ev-version.h
 848 libmisc/Makefile
 849 libview/Makefile
 850 Makefile
 851 po/Makefile.in
 852 previewer/Makefile
 853 properties/Makefile
 854 shell/Makefile
 855 test/Makefile
 856 thumbnailer/Makefile
 857 ])
 858
 859 AC_CONFIG_FILES(evince-document-[]ev_api_version[].pc:evince-document.pc.in)
 860 AC_CONFIG_FILES(evince-view-[]ev_api_version[].pc:evince-view.pc.in)
 861
 862 AC_OUTPUT
 863
 864 echo "
 865 Configure summary:
 866         Platform...........:  $with_platform
 867         GTK+ version.......:  $with_gtk
 868         GConf Support......:  $with_gconf
 869         GTK+ Unix Print....:  $with_gtk_unix_print
 870         Keyring Support....:  $with_keyring
 871         DBUS Support.......:  $enable_dbus
 872         SM client support..:  $with_smclient
 873         Help files.........:  $enable_help
 874         Nautilus Plugin....:  $enable_nautilus
 875         Thumbnailer........:  $enable_thumbnailer
 876         Previewer..........:  $enable_previewer
 877         Gtk-Doc Support....:  $enable_gtk_doc
 878         Debug mode.........:  $enable_debug
 879         GObj. Introspection:  $enable_introspection
 880         Tests..............:  $enable_tests
 881
 882         PDF Backend........:  $enable_pdf
 883         PostScript Backend.:  $enable_ps
 884         TIFF Backend.......:  $enable_tiff
 885         DJVU Backend.......:  $enable_djvu
 886         DVI Backend........:  $enable_dvi
 887         Pixbuf Backend.....:  $enable_pixbuf
 888         Comics Backend.....:  $enable_comics
 889         Impress Backend....:  $enable_impress
 890 "