#!/usr/bin/perl -w

package SCX::GUI;

use strict;
use utf8;

use Encode;
use Gtk2 '-init';
use Glib qw(TRUE FALSE);

use SCX::Reader;

sub new {
	my ($class, $args) = @_;

	my $self = {
		throttle_images => [ 
			load_image_set('img/throttle%d.svg', 13, 100)
		],
		fuel_images => [
			load_image_set('img/fuel%d.svg', 8, 100)
		],
		car_images => load_image_dir('img/SCXCars', 100),
		builder => Gtk2::Builder->new,
	};

	bless $self, $class;

	$self->{builder}->add_from_file('slotcarman.glade');

	$self->{builder}->connect_signals(undef);

	return $self;
}

sub show {
	my ($self) = @_;

	my $window = $self->{builder}->get_object('slotcarman');
	$window->show();
}

sub get_object { return shift->{builder}->get_object(@_); }

sub load_image_set {
	my ($pattern, $limit, $height) = @_;

	my @rv;
	for my $i (0..$limit) {
		my $file = sprintf($pattern, $i);
		
		my $dummy = Gtk2::Gdk::Pixbuf->new_from_file($file);
		my $width = $dummy->get_width * $height / $dummy->get_height;
		push @rv, Gtk2::Gdk::Pixbuf->new_from_file_at_scale(
			$file, $width, $height, TRUE
		);
	}
	return @rv;
}

sub load_image_dir {
	my ($dir, $height) = @_;

	my %rv;
	for my $file (<$dir/*>) {
		$file = Encode::decode('utf-8', $file);
		my $name = $file;
		$name =~ s/.*\///;
		$name =~ s/\..*?$//;
		$name =~ s/[-_]/ /g;
		$name =~ s/\s+/ /g;


		my $dummy = Gtk2::Gdk::Pixbuf->new_from_file($file)
			or next;

		my $width = $dummy->get_width * $height / $dummy->get_height;
		$rv{$name} = Gtk2::Gdk::Pixbuf->new_from_file_at_scale(
			$file, $width, $height, TRUE
		);
	}
	return \%rv;
}

sub set_throttle {
	my ($self, $row, $val) = @_;

	$row++;
	$val = 13 if !defined $val;

	my $image = $self->get_object("image_throttle$row");
	$image->set_from_pixbuf($self->{throttle_images}->[$val]);
}

sub set_fuel {
	my ($self, $row, $val) = @_;

	$row++;
	$val = 0 if !defined $val;

	my $image = $self->get_object("image_fuel$row");
	$image->set_from_pixbuf($self->{fuel_images}->[$val]);
}

sub set_car_icon {
	my ($self, $row, $name) = @_;

	$row++;
	my $pixbuf = $self->{car_images}->{$name};
	if (!$pixbuf) {
		print "No car image for $name.\n";
		return;
	}

	my $image = $self->get_object("image_car$row");
	$image->set_from_pixbuf($pixbuf);
}

sub set_lap {
	my ($self, $row, $text) = @_;

	++$row;
	my $label = $self->get_object("label_lap$row")
		or die "Can't get label_lap$row";
	$label->set_markup('<span font_desc="24" weight="bold">'.$text.'</span>');
}

sub set_laptime {
	my ($self, $row, $text) = @_;

	++$row;
	my $label = $self->get_object("label_laptime$row")
		or die "Can't get label_laptime$row";
	$label->set_markup('<span font_desc="18" weight="bold">'.$text.'</span>');
}

sub set_best_lap {
	my ($self, $row, $text) = @_;

	++$row;
	my $label = $self->get_object("label_best_lap$row")
		or die "Can't get label_best_lap$row";
	$label->set_markup('<span font_desc="18" weight="bold">'.$text.'</span>');
}

sub set_driver {
	my ($self, $row, $text) = @_;

	++$row;
	my $label = $self->get_object("label_name$row")
		or die "Can't get label_lap$row";
	$label->set_markup('<span font_desc="18" weight="bold">'.$text.'</span>');
}

1;