configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.57)
   4 AC_INIT([Evince],[2.25.2],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
   5 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-dist-gzip])
   6
   7 EV_API_VERSION=2.20
   8 AC_SUBST(EV_API_VERSION)
   9
  10 AM_CONFIG_HEADER(config.h)
  11
  12 AM_MAINTAINER_MODE
  13
  14 AM_PROG_LIBTOOL
  15
  16 AC_ISC_POSIX
  17 AC_PROG_CC
  18 AM_PROG_CC_STDC
  19 AC_PROG_CXX
  20 AC_STDC_HEADERS
  21 IT_PROG_INTLTOOL([0.35.0])
  22 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  23 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  24
  25 GNOME_COMMON_INIT
  26 GNOME_DOC_INIT
  27 GNOME_MAINTAINER_MODE_DEFINES
  28 GNOME_COMPILE_WARNINGS
  29 GNOME_CXX_WARNINGS
  30
  31 GTK_DOC_CHECK(1.0)
  32
  33 GETTEXT_PACKAGE=evince
  34 AC_SUBST(GETTEXT_PACKAGE)
  35 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  36 AM_GLIB_GNU_GETTEXT
  37
  38 dnl Check dependencies
  39
  40 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
  41 # BACKEND_CFLAGS   for backend implementations.
  42 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
  43 # FRONTEND_LIBS
  44 # SHELL_CFLAGS     for shell implementation.
  45 # SHELL_LIBS
  46
  47 DBUS_GLIB_REQUIRED=0.70
  48 GTK_REQUIRED=2.12.0
  49 GLIB_REQUIRED=2.18.0
  50 KEYRING_REQUIRED=2.22.0
  51
  52 GNOME_ICON_THEME_REQUIRED=2.17.1
  53 LIBXML_REQUIRED=2.5.0
  54
  55 PKG_CHECK_MODULES(LIB, gtk+-2.0 >= $GTK_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
  56 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
  57 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
  58 PKG_CHECK_MODULES(SHELL_CORE, libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED gthread-2.0 gconf-2.0)
  59
  60 PKG_CHECK_MODULES(SMCLIENT, gtk+-2.0 gthread-2.0)
  61 AC_SUBST(SMCLIENT_CFLAGS)
  62 AC_SUBST(SMCLIENT_LIBS)
  63
  64 BACKEND_LIBTOOL_FLAGS="-module -avoid-version"
  65 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
  66
  67 dnl ===== Check special functions
  68 evince_save_LIBS=$LIBS
  69 LIBS="$LIBS $BACKEND_LIBS"
  70 AC_CHECK_FUNCS(cairo_format_stride_for_width)
  71 LIBS=$evince_save_LIBS
  72
  73 AC_ARG_WITH(keyring,
  74         AC_HELP_STRING([--without-keyring],[disable the use of gnome-keyring]),
  75         [case "${withval}" in
  76         yes) WITH_KEYRING=yes ;;
  77         no) WITH_KEYRING=no ;;
  78         *) AC_MSG_ERROR(bad value ${withval} for --with-keyring) ;;
  79         esac],
  80         [WITH_KEYRING=yes]) dnl Default value
  81 AM_CONDITIONAL(WITH_KEYRING, test x$WITH_KEYRING = "xyes")
  82
  83 if test x$WITH_KEYRING = "xyes"; then
  84         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
  85         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
  86 fi
  87
  88 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
  89 AC_SUBST(GLIB_GENMARSHAL)
  90
  91 dnl ========= Check for DBUS
  92 AC_ARG_ENABLE(dbus,
  93         [AC_HELP_STRING([--enable-dbus], [Compile with support for dbus])],
  94         enable_dbus="$enableval",enable_dbus=yes)
  95 if test "x$enable_dbus" != "xno"; then
  96         PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
  97         [enable_dbus=yes],[enable_dbus=no])
  98
  99         if test "x$enable_dbus" = "xno"; then
 100            AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
 101         fi
 102
 103         if test "x$enable_dbus" = "xyes" ; then
 104                 AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 105
 106                 if test x$DBUS_BINDING_TOOL = "xno" ; then
 107                         AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 108                 fi
 109
 110                 AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 111         fi
 112 fi
 113
 114 AC_SUBST([DBUS_CFLAGS])
 115 AC_SUBST([DBUS_LIBS])
 116
 117 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
 118 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
 119
 120 dnl Debug mode
 121 AC_ARG_ENABLE([debug],
 122         AC_HELP_STRING([--enable-debug],
 123                         [Turn on evince debug mode]),,
 124                 [enable_debug=no])
 125
 126 if test "x$enable_debug" = "xyes"; then
 127    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 128 fi
 129
 130
 131 LIB_CFLAGS="$LIB_CFLAGS $DEBUG_FLAGS"
 132 LIB_LIBS="$LIB_LIBS"
 133 AC_SUBST(LIB_CFLAGS)
 134 AC_SUBST(LIB_LIBS)
 135
 136 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 137 AC_SUBST(BACKEND_CFLAGS)
 138 AC_SUBST(BACKEND_LIBS)
 139
 140 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS $KEYRING_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 141 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS $KEYRING_LIBS -lz"
 142 AC_SUBST(SHELL_CFLAGS)
 143 AC_SUBST(SHELL_LIBS)
 144
 145 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 146 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 147 AC_SUBST(FRONTEND_CFLAGS)
 148 AC_SUBST(FRONTEND_LIBS)
 149
 150 dnl Check for Nautilus property page build
 151 AC_ARG_ENABLE(nautilus,
 152         AC_HELP_STRING([--enable-nautilus],[compile the nautilus plugin]),
 153         [case "${enableval}" in
 154         yes) ENABLE_NAUTILUS=yes ;;
 155         no) ENABLE_NAUTILUS=no ;;
 156         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nautilus) ;;
 157         esac],
 158         [ENABLE_NAUTILUS=yes]) dnl Default value
 159
 160 if test x$ENABLE_NAUTILUS = "xyes" ; then
 161         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
 162                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
 163         NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 164         AC_SUBST(NAUTILUS_EXTENSION_DIR)
 165 fi
 166
 167 AC_SUBST(NAUTILUS_CFLAGS)
 168 AC_SUBST(NAUTILUS_LIBS)
 169 if test x$HAVE_NAUTILUS = "xyes"; then
 170         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
 171 fi
 172 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
 173
 174
 175 dnl Check for thumbnailer build
 176 AC_ARG_ENABLE(thumbnailer,
 177         AC_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer]),
 178         [case "${enableval}" in
 179         yes) ENABLE_THUMBNAILER=yes ;;
 180         no) ENABLE_THUMBNAILER=no ;;
 181         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thumbnailer) ;;
 182         esac],
 183         [ENABLE_THUMBNAILER=yes]) dnl Default value
 184 AM_CONDITIONAL(ENABLE_THUMBNAILER, test x$ENABLE_THUMBNAILER = "xyes")
 185
 186 dnl GConf configuration
 187 AM_GCONF_SOURCE_2
 188
 189 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
 190 if test "x$GCONFTOOL" = "xno"; then
 191         AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 192 fi
 193
 194 dnl ================== portability checks ===========================================
 195
 196 dnl for backtrace()
 197 AC_CHECK_HEADERS([execinfo.h])
 198
 199 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 200   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 201   ],[],[#include <langinfo.h>])
 202
 203 dnl ================== pdf checks ===================================================
 204 AC_ARG_ENABLE(pdf,
 205               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 206
 207 if test "x$enable_pdf" = "xyes"; then
 208     POPPLER_REQUIRED=0.8.0
 209     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED,enable_pdf=yes,enable_pdf=no)
 210
 211     if test "x$enable_pdf" = "xyes"; then
 212             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 213             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 214             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 215
 216             evince_save_LIBS=$LIBS
 217             LIBS="$LIBS $POPPLER_LIBS"
 218             AC_CHECK_FUNCS(poppler_page_render)
 219             AC_CHECK_FUNCS(poppler_layers_iter_new)
 220             LIBS=$evince_save_LIBS
 221
 222             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 223             if test x$enable_cairo_pdf = xyes; then
 224                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 225             fi
 226
 227             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 228             if test x$enable_cairo_ps = xyes; then
 229                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 230             fi
 231     else
 232             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 233     fi
 234 fi
 235
 236 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 237 dnl ================== end of pdf checks ============================================
 238
 239 dnl libspectre (used by ps and dvi backends)
 240 SPECTRE_REQUIRED=0.2.0
 241 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 242 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 243 if test "x$have_spectre" = "xyes"; then
 244    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 245 fi
 246
 247 dnl ================== ps checks ====================================================
 248 AC_ARG_ENABLE(ps,
 249         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 250
 251 if test "x$enable_ps" = "xyes"; then
 252    if test "x$have_spectre" = "xyes"; then
 253       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 254    else
 255       enable_ps="no"
 256       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 257    fi
 258 fi
 259 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 260 dnl ======================== End of ps checks ===================================
 261
 262 dnl ================== tiff checks ===================================================
 263 AC_ARG_ENABLE(tiff,
 264             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 265
 266 if test "x$enable_tiff" = "xyes"; then
 267     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 268     if test "x$enable_tiff" = "xyes"; then
 269         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 270         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 271     fi
 272     if test "x$enable_tiff" = "xyes"; then
 273             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 274     else
 275             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 276     fi
 277 fi
 278
 279 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 280 dnl ================== end of tiff checks ============================================
 281
 282 dnl ================== djvu checks ===================================================
 283
 284 AC_ARG_ENABLE(djvu,
 285             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=yes)
 286
 287 if test "x$enable_djvu" = "xyes"; then
 288     DJVULIBRE_REQUIRED=3.5.17
 289     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 290
 291     if test "x$enable_djvu" = "xyes"; then
 292         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 293     else
 294         AC_MSG_WARN([
 295 ** Djvu support is disabled since a recent version of the djvulibre
 296 ** library was not found. You need at least djvulibre-3.5.17 which
 297 ** can be found on http://djvulibre.djvuzone.org
 298 ])
 299     fi
 300 fi
 301
 302 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 303
 304 dnl ================== End of djvu checks ===================================================
 305
 306 dnl ================== dvi checks ===================================================
 307
 308 AC_ARG_ENABLE(dvi,
 309             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=yes)
 310
 311 AC_ARG_ENABLE(t1lib,
 312             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 313
 314 if test "x$enable_dvi" = "xyes"; then
 315     AC_C_CONST
 316     AC_C_INLINE
 317     AC_TYPE_SIZE_T
 318     AC_CHECK_SIZEOF(long, 4)
 319     AC_CHECK_SIZEOF(int, 4)
 320     AC_CHECK_SIZEOF(short, 2)
 321     AC_CHECK_SIZEOF(void *, 4)
 322     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 323
 324     if test "x$enable_dvi" = "xyes"; then
 325         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 326     else
 327         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 328     fi
 329 fi
 330 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 331
 332 if test "x$enable_dvi" = "xyes"; then
 333     if test "x$enable_type1_fonts" = "xyes"; then
 334         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 335     fi
 336
 337     if test "x$enable_type1_fonts" = xyes; then
 338         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 339     fi
 340 else
 341     enable_type1_fonts=no
 342 fi
 343 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 344
 345 dnl ================== End of dvi checks ===================================================
 346
 347 dnl ================== pixbuf checks ===================================================
 348
 349 AC_ARG_ENABLE(pixbuf,
 350             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 351 if test "x$enable_pixbuf" = "xyes"; then
 352         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 353 fi
 354 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 355
 356 dnl ================== End of pixbuf checks ===================================================
 357
 358 dnl ================== comic book checks ===================================================
 359
 360 AC_ARG_ENABLE(comics,
 361         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=yes)
 362 if test "x$enable_comics" = "xyes"; then
 363         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 364 fi
 365 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 366
 367 dnl ================== End of comic book checks ============================================
 368
 369 dnl ================== impress book checks ===================================================
 370
 371 AC_ARG_ENABLE(impress,
 372         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 373 if test "x$enable_impress" = "xyes"; then
 374         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 375 fi
 376 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 377
 378 dnl ================== End of impress book checks ============================================
 379
 380 dnl =================== Mime types list ====================================================
 381
 382 if test "x$enable_pdf" = "xyes" ; then
 383         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 384 fi
 385 if test "x$enable_ps" = "xyes" ; then
 386         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 387 fi
 388 if test "x$enable_dvi" = "xyes"; then
 389         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 390 fi
 391 if test "x$enable_djvu" = "xyes"; then
 392         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 393 fi
 394 if test "x$enable_tiff" = "xyes"; then
 395         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 396 fi
 397 if test "x$enable_comics" = "xyes"; then
 398         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;"
 399 fi
 400 if test "x$enable_pixbuf" = "xyes"; then
 401         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 402 fi
 403 if test "x$enable_impress" = "xyes"; then
 404         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 405 fi
 406 AC_SUBST(EVINCE_MIME_TYPES)
 407
 408 AC_CONFIG_FILES([
 409 backend/Makefile
 410 backend/comics/Makefile
 411 backend/djvu/Makefile
 412 backend/dvi/Makefile
 413 backend/dvi/mdvi-lib/Makefile
 414 backend/impress/Makefile
 415 backend/pdf/Makefile
 416 backend/pixbuf/Makefile
 417 backend/ps/Makefile
 418 backend/tiff/Makefile
 419 cut-n-paste/Makefile
 420 cut-n-paste/evmountoperation/Makefile
 421 cut-n-paste/gedit-message-area/Makefile
 422 cut-n-paste/gimpcellrenderertoggle/Makefile
 423 cut-n-paste/smclient/Makefile
 424 cut-n-paste/toolbar-editor/Makefile
 425 cut-n-paste/zoom-control/Makefile
 426 cut-n-paste/totem-screensaver/Makefile
 427 data/evince.desktop.in
 428 data/Makefile
 429 data/icons/Makefile
 430 data/icons/16x16/Makefile
 431 data/icons/16x16/apps/Makefile
 432 data/icons/16x16/actions/Makefile
 433 data/icons/22x22/Makefile
 434 data/icons/22x22/apps/Makefile
 435 data/icons/22x22/actions/Makefile
 436 data/icons/24x24/Makefile
 437 data/icons/24x24/apps/Makefile
 438 data/icons/24x24/actions/Makefile
 439 data/icons/32x32/Makefile
 440 data/icons/32x32/actions/Makefile
 441 data/icons/48x48/Makefile
 442 data/icons/48x48/apps/Makefile
 443 data/icons/48x48/actions/Makefile
 444 data/icons/scalable/Makefile
 445 data/icons/scalable/apps/Makefile
 446 help/Makefile
 447 help/reference/Makefile
 448 help/reference/version.xml
 449 libdocument/Makefile
 450 Makefile
 451 po/Makefile.in
 452 properties/Makefile
 453 shell/Makefile
 454 test/Makefile
 455 thumbnailer/Makefile
 456 ])
 457
 458 AC_OUTPUT
 459
 460 echo "
 461 Configure summary:
 462         Keyring Support....:  $WITH_KEYRING
 463         DBUS Support.......:  $enable_dbus
 464         Nautilus Plugin....:  $HAVE_NAUTILUS
 465         Thumbnailer........:  $ENABLE_THUMBNAILER
 466         Gtk-Doc Support....:  $enable_gtk_doc
 467         Debug mode.........:  $enable_debug
 468
 469         PDF Backend........:  $enable_pdf
 470         PostScript Backend.:  $enable_ps
 471         TIFF Backend.......:  $enable_tiff
 472         DJVU Backend.......:  $enable_djvu
 473         DVI Backend........:  $enable_dvi
 474         Pixbuf Backend.....:  $enable_pixbuf
 475         Comics Backend.....:  $enable_comics
 476         Impress Backend....:  $enable_impress
 477 "