configure.ac

   1 # *****************************************************************************
   2 # Versioning
   3 # *****************************************************************************
   4
   5 m4_define([ev_major_version],[2])
   6 m4_define([ev_minor_version],[27])
   7 m4_define([ev_micro_version],[4])
   8 m4_define([ev_extra_version],[])
   9 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version()ev_extra_version])
  10
  11 # The evince API version
  12 m4_define([ev_api_version], [2.25])
  13
  14 # Libtool versioning. The backend and view libraries have separate versions.
  15 # Before making a release, the libtool version should be modified.
  16 # The string is of the form C:R:A.
  17 # - If interfaces have been changed or added, but binary compatibility has
  18 #   been preserved, change to C+1:0:A+1
  19 # - If binary compatibility has been broken (eg removed or changed interfaces)
  20 #   change to C+1:0:0
  21 # - If the interface is the same as the previous version, change to C:R+1:A
  22
  23 # Libtool version of the backend library
  24 m4_define([ev_document_lt_current],[1])
  25 m4_define([ev_document_lt_revision],[0])
  26 m4_define([ev_document_lt_age],[0])
  27 m4_define([ev_document_lt_version_info],[ev_document_lt_current:ev_document_lt_revision:ev_document_lt_age])
  28 m4_define([ev_document_lt_current_minus_age],[m4_eval(ev_document_lt_current - ev_document_lt_age)])
  29
  30 # Libtool version of the view library
  31 m4_define([ev_view_lt_current],[1])
  32 m4_define([ev_view_lt_revision],[0])
  33 m4_define([ev_view_lt_age],[0])
  34 m4_define([ev_view_lt_version_info],[ev_view_lt_current:ev_view_lt_revision:ev_view_lt_age])
  35 m4_define([ev_view_lt_current_minus_age],[m4_eval(ev_view_lt_current - ev_view_lt_age)])
  36
  37 # Binary version for the document backends
  38 m4_define([ev_binary_version],[ev_document_lt_current])
  39
  40 # *****************************************************************************
  41
  42 AC_PREREQ([2.57])
  43 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
  44 AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip])
  45
  46 AC_CONFIG_HEADERS([config.h])
  47 AC_CONFIG_MACRO_DIR([m4])
  48
  49 if test -z "$enable_maintainer_mode"; then
  50   enable_maintainer_mode=yes
  51 fi
  52 AM_MAINTAINER_MODE([enable])
  53
  54 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  55
  56 AM_PROG_LIBTOOL
  57
  58 AC_ISC_POSIX
  59 AC_PROG_CC
  60 AM_PROG_CC_STDC
  61 AM_PROG_CC_C_O
  62 AC_PROG_CXX
  63 AC_STDC_HEADERS
  64 IT_PROG_INTLTOOL([0.35.0])
  65 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  66 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  67
  68 GNOME_COMMON_INIT
  69 GNOME_DOC_INIT
  70 GNOME_MAINTAINER_MODE_DEFINES
  71 GNOME_COMPILE_WARNINGS
  72 GNOME_CXX_WARNINGS
  73
  74 GTK_DOC_CHECK(1.0)
  75
  76 GETTEXT_PACKAGE=evince
  77 AC_SUBST(GETTEXT_PACKAGE)
  78 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  79 AM_GLIB_GNU_GETTEXT
  80
  81 # Check which platform to use
  82
  83 AC_MSG_CHECKING([for which platform to build])
  84 AC_ARG_WITH([platform],
  85   [AS_HELP_STRING([--with-platform=gnome|win32|hildon (default: gnome)])],
  86   [case "$withval" in
  87     gnome|win32|hildon) ;;
  88     *) AC_MSG_ERROR([invalid argument "$withval" for --with-platform]) ;;
  89    esac],
  90   [case "$host" in
  91      *-*-mingw*|*-*-cygwin*) with_platform="win32" ;;
  92      *) with_platform=gnome ;;
  93    esac])
  94
  95 AC_MSG_RESULT([$with_platform])
  96
  97 if test "$with_platform" = "win32"; then
  98   AC_CHECK_TOOL([WINDRES],[windres])
  99   AC_MSG_CHECKING([for native Win32])
 100   case "$host" in
 101     *-*-mingw*)
 102       os_win32=yes
 103       ;;
 104     *)
 105       os_win32=no
 106       ;;
 107   esac
 108   AC_MSG_RESULT([$os_win32])
 109 fi
 110
 111 AM_CONDITIONAL([PLATFORM_HILDON],[test "$with_platform" = "hildon"])
 112 AM_CONDITIONAL([PLATFORM_WIN32],[test "$with_platform" = "win32"])
 113
 114 dnl Specify required versions of dependencies
 115 DBUS_GLIB_REQUIRED=0.70
 116 GTK_REQUIRED=2.12.0
 117 GLIB_REQUIRED=2.18.0
 118 KEYRING_REQUIRED=2.22.0
 119 AC_SUBST([GLIB_REQUIRED])
 120 AC_SUBST([GTK_REQUIRED])
 121
 122 GNOME_ICON_THEME_REQUIRED=2.17.1
 123 LIBXML_REQUIRED=2.5.0
 124
 125 dnl Check dependencies
 126
 127 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
 128 # BACKEND_CFLAGS   for backend implementations.
 129 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
 130 # FRONTEND_LIBS
 131 # SHELL_CFLAGS     for shell implementation.
 132 # SHELL_LIBS
 133
 134 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
 135 PKG_CHECK_MODULES(LIBVIEW, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 136 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
 137 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 138 PKG_CHECK_MODULES(PREVIEWER, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 139
 140 SHELL_PLATFORM_PKGS=
 141 case "$with_platform" in
 142   hildon) AC_DEFINE([PLATFORM_HILDON],[1],[Define if building for the hildon platform])
 143           SHELL_PLATFORM_PKGS="hildon-1 hildon-fm-2 libosso"
 144           ;;
 145   *) SHELL_PLATFORM_PKGS="gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED"
 146      ;;
 147 esac
 148
 149 PKG_CHECK_MODULES([SHELL_CORE],[libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gthread-2.0 $SHELL_PLATFORM_PKGS])
 150
 151 # *********
 152 # SM client
 153 # *********
 154
 155 GDK_TARGET="$($PKG_CONFIG --variable target gdk-2.0)"
 156
 157 SMCLIENT_PKGS=
 158 AC_MSG_CHECKING([which smclient backend to use])
 159 AC_ARG_WITH([smclient],
 160   [AS_HELP_STRING([--with-smclient-backend],[which smclient backend to use (no|xsmp|win32|quartz)])],
 161   [],
 162   [case "$GDK_TARGET" in
 163     x11) case "$with_platform" in
 164            gnome) with_smclient=xsmp SMCLIENT_PKGS="sm >= 1.0.0" ;;
 165            *) with_smclient=no ;;
 166          esac ;;
 167     win32|quartz) with_smclient=$GDK_TARGET ;;
 168     *) with_smclient=no ;;
 169    esac])
 170 AC_MSG_RESULT([$with_smclient])
 171
 172 if test "$with_smclient" != "no"; then
 173   AC_DEFINE([WITH_SMCLIENT],[1],[Define if smclient is enabled])
 174
 175   PKG_CHECK_MODULES([SMCLIENT],[gtk+-2.0 gthread-2.0 $SMCLIENT_PKGS])
 176   AC_SUBST([SMCLIENT_CFLAGS])
 177   AC_SUBST([SMCLIENT_LIBS])
 178 fi
 179
 180 AM_CONDITIONAL([WITH_SMCLIENT],[test "$with_smclient" != "no"])
 181 AM_CONDITIONAL([WITH_SMCLIENT_XSMP],[test "$with_smclient" = "xsmp"])
 182 AM_CONDITIONAL([WITH_SMCLIENT_WIN32],[test "$with_smclient" = "win32"])
 183 AM_CONDITIONAL([WITH_SMCLIENT_QUARTZ],[test "$with_smclient" = "quartz"])
 184
 185 # ***
 186
 187 BACKEND_LIBTOOL_FLAGS="-module -avoid-version -no-undefined -export-symbols \$(top_srcdir)/backend/backend.symbols"
 188 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
 189
 190 dnl ===== Check special functions
 191 evince_save_LIBS=$LIBS
 192 LIBS="$LIBS $BACKEND_LIBS"
 193 AC_CHECK_FUNCS(cairo_format_stride_for_width)
 194 LIBS=$evince_save_LIBS
 195
 196 # ******************
 197 # GKT+ Unix Printing
 198 # ******************
 199
 200 AC_MSG_CHECKING([whether gtk+-unix-print support is requested])
 201 AC_ARG_WITH([gtk-unix-print],
 202   [AS_HELP_STRING([--without-gtk-unix-print],[disable the use of gtk-unix-print])],
 203   [],[case "$os_win32" in
 204         yes) with_gtk_unix_print=no ;;
 205         *) with_gtk_unix_print=yes ;;
 206       esac])
 207 AC_MSG_RESULT([$with_gtk_unix_print])
 208
 209 if test "$with_gtk_unix_print" = "yes"; then
 210    PKG_CHECK_MODULES(GTKUNIXPRINT, [gtk+-unix-print-2.0 >= $GTK_REQUIRED])
 211    AC_DEFINE([GTKUNIXPRINT_ENABLED], [1], [Define if gtk+-unix-print is enabled.])
 212 fi
 213
 214 # *********************
 215 # GNOME Keyring support
 216 # *********************
 217
 218 AC_ARG_WITH(keyring,
 219         [AS_HELP_STRING([--without-keyring],[disable the use of gnome-keyring])],
 220         [],
 221         [case "$with_platform" in
 222            gnome) with_keyring=yes ;;
 223            hildon|win32) with_keyring=no ;;
 224          esac])
 225
 226 AM_CONDITIONAL([WITH_KEYRING],[test "$with_keyring" = "yes"])
 227
 228 if test "$with_keyring" = "yes"; then
 229         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
 230         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
 231 fi
 232
 233 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
 234 AC_SUBST(GLIB_GENMARSHAL)
 235
 236 # ****
 237 # DBUS
 238 # ****
 239
 240 AC_ARG_ENABLE([dbus],
 241   [AS_HELP_STRING([--enable-dbus], [Compile with support for dbus])],
 242   [],
 243   [case "$with_platform" in
 244       gnome) enable_dbus=yes ;;
 245       hildon) enable_dbus=no ;;
 246     esac])
 247
 248 if test "$enable_dbus" = "yes"; then
 249   PKG_CHECK_MODULES([DBUS],[dbus-glib-1 >= $DBUS_GLIB_REQUIRED],[],
 250                     [AC_MSG_ERROR([DBUS not found; use --disable-dbus to disable DBUS support])])
 251
 252   AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 253   if test x$DBUS_BINDING_TOOL = "xno" ; then
 254           AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 255   fi
 256
 257   AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 258 fi
 259
 260 AC_SUBST([DBUS_CFLAGS])
 261 AC_SUBST([DBUS_LIBS])
 262
 263 AM_CONDITIONAL([ENABLE_DBUS], [test "$enable_dbus" = "yes"])
 264
 265 dnl ========= Check for GConf
 266
 267 AC_MSG_CHECKING([whether GConf support is requested])
 268 AC_ARG_WITH([gconf],
 269   [AS_HELP_STRING([--without-gconf],[disable the use of gconf])],
 270   [],
 271   [case "$os_win32" in
 272      yes) with_gconf=no ;;
 273      *) with_gconf=yes ;;
 274    esac])
 275 AC_MSG_RESULT([$with_gconf])
 276
 277 AM_CONDITIONAL([WITH_GCONF],[test "$with_gconf" = "yes"])
 278
 279 if test "$with_gconf" = "yes"; then
 280    PKG_CHECK_MODULES([GCONF],[gconf-2.0])
 281    AC_DEFINE([WITH_GCONF],[1],[Define if GConf support is enabled])
 282
 283    AM_GCONF_SOURCE_2
 284
 285    AC_PATH_PROG([GCONFTOOL], [gconftool-2], [false])
 286    if test "$GCONFTOOL" = "false"; then
 287       AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 288    fi
 289 else
 290    AM_CONDITIONAL([GCONF_SCHEMAS_INSTALL],false)
 291 fi
 292
 293 dnl Debug mode
 294
 295 AC_ARG_ENABLE([debug],
 296         AC_HELP_STRING([--enable-debug],
 297                         [Turn on evince debug mode]),,
 298                 [enable_debug=no])
 299
 300 if test "x$enable_debug" = "xyes"; then
 301    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 302 fi
 303
 304
 305 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 306 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 307 AC_SUBST(LIBDOCUMENT_CFLAGS)
 308 AC_SUBST(LIBDOCUMENT_LIBS)
 309
 310 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $DEBUG_FLAGS"
 311 LIBVIEW_LIBS="$LIBVIEW_LIBS"
 312 AC_SUBST(LIBVIEW_CFLAGS)
 313 AC_SUBST(LIBVIEW_LIBS)
 314
 315 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 316 AC_SUBST(BACKEND_CFLAGS)
 317 AC_SUBST(BACKEND_LIBS)
 318
 319 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $GTKUNIXPRINT_CFLAGS $DBUS_CFLAGS $KEYRING_CFLAGS $GCONF_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 320 SHELL_LIBS="$SHELL_CORE_LIBS $GTKUNIXPRINT_CFLAGS $DBUS_LIBS $KEYRING_LIBS $GCONF_LIBS -lz"
 321 AC_SUBST(SHELL_CFLAGS)
 322 AC_SUBST(SHELL_LIBS)
 323
 324 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 325 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 326 AC_SUBST(FRONTEND_CFLAGS)
 327 AC_SUBST(FRONTEND_LIBS)
 328
 329 # Check for Nautilus property page build
 330 AC_ARG_ENABLE([nautilus],
 331   [AS_HELP_STRING([--disable-nautilus],[Build the nautilus extensions])],
 332   [],
 333   [case "$with_platform" in
 334      gnome) enable_nautilus=yes ;;
 335      *) enable_nautilus=no ;;
 336     esac])
 337
 338 if test "$enable_nautilus" = "yes" ; then
 339   PKG_CHECK_MODULES([NAUTILUS],[gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension],
 340                     [],[AC_MSG_ERROR([libnautilus-extension not found; use --disable-nautilus to disable the nautilus extensions])])
 341   NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 342   AC_SUBST([nautilusextensiondir],[$NAUTILUS_EXTENSION_DIR])
 343   AC_SUBST(NAUTILUS_CFLAGS)
 344   AC_SUBST(NAUTILUS_LIBS)
 345
 346   AC_DEFINE([HAVE_NAUTILUS],[1], [defined if you build the nautilus plugin])
 347 fi
 348
 349 AM_CONDITIONAL([ENABLE_NAUTILUS],[test "$enable_nautilus" = "yes"])
 350
 351 # Check for thumbnailer build
 352
 353 AC_ARG_ENABLE([thumbnailer],
 354   [AS_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer])],
 355   [],
 356   [case "$with_platform" in
 357      gnome) enable_thumbnailer=yes ;;
 358      *) enable_thumbnailer=no ;;
 359     esac])
 360
 361 AM_CONDITIONAL([ENABLE_THUMBNAILER],[test "$enable_thumbnailer" = "yes"])
 362
 363 # ***************
 364 # Print Previewer
 365 # ***************
 366
 367 AC_ARG_ENABLE([previewer],
 368   [AS_HELP_STRING([--disable-previewer],[disable the GNOME Document Previewer])],
 369   [],
 370   [case "$with_platform" in
 371       gnome) enable_previewer=yes ;;
 372       *) enable_previewer=no ;;
 373     esac])
 374
 375 if test x$enable_previewer = "xyes" ; then
 376   PKG_CHECK_MODULES([PREVIEWER],[gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED])
 377 fi
 378
 379 AM_CONDITIONAL([ENABLE_PREVIEWER],[test "$enable_previewer" = "yes"])
 380 PREVIEWER_CFLAGS="$PREVIEWER_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 381 PREVIEWER_LIBS="$PREVIEWER_LIBS $GTKUNIXPRINT_LIBS -lz"
 382 AC_SUBST(PREVIEWER_CFLAGS)
 383 AC_SUBST(PREVIEWER_LIBS)
 384
 385 # ***
 386 # GIR
 387 # ***
 388
 389 AC_MSG_CHECKING([whether GObject introspection is requested])
 390 AC_ARG_ENABLE([introspection],
 391         AS_HELP_STRING([--enable-introspection],[Enable GObject introspection]),
 392         [],[enable_introspection=no])
 393 AC_MSG_RESULT([$enable_introspection])
 394
 395 G_IR_SCANNER=
 396 G_IR_COMPILER=
 397 G_IR_GENERATE=
 398 GIRDIR=
 399 GIRTYPELIBDIR=
 400
 401 if test "$enable_introspection" = "yes"; then
 402   GOBJECT_INTROSPECTION_REQUIRED=0.6
 403   PKG_CHECK_MODULES([GOBJECT_INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
 404
 405   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
 406   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
 407   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
 408   GIRDIR="$($PKG_CONFIG --variable=girdir gobject-introspection-1.0)"
 409   GIRTYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
 410 fi
 411
 412 AC_SUBST([G_IR_SCANNER])
 413 AC_SUBST([G_IR_COMPILER])
 414 AC_SUBST([G_IR_GENERATE])
 415 AC_SUBST([GIRDIR])
 416 AC_SUBST([GIRTYPELIBDIR])
 417
 418 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
 419
 420 dnl ================== portability checks ===========================================
 421
 422 dnl for backtrace()
 423 AC_CHECK_HEADERS([execinfo.h])
 424
 425 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 426   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 427   ],[],[#include <langinfo.h>])
 428
 429 dnl ================== pdf checks ===================================================
 430 AC_ARG_ENABLE(pdf,
 431               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 432
 433 if test "x$enable_pdf" = "xyes"; then
 434     POPPLER_REQUIRED=0.11.0
 435     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED,enable_pdf=yes,enable_pdf=no)
 436
 437     if test "x$enable_pdf" = "xyes"; then
 438             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 439             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 440             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 441
 442             evince_save_LIBS=$LIBS
 443             LIBS="$LIBS $POPPLER_LIBS"
 444             AC_CHECK_FUNCS(poppler_page_render)
 445             AC_CHECK_FUNCS(poppler_page_get_image)
 446             LIBS=$evince_save_LIBS
 447
 448             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 449             if test x$enable_cairo_pdf = xyes; then
 450                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 451             fi
 452
 453             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 454             if test x$enable_cairo_ps = xyes; then
 455                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 456             fi
 457     else
 458             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 459     fi
 460 fi
 461
 462 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 463 dnl ================== end of pdf checks ============================================
 464
 465 dnl libspectre (used by ps and dvi backends)
 466 SPECTRE_REQUIRED=0.2.0
 467 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 468 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 469 if test "x$have_spectre" = "xyes"; then
 470    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 471 fi
 472
 473 dnl ================== ps checks ====================================================
 474 AC_ARG_ENABLE(ps,
 475         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 476
 477 if test "x$enable_ps" = "xyes"; then
 478    if test "x$have_spectre" = "xyes"; then
 479       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 480    else
 481       enable_ps="no"
 482       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 483    fi
 484 fi
 485 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 486 dnl ======================== End of ps checks ===================================
 487
 488 dnl ================== tiff checks ===================================================
 489 AC_ARG_ENABLE(tiff,
 490             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 491
 492 if test "x$enable_tiff" = "xyes"; then
 493     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 494     if test "x$enable_tiff" = "xyes"; then
 495         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 496         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 497     fi
 498     if test "x$enable_tiff" = "xyes"; then
 499             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 500     else
 501             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 502     fi
 503 fi
 504
 505 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 506 dnl ================== end of tiff checks ============================================
 507
 508 dnl ================== djvu checks ===================================================
 509
 510 AC_ARG_ENABLE(djvu,
 511             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=yes)
 512
 513 if test "x$enable_djvu" = "xyes"; then
 514     DJVULIBRE_REQUIRED=3.5.17
 515     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 516
 517     if test "x$enable_djvu" = "xyes"; then
 518         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 519     else
 520         AC_MSG_WARN([
 521 ** Djvu support is disabled since a recent version of the djvulibre
 522 ** library was not found. You need at least djvulibre-3.5.17 which
 523 ** can be found on http://djvulibre.djvuzone.org
 524 ])
 525     fi
 526 fi
 527
 528 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 529
 530 dnl ================== End of djvu checks ===================================================
 531
 532 dnl ================== dvi checks ===================================================
 533
 534 AC_ARG_ENABLE(dvi,
 535             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=yes)
 536
 537 AC_ARG_ENABLE(t1lib,
 538             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 539
 540 if test "x$enable_dvi" = "xyes"; then
 541     AC_C_CONST
 542     AC_C_INLINE
 543     AC_TYPE_SIZE_T
 544     AC_CHECK_SIZEOF(long, 4)
 545     AC_CHECK_SIZEOF(int, 4)
 546     AC_CHECK_SIZEOF(short, 2)
 547     AC_CHECK_SIZEOF(void *, 4)
 548     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 549
 550     if test "x$enable_dvi" = "xyes"; then
 551         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 552     else
 553         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 554     fi
 555 fi
 556 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 557
 558 if test "x$enable_dvi" = "xyes"; then
 559     if test "x$enable_type1_fonts" = "xyes"; then
 560         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 561     fi
 562
 563     if test "x$enable_type1_fonts" = xyes; then
 564         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 565     fi
 566 else
 567     enable_type1_fonts=no
 568 fi
 569 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 570
 571 dnl ================== End of dvi checks ===================================================
 572
 573 dnl ================== pixbuf checks ===================================================
 574
 575 AC_ARG_ENABLE(pixbuf,
 576             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 577 if test "x$enable_pixbuf" = "xyes"; then
 578         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 579 fi
 580 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 581
 582 dnl ================== End of pixbuf checks ===================================================
 583
 584 dnl ================== comic book checks ===================================================
 585
 586 AC_ARG_ENABLE(comics,
 587         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=yes)
 588 if test "x$enable_comics" = "xyes"; then
 589         if test "x$os_win32" = "xyes"; then
 590                 # The comics backend is disabled on windows because:
 591                 # 1) it uses unix functions from sys/wait.h.
 592                 # 2) it uses external decompression tools not generally available on windows.
 593                 enable_comics=no
 594                 AC_MSG_WARN(The comics backend is not supported on windows.)
 595         else
 596                 AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 597         fi
 598 fi
 599 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 600
 601 dnl ================== End of comic book checks ============================================
 602
 603 dnl ================== impress book checks ===================================================
 604
 605 AC_ARG_ENABLE(impress,
 606         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 607 if test "x$enable_impress" = "xyes"; then
 608         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 609 fi
 610 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 611
 612 dnl ================== End of impress book checks ============================================
 613
 614 dnl =================== Mime types list ====================================================
 615
 616 if test "x$enable_pdf" = "xyes" ; then
 617         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 618 fi
 619 if test "x$enable_ps" = "xyes" ; then
 620         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 621 fi
 622 if test "x$enable_dvi" = "xyes"; then
 623         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 624 fi
 625 if test "x$enable_djvu" = "xyes"; then
 626         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 627 fi
 628 if test "x$enable_tiff" = "xyes"; then
 629         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 630 fi
 631 if test "x$enable_comics" = "xyes"; then
 632         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;"
 633 fi
 634 if test "x$enable_pixbuf" = "xyes"; then
 635         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 636 fi
 637 if test "x$enable_impress" = "xyes"; then
 638         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 639 fi
 640 AC_SUBST(EVINCE_MIME_TYPES)
 641
 642 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 643
 644 # Backends directory
 645
 646 AC_SUBST([backenddir],"\$(libdir)/evince/ev_binary_version/backends")
 647 AC_SUBST([backend_binary_version],"ev_binary_version")
 648
 649 # Versioning
 650
 651 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
 652 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
 653 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
 654
 655 AC_SUBST([EV_API_VERSION],[ev_api_version])
 656 AC_SUBST([EV_BINARY_VERSION],[ev_binary_version])
 657
 658 AC_SUBST([EV_DOCUMENT_LT_VERSION_INFO],[ev_document_lt_version_info])
 659 AC_SUBST([EV_DOCUMENT_LT_CURRENT_MINUS_AGE],[ev_document_lt_current_minus_age])
 660 AC_SUBST([EV_VIEW_LT_VERSION_INFO],[ev_view_lt_version_info])
 661 AC_SUBST([EV_VIEW_LT_CURRENT_MINUS_AGE],[ev_view_lt_current_minus_age])
 662
 663 # *****************************************************************************
 664
 665 AC_CONFIG_FILES([
 666 backend/Makefile
 667 backend/comics/Makefile
 668 backend/djvu/Makefile
 669 backend/dvi/Makefile
 670 backend/dvi/mdvi-lib/Makefile
 671 backend/impress/Makefile
 672 backend/pdf/Makefile
 673 backend/pixbuf/Makefile
 674 backend/ps/Makefile
 675 backend/tiff/Makefile
 676 cut-n-paste/Makefile
 677 cut-n-paste/gedit-message-area/Makefile
 678 cut-n-paste/gimpcellrenderertoggle/Makefile
 679 cut-n-paste/smclient/Makefile
 680 cut-n-paste/toolbar-editor/Makefile
 681 cut-n-paste/zoom-control/Makefile
 682 cut-n-paste/totem-screensaver/Makefile
 683 data/evince.desktop.in
 684 data/Makefile
 685 data/icons/Makefile
 686 data/icons/16x16/Makefile
 687 data/icons/16x16/apps/Makefile
 688 data/icons/16x16/actions/Makefile
 689 data/icons/22x22/Makefile
 690 data/icons/22x22/apps/Makefile
 691 data/icons/22x22/actions/Makefile
 692 data/icons/24x24/Makefile
 693 data/icons/24x24/apps/Makefile
 694 data/icons/24x24/actions/Makefile
 695 data/icons/32x32/Makefile
 696 data/icons/32x32/actions/Makefile
 697 data/icons/48x48/Makefile
 698 data/icons/48x48/apps/Makefile
 699 data/icons/48x48/actions/Makefile
 700 data/icons/scalable/Makefile
 701 data/icons/scalable/apps/Makefile
 702 help/Makefile
 703 help/reference/Makefile
 704 help/reference/libdocument/Makefile
 705 help/reference/libdocument/version.xml
 706 help/reference/libview/Makefile
 707 help/reference/libview/version.xml
 708 help/reference/shell/Makefile
 709 help/reference/shell/version.xml
 710 libdocument/Makefile
 711 libdocument/ev-version.h
 712 libmisc/Makefile
 713 libview/Makefile
 714 Makefile
 715 po/Makefile.in
 716 previewer/Makefile
 717 properties/Makefile
 718 shell/Makefile
 719 test/Makefile
 720 thumbnailer/Makefile
 721 ])
 722
 723 AC_CONFIG_FILES(evince-document-[]ev_api_version[].pc:evince-document.pc.in)
 724 AC_CONFIG_FILES(evince-view-[]ev_api_version[].pc:evince-view.pc.in)
 725
 726 AC_OUTPUT
 727
 728 echo "
 729 Configure summary:
 730         Platform...........:  $with_platform
 731         GConf Support......:  $with_gconf
 732         GTK+ Unix Print....:  $with_gtk_unix_print
 733         Keyring Support....:  $with_keyring
 734         DBUS Support.......:  $enable_dbus
 735         SM client support..:  $with_smclient
 736         Nautilus Plugin....:  $enable_nautilus
 737         Thumbnailer........:  $enable_thumbnailer
 738         Previewer..........:  $enable_previewer
 739         Gtk-Doc Support....:  $enable_gtk_doc
 740         Debug mode.........:  $enable_debug
 741         GObj. Introspection:  $enable_introspection
 742
 743         PDF Backend........:  $enable_pdf
 744         PostScript Backend.:  $enable_ps
 745         TIFF Backend.......:  $enable_tiff
 746         DJVU Backend.......:  $enable_djvu
 747         DVI Backend........:  $enable_dvi
 748         Pixbuf Backend.....:  $enable_pixbuf
 749         Comics Backend.....:  $enable_comics
 750         Impress Backend....:  $enable_impress
 751 "