// The Estes A8-3 and C6-7 motors have diameter of 17.7 mm,
// length 69.5 mm. The Estes Alpha launch pad has rod diameter 3.4 mm.

motor_diam = 17.7 + 1.2; // add some tolerance
motor_len  = 69.5 + 0.5;

segment_overlap = 15;

loose_fit_diam_diff = 1.1; // cylinder with outer diameter d1
	// will fit loosely into the hole with inner diameter
	// d1 + loose_fit_diam_diff
tight_fit_diam_diff = 0.4; // cylinder with outer diameter d1
	// will fit tightly into the hole with inner diameter
	// d1 + tight_fit_diam_diff

thin_wall = 1.0; // depends on the print width
thick_wall = 2*thin_wall + loose_fit_diam_diff/2;
	// motor_diam + 2*thick_wall is the outer diameter of the rocket
motor_wall = thick_wall; // above the motor

clip_height = 3.5;
clip_width = 1.2;
clip_clearance = 1.0;
clip_inner_space = motor_diam/2 - 1.5;

rod_diam = 3.4 + 1;
rubber_beam_height = 3;
rubber_beam_width = 1.5;

fin_thickness = 1.5;

eps = 0.01;
infty = 250;

// rod holder

module rod_holder() {
	// rod hole holder
	hull() {
		translate([motor_diam/2 + thick_wall + thin_wall + rod_diam/2, 0, 0])
			cylinder(r = rod_diam/2 + thin_wall, h = thick_wall);
		translate([motor_diam/2 + thick_wall - thin_wall - rod_diam/2, 0, 0])
				
			cylinder(r = rod_diam/2 + thin_wall, h = 3*thick_wall);
	}
}

module rod_hole() {
	// rod hole
	translate([motor_diam/2 + thick_wall + thin_wall + eps + rod_diam/2, 0, 0])
		cylinder(r = rod_diam/2, h = infty);
}

//----------------- MOTOR MODULE -----------------------------

module fin() {
	assign(h1 = 2*motor_len/3, // near end height
		h2 = 20,	// far end height
		h_off = motor_len, // height offset of the far height
		w = 30, // distance of the far height
		fin_w = fin_thickness)
	translate([0, -fin_w/2, -h1])
	hull() { 
		cube([eps, fin_w, h1]); // near end
		translate([w, 0, h_off]) // far end
			cube([eps, fin_w, h2]);
	};
};

// alternative fin layout
module fin2() {
	assign(h1 = motor_len/2, // near end height
		w2 = 23,	// bottom/far end width
		h_off = 60, // height offset of the far height
		w = 30, // distance of the far height
		fin_w = fin_thickness)
	translate([0, -fin_w/2, -h1])
	hull() { 
		cube([eps, fin_w, h1]); // near end
		translate([w-w2, 0, h_off]) // far end
			cube([w2, fin_w, eps]);
	};
};

rod_hole_height = 20;
rod_hole_side = 1.5*(rod_diam + thin_wall);

module motor_module_solid()
{
	// cone from loose_fit to tight fit, 1/3 of segment overlap
	cylinder(r1 = motor_diam/2 + thin_wall,
		r2 = motor_diam/2 + thick_wall - thin_wall - tight_fit_diam_diff/2,
		h = segment_overlap/3 + eps);

	// tight fit cylinder, 2/3 of segment overlap
	translate([0, 0, segment_overlap/3])
		cylinder(r = motor_diam/2 + thick_wall - thin_wall - tight_fit_diam_diff/2,
		h = 2*segment_overlap/3 + eps);

	// conical joint between the two cylinders
	translate([0, 0, segment_overlap - thick_wall + thin_wall])
		cylinder(r1 = motor_diam/2 + thick_wall - thin_wall - tight_fit_diam_diff/2,
			r2 = motor_diam/2 + thick_wall,
			h = thick_wall - thin_wall + eps);

	// the thick cylinder above it
	translate([0, 0, segment_overlap])
		cylinder(r = motor_diam/2 + thick_wall,
		h = motor_len + motor_wall - segment_overlap);

	// fins
        for (a = [60, 180, 300]) {
                rotate([0, 0, a])
                translate([motor_diam/2 + thick_wall-thin_wall, 0, motor_wall + motor_len])
                        // fin();
                        fin2();
        };

	// motor clip
	for (angle = [120, -120]) rotate([0, 0, angle]) intersection() {
		translate([clip_inner_space, -infty/2,
			motor_len + motor_wall + clip_clearance])
			cube([clip_width, infty, clip_height]);
		rotate([0, 0, -60])
			translate([-infty/2, 0, 0]) cube(infty);
		rotate([0, 0, -120])
			translate([-infty/2, 0, 0]) cube(infty);
	};

	translate([0, 0, motor_len + motor_wall])
		scale([1, 1, -1])
		rod_holder();
};
	
