configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.57)
   4 AC_INIT([Evince],[2.22.1.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
   5 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-dist-gzip])
   6
   7 EV_API_VERSION=2.20
   8 AC_SUBST(EV_API_VERSION)
   9
  10 AM_CONFIG_HEADER(config.h)
  11
  12 AM_MAINTAINER_MODE
  13
  14 AM_PROG_LIBTOOL
  15
  16 AC_ISC_POSIX
  17 AC_PROG_CC
  18 AM_PROG_CC_STDC
  19 AC_PROG_CXX
  20 AC_STDC_HEADERS
  21 IT_PROG_INTLTOOL([0.35.0])
  22 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  23 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  24
  25 GNOME_COMMON_INIT
  26 GNOME_DOC_INIT
  27 GNOME_MAINTAINER_MODE_DEFINES
  28 GNOME_COMPILE_WARNINGS
  29 GNOME_CXX_WARNINGS
  30 GNOME_DEBUG_CHECK
  31
  32 GTK_DOC_CHECK(1.0)
  33
  34 GETTEXT_PACKAGE=evince
  35 AC_SUBST(GETTEXT_PACKAGE)
  36 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  37 AM_GLIB_GNU_GETTEXT
  38
  39 dnl Check dependencies
  40
  41 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
  42 # BACKEND_CFLAGS   for backend implementations.
  43 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
  44 # FRONTEND_LIBS
  45 # SHELL_CFLAGS     for shell implementation.
  46 # SHELL_LIBS
  47
  48 DBUS_GLIB_REQUIRED=0.70
  49 GTK_REQUIRED=2.10.0
  50 GLIB_REQUIRED=2.15.6
  51 KEYRING_REQUIRED=0.4.0
  52
  53 LIBGNOMEUI_REQUIRED=2.14.0
  54 LIBGNOME_REQUIRED=2.14.0
  55 GNOME_ICON_THEME_REQUIRED=2.17.1
  56 LIBXML_REQUIRED=2.5.0
  57
  58 PKG_CHECK_MODULES(LIB, gtk+-2.0 >= $GTK_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
  59 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
  60 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED libglade-2.0 gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
  61 PKG_CHECK_MODULES(SHELL_CORE, libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED gthread-2.0 libglade-2.0 gconf-2.0)
  62
  63 BACKEND_LIBTOOL_FLAGS="-module -avoid-version"
  64 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
  65
  66 dnl ===== Check special functions
  67 evince_save_LIBS=$LIBS
  68 LIBS="$LIBS $BACKEND_LIBS"
  69 AC_CHECK_FUNCS(cairo_format_stride_for_width)
  70 LIBS=$evince_save_LIBS
  71
  72 AC_ARG_WITH(keyring,
  73         AC_HELP_STRING([--without-keyring],[disable the use of gnome-keyring]),
  74         [case "${withval}" in
  75         yes) WITH_KEYRING=yes ;;
  76         no) WITH_KEYRING=no ;;
  77         *) AC_MSG_ERROR(bad value ${withval} for --with-keyring) ;;
  78         esac],
  79         [WITH_KEYRING=yes]) dnl Default value
  80 AM_CONDITIONAL(WITH_KEYRING, test x$WITH_KEYRING = "xyes")
  81
  82 if test x$WITH_KEYRING = "xyes"; then
  83         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
  84         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
  85 fi
  86
  87 AC_ARG_WITH(libgnome,
  88         AC_HELP_STRING([--without-libgnome],[disable the use of libgnome]),
  89         [case "${withval}" in
  90         yes) WITH_GNOME=yes ;;
  91         no) WITH_GNOME=no ;;
  92         *) AC_MSG_ERROR(bad value ${withval} for --with-libgnome) ;;
  93         esac],
  94         [WITH_GNOME=yes]) dnl Default value
  95 AM_CONDITIONAL(WITH_GNOME, test x$WITH_GNOME = "xyes")
  96
  97 if test x$WITH_GNOME = "xyes"; then
  98         PKG_CHECK_MODULES(GNOME, libgnome-2.0 >= $LIBGNOME_REQUIRED)
  99         PKG_CHECK_MODULES(GNOMEUI, libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED)
 100         AC_DEFINE([WITH_GNOME],[1],[Define if GNOME support is enabled])
 101 fi
 102
 103 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
 104 AC_SUBST(GLIB_GENMARSHAL)
 105
 106 dnl ========= Check for DBUS
 107 AC_ARG_ENABLE(dbus,
 108         [AC_HELP_STRING([--enable-dbus], [Compile with support for dbus])],
 109         enable_dbus="$enableval",enable_dbus=yes)
 110 if test "x$enable_dbus" != "xno"; then
 111         PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
 112         [enable_dbus=yes],[enable_dbus=no])
 113
 114         if test "x$enable_dbus" = "xno"; then
 115            AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
 116         fi
 117
 118         if test "x$enable_dbus" = "xyes" ; then
 119                 AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 120
 121                 if test x$DBUS_BINDING_TOOL = "xno" ; then
 122                         AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 123                 fi
 124
 125                 AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 126         fi
 127 fi
 128
 129 AC_SUBST([DBUS_CFLAGS])
 130 AC_SUBST([DBUS_LIBS])
 131
 132 LIB_CFLAGS="$LIB_CFLAGS $GNOME_CFLAGS"
 133 LIB_LIBS="$LIB_LIBS $GNOME_LIBS"
 134 AC_SUBST(LIB_CFLAGS)
 135 AC_SUBST(LIB_LIBS)
 136
 137 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE"
 138 AC_SUBST(BACKEND_CFLAGS)
 139 AC_SUBST(BACKEND_LIBS)
 140
 141 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS $GNOMEUI_CFLAGS $KEYRING_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE"
 142 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS $GNOMEUI_LIBS $KEYRING_LIBS -lz"
 143 AC_SUBST(SHELL_CFLAGS)
 144 AC_SUBST(SHELL_LIBS)
 145
 146 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $GNOME_CFLAGS"
 147 FRONTEND_LIBS="$FRONTEND_CORE_LIBS $GNOME_LIBS -lz"
 148 AC_SUBST(FRONTEND_CFLAGS)
 149 AC_SUBST(FRONTEND_LIBS)
 150
 151 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
 152 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
 153
 154 dnl Check for Nautilus property page build
 155 AC_ARG_ENABLE(nautilus,
 156         AC_HELP_STRING([--enable-nautilus],[compile the nautilus plugin]),
 157         [case "${enableval}" in
 158         yes) ENABLE_NAUTILUS=yes ;;
 159         no) ENABLE_NAUTILUS=no ;;
 160         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nautilus) ;;
 161         esac],
 162         [ENABLE_NAUTILUS=yes]) dnl Default value
 163
 164 if test x$ENABLE_NAUTILUS = "xyes" ; then
 165         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
 166                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
 167         NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 168         AC_SUBST(NAUTILUS_EXTENSION_DIR)
 169 fi
 170
 171 AC_SUBST(NAUTILUS_CFLAGS)
 172 AC_SUBST(NAUTILUS_LIBS)
 173 if test x$HAVE_NAUTILUS = "xyes"; then
 174         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
 175 fi
 176 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
 177
 178
 179 dnl Check for thumbnailer build
 180 AC_ARG_ENABLE(thumbnailer,
 181         AC_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer]),
 182         [case "${enableval}" in
 183         yes) ENABLE_THUMBNAILER=yes ;;
 184         no) ENABLE_THUMBNAILER=no ;;
 185         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thumbnailer) ;;
 186         esac],
 187         [ENABLE_THUMBNAILER=yes]) dnl Default value
 188 AM_CONDITIONAL(ENABLE_THUMBNAILER, test x$ENABLE_THUMBNAILER = "xyes")
 189
 190 dnl GConf configuration
 191 AM_GCONF_SOURCE_2
 192
 193 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
 194 if test "x$GCONFTOOL" = "xno"; then
 195         AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 196 fi
 197
 198 dnl ================== portability checks ===========================================
 199
 200 dnl for backtrace()
 201 AC_CHECK_HEADERS([execinfo.h])
 202
 203 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 204   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 205   ],[],[#include <langinfo.h>])
 206
 207 dnl ================== pdf checks ===================================================
 208 AC_ARG_ENABLE(pdf,
 209               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 210
 211 if test "x$enable_pdf" = "xyes"; then
 212     POPPLER_REQUIRED=0.8.0
 213     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED,enable_pdf=yes,enable_pdf=no)
 214
 215     if test "x$enable_pdf" = "xyes"; then
 216             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 217             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 218             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 219
 220             evince_save_LIBS=$LIBS
 221             LIBS="$LIBS $POPPLER_LIBS"
 222             AC_CHECK_FUNCS(poppler_page_render)
 223             LIBS=$evince_save_LIBS
 224
 225             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 226             if test x$enable_cairo_pdf = xyes; then
 227                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 228             fi
 229
 230             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 231             if test x$enable_cairo_ps = xyes; then
 232                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 233             fi
 234     else
 235             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 236     fi
 237 fi
 238
 239 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 240 dnl ================== end of pdf checks ============================================
 241 SPECTRE_REQUIRED=0.2.0
 242
 243 dnl libspectre (used by ps and dvi backends)
 244 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 245 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 246 if test "x$have_spectre" = "xyes"; then
 247    AC_DEFINE([HAVE_SPECTRE], [1], [Have libpectre])
 248 fi
 249
 250 dnl ================== ps checks ====================================================
 251 AC_ARG_ENABLE(ps,
 252         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 253
 254 ps_backend=""
 255 if test x$enable_ps = xyes; then
 256    AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 257
 258    if test "x$have_spectre" = "xyes"; then
 259       ps_backend="(libspectre)"
 260    else
 261       dnl check for GS version
 262       AC_MSG_CHECKING(for Ghostscript version...)
 263       GS_VERSION=`gs --version | head -n 1 | sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
 264       AC_MSG_RESULT(found $GS_VERSION)
 265       if test "$GS_VERSION" -lt "7"; then
 266          AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) or Ghostscript (version >= 7) are needed])
 267          enable_ps=no
 268       else
 269          AC_ARG_WITH(gs-aa-params,
 270                      [AC_HELP_STRING([--with-gs-aa-params], [Define antialiasing params for ghostscript])],AA_PARAMS=$withval,
 271                      AA_PARMS="-sDEVICE=x11alpha -dNOPLATFONTS -dGraphicsAlphaBits=4 -dTextAlphaBits=4 -dDOINTERPOLATE"
 272                      )
 273          AC_DEFINE_UNQUOTED(ALPHA_PARAMS, "$AA_PARMS", [Anti-aliasing parameters for Ghostscript.])
 274          AC_MSG_RESULT(Antialiasing parameters for Ghostscript: $AA_PARMS)
 275          ps_backend="(gs)"
 276       fi
 277    fi
 278 fi
 279 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 280 dnl ======================== End of ps checks ===================================
 281
 282 dnl ================== tiff checks ===================================================
 283 AC_ARG_ENABLE(tiff,
 284             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 285
 286 if test "x$enable_tiff" = "xyes"; then
 287     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 288     if test "x$enable_tiff" = "xyes"; then
 289         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 290         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 291     fi
 292     if test "x$enable_tiff" = "xyes"; then
 293             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 294     else
 295             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 296     fi
 297 fi
 298
 299 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 300 dnl ================== end of tiff checks ============================================
 301
 302 dnl ================== djvu checks ===================================================
 303
 304 AC_ARG_ENABLE(djvu,
 305             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=yes)
 306
 307 if test "x$enable_djvu" = "xyes"; then
 308     DJVULIBRE_REQUIRED=3.5.17
 309     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 310
 311     if test "x$enable_djvu" = "xyes"; then
 312         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 313     else
 314         AC_MSG_WARN([
 315 ** Djvu support is disabled since a recent version of the djvulibre
 316 ** library was not found. You need at least djvulibre-3.5.17 which
 317 ** can be found on http://djvulibre.djvuzone.org
 318 ])
 319     fi
 320 fi
 321
 322 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 323
 324 dnl ================== End of djvu checks ===================================================
 325
 326 dnl ================== dvi checks ===================================================
 327
 328 AC_ARG_ENABLE(dvi,
 329             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=yes)
 330
 331 AC_ARG_ENABLE(t1lib,
 332             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 333
 334 if test "x$enable_dvi" = "xyes"; then
 335     AC_C_CONST
 336     AC_C_INLINE
 337     AC_TYPE_SIZE_T
 338     AC_CHECK_SIZEOF(long, 4)
 339     AC_CHECK_SIZEOF(int, 4)
 340     AC_CHECK_SIZEOF(short, 2)
 341     AC_CHECK_SIZEOF(void *, 4)
 342     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 343
 344     if test "x$enable_dvi" = "xyes"; then
 345         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 346     else
 347         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 348     fi
 349 fi
 350 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 351
 352 if test "x$enable_dvi" = "xyes"; then
 353     if test "x$enable_type1_fonts" = "xyes"; then
 354         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 355     fi
 356
 357     if test "x$enable_type1_fonts" = xyes; then
 358         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 359     fi
 360 else
 361     enable_type1_fonts=no
 362 fi
 363 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 364
 365 dnl ================== End of dvi checks ===================================================
 366
 367 dnl ================== pixbuf checks ===================================================
 368
 369 AC_ARG_ENABLE(pixbuf,
 370             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 371 if test "x$enable_pixbuf" = "xyes"; then
 372         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 373 fi
 374 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 375
 376 dnl ================== End of pixbuf checks ===================================================
 377
 378 dnl ================== comic book checks ===================================================
 379
 380 AC_ARG_ENABLE(comics,
 381         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=yes)
 382 if test "x$enable_comics" = "xyes"; then
 383         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 384 fi
 385 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 386
 387 dnl ================== End of comic book checks ============================================
 388
 389 dnl ================== impress book checks ===================================================
 390
 391 AC_ARG_ENABLE(impress,
 392         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 393 if test "x$enable_impress" = "xyes"; then
 394         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 395 fi
 396 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 397
 398 dnl ================== End of impress book checks ============================================
 399
 400 dnl =================== Mime types list ====================================================
 401
 402 if test "x$enable_pdf" = "xyes" ; then
 403         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 404 fi
 405 if test "x$enable_ps" = "xyes" ; then
 406         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 407 fi
 408 if test "x$enable_dvi" = "xyes"; then
 409         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 410 fi
 411 if test "x$enable_djvu" = "xyes"; then
 412         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 413 fi
 414 if test "x$enable_tiff" = "xyes"; then
 415         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 416 fi
 417 if test "x$enable_comics" = "xyes"; then
 418         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;"
 419 fi
 420 if test "x$enable_pixbuf" = "xyes"; then
 421         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 422 fi
 423 if test "x$enable_impress" = "xyes"; then
 424         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 425 fi
 426 AC_SUBST(EVINCE_MIME_TYPES)
 427
 428 AC_CONFIG_FILES([
 429 backend/Makefile
 430 backend/comics/Makefile
 431 backend/djvu/Makefile
 432 backend/dvi/Makefile
 433 backend/dvi/mdvi-lib/Makefile
 434 backend/impress/Makefile
 435 backend/pdf/Makefile
 436 backend/pixbuf/Makefile
 437 backend/ps/Makefile
 438 backend/tiff/Makefile
 439 cut-n-paste/Makefile
 440 cut-n-paste/gedit-message-area/Makefile
 441 cut-n-paste/toolbar-editor/Makefile
 442 cut-n-paste/zoom-control/Makefile
 443 cut-n-paste/totem-screensaver/Makefile
 444 data/evince.desktop.in
 445 data/Makefile
 446 data/icons/Makefile
 447 data/icons/16x16/Makefile
 448 data/icons/16x16/apps/Makefile
 449 data/icons/16x16/actions/Makefile
 450 data/icons/22x22/Makefile
 451 data/icons/22x22/apps/Makefile
 452 data/icons/22x22/actions/Makefile
 453 data/icons/24x24/Makefile
 454 data/icons/24x24/apps/Makefile
 455 data/icons/24x24/actions/Makefile
 456 data/icons/32x32/Makefile
 457 data/icons/32x32/actions/Makefile
 458 data/icons/48x48/Makefile
 459 data/icons/48x48/apps/Makefile
 460 data/icons/48x48/actions/Makefile
 461 data/icons/scalable/Makefile
 462 data/icons/scalable/apps/Makefile
 463 help/Makefile
 464 help/reference/Makefile
 465 help/reference/version.xml
 466 libdocument/Makefile
 467 Makefile
 468 po/Makefile.in
 469 properties/Makefile
 470 shell/Makefile
 471 test/Makefile
 472 thumbnailer/Makefile
 473 ])
 474
 475 AC_OUTPUT
 476
 477 echo "
 478 Configure summary:
 479         GNOME Support......:  $WITH_GNOME
 480         Keyring Support....:  $WITH_KEYRING
 481         DBUS Support.......:  $enable_dbus
 482         Nautilus Plugin....:  $HAVE_NAUTILUS
 483         Thumbnailer........:  $ENABLE_THUMBNAILER
 484         Gtk-Doc Support....:  $enable_gtk_doc
 485
 486         PDF Backend........:  $enable_pdf
 487         PostScript Backend.:  $enable_ps $ps_backend
 488         TIFF Backend.......:  $enable_tiff
 489         DJVU Backend.......:  $enable_djvu
 490         DVI Backend........:  $enable_dvi
 491         Pixbuf Backend.....:  $enable_pixbuf
 492         Comics Backend.....:  $enable_comics
 493         Impress Backend....:  $enable_impress
 494 "