configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.57)
   4 AC_INIT([Evince],[2.21.90],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
   5 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-dist-gzip])
   6
   7 EV_API_VERSION=2.20
   8 AC_SUBST(EV_API_VERSION)
   9
  10 AM_CONFIG_HEADER(config.h)
  11
  12 AM_MAINTAINER_MODE
  13
  14 AM_PROG_LIBTOOL
  15
  16 AC_ISC_POSIX
  17 AC_PROG_CC
  18 AM_PROG_CC_STDC
  19 AC_PROG_CXX
  20 AC_STDC_HEADERS
  21 IT_PROG_INTLTOOL([0.35.0])
  22 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  23 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  24
  25 GNOME_COMMON_INIT
  26 GNOME_DOC_INIT
  27 GNOME_MAINTAINER_MODE_DEFINES
  28 GNOME_COMPILE_WARNINGS
  29 GNOME_CXX_WARNINGS
  30 GNOME_DEBUG_CHECK
  31
  32 GTK_DOC_CHECK(1.0)
  33
  34 GETTEXT_PACKAGE=evince
  35 AC_SUBST(GETTEXT_PACKAGE)
  36 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  37 AM_GLIB_GNU_GETTEXT
  38
  39 dnl Check dependencies
  40
  41 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
  42 # BACKEND_CFLAGS   for backend implementations.
  43 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
  44 # FRONTEND_LIBS
  45 # SHELL_CFLAGS     for shell implementation.
  46 # SHELL_LIBS
  47
  48 DBUS_GLIB_REQUIRED=0.70
  49 GTK_REQUIRED=2.10.0
  50 GLIB_REQUIRED=2.15.4
  51 KEYRING_REQUIRED=0.4.0
  52
  53 LIBGNOMEUI_REQUIRED=2.14.0
  54 LIBGNOME_REQUIRED=2.14.0
  55 LIBGNOMEPRINTUI_REQUIRED=2.6.0
  56 GNOME_ICON_THEME_REQUIRED=2.17.1
  57 LIBXML_REQUIRED=2.5.0
  58
  59 GTK_PRINT_REQUIRED=2.10.0
  60
  61 PKG_CHECK_MODULES(LIB, gtk+-2.0 >= $GTK_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
  62 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
  63 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED libglade-2.0 gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
  64 PKG_CHECK_MODULES(SHELL_CORE, libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED gthread-2.0 libglade-2.0 gconf-2.0)
  65
  66 BACKEND_LIBTOOL_FLAGS="-module -avoid-version"
  67 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
  68
  69 dnl ===== Check special functions
  70 evince_save_LIBS=$LIBS
  71 LIBS="$LIBS $BACKEND_LIBS"
  72 AC_CHECK_FUNCS(cairo_format_stride_for_width)
  73 LIBS=$evince_save_LIBS
  74
  75 AC_ARG_WITH(keyring,
  76         AC_HELP_STRING([--without-keyring],[disable the use of gnome-keyring]),
  77         [case "${withval}" in
  78         yes) WITH_KEYRING=yes ;;
  79         no) WITH_KEYRING=no ;;
  80         *) AC_MSG_ERROR(bad value ${withval} for --with-keyring) ;;
  81         esac],
  82         [WITH_KEYRING=yes]) dnl Default value
  83 AM_CONDITIONAL(WITH_KEYRING, test x$WITH_KEYRING = "xyes")
  84
  85 if test x$WITH_KEYRING = "xyes"; then
  86         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
  87         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
  88 fi
  89
  90 AC_ARG_WITH(libgnome,
  91         AC_HELP_STRING([--without-libgnome],[disable the use of libgnome]),
  92         [case "${withval}" in
  93         yes) WITH_GNOME=yes ;;
  94         no) WITH_GNOME=no ;;
  95         *) AC_MSG_ERROR(bad value ${withval} for --with-libgnome) ;;
  96         esac],
  97         [WITH_GNOME=yes]) dnl Default value
  98 AM_CONDITIONAL(WITH_GNOME, test x$WITH_GNOME = "xyes")
  99
 100 if test x$WITH_GNOME = "xyes"; then
 101         PKG_CHECK_MODULES(GNOME, libgnome-2.0 >= $LIBGNOME_REQUIRED)
 102         PKG_CHECK_MODULES(GNOMEUI, libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED)
 103         AC_DEFINE([WITH_GNOME],[1],[Define if GNOME support is enabled])
 104 fi
 105
 106 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
 107 AC_SUBST(GLIB_GENMARSHAL)
 108
 109 dnl ========= Print support
 110 AC_ARG_WITH(print,
 111             [AC_HELP_STRING([--with-print=no/gtk/gnome/auto], [Compile with print support [default=auto]])],
 112             PRINT=$withval,
 113             PRINT="auto")
 114
 115 PKG_CHECK_MODULES(GNOME_PRINT,
 116                   libgnomeprintui-2.2 >= $LIBGNOMEPRINTUI_REQUIRED,
 117                   enable_gnome_print=yes, enable_gnome_print=no)
 118 PKG_CHECK_MODULES(GTK_PRINT,
 119                   gtk+-unix-print-2.0 >= $GTK_PRINT_REQUIRED,
 120                   enable_gtk_print=yes, enable_gtk_print=no)
 121 enable_print=no
 122 if test x$PRINT = xgnome -a x$enable_gnome_print = xyes; then
 123    enable_print=gnome
 124 else
 125    if test x$PRINT = xgtk -a x$enable_gtk_print = xyes; then
 126       enable_print=gtk
 127    else
 128       if test x$PRINT = xauto; then
 129          if test x$enable_gtk_print = xyes; then
 130             enable_print=gtk
 131          else
 132             if test x$enable_gnome_print = xyes; then
 133                enable_print=gnome
 134             fi
 135          fi
 136       fi
 137    fi
 138 fi
 139
 140 if test x$enable_print = xgnome; then
 141    AC_SUBST(GNOME_PRINT_CFLAGS)
 142    AC_SUBST(GNOME_PRINT_LIBS)
 143    AC_DEFINE([WITH_GNOME_PRINT],[1],[Enable GNOME Print Support.])
 144    AC_DEFINE([WITH_PRINT],[1],[Enable Print Support.])
 145 fi
 146
 147 if test x$enable_print = xgtk; then
 148    AC_SUBST(GTK_PRINT_CFLAGS)
 149    AC_SUBST(GTK_PRINT_LIBS)
 150    AC_DEFINE([WITH_GTK_PRINT],[1],[Enable GTK Print Support.])
 151    AC_DEFINE([WITH_PRINT],[1],[Enable Print Support.])
 152 fi
 153
 154 AM_CONDITIONAL(WITH_GNOME_PRINT, test x$enable_print = xgnome)
 155 AM_CONDITIONAL(WITH_GTK_PRINT, test x$enable_print = xgtk)
 156
 157
 158 dnl ========= Check for DBUS
 159 PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
 160         [enable_dbus=yes],[enable_dbus=no])
 161 AC_SUBST([DBUS_CFLAGS])
 162 AC_SUBST([DBUS_LIBS])
 163
 164 if test "x$enable_dbus" = "xno"; then
 165         AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
 166 fi
 167
 168 if test "x$enable_dbus" = "xyes" ; then
 169         AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 170
 171         if test x$DBUS_BINDING_TOOL = "xno" ; then
 172                 AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 173         fi
 174
 175         AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 176 fi
 177
 178 LIB_CFLAGS="$LIB_CFLAGS $GNOME_CFLAGS"
 179 LIB_LIBS="$LIB_LIBS $GNOME_LIBS"
 180 AC_SUBST(LIB_CFLAGS)
 181 AC_SUBST(LIB_LIBS)
 182
 183 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE"
 184 AC_SUBST(BACKEND_CFLAGS)
 185 AC_SUBST(BACKEND_LIBS)
 186
 187 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS $GNOMEUI_CFLAGS $KEYRING_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE"
 188 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS $GNOMEUI_LIBS $KEYRING_LIBS -lz"
 189 AC_SUBST(SHELL_CFLAGS)
 190 AC_SUBST(SHELL_LIBS)
 191
 192 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $GNOME_CFLAGS"
 193 FRONTEND_LIBS="$FRONTEND_CORE_LIBS $GNOME_LIBS -lz"
 194 AC_SUBST(FRONTEND_CFLAGS)
 195 AC_SUBST(FRONTEND_LIBS)
 196
 197 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
 198 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
 199
 200 dnl Check for Nautilus property page build
 201 AC_ARG_ENABLE(nautilus,
 202         AC_HELP_STRING([--enable-nautilus],[compile the nautilus plugin]),
 203         [case "${enableval}" in
 204         yes) ENABLE_NAUTILUS=yes ;;
 205         no) ENABLE_NAUTILUS=no ;;
 206         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nautilus) ;;
 207         esac],
 208         [ENABLE_NAUTILUS=yes]) dnl Default value
 209
 210 if test x$ENABLE_NAUTILUS = "xyes" ; then
 211         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
 212                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
 213         NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 214         AC_SUBST(NAUTILUS_EXTENSION_DIR)
 215 fi
 216
 217 AC_SUBST(NAUTILUS_CFLAGS)
 218 AC_SUBST(NAUTILUS_LIBS)
 219 if test x$HAVE_NAUTILUS = "xyes"; then
 220         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
 221 fi
 222 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
 223
 224
 225 dnl Check for thumbnailer build
 226 AC_ARG_ENABLE(thumbnailer,
 227         AC_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer]),
 228         [case "${enableval}" in
 229         yes) ENABLE_THUMBNAILER=yes ;;
 230         no) ENABLE_THUMBNAILER=no ;;
 231         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thumbnailer) ;;
 232         esac],
 233         [ENABLE_THUMBNAILER=yes]) dnl Default value
 234 AM_CONDITIONAL(ENABLE_THUMBNAILER, test x$ENABLE_THUMBNAILER = "xyes")
 235
 236 dnl GConf configuration
 237 AM_GCONF_SOURCE_2
 238
 239 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
 240 if test "x$GCONFTOOL" = "xno"; then
 241         AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 242 fi
 243
 244 dnl ================== portability checks ===========================================
 245
 246 dnl for backtrace()
 247 AC_CHECK_HEADERS([execinfo.h])
 248
 249 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 250   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 251   ],[],[#include <langinfo.h>])
 252
 253 dnl ================== pdf checks ===================================================
 254 AC_ARG_ENABLE(pdf,
 255               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 256
 257 if test "x$enable_pdf" = "xyes"; then
 258     POPPLER_REQUIRED=0.6
 259     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED,enable_pdf=yes,enable_pdf=no)
 260
 261     if test "x$enable_pdf" = "xyes"; then
 262             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 263             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 264             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 265
 266             evince_save_LIBS=$LIBS
 267             LIBS="$LIBS $POPPLER_LIBS"
 268             AC_CHECK_FUNCS(poppler_page_render)
 269             AC_CHECK_FUNCS(poppler_page_render_for_printing)
 270             AC_CHECK_FUNCS(poppler_page_get_image)
 271             LIBS=$evince_save_LIBS
 272
 273             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 274             if test x$enable_cairo_pdf == xyes; then
 275                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 276             fi
 277
 278             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 279             if test x$enable_cairo_ps == xyes; then
 280                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 281             fi
 282     else
 283             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 284     fi
 285 fi
 286
 287 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 288 dnl ================== end of pdf checks ============================================
 289 SPECTRE_REQUIRED=0.2.0
 290
 291 dnl libspectre (used by ps and dvi backends)
 292 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 293 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 294 if test "x$have_spectre" = "xyes"; then
 295    AC_DEFINE([HAVE_SPECTRE], [1], [Have libpectre])
 296 fi
 297
 298 dnl ================== ps checks ====================================================
 299 AC_ARG_ENABLE(ps,
 300         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 301
 302 ps_backend=""
 303 if test x$enable_ps = xyes; then
 304    AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 305
 306    if test "x$have_spectre" = "xyes"; then
 307       ps_backend="(libspectre)"
 308    else
 309       dnl check for GS version
 310       AC_MSG_CHECKING(for Ghostscript version...)
 311       GS_VERSION=`gs --version | head -n 1 | sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
 312       AC_MSG_RESULT(found $GS_VERSION)
 313       if test "$GS_VERSION" -lt "7"; then
 314          AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) or Ghostscript (version >= 7) are needed])
 315          enable_ps=no
 316       else
 317          AC_ARG_WITH(gs-aa-params,
 318                      [AC_HELP_STRING([--with-gs-aa-params], [Define antialiasing params for ghostscript])],AA_PARAMS=$withval,
 319                      AA_PARMS="-sDEVICE=x11alpha -dNOPLATFONTS -dGraphicsAlphaBits=4 -dTextAlphaBits=4 -dDOINTERPOLATE"
 320                      )
 321          AC_DEFINE_UNQUOTED(ALPHA_PARAMS, "$AA_PARMS", [Anti-aliasing parameters for Ghostscript.])
 322          AC_MSG_RESULT(Antialiasing parameters for Ghostscript: $AA_PARMS)
 323          ps_backend="(gs)"
 324       fi
 325    fi
 326 fi
 327 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 328 dnl ======================== End of ps checks ===================================
 329
 330 dnl ================== tiff checks ===================================================
 331 AC_ARG_ENABLE(tiff,
 332             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 333
 334 if test "x$enable_tiff" = "xyes"; then
 335     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 336     if test "x$enable_tiff" = "xyes"; then
 337         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 338         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 339     fi
 340     if test "x$enable_tiff" = "xyes"; then
 341             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 342     else
 343             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 344     fi
 345 fi
 346
 347 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 348 dnl ================== end of tiff checks ============================================
 349
 350 dnl ================== djvu checks ===================================================
 351
 352 AC_ARG_ENABLE(djvu,
 353             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=yes)
 354
 355 if test "x$enable_djvu" = "xyes"; then
 356     DJVULIBRE_REQUIRED=3.5.17
 357     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 358
 359     if test "x$enable_djvu" = "xyes"; then
 360         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 361     else
 362         AC_MSG_WARN([
 363 ** Djvu support is disabled since a recent version of the djvulibre
 364 ** library was not found. You need at least djvulibre-3.5.17 which
 365 ** can be found on http://djvulibre.djvuzone.org
 366 ])
 367     fi
 368 fi
 369
 370 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 371
 372 dnl ================== End of djvu checks ===================================================
 373
 374 dnl ================== dvi checks ===================================================
 375
 376 AC_ARG_ENABLE(dvi,
 377             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=yes)
 378
 379 AC_ARG_ENABLE(t1lib,
 380             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 381
 382 if test "x$enable_dvi" = "xyes"; then
 383     AC_C_CONST
 384     AC_C_INLINE
 385     AC_TYPE_SIZE_T
 386     AC_CHECK_SIZEOF(long, 4)
 387     AC_CHECK_SIZEOF(int, 4)
 388     AC_CHECK_SIZEOF(short, 2)
 389     AC_CHECK_SIZEOF(void *, 4)
 390     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 391
 392     if test "x$enable_dvi" = "xyes"; then
 393         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 394     else
 395         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 396     fi
 397 fi
 398 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 399
 400 if test "x$enable_dvi" = "xyes"; then
 401     if test "x$enable_type1_fonts" = "xyes"; then
 402         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 403     fi
 404
 405     if test "x$enable_type1_fonts" = xyes; then
 406         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 407     fi
 408 else
 409     enable_type1_fonts=no
 410 fi
 411 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 412
 413 dnl ================== End of dvi checks ===================================================
 414
 415 dnl ================== pixbuf checks ===================================================
 416
 417 AC_ARG_ENABLE(pixbuf,
 418             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 419 if test "x$enable_pixbuf" = "xyes"; then
 420         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 421 fi
 422 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 423
 424 dnl ================== End of pixbuf checks ===================================================
 425
 426 dnl ================== comic book checks ===================================================
 427
 428 AC_ARG_ENABLE(comics,
 429         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=yes)
 430 if test "x$enable_comics" = "xyes"; then
 431         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 432 fi
 433 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 434
 435 dnl ================== End of comic book checks ============================================
 436
 437 dnl ================== impress book checks ===================================================
 438
 439 AC_ARG_ENABLE(impress,
 440         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 441 if test "x$enable_impress" = "xyes"; then
 442         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 443 fi
 444 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 445
 446 dnl ================== End of impress book checks ============================================
 447
 448 dnl =================== Mime types list ====================================================
 449
 450 if test "x$enable_pdf" = "xyes" ; then
 451         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 452 fi
 453 if test "x$enable_ps" = "xyes" ; then
 454         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 455 fi
 456 if test "x$enable_dvi" = "xyes"; then
 457         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;"
 458 fi
 459 if test "x$enable_djvu" = "xyes"; then
 460         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 461 fi
 462 if test "x$enable_tiff" = "xyes"; then
 463         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 464 fi
 465 if test "x$enable_comics" = "xyes"; then
 466         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;"
 467 fi
 468 if test "x$enable_pixbuf" = "xyes"; then
 469         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 470 fi
 471 if test "x$enable_impress" = "xyes"; then
 472         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 473 fi
 474 AC_SUBST(EVINCE_MIME_TYPES)
 475
 476 AC_CONFIG_FILES([
 477 backend/Makefile
 478 backend/comics/Makefile
 479 backend/djvu/Makefile
 480 backend/dvi/Makefile
 481 backend/dvi/mdvi-lib/Makefile
 482 backend/impress/Makefile
 483 backend/pdf/Makefile
 484 backend/pixbuf/Makefile
 485 backend/ps/Makefile
 486 backend/tiff/Makefile
 487 cut-n-paste/Makefile
 488 cut-n-paste/gedit-message-area/Makefile
 489 cut-n-paste/toolbar-editor/Makefile
 490 cut-n-paste/zoom-control/Makefile
 491 cut-n-paste/totem-screensaver/Makefile
 492 data/evince.desktop.in
 493 data/Makefile
 494 data/icons/Makefile
 495 data/icons/16x16/Makefile
 496 data/icons/16x16/apps/Makefile
 497 data/icons/16x16/actions/Makefile
 498 data/icons/22x22/Makefile
 499 data/icons/22x22/apps/Makefile
 500 data/icons/22x22/actions/Makefile
 501 data/icons/24x24/Makefile
 502 data/icons/24x24/apps/Makefile
 503 data/icons/24x24/actions/Makefile
 504 data/icons/32x32/Makefile
 505 data/icons/32x32/actions/Makefile
 506 data/icons/48x48/Makefile
 507 data/icons/48x48/apps/Makefile
 508 data/icons/48x48/actions/Makefile
 509 data/icons/scalable/Makefile
 510 data/icons/scalable/apps/Makefile
 511 help/Makefile
 512 help/reference/Makefile
 513 help/reference/version.xml
 514 libdocument/Makefile
 515 Makefile
 516 po/Makefile.in
 517 properties/Makefile
 518 shell/Makefile
 519 test/Makefile
 520 thumbnailer/Makefile
 521 ])
 522
 523 AC_OUTPUT
 524
 525 echo "
 526 Configure summary:
 527         GNOME Support......:  $WITH_GNOME
 528         Print Support......:  $enable_print
 529         Keyring Support....:  $WITH_KEYRING
 530         DBUS Support.......:  $enable_dbus
 531         Nautilus Plugin....:  $HAVE_NAUTILUS
 532         Thumbnailer........:  $ENABLE_THUMBNAILER
 533         Gtk-Doc Support....:  $enable_gtk_doc
 534
 535         PDF Backend........:  $enable_pdf
 536         PostScript Backend.:  $enable_ps $ps_backend
 537         TIFF Backend.......:  $enable_tiff
 538         DJVU Backend.......:  $enable_djvu
 539         DVI Backend........:  $enable_dvi
 540         Pixbuf Backend.....:  $enable_pixbuf
 541         Comics Backend.....:  $enable_comics
 542         Impress Backend....:  $enable_impress
 543 "