#!/usr/bin/perl -w

package SCX::GUI;

use strict;
use utf8;

use Encode;
use Gtk2 '-init';
use Glib qw(TRUE FALSE);

use SCX::Reader;

sub new {
	my ($class, $args) = @_;

	my $self = {
		throttle_images => [ 
			load_image_set('img/throttle%d.svg', 13, 100)
		],
		fuel_images => [
			load_image_set('img/fuel%d.svg', 8, 60)
		],
		car_images => load_image_dir('img/SCXCars', 100),
		semaphore_images => [
			load_image_set('img/semaphore%d.svg', 5, 200)
		],
		builder => Gtk2::Builder->new,
		semaphore_win => Gtk2::Window->new('popup'),
		semaphore_img => Gtk2::Image->new,
	};

	bless $self, $class;

	$self->{builder}->add_from_file('slotcarman.glade');

	$self->{builder}->connect_signals(undef);

	my $pixbuf = $self->{semaphore_images}->[0];
	$self->{semaphore_img}->set_from_pixbuf($pixbuf);
	$self->{semaphore_img}->show;
	$self->{semaphore_win}->add($self->{semaphore_img});
	$self->{semaphore_win}->set_type_hint('splashscreen');
	$self->{semaphore_win}->set_position('center-on-parent');
	$self->{semaphore_win}->set_transient_for(
		$self->{builder}->get_object('slotcarman')
	);

	return $self;
}

sub show {
	my ($self) = @_;

	my $window = $self->{builder}->get_object('slotcarman');
	$window->signal_connect(delete_event => \&delete_event);
	$window->show();
}

sub delete_event { Gtk2->main_quit; }

sub get_object { return shift->{builder}->get_object(@_); }

sub load_image_set {
	my ($pattern, $limit, $height) = @_;

	my @rv;
	for my $i (0..$limit) {
		my $file = sprintf($pattern, $i);
		
		my $dummy = Gtk2::Gdk::Pixbuf->new_from_file($file);
		my $width = $dummy->get_width * $height / $dummy->get_height;
		push @rv, Gtk2::Gdk::Pixbuf->new_from_file_at_scale(
			$file, $width, $height, TRUE
		);
	}
	return @rv;
}

sub load_image_dir {
	my ($dir, $height) = @_;

	my %rv;
	for my $file (<$dir/*>) {
		$file = Encode::decode('utf-8', $file);
		my $name = $file;
		$name =~ s/.*\///;
		$name =~ s/\..*?$//;
		$name =~ s/[-_]/ /g;
		$name =~ s/\s+/ /g;


		my $dummy = Gtk2::Gdk::Pixbuf->new_from_file($file)
			or next;

		my $width = $dummy->get_width * $height / $dummy->get_height;
		$rv{$name} = Gtk2::Gdk::Pixbuf->new_from_file_at_scale(
			$file, $width, $height, TRUE
		);
	}
	return \%rv;
}

sub set_throttle {
	my ($self, $row, $val) = @_;

	$row++;
	$val = 13 if !defined $val;

	my $image = $self->get_object("image_throttle$row");
	$image->set_from_pixbuf($self->{throttle_images}->[$val]);
}

sub set_fuel {
	my ($self, $row, $val) = @_;

	$row++;
	$val = 0 if !defined $val;

	my $image = $self->get_object("image_fuel$row");
	$image->set_from_pixbuf($self->{fuel_images}->[$val]);
}

sub set_car_icon {
	my ($self, $row, $name) = @_;

	$row++;
	my $pixbuf = $self->{car_images}->{$name};
	if (!$pixbuf) {
		print "No car image for $name.\n";
		return;
	}

	my $image = $self->get_object("image_car$row");
	$image->set_from_pixbuf($pixbuf);
}

sub set_lap {
	my ($self, $row, $text) = @_;

	++$row;
	my $label = $self->get_object("label_lap$row")
		or die "Can't get label_lap$row";
	$label->set_markup('<span font_desc="24" weight="bold">'.$text.'</span>');
}

sub set_laptime {
	my ($self, $row, $text) = @_;

	++$row;
	my $label = $self->get_object("label_laptime$row")
		or die "Can't get label_laptime$row";
	$label->set_markup('<span font_desc="18" weight="bold">'.$text.'</span>');
}

sub set_best_lap {
	my ($self, $row, $text, $global) = @_;

	++$row;
	my $label = $self->get_object("label_best_lap$row")
		or die "Can't get label_best_lap$row";

	if ($global) {
		$global = ' foreground="#e00000"';
	} else {
		$global = '';
	}

	$label->set_markup('<span font_desc="18" weight="bold"'.$global.'>'
		.$text.'</span>');
}

sub set_driver {
	my ($self, $row, $text) = @_;

	++$row;
	my $label = $self->get_object("label_name$row")
		or die "Can't get label_lap$row";
	$label->set_markup('<span font_desc="18" weight="bold">'.$text.'</span>');
}

sub enter_pit_lane {
	my ($self, $row) = @_;
	$self->set_laptime($row, 'PIT');
}

sub leave_pit_lane {
	my ($self, $row) = @_;
	$self->set_laptime($row, 'GO!');
}

sub show_semaphore {
	my ($self, $num) = @_;

	my $win = $self->{semaphore_win};
	if (defined $num) {
		my $img = $self->{semaphore_img};
		my $pixbuf = $self->{semaphore_images}->[$num];
		$img->set_from_pixbuf($pixbuf);
		$win->show;
	} else {
		$win->hide;
	}
}

sub rounds {
	my ($self, $text) = @_;

	my $label = $self->get_object("label_lap_global")
		or die "Can't get label_lap_global";
	$label->set_markup('<span font_desc="18" weight="bold">Lap: '.$text.'</span>');
}

sub time {
	my ($self, $text) = @_;

	my $label = $self->get_object("label_time_global")
		or die "Can't get label_time_global";
	$label->set_markup('<span font_desc="18" weight="bold">Time: '.$text.'</span>');
}

sub best_lap {
	my ($self, $time, $who) = @_;

	my $text = $time;
	$text .= ' by ' . $who
		if defined $who;

	my $label = $self->get_object("label_best_lap_global")
		or die "Can't get label_best_lap_global";
	$label->set_markup('<span font_desc="18" weight="bold">Best lap: '.$text.'</span>');
}

1;