module motor_module() {
	difference() {
		motor_module_solid();

		// top ring to hold the motor inside
		translate([0, 0, -eps])
			cylinder(r = motor_diam/2 - motor_wall,
				h = motor_wall + 2*eps);

		// motor hole
		translate([0, 0, motor_wall - eps])
			cylinder(r = motor_diam/2, h = motor_len + 2*eps);

		// three rails inside the motor hole
		translate([0, 0, segment_overlap + thick_wall]) difference() {
			union() {
				cylinder(r = motor_diam/2 + thin_wall,
					h = motor_len - segment_overlap - 2*thick_wall + eps);
				translate([0, 0, motor_len - segment_overlap - 2*thick_wall])
					cylinder(r1 = motor_diam/2 + thin_wall, r2 = motor_diam/2, h = thick_wall + eps);
			};
			for (a = [0, 120, 240]) rotate([0, 0, a])
				translate([motor_diam/2 + 2.5, 0, -eps])
					cylinder(r = 3, h = infty);
		};

		rod_hole();
	};
};

// -------------------- CENTRAL TUBE ---------------------

central_tube_h = 97;

central_clip_r = 12;
central_clip_w = 4;
central_clip_wall = 1.5;
central_clip_clearance = 2.5;

module central_tube_solid() {
	cylinder(r = motor_diam/2 + thick_wall, h = central_tube_h);
	rod_holder();
};

module central_tube() {
	difference() {
		central_tube_solid();
		translate([0, 0, -eps])
			cylinder(r = motor_diam/2 + thick_wall - thin_wall,
				h = infty);
		rod_hole();
	};
};

//------------------------- FRONT CONE -----------------------
cone_h = 45;
cone_resolution = 40;
cone_solid_h = 10;

function bez_i4(t, ctls) =
	(pow(1-t, 3) * ctls[0])
	+ (3 * t * pow(1-t, 2) * ctls[1])
	+ (3 * pow(t, 2) * (1-t) * ctls[2])
	+ (pow(t, 3) * ctls[3]);

module bezier_cone(cps, res)
{
	for (t = [0:1:res])
		translate([0, 0, (bez_i4(t/res, cps))[0]])
			cylinder(r1 = (bez_i4(t/res, cps))[1],
				r2 = (bez_i4((t + 1)/res, cps))[1],
				h = (bez_i4((t + 1)/res, cps))[0]
				    - (bez_i4(t/res, cps))[0] + eps);
};

module front_cone_body() {
	translate([0, 0, segment_overlap])
		bezier_cone([
			[ 0, motor_diam/2 + thick_wall ], // start
			[ cone_h/4, motor_diam/2 + thick_wall ], // cp 1
			[ cone_h - motor_diam/2 - thick_wall, motor_diam/2 + thick_wall ], // cp 2
			[ cone_h, 0 ],
		], 40);

	translate([0, 0, segment_overlap-thick_wall+thin_wall])
		cylinder(r1 = motor_diam/2+thin_wall,
			r2 = motor_diam/2 + thick_wall,
			h = thick_wall - thin_wall + eps);

	cylinder(r = motor_diam/2+thin_wall, h = segment_overlap + eps);
};

module front_cone() {
	difference() {
		front_cone_body();
		intersection() {
			translate([0, 0, segment_overlap])
				bezier_cone([
					[ 0.7*thin_wall, motor_diam/2 + thick_wall - thin_wall ], // start
				[ cone_h/4-0.7*thin_wall, motor_diam/2 + thick_wall - thin_wall], // cp 1
				[ cone_h - motor_diam/2 - thick_wall + thin_wall - 1.4*thin_wall, motor_diam/2 + thick_wall - thin_wall ], // cp 2
				[ cone_h - 1.4*thin_wall, 0 ],
			], 40);
			cylinder(r = motor_diam/2 + thick_wall + eps,
				h = cone_h + segment_overlap - cone_solid_h);
		};

		translate([0, 0, segment_overlap-thick_wall+1.7*thin_wall])
			cylinder(r1 = motor_diam/2,
				r2 = motor_diam/2 + thick_wall-thin_wall,
				h = thick_wall-thin_wall + eps);

		translate([0, 0, -eps])
			cylinder(r = motor_diam/2, h = segment_overlap + 2*eps);
	};
};

debug = 0;

if (debug == 1) {
// debug
difference($fn = 16) {
	front_cone();
	central_tube();
	motor_module();

	translate([0, 0, -infty/2]) cube(infty);
};

} else {

// production
$fn = 128;

translate([motor_diam + thick_wall, 0, 0])
	motor_module();

rotate([0, 0, 120])
translate([motor_diam + thick_wall, 0, 0])
	central_tube();

rotate([0, 0, 240])
translate([motor_diam + thick_wall, 0, 0])
	front_cone();

}