configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.57)
   4 AC_INIT(evince, 0.3.2)
   5 AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)
   6
   7 dnl make sure we keep ACLOCAL_FLAGS around for maintainer builds to work
   8 AC_SUBST(ACLOCAL_AMFLAGS, "$ACLOCAL_FLAGS")
   9
  10 AM_CONFIG_HEADER(config.h)
  11
  12 AM_MAINTAINER_MODE
  13
  14 AM_PROG_LIBTOOL
  15
  16 AC_ISC_POSIX
  17 AC_PROG_CC
  18 AM_PROG_CC_STDC
  19 AC_PROG_CXX
  20 AC_STDC_HEADERS
  21 AC_PROG_INTLTOOL
  22 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  23 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  24
  25 GNOME_DEBUG_CHECK
  26
  27 ALL_LINGUAS="bg ca cs da de el en_CA en_GB es fi fr hu ja ko lt nb nl no pt_BR ru rw sk sv th uk wa zh_CN zh_TW"
  28
  29 AM_GLIB_GNU_GETTEXT
  30
  31 GETTEXT_PACKAGE=AC_PACKAGE_NAME
  32 AC_SUBST(GETTEXT_PACKAGE)
  33 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package.])
  34
  35 POPPLER_REQUIRED=0.3.3
  36 DBUS_GLIB_REQUIRED=0.33
  37
  38 PKG_CHECK_MODULES(LIBEVPRIVATE, gtk+-2.0 >= 2.4.0)
  39 PKG_CHECK_MODULES(TOOLBAR_EDITOR, gtk+-2.0 >= 2.4.0 libgnomeui-2.0 >= 2.4.0)
  40 PKG_CHECK_MODULES(RECENT_FILES, gtk+-2.0 >= 2.4.0 libgnomeui-2.0 >= 2.4.0)
  41 PKG_CHECK_MODULES(ZOOM_CONTROL, gtk+-2.0 >= 2.4.0)
  42 PKG_CHECK_MODULES(SHELL, gtk+-2.0 >= 2.6.0 libgnomeui-2.0 >= 2.6.0 gnome-vfs-2.0 libgnomeprint-2.2 >= 2.5.1 libgnomeprintui-2.2 libglade-2.0 gconf-2.0 poppler-glib >= $POPPLER_REQUIRED)
  43 PKG_CHECK_MODULES(THUMBNAILER, gtk+-2.0 >= 2.6.0 gnome-vfs-2.0 poppler-glib >= $POPPLER_REQUIRED)
  44 PKG_CHECK_MODULES(PROPERTIES, gtk+-2.0 >= 2.6.0 libglade-2.0 poppler-glib >= $POPPLER_REQUIRED)
  45 PKG_CHECK_MODULES(DVI, gtk+-2.0 >= 2.6.0)
  46 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.6.0)
  47 PKG_CHECK_MODULES(PS, gtk+-2.0 >= 2.6.0 gnome-vfs-2.0 libgnomeui-2.0)
  48 PKG_CHECK_MODULES(POPPLER_GLIB, poppler-glib >= $POPPLER_REQUIRED)
  49
  50 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
  51 AC_SUBST(GLIB_GENMARSHAL)
  52
  53 AC_ARG_ENABLE([dbus],
  54         AS_HELP_STRING([--enable-dbus],[Enable DBUS (default=no)]),
  55         [enable_dbus=$enableval],
  56         [enable_dbus=no])
  57
  58 AC_MSG_RESULT([$enable_dbus])
  59
  60 if test "x$enable_dbus" = "xyes" ; then
  61         AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
  62         AC_DEFINE([ENABLE_METADATA],[1],[Define if metadata support is enabled])
  63         PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED])
  64
  65         DBUS_VERSION=`$PKG_CONFIG --modversion dbus-glib-1 | sed 's/0.\([[0-9]]*\)/\1/'`
  66         AC_DEFINE_UNQUOTED(DBUS_VERSION, $DBUS_VERSION, [DBUS version.])
  67         AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
  68 fi
  69
  70 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
  71 AM_CONDITIONAL([ENABLE_METADATA], [test "x$enable_dbus" = "xyes"])
  72
  73 dnl Check for Nautilus property page build
  74 AC_ARG_ENABLE(nautilus,
  75         AC_HELP_STRING([--enable-nautilus],[compile the nautilus plugin]),
  76         [case "${enableval}" in
  77         yes) ENABLE_NAUTILUS=yes ;;
  78         no) ENABLE_NAUTILUS=no ;;
  79         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nautilus) ;;
  80         esac],
  81         [ENABLE_NAUTILUS=yes]) dnl Default value
  82
  83 if test x$ENABLE_NAUTILUS = "xyes" ; then
  84         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
  85                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
  86 fi
  87
  88 AC_SUBST(NAUTILUS_CFLAGS)
  89 AC_SUBST(NAUTILUS_LIBS)
  90 if test x$HAVE_NAUTILUS = "xyes"; then
  91         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
  92 fi
  93 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
  94
  95 dnl Compile with disable-deprecated switches
  96
  97 AC_ARG_ENABLE(deprecated,
  98 AC_HELP_STRING([--disable-deprecated],
  99                [Don't allow any deprecated GTK+/etc. features.]),
 100 set_enable_deprecated="$enableval",[
 101 if test -f $srcdir/autogen.sh; then
 102         is_cvs_version=true
 103         set_enable_deprecated=no
 104 else
 105         set_enable_deprecated=yes
 106         fi
 107 ])
 108 AC_MSG_CHECKING([whether to disable deprecated glib/gtk+/etc. features])
 109 if test "$set_enable_deprecated" != "yes"; then
 110         AC_MSG_RESULT(yes)
 111         EVINCE_DISABLE_DEPRECATED="-DG_DISABLE_DEPRECATED -DGDK_DISABLE_DEPRECATED -DGTK_DISABLE_DEPRECATED -DGNOME_DISABLE_DEPRECATED -DBONOBO_DISABLE_DEPRECATED"
 112 else
 113         AC_MSG_RESULT(no)
 114         EVINCE_DISABLE_DEPRECATED=""
 115 fi
 116 AC_SUBST(EVINCE_DISABLE_DEPRECATED)
 117
 118 evince_save_LIBS=$LIBS
 119 LIBS="$LIBS $GTK_LIBS"
 120 AC_CHECK_FUNCS(gtk_icon_view_get_visible_range)
 121 LIBS=$evince_save_LIBS
 122
 123 AM_GCONF_SOURCE_2
 124
 125 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
 126 if test "x$GCONFTOOL" = "xno"; then
 127         AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 128 fi
 129
 130 dnl ================== ggv checks ===================================================
 131 AC_ARG_WITH(gs-pkg,
 132             [  --with-gs=dir       Directory Where GhostScript package is installed.])
 133
 134 if test "x$with_gs" = "x"; then
 135         AC_PATH_PROG(GS_PROG, gs)
 136         if test -z "$GS_PROG"; then
 137                 AC_MSG_ERROR(Unable to find GhostScript in the PATH. Provide the full path for GhostScript(--with-gs=PATH). You need to have Ghostscript installed in order to run evince)
 138         fi
 139 else
 140         GS_PROG=$with_gs
 141 fi
 142
 143 AC_DEFINE_UNQUOTED(GS_PATH, "$GS_PROG", [Path to the 'gs' executable.])
 144
 145
 146 dnl check for GS version
 147 AC_MSG_CHECKING(for Ghostscript version...)
 148 GS_VERSION=`gs --version | head -n 1 | sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
 149 AC_MSG_RESULT(found $GS_VERSION)
 150 if test "$GS_VERSION" -lt "7"; then
 151         AC_MSG_ERROR([You need Ghostscript version >= 7 in order to run evince])
 152 fi
 153 AA_PARMS="-sDEVICE=x11alpha -dNOPLATFONTS"
 154 AC_DEFINE_UNQUOTED(ALPHA_PARAMS, "$AA_PARMS", [Anti-aliasing parameters for Ghostscript.])
 155 AC_MSG_RESULT(Antialiasing parameters for Ghostscript: $AA_PARMS)
 156 dnl ======================== End of ggv checks =================================
 157
 158 dnl ================== tiff checks ===================================================
 159 AC_ARG_ENABLE(tiff,
 160             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 161
 162 if test "x$enable_tiff" = "xyes"; then
 163     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 164     if test "x$enable_tiff" = "xyes"; then
 165         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 166         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 167     fi
 168     if test "x$enable_tiff" = "xyes"; then
 169             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 170     else
 171             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 172     fi
 173 fi
 174
 175 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 176 dnl ================== end of tiff checks ============================================
 177
 178 dnl ================== djvu checks ===================================================
 179
 180 AC_ARG_ENABLE(djvu,
 181             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=no)
 182
 183 if test "x$enable_djvu" = "xyes"; then
 184     AC_CHECK_HEADERS([libdjvu/ddjvuapi.h],enable_djvu=yes,enable_djvu=no,)
 185
 186     if test "x$enable_djvu" = "xyes"; then
 187         AC_CHECK_LIB([djvulibre],ddjvu_context_create,enable_djvu=yes,enable_djvu=no,"-lpthread")
 188         AC_CHECK_LIB([djvulibre],ddjvu_document_get_pageinfo,enable_djvu=yes,enable_djvu=no,"-lpthread")
 189     fi
 190
 191     if test "x$enable_djvu" = "xyes"; then
 192         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 193     else
 194         AC_MSG_WARN([
 195 ** Djvu support is disabled since recent version of djvulibre
 196 ** library was not found. To get proper djvu support you need to
 197 ** install development version of djvulibre. You can get it from
 198 ** anonymous CVS server on djvulibre.sf.net. Just use something
 199 ** like:
 200
 201 ** cvs -d :pserver:anonymous@cvs.sourceforge.net:/cvsroot/djvu co djvulibre-3.5
 202 ])
 203     fi
 204 fi
 205
 206 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 207
 208 dnl ================== End of djvu checks ===================================================
 209
 210 dnl ================== dvi checks ===================================================
 211
 212 AC_ARG_ENABLE(dvi,
 213             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=no)
 214
 215 AC_ARG_ENABLE(t1lib,
 216             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 217
 218 if test "x$enable_dvi" = "xyes"; then
 219     AC_C_CONST
 220     AC_C_INLINE
 221     AC_TYPE_SIZE_T
 222     AC_CHECK_SIZEOF(long, 4)
 223     AC_CHECK_SIZEOF(int, 4)
 224     AC_CHECK_SIZEOF(short, 2)
 225     AC_CHECK_SIZEOF(void *, 4)
 226     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 227
 228     if test "x$enable_dvi" = "xyes"; then
 229         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 230     else
 231         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 232     fi
 233 fi
 234 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 235
 236 if test "x$enable_dvi" = "xyes"; then
 237     if test "x$enable_type1_fonts" = "xyes"; then
 238         AC_CHECK_LIB([t1lib],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no)
 239     fi
 240
 241     if test "x$enable_type1_fonts" = xyes; then
 242         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 243     fi
 244 else
 245     enable_type1_fonts=no
 246 fi
 247 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 248
 249 dnl ================== End of dvi checks ===================================================
 250
 251 dnl =================== Mime types list ====================================================
 252
 253 EVINCE_MIME_TYPES="application/pdf;application/postscript;application/x-gzpostscript"
 254
 255 if test "x$enable_dvi" = "xyes"; then
 256         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;application/x-dvi"
 257 fi
 258 if test "x$enable_djvu" = "xyes"; then
 259         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;image/vnd.djvu"
 260 fi
 261 if test "x$enable_tiff" = "xyes"; then
 262         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;image/tiff"
 263 fi
 264 AC_SUBST(EVINCE_MIME_TYPES)
 265
 266 dnl Turn on the additional warnings last, so -Werror doesn't affect other tests.
 267 dnl stolen from nautilus and gnome-common
 268
 269 AC_ARG_ENABLE(more-warnings,
 270 [  --enable-more-warnings  Maximum compiler warnings],
 271 set_more_warnings="$enableval",[
 272 if test -f $srcdir/autogen.sh; then
 273         is_cvs_version=true
 274         set_more_warnings=yes
 275 else
 276         set_more_warnings=no
 277 fi
 278 ])
 279 AC_MSG_CHECKING(for more warnings, including -Werror)
 280 if test "$GCC" = "yes" -a "$set_more_warnings" != "no"; then
 281         AC_MSG_RESULT([yes, using gcc])
 282         CFLAGS="\
 283         -Wall \
 284         -Wchar-subscripts -Wmissing-declarations -Wmissing-prototypes \
 285         -Wnested-externs -Wpointer-arith \
 286         -Wcast-align -Wsign-compare \
 287         -Werror \
 288         $CFLAGS"
 289
 290 dnl     case " $CFLAGS " in
 291 dnl         *[\ \       ]-ansi[\ \      ]*) ;;
 292 dnl         *) CFLAGS="$CFLAGS -ansi" ;;
 293 dnl     esac
 294 dnl     case " $CFLAGS " in
 295 dnl         *[\ \       ]-pedantic[\ \  ]*) ;;
 296 dnl         *) CFLAGS="$CFLAGS -pedantic" ;;
 297 dnl     esac
 298
 299         for option in -Wno-strict-aliasing -Wno-sign-compare; do
 300                 SAVE_CFLAGS="$CFLAGS"
 301                 CFLAGS="$CFLAGS $option"
 302                 AC_MSG_CHECKING([whether gcc understands $option])
 303                 AC_TRY_COMPILE([], [],
 304                         has_option=yes,
 305                         has_option=no,)
 306                 if test $has_option = no; then
 307                         CFLAGS="$SAVE_CFLAGS"
 308                 fi
 309                 AC_MSG_RESULT($has_option)
 310                 unset has_option
 311                 unset SAVE_CFLAGS
 312         done
 313         unset option
 314 else
 315         AC_MSG_RESULT(no)
 316 fi
 317
 318 AC_OUTPUT([
 319 Makefile
 320 cut-n-paste/Makefile
 321 cut-n-paste/recent-files/Makefile
 322 cut-n-paste/zoom-control/Makefile
 323 cut-n-paste/toolbar-editor/Makefile
 324 data/Makefile
 325 data/evince.desktop.in
 326 lib/Makefile
 327 pdf/Makefile
 328 pixbuf/Makefile
 329 tiff/Makefile
 330 ps/Makefile
 331 djvu/Makefile
 332 dvi/Makefile
 333 dvi/mdvi-lib/Makefile
 334 po/Makefile.in
 335 backend/Makefile
 336 properties/Makefile
 337 shell/Makefile
 338 thumbnailer/Makefile
 339 help/Makefile
 340 help/C/Makefile
 341 ])