configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.57)
   4 AC_INIT([Evince],[0.9.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
   5 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-dist-gzip])
   6
   7 AM_CONFIG_HEADER(config.h)
   8
   9 AM_MAINTAINER_MODE
  10
  11 AM_PROG_LIBTOOL
  12
  13 AC_ISC_POSIX
  14 AC_PROG_CC
  15 AM_PROG_CC_STDC
  16 AC_PROG_CXX
  17 AC_STDC_HEADERS
  18 IT_PROG_INTLTOOL([0.35.0])
  19 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  20 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  21
  22 GNOME_COMMON_INIT
  23 GNOME_DOC_INIT
  24 GNOME_MAINTAINER_MODE_DEFINES
  25 GNOME_COMPILE_WARNINGS
  26 GNOME_CXX_WARNINGS
  27 GNOME_DEBUG_CHECK
  28
  29 GTK_DOC_CHECK(1.0)
  30
  31 GETTEXT_PACKAGE=evince
  32 AC_SUBST(GETTEXT_PACKAGE)
  33 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  34 AM_GLIB_GNU_GETTEXT
  35
  36 dnl Check dependencies
  37
  38 # LIB_CFLAGS       for helpers and generic widgets. (lib, cut-and-paste)
  39 # BACKEND_CFLAGS   for backend implementations.
  40 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
  41 # FRONTEND_LIBS
  42 # SHELL_CFLAGS     for shell implementation.
  43 # SHELL_LIBS
  44
  45 DBUS_GLIB_REQUIRED=0.70
  46 GTK_REQUIRED=2.8.15
  47 KEYRING_REQUIRED=0.4.0
  48
  49 LIBGNOMEUI_REQUIRED=2.14.0
  50 LIBGNOME_REQUIRED=2.14.0
  51 LIBGNOMEPRINTUI_REQUIRED=2.6.0
  52 GNOME_ICON_THEME_REQUIRED=2.17.1
  53 LIBXML_REQUIRED=2.5.0
  54
  55 GTK_PRINT_REQUIRED=2.10.0
  56
  57 PKG_CHECK_MODULES(LIB, gtk+-2.0 >= $GTK_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED)
  58 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED gnome-vfs-2.0)
  59 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED libglade-2.0 gnome-vfs-2.0)
  60 PKG_CHECK_MODULES(SHELL_CORE, libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED gnome-vfs-2.0 libglade-2.0 gconf-2.0 gnome-keyring-1 >= $KEYRING_REQUIRED)
  61
  62 AC_ARG_WITH(libgnome,
  63         AC_HELP_STRING([--without-libgnome],[disable the use of libgnome]),
  64         [case "${withval}" in
  65         yes) WITH_GNOME=yes ;;
  66         no) WITH_GNOME=no ;;
  67         *) AC_MSG_ERROR(bad value ${withval} for --with-libgnome) ;;
  68         esac],
  69         [WITH_GNOME=yes]) dnl Default value
  70 AM_CONDITIONAL(WITH_GNOME, test x$WITH_GNOME = "xyes")
  71
  72 if test x$WITH_GNOME = "xyes"; then
  73         PKG_CHECK_MODULES(GNOME, libgnome-2.0 >= $LIBGNOME_REQUIRED)
  74         PKG_CHECK_MODULES(GNOMEUI, libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED)
  75         AC_DEFINE([WITH_GNOME],[1],[Define if GNOME support is enabled])
  76 fi
  77
  78 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
  79 AC_SUBST(GLIB_GENMARSHAL)
  80
  81 dnl ========= Print support
  82 AC_ARG_WITH(print,
  83             [AC_HELP_STRING([--with-print=no/gtk/gnome/auto], [Compile with print support [default=auto]])],
  84             PRINT=$withval,
  85             PRINT="auto")
  86
  87 PKG_CHECK_MODULES(GNOME_PRINT,
  88                   libgnomeprintui-2.2 >= $LIBGNOMEPRINTUI_REQUIRED,
  89                   enable_gnome_print=yes, enable_gnome_print=no)
  90 PKG_CHECK_MODULES(GTK_PRINT,
  91                   gtk+-unix-print-2.0 >= $GTK_PRINT_REQUIRED,
  92                   enable_gtk_print=yes, enable_gtk_print=no)
  93 enable_print=no
  94 if test x$PRINT = xgnome -a x$enable_gnome_print = xyes; then
  95    enable_print=gnome
  96 else
  97    if test x$PRINT = xgtk -a x$enable_gtk_print = xyes; then
  98       enable_print=gtk
  99    else
 100       if test x$PRINT = xauto; then
 101          if test x$enable_gtk_print = xyes; then
 102             enable_print=gtk
 103          else
 104             if test x$enable_gnome_print = xyes; then
 105                enable_print=gnome
 106             fi
 107          fi
 108       fi
 109    fi
 110 fi
 111
 112 if test x$enable_print = xgnome; then
 113    AC_SUBST(GNOME_PRINT_CFLAGS)
 114    AC_SUBST(GNOME_PRINT_LIBS)
 115    AC_DEFINE([WITH_GNOME_PRINT],[1],[Enable GNOME Print Support.])
 116    AC_DEFINE([WITH_PRINT],[1],[Enable Print Support.])
 117 fi
 118
 119 if test x$enable_print = xgtk; then
 120    AC_SUBST(GTK_PRINT_CFLAGS)
 121    AC_SUBST(GTK_PRINT_LIBS)
 122    AC_DEFINE([WITH_GTK_PRINT],[1],[Enable GTK Print Support.])
 123    AC_DEFINE([WITH_PRINT],[1],[Enable Print Support.])
 124 fi
 125
 126 AM_CONDITIONAL(WITH_GNOME_PRINT, test x$enable_print = xgnome)
 127 AM_CONDITIONAL(WITH_GTK_PRINT, test x$enable_print = xgtk)
 128
 129
 130 dnl ========= Check for DBUS
 131 PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
 132         [enable_dbus=yes],[enable_dbus=no])
 133 AC_SUBST([DBUS_CFLAGS])
 134 AC_SUBST([DBUS_LIBS])
 135
 136 if test "x$enable_dbus" = "xno"; then
 137         AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
 138 fi
 139
 140 if test "x$enable_dbus" = "xyes" ; then
 141         AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 142
 143         if test x$DBUS_BINDING_TOOL = "xno" ; then
 144                 AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 145         fi
 146
 147         AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 148 fi
 149
 150 LIB_CFLAGS="$LIB_CFLAGS $GNOME_CFLAGS"
 151 LIB_LIBS="$LIB_LIBS $GNOME_LIBS"
 152 AC_SUBST(LIB_CFLAGS)
 153 AC_SUBST(LIB_LIBS)
 154
 155 BACKEND_CFLAGS="$BACKEND_CFLAGS $GNOME_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE"
 156 BACKEND_LIBS="$BACKEND_LIBS $GNOME_LIBS"
 157 AC_SUBST(BACKEND_CFLAGS)
 158 AC_SUBST(BACKEND_LIBS)
 159
 160 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS $GNOMEUI_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE"
 161 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS $GNOMEUI_LIBS -lz"
 162 AC_SUBST(SHELL_CFLAGS)
 163 AC_SUBST(SHELL_LIBS)
 164
 165 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $GNOME_CFLAGS"
 166 FRONTEND_LIBS="$FRONTEND_CORE_LIBS $GNOME_LIBS -lz"
 167 AC_SUBST(FRONTEND_CFLAGS)
 168 AC_SUBST(FRONTEND_LIBS)
 169
 170 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
 171 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
 172
 173 dnl Check for Nautilus property page build
 174 AC_ARG_ENABLE(nautilus,
 175         AC_HELP_STRING([--enable-nautilus],[compile the nautilus plugin]),
 176         [case "${enableval}" in
 177         yes) ENABLE_NAUTILUS=yes ;;
 178         no) ENABLE_NAUTILUS=no ;;
 179         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nautilus) ;;
 180         esac],
 181         [ENABLE_NAUTILUS=yes]) dnl Default value
 182
 183 if test x$ENABLE_NAUTILUS = "xyes" ; then
 184         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
 185                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
 186 fi
 187
 188 AC_SUBST(NAUTILUS_CFLAGS)
 189 AC_SUBST(NAUTILUS_LIBS)
 190 if test x$HAVE_NAUTILUS = "xyes"; then
 191         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
 192 fi
 193 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
 194
 195
 196 dnl Check for thumbnailer build
 197 AC_ARG_ENABLE(thumbnailer,
 198         AC_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer]),
 199         [case "${enableval}" in
 200         yes) ENABLE_THUMBNAILER=yes ;;
 201         no) ENABLE_THUMBNAILER=no ;;
 202         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thumbnailer) ;;
 203         esac],
 204         [ENABLE_THUMBNAILER=yes]) dnl Default value
 205 AM_CONDITIONAL(ENABLE_THUMBNAILER, test x$ENABLE_THUMBNAILER = "xyes")
 206
 207
 208 dnl Check for GtkRecent
 209 PKG_CHECK_MODULES(GTK_RECENT, gtk+-2.0 >= 2.10.0,
 210                   [HAVE_GTK_RECENT=yes], [HAVE_GTK_RECENT=no])
 211 if test x$HAVE_GTK_RECENT = xyes; then
 212    AC_DEFINE([HAVE_GTK_RECENT], [1], [defined if GtkRecent is available])
 213 fi
 214 AM_CONDITIONAL(HAVE_GTK_RECENT, test x$HAVE_GTK_RECENT = "xyes")
 215
 216 dnl GConf configuration
 217 AM_GCONF_SOURCE_2
 218
 219 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
 220 if test "x$GCONFTOOL" = "xno"; then
 221         AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 222 fi
 223
 224 dnl ================== portability checks ===========================================
 225
 226 dnl for backtrace()
 227 AC_CHECK_HEADERS([execinfo.h])
 228
 229 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 230   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 231   ],[],[#include <langinfo.h>])
 232
 233 dnl ================== pdf checks ===================================================
 234 AC_ARG_ENABLE(pdf,
 235               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 236
 237 if test "x$enable_pdf" = "xyes"; then
 238     POPPLER_REQUIRED=0.5.9
 239     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED,enable_pdf=yes,enable_pdf=no)
 240
 241     if test "x$enable_pdf" = "xyes"; then
 242             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 243             FRONTEND_LIBS="$FRONTEND_LIBS $POPPLER_LIBS"
 244             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 245             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 246
 247             evince_save_LIBS=$LIBS
 248             LIBS="$LIBS $FRONTEND_LIBS"
 249             AC_CHECK_FUNCS(poppler_page_render)
 250             LIBS=$evince_save_LIBS
 251
 252             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 253             if test x$enable_cairo_pdf == xyes; then
 254                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 255             fi
 256     else
 257             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 258     fi
 259 fi
 260
 261 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 262 dnl ================== end of pdf checks ============================================
 263
 264 dnl ================== ggv checks ===================================================
 265 AC_ARG_ENABLE(ps,
 266         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 267
 268 if test x$enable_ps = xyes; then
 269         AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 270 fi
 271
 272 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 273
 274 if test x$enable_ps = xyes; then
 275
 276 dnl check for GS version
 277 AC_MSG_CHECKING(for Ghostscript version...)
 278 GS_VERSION=`gs --version | head -n 1 | sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
 279 AC_MSG_RESULT(found $GS_VERSION)
 280 if test "$GS_VERSION" -lt "7"; then
 281         AC_MSG_ERROR([You need Ghostscript version >= 7 in order to run evince])
 282 fi
 283
 284 AC_ARG_WITH(gs-aa-params,
 285             [AC_HELP_STRING([--with-gs-aa-params], [Define antialiasing params for ghostscript])],AA_PARAMS=$withval,
 286             AA_PARMS="-sDEVICE=x11alpha -dNOPLATFONTS -dGraphicsAlphaBits=4 -dTextAlphaBits=4 -dDOINTERPOLATE"
 287             )
 288 AC_DEFINE_UNQUOTED(ALPHA_PARAMS, "$AA_PARMS", [Anti-aliasing parameters for Ghostscript.])
 289 AC_MSG_RESULT(Antialiasing parameters for Ghostscript: $AA_PARMS)
 290
 291 fi
 292 dnl ======================== End of ggv checks =================================
 293
 294 dnl ================== tiff checks ===================================================
 295 AC_ARG_ENABLE(tiff,
 296             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 297
 298 if test "x$enable_tiff" = "xyes"; then
 299     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 300     if test "x$enable_tiff" = "xyes"; then
 301         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 302         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 303     fi
 304     if test "x$enable_tiff" = "xyes"; then
 305             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 306             FRONTEND_LIBS="$FRONTEND_LIBS -ltiff"
 307             SHELL_LIBS="$SHELL_LIBS -ltiff"
 308     else
 309             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 310     fi
 311 fi
 312
 313 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 314 dnl ================== end of tiff checks ============================================
 315
 316 dnl ================== djvu checks ===================================================
 317
 318 AC_ARG_ENABLE(djvu,
 319             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=no)
 320
 321 if test "x$enable_djvu" = "xyes"; then
 322
 323 DJVULIBRE_REQUIRED=3.5.17
 324
 325 PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 326
 327     if test "x$enable_djvu" = "xyes"; then
 328         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 329     else
 330         AC_MSG_WARN([
 331 ** Djvu support is disabled since a recent version of the djvulibre
 332 ** library was not found. You need at least djvulibre-3.5.17 which
 333 ** can be found on http://djvulibre.djvuzone.org
 334 ])
 335     fi
 336 fi
 337
 338 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 339
 340 dnl ================== End of djvu checks ===================================================
 341
 342 dnl ================== dvi checks ===================================================
 343
 344 AC_ARG_ENABLE(dvi,
 345             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=no)
 346
 347 AC_ARG_ENABLE(t1lib,
 348             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 349
 350 if test "x$enable_dvi" = "xyes"; then
 351     AC_C_CONST
 352     AC_C_INLINE
 353     AC_TYPE_SIZE_T
 354     AC_CHECK_SIZEOF(long, 4)
 355     AC_CHECK_SIZEOF(int, 4)
 356     AC_CHECK_SIZEOF(short, 2)
 357     AC_CHECK_SIZEOF(void *, 4)
 358     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 359
 360     if test "x$enable_dvi" = "xyes"; then
 361         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 362     else
 363         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 364     fi
 365 fi
 366 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 367
 368 if test "x$enable_dvi" = "xyes"; then
 369     if test "x$enable_type1_fonts" = "xyes"; then
 370         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 371     fi
 372
 373     if test "x$enable_type1_fonts" = xyes; then
 374         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 375     fi
 376 else
 377     enable_type1_fonts=no
 378 fi
 379 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 380
 381 dnl ================== End of dvi checks ===================================================
 382
 383 dnl ================== pixbuf checks ===================================================
 384
 385 AC_ARG_ENABLE(pixbuf,
 386             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 387 if test "x$enable_pixbuf" = "xyes"; then
 388         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 389 fi
 390 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 391
 392 dnl ================== End of pixbuf checks ===================================================
 393
 394 dnl ================== comic book checks ===================================================
 395
 396 AC_ARG_ENABLE(comics,
 397         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=no)
 398 if test "x$enable_comics" = "xyes"; then
 399         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 400 fi
 401 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 402
 403 dnl ================== End of comic book checks ============================================
 404
 405 dnl ================== impress book checks ===================================================
 406
 407 AC_ARG_ENABLE(impress,
 408         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 409 if test "x$enable_impress" = "xyes"; then
 410         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 411 fi
 412 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 413
 414 dnl ================== End of impress book checks ============================================
 415
 416 dnl =================== Mime types list ====================================================
 417
 418 if test "x$enable_pdf" = "xyes" ; then
 419         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf"
 420 fi
 421 if test "x$enable_ps" = "xyes" ; then
 422         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps"
 423 fi
 424 if test "x$enable_dvi" = "xyes"; then
 425         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;application/x-dvi"
 426 fi
 427 if test "x$enable_djvu" = "xyes"; then
 428         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;image/vnd.djvu"
 429 fi
 430 if test "x$enable_tiff" = "xyes"; then
 431         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;image/tiff"
 432 fi
 433 if test "x$enable_comics" = "xyes"; then
 434         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;application/x-cbr;application/x-cbz"
 435 fi
 436 if test "x$enable_pixbuf" = "xyes"; then
 437         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;image/*"
 438 fi
 439 if test "x$enable_impress" = "xyes"; then
 440         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation"
 441 fi
 442 AC_SUBST(EVINCE_MIME_TYPES)
 443
 444 AC_CONFIG_FILES([
 445 backend/Makefile
 446 backend/comics/Makefile
 447 backend/djvu/Makefile
 448 backend/dvi/Makefile
 449 backend/dvi/mdvi-lib/Makefile
 450 backend/impress/Makefile
 451 backend/pdf/Makefile
 452 backend/pixbuf/Makefile
 453 backend/ps/Makefile
 454 backend/tiff/Makefile
 455 cut-n-paste/Makefile
 456 cut-n-paste/recent-files/Makefile
 457 cut-n-paste/toolbar-editor/Makefile
 458 cut-n-paste/zoom-control/Makefile
 459 cut-n-paste/totem-screensaver/Makefile
 460 data/evince.desktop.in
 461 data/Makefile
 462 data/icons/Makefile
 463 data/icons/16x16/Makefile
 464 data/icons/16x16/apps/Makefile
 465 data/icons/16x16/actions/Makefile
 466 data/icons/22x22/Makefile
 467 data/icons/22x22/apps/Makefile
 468 data/icons/22x22/actions/Makefile
 469 data/icons/24x24/Makefile
 470 data/icons/24x24/apps/Makefile
 471 data/icons/24x24/actions/Makefile
 472 data/icons/48x48/Makefile
 473 data/icons/48x48/apps/Makefile
 474 data/icons/scalable/Makefile
 475 data/icons/scalable/apps/Makefile
 476 help/Makefile
 477 help/reference/Makefile
 478 help/reference/version.xml
 479 libdocument/Makefile
 480 Makefile
 481 po/Makefile.in
 482 properties/Makefile
 483 shell/Makefile
 484 test/Makefile
 485 thumbnailer/Makefile
 486 ])
 487
 488 AC_OUTPUT
 489
 490 echo "
 491 Configure summary:
 492         GNOME Support......:  $WITH_GNOME
 493         Print Support......:  $enable_print
 494         DBUS Support.......:  $enable_dbus
 495         Nautilus Plugin....:  $HAVE_NAUTILUS
 496         Thumbnailer........:  $ENABLE_THUMBNAILER
 497         Gtk-Doc Support....:  $enable_gtk_doc
 498
 499         PDF Backend........:  $enable_pdf
 500         PostScript Backend.:  $enable_ps
 501         TIFF Backend.......:  $enable_tiff
 502         DJVU Backend.......:  $enable_djvu
 503         DVI Backend........:  $enable_dvi
 504         Pixbuf Backend.....:  $enable_pixbuf
 505         Comics Backend.....:  $enable_comics
 506         Impress Backend....:  $enable_impress
 507 "