configure.ac

   1 # *****************************************************************************
   2 # Versioning
   3 # *****************************************************************************
   4
   5 m4_define([ev_major_version],[2])
   6 m4_define([ev_minor_version],[27])
   7 m4_define([ev_micro_version],[1])
   8 m4_define([ev_extra_version],[])
   9 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version()ev_extra_version])
  10
  11 # The evince API version
  12 m4_define([ev_api_version], [2.25])
  13
  14 # Libtool versioning. The backend and view libraries have separate versions.
  15 # Before making a release, the libtool version should be modified.
  16 # The string is of the form C:R:A.
  17 # - If interfaces have been changed or added, but binary compatibility has
  18 #   been preserved, change to C+1:0:A+1
  19 # - If binary compatibility has been broken (eg removed or changed interfaces)
  20 #   change to C+1:0:0
  21 # - If the interface is the same as the previous version, change to C:R+1:A
  22
  23 # Libtool version of the backend library
  24 m4_define([ev_document_lt_current],[1])
  25 m4_define([ev_document_lt_revision],[0])
  26 m4_define([ev_document_lt_age],[0])
  27 m4_define([ev_document_lt_version_info],[ev_document_lt_current:ev_document_lt_revision:ev_document_lt_age])
  28 m4_define([ev_document_lt_current_minus_age],[m4_eval(ev_document_lt_current - ev_document_lt_age)])
  29
  30 # Libtool version of the view library
  31 m4_define([ev_view_lt_current],[1])
  32 m4_define([ev_view_lt_revision],[0])
  33 m4_define([ev_view_lt_age],[0])
  34 m4_define([ev_view_lt_version_info],[ev_view_lt_current:ev_view_lt_revision:ev_view_lt_age])
  35 m4_define([ev_view_lt_current_minus_age],[m4_eval(ev_view_lt_current - ev_view_lt_age)])
  36
  37 # Binary version for the document backends
  38 m4_define([ev_binary_version],[ev_document_lt_current])
  39
  40 # *****************************************************************************
  41
  42 AC_PREREQ([2.57])
  43 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
  44 AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip])
  45
  46 AC_CONFIG_HEADERS([config.h])
  47 AC_CONFIG_MACRO_DIR([m4])
  48
  49 if test -z "$enable_maintainer_mode"; then
  50   enable_maintainer_mode=yes
  51 fi
  52 AM_MAINTAINER_MODE([enable])
  53
  54 AM_PROG_LIBTOOL
  55
  56 AC_ISC_POSIX
  57 AC_PROG_CC
  58 AM_PROG_CC_STDC
  59 AM_PROG_CC_C_O
  60 AC_PROG_CXX
  61 AC_STDC_HEADERS
  62 IT_PROG_INTLTOOL([0.35.0])
  63 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  64 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  65
  66 GNOME_COMMON_INIT
  67 GNOME_DOC_INIT
  68 GNOME_MAINTAINER_MODE_DEFINES
  69 GNOME_COMPILE_WARNINGS
  70 GNOME_CXX_WARNINGS
  71
  72 GTK_DOC_CHECK(1.0)
  73
  74 GETTEXT_PACKAGE=evince
  75 AC_SUBST(GETTEXT_PACKAGE)
  76 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  77 AM_GLIB_GNU_GETTEXT
  78
  79 # Check which platform to use
  80
  81 AC_MSG_CHECKING([for which platform to build])
  82 AC_ARG_WITH([platform],
  83   [AS_HELP_STRING([--with-platform=gnome|win32|hildon (default: gnome)])],
  84   [case "$withval" in
  85     gnome|win32|hildon) ;;
  86     *) AC_MSG_ERROR([invalid argument "$withval" for --with-platform]) ;;
  87    esac],
  88   [case "$host" in
  89      *-*-mingw*|*-*-cygwin*) with_platform="win32" ;;
  90      *) with_platform=gnome ;;
  91    esac])
  92
  93 AC_MSG_RESULT([$with_platform])
  94
  95 if test "$with_platform" = "win32"; then
  96   AC_CHECK_TOOL([WINDRES],[windres])
  97   AC_MSG_CHECKING([for native Win32])
  98   case "$host" in
  99     *-*-mingw*)
 100       os_win32=yes
 101       ;;
 102     *)
 103       os_win32=no
 104       ;;
 105   esac
 106   AC_MSG_RESULT([$os_win32])
 107 fi
 108
 109 AM_CONDITIONAL([PLATFORM_HILDON],[test "$with_platform" = "hildon"])
 110 AM_CONDITIONAL([PLATFORM_WIN32],[test "with_platform" = "win32"])
 111
 112 dnl Specify required versions of dependencies
 113 DBUS_GLIB_REQUIRED=0.70
 114 GTK_REQUIRED=2.12.0
 115 GLIB_REQUIRED=2.18.0
 116 KEYRING_REQUIRED=2.22.0
 117 AC_SUBST([GLIB_REQUIRED])
 118 AC_SUBST([GTK_REQUIRED])
 119
 120 GNOME_ICON_THEME_REQUIRED=2.17.1
 121 LIBXML_REQUIRED=2.5.0
 122
 123 dnl Check dependencies
 124
 125 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
 126 # BACKEND_CFLAGS   for backend implementations.
 127 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
 128 # FRONTEND_LIBS
 129 # SHELL_CFLAGS     for shell implementation.
 130 # SHELL_LIBS
 131
 132 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
 133 PKG_CHECK_MODULES(LIBVIEW, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 134 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
 135 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 136 PKG_CHECK_MODULES(PREVIEWER, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 137
 138 SHELL_PLATFORM_PKGS=
 139 case "$with_platform" in
 140   hildon) AC_DEFINE([PLATFORM_HILDON],[1],[Define if building for the hildon platform])
 141           SHELL_PLATFORM_PKGS="hildon-1 hildon-fm-2 libosso"
 142           ;;
 143   *) SHELL_PLATFORM_PKGS="gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED"
 144      ;;
 145 esac
 146
 147 PKG_CHECK_MODULES([SHELL_CORE],[libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gthread-2.0 $SHELL_PLATFORM_PKGS])
 148
 149 # *********
 150 # SM client
 151 # *********
 152
 153 GDK_TARGET="$($PKG_CONFIG --variable target gdk-2.0)"
 154
 155 SMCLIENT_PKGS=
 156 AC_MSG_CHECKING([which smclient backend to use])
 157 AC_ARG_WITH([smclient],
 158   [AS_HELP_STRING([--with-smclient-backend],[which smclient backend to use (no|xsmp|win32|quartz)])],
 159   [],
 160   [case "$GDK_TARGET" in
 161     x11) case "$with_platform" in
 162            gnome) with_smclient=xsmp SMCLIENT_PKGS="sm >= 1.0.0" ;;
 163            *) with_smclient=no ;;
 164          esac ;;
 165     win32|quartz) with_smclient=$GDK_TARGET ;;
 166     *) with_smclient=no ;;
 167    esac])
 168 AC_MSG_RESULT([$with_smclient])
 169
 170 if test "$with_smclient" != "no"; then
 171   AC_DEFINE([WITH_SMCLIENT],[1],[Define if smclient is enabled])
 172
 173   PKG_CHECK_MODULES([SMCLIENT],[gtk+-2.0 gthread-2.0 $SMCLIENT_PKGS])
 174   AC_SUBST([SMCLIENT_CFLAGS])
 175   AC_SUBST([SMCLIENT_LIBS])
 176 fi
 177
 178 AM_CONDITIONAL([WITH_SMCLIENT],[test "$with_smclient" != "no"])
 179 AM_CONDITIONAL([WITH_SMCLIENT_XSMP],[test "$with_smclient" = "xsmp"])
 180 AM_CONDITIONAL([WITH_SMCLIENT_WIN32],[test "$with_smclient" = "win32"])
 181 AM_CONDITIONAL([WITH_SMCLIENT_QUARTZ],[test "$with_smclient" = "quartz"])
 182
 183 # ***
 184
 185 BACKEND_LIBTOOL_FLAGS="-module -avoid-version -no-undefined -export-symbols \$(top_srcdir)/backend/backend.symbols"
 186 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
 187
 188 dnl ===== Check special functions
 189 evince_save_LIBS=$LIBS
 190 LIBS="$LIBS $BACKEND_LIBS"
 191 AC_CHECK_FUNCS(cairo_format_stride_for_width)
 192 LIBS=$evince_save_LIBS
 193
 194 # ******************
 195 # GKT+ Unix Printing
 196 # ******************
 197
 198 AC_MSG_CHECKING([whether gtk+-unix-print support is requested])
 199 AC_ARG_WITH([gtk-unix-print],
 200   [AS_HELP_STRING([--without-gtk-unix-print],[disable the use of gtk-unix-print])],
 201   [],[case "$os_win32" in
 202         yes) with_gtk_unix_print=no ;;
 203         *) with_gtk_unix_print=yes ;;
 204       esac])
 205 AC_MSG_RESULT([$with_gtk_unix_print])
 206
 207 if test "$with_gtk_unix_print" = "yes"; then
 208    PKG_CHECK_MODULES(GTKUNIXPRINT, [gtk+-unix-print-2.0 >= $GTK_REQUIRED])
 209    AC_DEFINE([GTKUNIXPRINT_ENABLED], [1], [Define if gtk+-unix-print is enabled.])
 210 fi
 211
 212 # *********************
 213 # GNOME Keyring support
 214 # *********************
 215
 216 AC_ARG_WITH(keyring,
 217         [AS_HELP_STRING([--without-keyring],[disable the use of gnome-keyring])],
 218         [],
 219         [case "$with_platform" in
 220            gnome) with_keyring=yes ;;
 221            hildon|win32) with_keyring=no ;;
 222          esac])
 223
 224 AM_CONDITIONAL([WITH_KEYRING],[test "$with_keyring" = "yes"])
 225
 226 if test "$with_keyring" = "yes"; then
 227         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
 228         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
 229 fi
 230
 231 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
 232 AC_SUBST(GLIB_GENMARSHAL)
 233
 234 # ****
 235 # DBUS
 236 # ****
 237
 238 AC_ARG_ENABLE([dbus],
 239   [AS_HELP_STRING([--enable-dbus], [Compile with support for dbus])],
 240   [],
 241   [case "$with_platform" in
 242       gnome) enable_dbus=yes ;;
 243       hildon) enable_dbus=no ;;
 244     esac])
 245
 246 if test "$enable_dbus" = "yes"; then
 247   PKG_CHECK_MODULES([DBUS],[dbus-glib-1 >= $DBUS_GLIB_REQUIRED],[],
 248                     [AC_MSG_ERROR([DBUS not found; use --disable-dbus to disable DBUS support])])
 249
 250   AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 251   if test x$DBUS_BINDING_TOOL = "xno" ; then
 252           AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 253   fi
 254
 255   AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 256 fi
 257
 258 AC_SUBST([DBUS_CFLAGS])
 259 AC_SUBST([DBUS_LIBS])
 260
 261 AM_CONDITIONAL([ENABLE_DBUS], [test "$enable_dbus" = "yes"])
 262
 263 dnl ========= Check for GConf
 264
 265 AC_MSG_CHECKING([whether GConf support is requested])
 266 AC_ARG_WITH([gconf],
 267   [AS_HELP_STRING([--without-gconf],[disable the use of gconf])],
 268   [],
 269   [case "$os_win32" in
 270      yes) with_gconf=no ;;
 271      *) with_gconf=yes ;;
 272    esac])
 273 AC_MSG_RESULT([$with_gconf])
 274
 275 AM_CONDITIONAL([WITH_GCONF],[test "$with_gconf" = "yes"])
 276
 277 if test "$with_gconf" = "yes"; then
 278    PKG_CHECK_MODULES([GCONF],[gconf-2.0])
 279    AC_DEFINE([WITH_GCONF],[1],[Define if GConf support is enabled])
 280 fi
 281
 282 AM_GCONF_SOURCE_2
 283
 284 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [false])
 285 if test "$with_gconf" = "yes" -a "$GCONFTOOL" = "false"; then
 286   AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 287 fi
 288
 289 dnl Debug mode
 290
 291 AC_ARG_ENABLE([debug],
 292         AC_HELP_STRING([--enable-debug],
 293                         [Turn on evince debug mode]),,
 294                 [enable_debug=no])
 295
 296 if test "x$enable_debug" = "xyes"; then
 297    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 298 fi
 299
 300
 301 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 302 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 303 AC_SUBST(LIBDOCUMENT_CFLAGS)
 304 AC_SUBST(LIBDOCUMENT_LIBS)
 305
 306 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $DEBUG_FLAGS"
 307 LIBVIEW_LIBS="$LIBVIEW_LIBS"
 308 AC_SUBST(LIBVIEW_CFLAGS)
 309 AC_SUBST(LIBVIEW_LIBS)
 310
 311 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 312 AC_SUBST(BACKEND_CFLAGS)
 313 AC_SUBST(BACKEND_LIBS)
 314
 315 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $GTKUNIXPRINT_CFLAGS $DBUS_CFLAGS $KEYRING_CFLAGS $GCONF_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 316 SHELL_LIBS="$SHELL_CORE_LIBS $GTKUNIXPRINT_CFLAGS $DBUS_LIBS $KEYRING_LIBS $GCONF_LIBS -lz"
 317 AC_SUBST(SHELL_CFLAGS)
 318 AC_SUBST(SHELL_LIBS)
 319
 320 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 321 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 322 AC_SUBST(FRONTEND_CFLAGS)
 323 AC_SUBST(FRONTEND_LIBS)
 324
 325 # Check for Nautilus property page build
 326 AC_ARG_ENABLE([nautilus],
 327   [AS_HELP_STRING([--enable-nautilus],[compile the nautilus plugin])],
 328   [],
 329   [case "$with_platform" in
 330      gnome) enable_nautilus=yes ;;
 331      *) enable_nautilus=no ;;
 332     esac])
 333
 334 if test "$enable_nautilus" = "yes" ; then
 335   PKG_CHECK_MODULES([NAUTILUS],[gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension])
 336   NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 337   AC_SUBST([nautilusextensiondir],[$NAUTILUS_EXTENSION_DIR])
 338   AC_SUBST(NAUTILUS_CFLAGS)
 339   AC_SUBST(NAUTILUS_LIBS)
 340
 341   AC_DEFINE([HAVE_NAUTILUS],[1], [defined if you build the nautilus plugin])
 342 fi
 343
 344 AM_CONDITIONAL([ENABLE_NAUTILUS],[test "$enable_nautilus" = "yes"])
 345
 346 # Check for thumbnailer build
 347
 348 AC_ARG_ENABLE([thumbnailer],
 349   [AS_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer])],
 350   [],
 351   [case "$with_platform" in
 352      gnome) enable_thumbnailer=yes ;;
 353      *) enable_thumbnailer=no ;;
 354     esac])
 355
 356 AM_CONDITIONAL([ENABLE_THUMBNAILER],[test "$enable_thumbnailer" = "yes"])
 357
 358 # ***************
 359 # Print Previewer
 360 # ***************
 361
 362 AC_ARG_ENABLE([previewer],
 363   [AS_HELP_STRING([--disable-previewer],[disable the GNOME Document Previewer])],
 364   [],
 365   [case "$with_platform" in
 366       gnome) enable_previewer=yes ;;
 367       *) enable_previewer=no ;;
 368     esac])
 369
 370 if test x$enable_previewer = "xyes" ; then
 371   PKG_CHECK_MODULES([PREVIEWER],[gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED])
 372 fi
 373
 374 AM_CONDITIONAL([ENABLE_PREVIEWER],[test "$enable_previewer" = "yes"])
 375 PREVIEWER_CFLAGS="$PREVIEWER_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 376 PREVIEWER_LIBS="$PREVIEWER_LIBS $GTKUNIXPRINT_LIBS -lz"
 377 AC_SUBST(PREVIEWER_CFLAGS)
 378 AC_SUBST(PREVIEWER_LIBS)
 379
 380 # ***
 381 # GIR
 382 # ***
 383
 384 AC_MSG_CHECKING([whether GObject introspection is requested])
 385 AC_ARG_ENABLE([introspection],
 386         AS_HELP_STRING([--enable-introspection],[Enable GObject introspection]),
 387         [],[enable_introspection=no])
 388 AC_MSG_RESULT([$enable_introspection])
 389
 390 G_IR_SCANNER=
 391 G_IR_COMPILER=
 392 G_IR_GENERATE=
 393 GIRDIR=
 394 GIRTYPELIBDIR=
 395
 396 if test "$enable_introspection" = "yes"; then
 397   GOBJECT_INTROSPECTION_REQUIRED=0.6
 398   PKG_CHECK_MODULES([GOBJECT_INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
 399
 400   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
 401   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
 402   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
 403   GIRDIR="$($PKG_CONFIG --variable=girdir gobject-introspection-1.0)"
 404   GIRTYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
 405 fi
 406
 407 AC_SUBST([G_IR_SCANNER])
 408 AC_SUBST([G_IR_COMPILER])
 409 AC_SUBST([G_IR_GENERATE])
 410 AC_SUBST([GIRDIR])
 411 AC_SUBST([GIRTYPELIBDIR])
 412
 413 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
 414
 415 dnl ================== portability checks ===========================================
 416
 417 dnl for backtrace()
 418 AC_CHECK_HEADERS([execinfo.h])
 419
 420 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 421   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 422   ],[],[#include <langinfo.h>])
 423
 424 dnl ================== pdf checks ===================================================
 425 AC_ARG_ENABLE(pdf,
 426               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 427
 428 if test "x$enable_pdf" = "xyes"; then
 429     POPPLER_REQUIRED=0.11.0
 430     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED,enable_pdf=yes,enable_pdf=no)
 431
 432     if test "x$enable_pdf" = "xyes"; then
 433             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 434             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 435             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 436
 437             evince_save_LIBS=$LIBS
 438             LIBS="$LIBS $POPPLER_LIBS"
 439             AC_CHECK_FUNCS(poppler_page_render)
 440             AC_CHECK_FUNCS(poppler_page_get_image)
 441             LIBS=$evince_save_LIBS
 442
 443             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 444             if test x$enable_cairo_pdf = xyes; then
 445                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 446             fi
 447
 448             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 449             if test x$enable_cairo_ps = xyes; then
 450                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 451             fi
 452     else
 453             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 454     fi
 455 fi
 456
 457 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 458 dnl ================== end of pdf checks ============================================
 459
 460 dnl libspectre (used by ps and dvi backends)
 461 SPECTRE_REQUIRED=0.2.0
 462 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 463 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 464 if test "x$have_spectre" = "xyes"; then
 465    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 466 fi
 467
 468 dnl ================== ps checks ====================================================
 469 AC_ARG_ENABLE(ps,
 470         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 471
 472 if test "x$enable_ps" = "xyes"; then
 473    if test "x$have_spectre" = "xyes"; then
 474       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 475    else
 476       enable_ps="no"
 477       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 478    fi
 479 fi
 480 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 481 dnl ======================== End of ps checks ===================================
 482
 483 dnl ================== tiff checks ===================================================
 484 AC_ARG_ENABLE(tiff,
 485             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 486
 487 if test "x$enable_tiff" = "xyes"; then
 488     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 489     if test "x$enable_tiff" = "xyes"; then
 490         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 491         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 492     fi
 493     if test "x$enable_tiff" = "xyes"; then
 494             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 495     else
 496             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 497     fi
 498 fi
 499
 500 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 501 dnl ================== end of tiff checks ============================================
 502
 503 dnl ================== djvu checks ===================================================
 504
 505 AC_ARG_ENABLE(djvu,
 506             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=yes)
 507
 508 if test "x$enable_djvu" = "xyes"; then
 509     DJVULIBRE_REQUIRED=3.5.17
 510     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 511
 512     if test "x$enable_djvu" = "xyes"; then
 513         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 514     else
 515         AC_MSG_WARN([
 516 ** Djvu support is disabled since a recent version of the djvulibre
 517 ** library was not found. You need at least djvulibre-3.5.17 which
 518 ** can be found on http://djvulibre.djvuzone.org
 519 ])
 520     fi
 521 fi
 522
 523 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 524
 525 dnl ================== End of djvu checks ===================================================
 526
 527 dnl ================== dvi checks ===================================================
 528
 529 AC_ARG_ENABLE(dvi,
 530             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=yes)
 531
 532 AC_ARG_ENABLE(t1lib,
 533             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 534
 535 if test "x$enable_dvi" = "xyes"; then
 536     AC_C_CONST
 537     AC_C_INLINE
 538     AC_TYPE_SIZE_T
 539     AC_CHECK_SIZEOF(long, 4)
 540     AC_CHECK_SIZEOF(int, 4)
 541     AC_CHECK_SIZEOF(short, 2)
 542     AC_CHECK_SIZEOF(void *, 4)
 543     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 544
 545     if test "x$enable_dvi" = "xyes"; then
 546         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 547     else
 548         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 549     fi
 550 fi
 551 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 552
 553 if test "x$enable_dvi" = "xyes"; then
 554     if test "x$enable_type1_fonts" = "xyes"; then
 555         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 556     fi
 557
 558     if test "x$enable_type1_fonts" = xyes; then
 559         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 560     fi
 561 else
 562     enable_type1_fonts=no
 563 fi
 564 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 565
 566 dnl ================== End of dvi checks ===================================================
 567
 568 dnl ================== pixbuf checks ===================================================
 569
 570 AC_ARG_ENABLE(pixbuf,
 571             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 572 if test "x$enable_pixbuf" = "xyes"; then
 573         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 574 fi
 575 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 576
 577 dnl ================== End of pixbuf checks ===================================================
 578
 579 dnl ================== comic book checks ===================================================
 580
 581 AC_ARG_ENABLE(comics,
 582         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=yes)
 583 if test "x$enable_comics" = "xyes"; then
 584         if test "x$os_win32" = "xyes"; then
 585                 # The comics backend is disabled on windows because:
 586                 # 1) it uses unix functions from sys/wait.h.
 587                 # 2) it uses external decompression tools not generally available on windows.
 588                 enable_comics=no
 589                 AC_MSG_WARN(The comics backend is not supported on windows.)
 590         else
 591                 AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 592         fi
 593 fi
 594 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 595
 596 dnl ================== End of comic book checks ============================================
 597
 598 dnl ================== impress book checks ===================================================
 599
 600 AC_ARG_ENABLE(impress,
 601         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 602 if test "x$enable_impress" = "xyes"; then
 603         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 604 fi
 605 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 606
 607 dnl ================== End of impress book checks ============================================
 608
 609 dnl =================== Mime types list ====================================================
 610
 611 if test "x$enable_pdf" = "xyes" ; then
 612         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 613 fi
 614 if test "x$enable_ps" = "xyes" ; then
 615         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 616 fi
 617 if test "x$enable_dvi" = "xyes"; then
 618         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 619 fi
 620 if test "x$enable_djvu" = "xyes"; then
 621         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 622 fi
 623 if test "x$enable_tiff" = "xyes"; then
 624         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 625 fi
 626 if test "x$enable_comics" = "xyes"; then
 627         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;"
 628 fi
 629 if test "x$enable_pixbuf" = "xyes"; then
 630         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 631 fi
 632 if test "x$enable_impress" = "xyes"; then
 633         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 634 fi
 635 AC_SUBST(EVINCE_MIME_TYPES)
 636
 637 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 638
 639 # Backends directory
 640
 641 AC_SUBST([backenddir],"\$(libdir)/evince/ev_binary_version/backends")
 642 AC_SUBST([backend_binary_version],"ev_binary_version")
 643
 644 # Versioning
 645
 646 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
 647 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
 648 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
 649
 650 AC_SUBST([EV_API_VERSION],[ev_api_version])
 651 AC_SUBST([EV_BINARY_VERSION],[ev_binary_version])
 652
 653 AC_SUBST([EV_DOCUMENT_LT_VERSION_INFO],[ev_document_lt_version_info])
 654 AC_SUBST([EV_DOCUMENT_LT_CURRENT_MINUS_AGE],[ev_document_lt_current_minus_age])
 655 AC_SUBST([EV_VIEW_LT_VERSION_INFO],[ev_view_lt_version_info])
 656 AC_SUBST([EV_VIEW_LT_CURRENT_MINUS_AGE],[ev_view_lt_current_minus_age])
 657
 658 # *****************************************************************************
 659
 660 SHAVE_INIT([], [enable])
 661
 662 AC_CONFIG_FILES([
 663 backend/Makefile
 664 backend/comics/Makefile
 665 backend/djvu/Makefile
 666 backend/dvi/Makefile
 667 backend/dvi/mdvi-lib/Makefile
 668 backend/impress/Makefile
 669 backend/pdf/Makefile
 670 backend/pixbuf/Makefile
 671 backend/ps/Makefile
 672 backend/tiff/Makefile
 673 cut-n-paste/Makefile
 674 cut-n-paste/gedit-message-area/Makefile
 675 cut-n-paste/gimpcellrenderertoggle/Makefile
 676 cut-n-paste/smclient/Makefile
 677 cut-n-paste/toolbar-editor/Makefile
 678 cut-n-paste/zoom-control/Makefile
 679 cut-n-paste/totem-screensaver/Makefile
 680 data/evince.desktop.in
 681 data/Makefile
 682 data/icons/Makefile
 683 data/icons/16x16/Makefile
 684 data/icons/16x16/apps/Makefile
 685 data/icons/16x16/actions/Makefile
 686 data/icons/22x22/Makefile
 687 data/icons/22x22/apps/Makefile
 688 data/icons/22x22/actions/Makefile
 689 data/icons/24x24/Makefile
 690 data/icons/24x24/apps/Makefile
 691 data/icons/24x24/actions/Makefile
 692 data/icons/32x32/Makefile
 693 data/icons/32x32/actions/Makefile
 694 data/icons/48x48/Makefile
 695 data/icons/48x48/apps/Makefile
 696 data/icons/48x48/actions/Makefile
 697 data/icons/scalable/Makefile
 698 data/icons/scalable/apps/Makefile
 699 help/Makefile
 700 help/reference/Makefile
 701 help/reference/libdocument/Makefile
 702 help/reference/libdocument/version.xml
 703 help/reference/libview/Makefile
 704 help/reference/libview/version.xml
 705 help/reference/shell/Makefile
 706 help/reference/shell/version.xml
 707 libdocument/Makefile
 708 libdocument/ev-version.h
 709 libmisc/Makefile
 710 libview/Makefile
 711 Makefile
 712 po/Makefile.in
 713 previewer/Makefile
 714 properties/Makefile
 715 shave
 716 shave-libtool
 717 shell/Makefile
 718 test/Makefile
 719 thumbnailer/Makefile
 720 ])
 721
 722 AC_CONFIG_FILES(evince-document-[]ev_api_version[].pc:evince-document.pc.in)
 723 AC_CONFIG_FILES(evince-view-[]ev_api_version[].pc:evince-view.pc.in)
 724
 725 AC_OUTPUT
 726
 727 echo "
 728 Configure summary:
 729         Platform...........:  $with_platform
 730         GConf Support......:  $with_gconf
 731         GTK+ Unix Print....:  $with_gtk_unix_print
 732         Keyring Support....:  $with_keyring
 733         DBUS Support.......:  $enable_dbus
 734         SM client support..:  $with_smclient
 735         Nautilus Plugin....:  $enable_nautilus
 736         Thumbnailer........:  $enable_thumbnailer
 737         Previewer..........:  $enable_previewer
 738         Gtk-Doc Support....:  $enable_gtk_doc
 739         Debug mode.........:  $enable_debug
 740         GObj. Introspection:  $enable_introspection
 741
 742         PDF Backend........:  $enable_pdf
 743         PostScript Backend.:  $enable_ps
 744         TIFF Backend.......:  $enable_tiff
 745         DJVU Backend.......:  $enable_djvu
 746         DVI Backend........:  $enable_dvi
 747         Pixbuf Backend.....:  $enable_pixbuf
 748         Comics Backend.....:  $enable_comics
 749         Impress Backend....:  $enable_impress
 750 "