configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.57)
   4 AC_INIT([Evince],[2.21.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
   5 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-dist-gzip])
   6
   7 EV_API_VERSION=2.20
   8 AC_SUBST(EV_API_VERSION)
   9
  10 AM_CONFIG_HEADER(config.h)
  11
  12 AM_MAINTAINER_MODE
  13
  14 AM_PROG_LIBTOOL
  15
  16 AC_ISC_POSIX
  17 AC_PROG_CC
  18 AM_PROG_CC_STDC
  19 AC_PROG_CXX
  20 AC_STDC_HEADERS
  21 IT_PROG_INTLTOOL([0.35.0])
  22 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  23 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  24
  25 GNOME_COMMON_INIT
  26 GNOME_DOC_INIT
  27 GNOME_MAINTAINER_MODE_DEFINES
  28 GNOME_COMPILE_WARNINGS
  29 GNOME_CXX_WARNINGS
  30 GNOME_DEBUG_CHECK
  31
  32 GTK_DOC_CHECK(1.0)
  33
  34 GETTEXT_PACKAGE=evince
  35 AC_SUBST(GETTEXT_PACKAGE)
  36 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  37 AM_GLIB_GNU_GETTEXT
  38
  39 dnl Check dependencies
  40
  41 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
  42 # BACKEND_CFLAGS   for backend implementations.
  43 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
  44 # FRONTEND_LIBS
  45 # SHELL_CFLAGS     for shell implementation.
  46 # SHELL_LIBS
  47
  48 DBUS_GLIB_REQUIRED=0.70
  49 GTK_REQUIRED=2.10.0
  50 GLIB_REQUIRED=2.15.4
  51 KEYRING_REQUIRED=0.4.0
  52
  53 LIBGNOMEUI_REQUIRED=2.14.0
  54 LIBGNOME_REQUIRED=2.14.0
  55 LIBGNOMEPRINTUI_REQUIRED=2.6.0
  56 GNOME_ICON_THEME_REQUIRED=2.17.1
  57 LIBXML_REQUIRED=2.5.0
  58
  59 GTK_PRINT_REQUIRED=2.10.0
  60
  61 PKG_CHECK_MODULES(LIB, gtk+-2.0 >= $GTK_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
  62 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
  63 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED libglade-2.0 gio-2.0 >= $GLIB_REQUIRED)
  64 PKG_CHECK_MODULES(SHELL_CORE, libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED libglade-2.0 gconf-2.0)
  65
  66 BACKEND_LIBTOOL_FLAGS="-module -avoid-version"
  67 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
  68
  69 AC_ARG_WITH(keyring,
  70         AC_HELP_STRING([--without-keyring],[disable the use of gnome-keyring]),
  71         [case "${withval}" in
  72         yes) WITH_KEYRING=yes ;;
  73         no) WITH_KEYRING=no ;;
  74         *) AC_MSG_ERROR(bad value ${withval} for --with-keyring) ;;
  75         esac],
  76         [WITH_KEYRING=yes]) dnl Default value
  77 AM_CONDITIONAL(WITH_KEYRING, test x$WITH_KEYRING = "xyes")
  78
  79 if test x$WITH_KEYRING = "xyes"; then
  80         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
  81         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
  82 fi
  83
  84 AC_ARG_WITH(libgnome,
  85         AC_HELP_STRING([--without-libgnome],[disable the use of libgnome]),
  86         [case "${withval}" in
  87         yes) WITH_GNOME=yes ;;
  88         no) WITH_GNOME=no ;;
  89         *) AC_MSG_ERROR(bad value ${withval} for --with-libgnome) ;;
  90         esac],
  91         [WITH_GNOME=yes]) dnl Default value
  92 AM_CONDITIONAL(WITH_GNOME, test x$WITH_GNOME = "xyes")
  93
  94 if test x$WITH_GNOME = "xyes"; then
  95         PKG_CHECK_MODULES(GNOME, libgnome-2.0 >= $LIBGNOME_REQUIRED)
  96         PKG_CHECK_MODULES(GNOMEUI, libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED)
  97         AC_DEFINE([WITH_GNOME],[1],[Define if GNOME support is enabled])
  98 fi
  99
 100 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
 101 AC_SUBST(GLIB_GENMARSHAL)
 102
 103 dnl ========= Print support
 104 AC_ARG_WITH(print,
 105             [AC_HELP_STRING([--with-print=no/gtk/gnome/auto], [Compile with print support [default=auto]])],
 106             PRINT=$withval,
 107             PRINT="auto")
 108
 109 PKG_CHECK_MODULES(GNOME_PRINT,
 110                   libgnomeprintui-2.2 >= $LIBGNOMEPRINTUI_REQUIRED,
 111                   enable_gnome_print=yes, enable_gnome_print=no)
 112 PKG_CHECK_MODULES(GTK_PRINT,
 113                   gtk+-unix-print-2.0 >= $GTK_PRINT_REQUIRED,
 114                   enable_gtk_print=yes, enable_gtk_print=no)
 115 enable_print=no
 116 if test x$PRINT = xgnome -a x$enable_gnome_print = xyes; then
 117    enable_print=gnome
 118 else
 119    if test x$PRINT = xgtk -a x$enable_gtk_print = xyes; then
 120       enable_print=gtk
 121    else
 122       if test x$PRINT = xauto; then
 123          if test x$enable_gtk_print = xyes; then
 124             enable_print=gtk
 125          else
 126             if test x$enable_gnome_print = xyes; then
 127                enable_print=gnome
 128             fi
 129          fi
 130       fi
 131    fi
 132 fi
 133
 134 if test x$enable_print = xgnome; then
 135    AC_SUBST(GNOME_PRINT_CFLAGS)
 136    AC_SUBST(GNOME_PRINT_LIBS)
 137    AC_DEFINE([WITH_GNOME_PRINT],[1],[Enable GNOME Print Support.])
 138    AC_DEFINE([WITH_PRINT],[1],[Enable Print Support.])
 139 fi
 140
 141 if test x$enable_print = xgtk; then
 142    AC_SUBST(GTK_PRINT_CFLAGS)
 143    AC_SUBST(GTK_PRINT_LIBS)
 144    AC_DEFINE([WITH_GTK_PRINT],[1],[Enable GTK Print Support.])
 145    AC_DEFINE([WITH_PRINT],[1],[Enable Print Support.])
 146 fi
 147
 148 AM_CONDITIONAL(WITH_GNOME_PRINT, test x$enable_print = xgnome)
 149 AM_CONDITIONAL(WITH_GTK_PRINT, test x$enable_print = xgtk)
 150
 151
 152 dnl ========= Check for DBUS
 153 PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
 154         [enable_dbus=yes],[enable_dbus=no])
 155 AC_SUBST([DBUS_CFLAGS])
 156 AC_SUBST([DBUS_LIBS])
 157
 158 if test "x$enable_dbus" = "xno"; then
 159         AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
 160 fi
 161
 162 if test "x$enable_dbus" = "xyes" ; then
 163         AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 164
 165         if test x$DBUS_BINDING_TOOL = "xno" ; then
 166                 AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 167         fi
 168
 169         AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 170 fi
 171
 172 LIB_CFLAGS="$LIB_CFLAGS $GNOME_CFLAGS"
 173 LIB_LIBS="$LIB_LIBS $GNOME_LIBS"
 174 AC_SUBST(LIB_CFLAGS)
 175 AC_SUBST(LIB_LIBS)
 176
 177 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE"
 178 AC_SUBST(BACKEND_CFLAGS)
 179 AC_SUBST(BACKEND_LIBS)
 180
 181 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS $GNOMEUI_CFLAGS $KEYRING_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE"
 182 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS $GNOMEUI_LIBS $KEYRING_LIBS -lz"
 183 AC_SUBST(SHELL_CFLAGS)
 184 AC_SUBST(SHELL_LIBS)
 185
 186 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $GNOME_CFLAGS"
 187 FRONTEND_LIBS="$FRONTEND_CORE_LIBS $GNOME_LIBS -lz"
 188 AC_SUBST(FRONTEND_CFLAGS)
 189 AC_SUBST(FRONTEND_LIBS)
 190
 191 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
 192 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
 193
 194 dnl Check for Nautilus property page build
 195 AC_ARG_ENABLE(nautilus,
 196         AC_HELP_STRING([--enable-nautilus],[compile the nautilus plugin]),
 197         [case "${enableval}" in
 198         yes) ENABLE_NAUTILUS=yes ;;
 199         no) ENABLE_NAUTILUS=no ;;
 200         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nautilus) ;;
 201         esac],
 202         [ENABLE_NAUTILUS=yes]) dnl Default value
 203
 204 if test x$ENABLE_NAUTILUS = "xyes" ; then
 205         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
 206                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
 207         NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 208         AC_SUBST(NAUTILUS_EXTENSION_DIR)
 209 fi
 210
 211 AC_SUBST(NAUTILUS_CFLAGS)
 212 AC_SUBST(NAUTILUS_LIBS)
 213 if test x$HAVE_NAUTILUS = "xyes"; then
 214         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
 215 fi
 216 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
 217
 218
 219 dnl Check for thumbnailer build
 220 AC_ARG_ENABLE(thumbnailer,
 221         AC_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer]),
 222         [case "${enableval}" in
 223         yes) ENABLE_THUMBNAILER=yes ;;
 224         no) ENABLE_THUMBNAILER=no ;;
 225         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thumbnailer) ;;
 226         esac],
 227         [ENABLE_THUMBNAILER=yes]) dnl Default value
 228 AM_CONDITIONAL(ENABLE_THUMBNAILER, test x$ENABLE_THUMBNAILER = "xyes")
 229
 230 dnl GConf configuration
 231 AM_GCONF_SOURCE_2
 232
 233 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
 234 if test "x$GCONFTOOL" = "xno"; then
 235         AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 236 fi
 237
 238 dnl ================== portability checks ===========================================
 239
 240 dnl for backtrace()
 241 AC_CHECK_HEADERS([execinfo.h])
 242
 243 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 244   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 245   ],[],[#include <langinfo.h>])
 246
 247 dnl ================== pdf checks ===================================================
 248 AC_ARG_ENABLE(pdf,
 249               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 250
 251 if test "x$enable_pdf" = "xyes"; then
 252     POPPLER_REQUIRED=0.6
 253     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED,enable_pdf=yes,enable_pdf=no)
 254
 255     if test "x$enable_pdf" = "xyes"; then
 256             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 257             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 258             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 259
 260             evince_save_LIBS=$LIBS
 261             LIBS="$LIBS $POPPLER_LIBS"
 262             AC_CHECK_FUNCS(poppler_page_render)
 263             AC_CHECK_FUNCS(poppler_page_render_for_printing)
 264             AC_CHECK_FUNCS(poppler_page_get_image)
 265             LIBS=$evince_save_LIBS
 266
 267             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 268             if test x$enable_cairo_pdf == xyes; then
 269                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 270             fi
 271
 272             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 273             if test x$enable_cairo_ps == xyes; then
 274                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 275             fi
 276     else
 277             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 278     fi
 279 fi
 280
 281 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 282 dnl ================== end of pdf checks ============================================
 283 SPECTRE_REQUIRED=0.2.0
 284
 285 dnl libspectre (used by ps and dvi backends)
 286 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 287 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 288 if test "x$have_spectre" = "xyes"; then
 289    AC_DEFINE([HAVE_SPECTRE], [1], [Have libpectre])
 290 fi
 291
 292 dnl ================== ps checks ====================================================
 293 AC_ARG_ENABLE(ps,
 294         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 295
 296 ps_backend=""
 297 if test x$enable_ps = xyes; then
 298    AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 299
 300    if test "x$have_spectre" = "xyes"; then
 301       ps_backend="(libspectre)"
 302    else
 303       dnl check for GS version
 304       AC_MSG_CHECKING(for Ghostscript version...)
 305       GS_VERSION=`gs --version | head -n 1 | sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
 306       AC_MSG_RESULT(found $GS_VERSION)
 307       if test "$GS_VERSION" -lt "7"; then
 308          AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) or Ghostscript (version >= 7) are needed])
 309          enable_ps=no
 310       else
 311          AC_ARG_WITH(gs-aa-params,
 312                      [AC_HELP_STRING([--with-gs-aa-params], [Define antialiasing params for ghostscript])],AA_PARAMS=$withval,
 313                      AA_PARMS="-sDEVICE=x11alpha -dNOPLATFONTS -dGraphicsAlphaBits=4 -dTextAlphaBits=4 -dDOINTERPOLATE"
 314                      )
 315          AC_DEFINE_UNQUOTED(ALPHA_PARAMS, "$AA_PARMS", [Anti-aliasing parameters for Ghostscript.])
 316          AC_MSG_RESULT(Antialiasing parameters for Ghostscript: $AA_PARMS)
 317          ps_backend="(gs)"
 318       fi
 319    fi
 320 fi
 321 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 322 dnl ======================== End of ps checks ===================================
 323
 324 dnl ================== tiff checks ===================================================
 325 AC_ARG_ENABLE(tiff,
 326             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 327
 328 if test "x$enable_tiff" = "xyes"; then
 329     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 330     if test "x$enable_tiff" = "xyes"; then
 331         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 332         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 333     fi
 334     if test "x$enable_tiff" = "xyes"; then
 335             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 336     else
 337             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 338     fi
 339 fi
 340
 341 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 342 dnl ================== end of tiff checks ============================================
 343
 344 dnl ================== djvu checks ===================================================
 345
 346 AC_ARG_ENABLE(djvu,
 347             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=yes)
 348
 349 if test "x$enable_djvu" = "xyes"; then
 350     DJVULIBRE_REQUIRED=3.5.17
 351     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 352
 353     if test "x$enable_djvu" = "xyes"; then
 354         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 355     else
 356         AC_MSG_WARN([
 357 ** Djvu support is disabled since a recent version of the djvulibre
 358 ** library was not found. You need at least djvulibre-3.5.17 which
 359 ** can be found on http://djvulibre.djvuzone.org
 360 ])
 361     fi
 362 fi
 363
 364 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 365
 366 dnl ================== End of djvu checks ===================================================
 367
 368 dnl ================== dvi checks ===================================================
 369
 370 AC_ARG_ENABLE(dvi,
 371             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=yes)
 372
 373 AC_ARG_ENABLE(t1lib,
 374             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 375
 376 if test "x$enable_dvi" = "xyes"; then
 377     AC_C_CONST
 378     AC_C_INLINE
 379     AC_TYPE_SIZE_T
 380     AC_CHECK_SIZEOF(long, 4)
 381     AC_CHECK_SIZEOF(int, 4)
 382     AC_CHECK_SIZEOF(short, 2)
 383     AC_CHECK_SIZEOF(void *, 4)
 384     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 385
 386     if test "x$enable_dvi" = "xyes"; then
 387         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 388     else
 389         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 390     fi
 391 fi
 392 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 393
 394 if test "x$enable_dvi" = "xyes"; then
 395     if test "x$enable_type1_fonts" = "xyes"; then
 396         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 397     fi
 398
 399     if test "x$enable_type1_fonts" = xyes; then
 400         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 401     fi
 402 else
 403     enable_type1_fonts=no
 404 fi
 405 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 406
 407 dnl ================== End of dvi checks ===================================================
 408
 409 dnl ================== pixbuf checks ===================================================
 410
 411 AC_ARG_ENABLE(pixbuf,
 412             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 413 if test "x$enable_pixbuf" = "xyes"; then
 414         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 415 fi
 416 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 417
 418 dnl ================== End of pixbuf checks ===================================================
 419
 420 dnl ================== comic book checks ===================================================
 421
 422 AC_ARG_ENABLE(comics,
 423         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=yes)
 424 if test "x$enable_comics" = "xyes"; then
 425         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 426 fi
 427 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 428
 429 dnl ================== End of comic book checks ============================================
 430
 431 dnl ================== impress book checks ===================================================
 432
 433 AC_ARG_ENABLE(impress,
 434         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 435 if test "x$enable_impress" = "xyes"; then
 436         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 437 fi
 438 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 439
 440 dnl ================== End of impress book checks ============================================
 441
 442 dnl =================== Mime types list ====================================================
 443
 444 if test "x$enable_pdf" = "xyes" ; then
 445         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 446 fi
 447 if test "x$enable_ps" = "xyes" ; then
 448         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 449 fi
 450 if test "x$enable_dvi" = "xyes"; then
 451         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;"
 452 fi
 453 if test "x$enable_djvu" = "xyes"; then
 454         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 455 fi
 456 if test "x$enable_tiff" = "xyes"; then
 457         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 458 fi
 459 if test "x$enable_comics" = "xyes"; then
 460         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;"
 461 fi
 462 if test "x$enable_pixbuf" = "xyes"; then
 463         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 464 fi
 465 if test "x$enable_impress" = "xyes"; then
 466         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 467 fi
 468 AC_SUBST(EVINCE_MIME_TYPES)
 469
 470 AC_CONFIG_FILES([
 471 backend/Makefile
 472 backend/comics/Makefile
 473 backend/djvu/Makefile
 474 backend/dvi/Makefile
 475 backend/dvi/mdvi-lib/Makefile
 476 backend/impress/Makefile
 477 backend/pdf/Makefile
 478 backend/pixbuf/Makefile
 479 backend/ps/Makefile
 480 backend/tiff/Makefile
 481 cut-n-paste/Makefile
 482 cut-n-paste/gedit-message-area/Makefile
 483 cut-n-paste/toolbar-editor/Makefile
 484 cut-n-paste/zoom-control/Makefile
 485 cut-n-paste/totem-screensaver/Makefile
 486 data/evince.desktop.in
 487 data/Makefile
 488 data/icons/Makefile
 489 data/icons/16x16/Makefile
 490 data/icons/16x16/apps/Makefile
 491 data/icons/16x16/actions/Makefile
 492 data/icons/22x22/Makefile
 493 data/icons/22x22/apps/Makefile
 494 data/icons/22x22/actions/Makefile
 495 data/icons/24x24/Makefile
 496 data/icons/24x24/apps/Makefile
 497 data/icons/24x24/actions/Makefile
 498 data/icons/32x32/Makefile
 499 data/icons/32x32/actions/Makefile
 500 data/icons/48x48/Makefile
 501 data/icons/48x48/apps/Makefile
 502 data/icons/48x48/actions/Makefile
 503 data/icons/scalable/Makefile
 504 data/icons/scalable/apps/Makefile
 505 help/Makefile
 506 help/reference/Makefile
 507 help/reference/version.xml
 508 libdocument/Makefile
 509 Makefile
 510 po/Makefile.in
 511 properties/Makefile
 512 shell/Makefile
 513 test/Makefile
 514 thumbnailer/Makefile
 515 ])
 516
 517 AC_OUTPUT
 518
 519 echo "
 520 Configure summary:
 521         GNOME Support......:  $WITH_GNOME
 522         Print Support......:  $enable_print
 523         Keyring Support....:  $WITH_KEYRING
 524         DBUS Support.......:  $enable_dbus
 525         Nautilus Plugin....:  $HAVE_NAUTILUS
 526         Thumbnailer........:  $ENABLE_THUMBNAILER
 527         Gtk-Doc Support....:  $enable_gtk_doc
 528
 529         PDF Backend........:  $enable_pdf
 530         PostScript Backend.:  $enable_ps $ps_backend
 531         TIFF Backend.......:  $enable_tiff
 532         DJVU Backend.......:  $enable_djvu
 533         DVI Backend........:  $enable_dvi
 534         Pixbuf Backend.....:  $enable_pixbuf
 535         Comics Backend.....:  $enable_comics
 536         Impress Backend....:  $enable_impress
 537 "