configure.ac

   1 # *****************************************************************************
   2 # Versioning
   3 # *****************************************************************************
   4
   5 m4_define([ev_major_version],[2])
   6 m4_define([ev_minor_version],[27])
   7 m4_define([ev_micro_version],[1])
   8 m4_define([ev_extra_version],[])
   9 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version()ev_extra_version])
  10
  11 # The evince API version
  12 m4_define([ev_api_version], [2.25])
  13
  14 # Libtool versioning. The backend and view libraries have separate versions.
  15 # Before making a release, the libtool version should be modified.
  16 # The string is of the form C:R:A.
  17 # - If interfaces have been changed or added, but binary compatibility has
  18 #   been preserved, change to C+1:0:A+1
  19 # - If binary compatibility has been broken (eg removed or changed interfaces)
  20 #   change to C+1:0:0
  21 # - If the interface is the same as the previous version, change to C:R+1:A
  22
  23 # Libtool version of the backend library
  24 m4_define([ev_document_lt_current],[1])
  25 m4_define([ev_document_lt_revision],[0])
  26 m4_define([ev_document_lt_age],[0])
  27 m4_define([ev_document_lt_version_info],[ev_document_lt_current:ev_document_lt_revision:ev_document_lt_age])
  28 m4_define([ev_document_lt_current_minus_age],[m4_eval(ev_document_lt_current - ev_document_lt_age)])
  29
  30 # Libtool version of the view library
  31 m4_define([ev_view_lt_current],[1])
  32 m4_define([ev_view_lt_revision],[0])
  33 m4_define([ev_view_lt_age],[0])
  34 m4_define([ev_view_lt_version_info],[ev_view_lt_current:ev_view_lt_revision:ev_view_lt_age])
  35 m4_define([ev_view_lt_current_minus_age],[m4_eval(ev_view_lt_current - ev_view_lt_age)])
  36
  37 # Binary version for the document backends
  38 m4_define([ev_binary_version],[ev_document_lt_current])
  39
  40 # *****************************************************************************
  41
  42 AC_PREREQ([2.57])
  43 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
  44 AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip])
  45
  46 AC_CONFIG_HEADERS([config.h])
  47 AC_CONFIG_MACRO_DIR([m4])
  48
  49 if test -z "$enable_maintainer_mode"; then
  50   enable_maintainer_mode=yes
  51 fi
  52 AM_MAINTAINER_MODE([enable])
  53
  54 AM_PROG_LIBTOOL
  55
  56 AC_ISC_POSIX
  57 AC_PROG_CC
  58 AM_PROG_CC_STDC
  59 AM_PROG_CC_C_O
  60 AC_PROG_CXX
  61 AC_STDC_HEADERS
  62 IT_PROG_INTLTOOL([0.35.0])
  63 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  64 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  65
  66 GNOME_COMMON_INIT
  67 GNOME_DOC_INIT
  68 GNOME_MAINTAINER_MODE_DEFINES
  69 GNOME_COMPILE_WARNINGS
  70 GNOME_CXX_WARNINGS
  71
  72 GTK_DOC_CHECK(1.0)
  73
  74 GETTEXT_PACKAGE=evince
  75 AC_SUBST(GETTEXT_PACKAGE)
  76 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  77 AM_GLIB_GNU_GETTEXT
  78
  79 # Check which platform to use
  80
  81 AC_MSG_CHECKING([for which platform to build])
  82 AC_ARG_WITH([platform],
  83   [AS_HELP_STRING([--with-platform=gnome|win32|hildon (default: gnome)])],
  84   [case "$withval" in
  85     gnome|win32|hildon) ;;
  86     *) AC_MSG_ERROR([invalid argument "$withval" for --with-platform]) ;;
  87    esac],
  88   [case "$host" in
  89      *-*-mingw*|*-*-cygwin*) with_platform="win32" ;;
  90      *) with_platform=gnome ;;
  91    esac])
  92
  93 AC_MSG_RESULT([$with_platform])
  94
  95 if test "$with_platform" = "win32"; then
  96   AC_CHECK_TOOL([WINDRES],[windres])
  97   AC_MSG_CHECKING([for native Win32])
  98   case "$host" in
  99     *-*-mingw*)
 100       os_win32=yes
 101       ;;
 102     *)
 103       os_win32=no
 104       ;;
 105   esac
 106   AC_MSG_RESULT([$os_win32])
 107 fi
 108
 109 AM_CONDITIONAL([PLATFORM_WIN32],[test "with_platform" = "win32"])
 110 AM_CONDITIONAL([OS_WIN32],[test "$os_win32" = "yes"])
 111
 112 dnl Specify required versions of dependencies
 113 DBUS_GLIB_REQUIRED=0.70
 114 GTK_REQUIRED=2.12.0
 115 GLIB_REQUIRED=2.18.0
 116 KEYRING_REQUIRED=2.22.0
 117 AC_SUBST([GLIB_REQUIRED])
 118 AC_SUBST([GTK_REQUIRED])
 119
 120 GNOME_ICON_THEME_REQUIRED=2.17.1
 121 LIBXML_REQUIRED=2.5.0
 122
 123 dnl Check dependencies
 124
 125 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
 126 # BACKEND_CFLAGS   for backend implementations.
 127 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
 128 # FRONTEND_LIBS
 129 # SHELL_CFLAGS     for shell implementation.
 130 # SHELL_LIBS
 131
 132 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
 133 PKG_CHECK_MODULES(LIBVIEW, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 134 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
 135 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 136 PKG_CHECK_MODULES(PREVIEWER, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 137 PKG_CHECK_MODULES(SHELL_CORE, libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED gthread-2.0)
 138
 139 if test "$os_win32" = no; then
 140         PKG_CHECK_MODULES(SMCLIENT, gtk+-2.0 gthread-2.0 sm >= 1.0.0)
 141 else
 142         PKG_CHECK_MODULES(SMCLIENT, gtk+-2.0 gthread-2.0)
 143 fi
 144
 145 AC_SUBST(SMCLIENT_CFLAGS)
 146 AC_SUBST(SMCLIENT_LIBS)
 147
 148 BACKEND_LIBTOOL_FLAGS="-module -avoid-version -no-undefined -export-symbols \$(top_srcdir)/backend/backend.symbols"
 149 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
 150
 151 dnl ===== Check special functions
 152 evince_save_LIBS=$LIBS
 153 LIBS="$LIBS $BACKEND_LIBS"
 154 AC_CHECK_FUNCS(cairo_format_stride_for_width)
 155 LIBS=$evince_save_LIBS
 156
 157 # ******************
 158 # GKT+ Unix Printing
 159 # ******************
 160
 161 AC_MSG_CHECKING([whether gtk+-unix-print support is requested])
 162 AC_ARG_WITH([gtk-unix-print],
 163   [AS_HELP_STRING([--without-gtk-unix-print],[disable the use of gtk-unix-print])],
 164   [],[case "$os_win32" in
 165         yes) with_gtk_unix_print=no ;;
 166         *) with_gtk_unix_print=yes ;;
 167       esac])
 168 AC_MSG_RESULT([$with_gtk_unix_print])
 169
 170 if test "$with_gtk_unix_print" = "yes"; then
 171    PKG_CHECK_MODULES(GTKUNIXPRINT, [gtk+-unix-print-2.0 >= $GTK_REQUIRED])
 172    AC_DEFINE([GTKUNIXPRINT_ENABLED], [1], [Define if gtk+-unix-print is enabled.])
 173 fi
 174
 175 # *********************
 176 # GNOME Keyring support
 177 # *********************
 178
 179 AC_ARG_WITH(keyring,
 180         [AS_HELP_STRING([--without-keyring],[disable the use of gnome-keyring])],
 181         [],
 182         [case "$with_platform" in
 183            gnome) with_keyring=yes ;;
 184            hildon|win32) with_keyring=no ;;
 185          esac])
 186
 187 AM_CONDITIONAL([WITH_KEYRING],[test "$with_keyring" = "yes"])
 188
 189 if test "$with_keyring" = "yes"; then
 190         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
 191         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
 192 fi
 193
 194 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
 195 AC_SUBST(GLIB_GENMARSHAL)
 196
 197 dnl ========= Check for DBUS
 198 AC_ARG_ENABLE(dbus,
 199         [AC_HELP_STRING([--enable-dbus], [Compile with support for dbus])],
 200         enable_dbus="$enableval",enable_dbus=yes)
 201 if test "x$enable_dbus" != "xno"; then
 202         PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
 203         [enable_dbus=yes],[enable_dbus=no])
 204
 205         if test "x$enable_dbus" = "xno"; then
 206            AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
 207         fi
 208
 209         if test "x$enable_dbus" = "xyes" ; then
 210                 AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 211
 212                 if test x$DBUS_BINDING_TOOL = "xno" ; then
 213                         AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 214                 fi
 215
 216                 AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 217         fi
 218 fi
 219
 220 AC_SUBST([DBUS_CFLAGS])
 221 AC_SUBST([DBUS_LIBS])
 222
 223 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
 224 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
 225
 226 dnl ========= Check for GConf
 227
 228 AC_MSG_CHECKING([whether GConf support is requested])
 229 AC_ARG_WITH([gconf],
 230   [AS_HELP_STRING([--without-gconf],[disable the use of gconf])],
 231   [],
 232   [case "$os_win32" in
 233      yes) with_gconf=no ;;
 234      *) with_gconf=yes ;;
 235    esac])
 236 AC_MSG_RESULT([$with_gconf])
 237
 238 AM_CONDITIONAL([WITH_GCONF],[test "$with_gconf" = "yes"])
 239
 240 if test "$with_gconf" = "yes"; then
 241    PKG_CHECK_MODULES([GCONF],[gconf-2.0])
 242    AC_DEFINE([WITH_GCONF],[1],[Define if GConf support is enabled])
 243 fi
 244
 245 AM_GCONF_SOURCE_2
 246
 247 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [false])
 248 if test "$with_gconf" = "yes" -a "$GCONFTOOL" = "false"; then
 249   AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 250 fi
 251
 252 dnl Debug mode
 253
 254 AC_ARG_ENABLE([debug],
 255         AC_HELP_STRING([--enable-debug],
 256                         [Turn on evince debug mode]),,
 257                 [enable_debug=no])
 258
 259 if test "x$enable_debug" = "xyes"; then
 260    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 261 fi
 262
 263
 264 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 265 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 266 AC_SUBST(LIBDOCUMENT_CFLAGS)
 267 AC_SUBST(LIBDOCUMENT_LIBS)
 268
 269 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $DEBUG_FLAGS"
 270 LIBVIEW_LIBS="$LIBVIEW_LIBS"
 271 AC_SUBST(LIBVIEW_CFLAGS)
 272 AC_SUBST(LIBVIEW_LIBS)
 273
 274 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 275 AC_SUBST(BACKEND_CFLAGS)
 276 AC_SUBST(BACKEND_LIBS)
 277
 278 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $GTKUNIXPRINT_CFLAGS $DBUS_CFLAGS $KEYRING_CFLAGS $GCONF_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 279 SHELL_LIBS="$SHELL_CORE_LIBS $GTKUNIXPRINT_CFLAGS $DBUS_LIBS $KEYRING_LIBS $GCONF_LIBS -lz"
 280 AC_SUBST(SHELL_CFLAGS)
 281 AC_SUBST(SHELL_LIBS)
 282
 283 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 284 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 285 AC_SUBST(FRONTEND_CFLAGS)
 286 AC_SUBST(FRONTEND_LIBS)
 287
 288 # Check for Nautilus property page build
 289 AC_ARG_ENABLE(nautilus,
 290         [AS_HELP_STRING([--enable-nautilus],[compile the nautilus plugin])],
 291         [],
 292         [case "$with_platform" in
 293            gnome) enable_nautilus=yes ;;
 294            hildon) enable_nautilus=no ;;
 295          esac])
 296
 297 if test x$enable_nautilus = "xyes" ; then
 298         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
 299                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
 300         NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 301         AC_SUBST(NAUTILUS_EXTENSION_DIR)
 302 fi
 303
 304 AC_SUBST(NAUTILUS_CFLAGS)
 305 AC_SUBST(NAUTILUS_LIBS)
 306 if test x$HAVE_NAUTILUS = "xyes"; then
 307         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
 308 fi
 309 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
 310
 311
 312 dnl Check for thumbnailer build
 313 AC_ARG_ENABLE(thumbnailer,
 314         [AS_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer])],
 315         [],
 316         [case "$with_platform" in
 317            gnome) enable_thumbnailer=yes ;;
 318            hildon) enable_thumbnailer=no ;;
 319          esac])
 320
 321 AM_CONDITIONAL(ENABLE_THUMBNAILER, test x$enable_thumbnailer = "xyes")
 322
 323 dnl Check for previewer build
 324 AC_ARG_ENABLE([previewer],
 325         [AS_HELP_STRING([--disable-previewer],[disable the GNOME Document Previewer])],
 326         [],
 327         [case "$with_platform" in
 328            gnome) enable_previewer=yes ;;
 329            *) enable_previewer=no ;;
 330          esac])
 331
 332 if test "$enable_previewer" = "yes" ; then
 333    PKG_CHECK_MODULES(PREVIEWER, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED,
 334                      [enable_previewer=yes],[enable_previewer=no])
 335    if test x$enable_previewer = "xno" ; then
 336       AC_MSG_WARN([Previewer support is disabled since gtk+-unix-print $GTK_REQUIRED or higher was not found])
 337    fi
 338 fi
 339 AM_CONDITIONAL([ENABLE_PREVIEWER],[test "$enable_previewer" = "yes"])
 340 PREVIEWER_CFLAGS="$PREVIEWER_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 341 PREVIEWER_LIBS="$PREVIEWER_LIBS $GTKUNIXPRINT_LIBS -lz"
 342 AC_SUBST(PREVIEWER_CFLAGS)
 343 AC_SUBST(PREVIEWER_LIBS)
 344
 345 # ***
 346 # GIR
 347 # ***
 348
 349 AC_MSG_CHECKING([whether GObject introspection is requested])
 350 AC_ARG_ENABLE([introspection],
 351         AS_HELP_STRING([--enable-introspection],[Enable GObject introspection]),
 352         [],[enable_introspection=no])
 353 AC_MSG_RESULT([$enable_introspection])
 354
 355 G_IR_SCANNER=
 356 G_IR_COMPILER=
 357 G_IR_GENERATE=
 358 GIRDIR=
 359 GIRTYPELIBDIR=
 360
 361 if test "$enable_introspection" = "yes"; then
 362   GOBJECT_INTROSPECTION_REQUIRED=0.6
 363   PKG_CHECK_MODULES([GOBJECT_INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
 364
 365   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
 366   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
 367   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
 368   GIRDIR="$($PKG_CONFIG --variable=girdir gobject-introspection-1.0)"
 369   GIRTYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
 370 fi
 371
 372 AC_SUBST([G_IR_SCANNER])
 373 AC_SUBST([G_IR_COMPILER])
 374 AC_SUBST([G_IR_GENERATE])
 375 AC_SUBST([GIRDIR])
 376 AC_SUBST([GIRTYPELIBDIR])
 377
 378 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
 379
 380 dnl ================== portability checks ===========================================
 381
 382 dnl for backtrace()
 383 AC_CHECK_HEADERS([execinfo.h])
 384
 385 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 386   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 387   ],[],[#include <langinfo.h>])
 388
 389 dnl ================== pdf checks ===================================================
 390 AC_ARG_ENABLE(pdf,
 391               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 392
 393 if test "x$enable_pdf" = "xyes"; then
 394     POPPLER_REQUIRED=0.11.0
 395     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED,enable_pdf=yes,enable_pdf=no)
 396
 397     if test "x$enable_pdf" = "xyes"; then
 398             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 399             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 400             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 401
 402             evince_save_LIBS=$LIBS
 403             LIBS="$LIBS $POPPLER_LIBS"
 404             AC_CHECK_FUNCS(poppler_page_render)
 405             AC_CHECK_FUNCS(poppler_page_get_image)
 406             LIBS=$evince_save_LIBS
 407
 408             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 409             if test x$enable_cairo_pdf = xyes; then
 410                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 411             fi
 412
 413             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 414             if test x$enable_cairo_ps = xyes; then
 415                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 416             fi
 417     else
 418             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 419     fi
 420 fi
 421
 422 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 423 dnl ================== end of pdf checks ============================================
 424
 425 dnl libspectre (used by ps and dvi backends)
 426 SPECTRE_REQUIRED=0.2.0
 427 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 428 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 429 if test "x$have_spectre" = "xyes"; then
 430    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 431 fi
 432
 433 dnl ================== ps checks ====================================================
 434 AC_ARG_ENABLE(ps,
 435         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 436
 437 if test "x$enable_ps" = "xyes"; then
 438    if test "x$have_spectre" = "xyes"; then
 439       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 440    else
 441       enable_ps="no"
 442       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 443    fi
 444 fi
 445 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 446 dnl ======================== End of ps checks ===================================
 447
 448 dnl ================== tiff checks ===================================================
 449 AC_ARG_ENABLE(tiff,
 450             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 451
 452 if test "x$enable_tiff" = "xyes"; then
 453     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 454     if test "x$enable_tiff" = "xyes"; then
 455         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 456         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 457     fi
 458     if test "x$enable_tiff" = "xyes"; then
 459             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 460     else
 461             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 462     fi
 463 fi
 464
 465 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 466 dnl ================== end of tiff checks ============================================
 467
 468 dnl ================== djvu checks ===================================================
 469
 470 AC_ARG_ENABLE(djvu,
 471             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=yes)
 472
 473 if test "x$enable_djvu" = "xyes"; then
 474     DJVULIBRE_REQUIRED=3.5.17
 475     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 476
 477     if test "x$enable_djvu" = "xyes"; then
 478         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 479     else
 480         AC_MSG_WARN([
 481 ** Djvu support is disabled since a recent version of the djvulibre
 482 ** library was not found. You need at least djvulibre-3.5.17 which
 483 ** can be found on http://djvulibre.djvuzone.org
 484 ])
 485     fi
 486 fi
 487
 488 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 489
 490 dnl ================== End of djvu checks ===================================================
 491
 492 dnl ================== dvi checks ===================================================
 493
 494 AC_ARG_ENABLE(dvi,
 495             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=yes)
 496
 497 AC_ARG_ENABLE(t1lib,
 498             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 499
 500 if test "x$enable_dvi" = "xyes"; then
 501     AC_C_CONST
 502     AC_C_INLINE
 503     AC_TYPE_SIZE_T
 504     AC_CHECK_SIZEOF(long, 4)
 505     AC_CHECK_SIZEOF(int, 4)
 506     AC_CHECK_SIZEOF(short, 2)
 507     AC_CHECK_SIZEOF(void *, 4)
 508     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 509
 510     if test "x$enable_dvi" = "xyes"; then
 511         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 512     else
 513         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 514     fi
 515 fi
 516 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 517
 518 if test "x$enable_dvi" = "xyes"; then
 519     if test "x$enable_type1_fonts" = "xyes"; then
 520         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 521     fi
 522
 523     if test "x$enable_type1_fonts" = xyes; then
 524         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 525     fi
 526 else
 527     enable_type1_fonts=no
 528 fi
 529 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 530
 531 dnl ================== End of dvi checks ===================================================
 532
 533 dnl ================== pixbuf checks ===================================================
 534
 535 AC_ARG_ENABLE(pixbuf,
 536             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 537 if test "x$enable_pixbuf" = "xyes"; then
 538         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 539 fi
 540 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 541
 542 dnl ================== End of pixbuf checks ===================================================
 543
 544 dnl ================== comic book checks ===================================================
 545
 546 AC_ARG_ENABLE(comics,
 547         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=yes)
 548 if test "x$enable_comics" = "xyes"; then
 549         if test "x$os_win32" = "xyes"; then
 550                 # The comics backend is disabled on windows because:
 551                 # 1) it uses unix functions from sys/wait.h.
 552                 # 2) it uses external decompression tools not generally available on windows.
 553                 enable_comics=no
 554                 AC_MSG_WARN(The comics backend is not supported on windows.)
 555         else
 556                 AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 557         fi
 558 fi
 559 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 560
 561 dnl ================== End of comic book checks ============================================
 562
 563 dnl ================== impress book checks ===================================================
 564
 565 AC_ARG_ENABLE(impress,
 566         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 567 if test "x$enable_impress" = "xyes"; then
 568         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 569 fi
 570 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 571
 572 dnl ================== End of impress book checks ============================================
 573
 574 dnl =================== Mime types list ====================================================
 575
 576 if test "x$enable_pdf" = "xyes" ; then
 577         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 578 fi
 579 if test "x$enable_ps" = "xyes" ; then
 580         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 581 fi
 582 if test "x$enable_dvi" = "xyes"; then
 583         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 584 fi
 585 if test "x$enable_djvu" = "xyes"; then
 586         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 587 fi
 588 if test "x$enable_tiff" = "xyes"; then
 589         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 590 fi
 591 if test "x$enable_comics" = "xyes"; then
 592         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;"
 593 fi
 594 if test "x$enable_pixbuf" = "xyes"; then
 595         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 596 fi
 597 if test "x$enable_impress" = "xyes"; then
 598         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 599 fi
 600 AC_SUBST(EVINCE_MIME_TYPES)
 601
 602 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 603
 604 # Backends directory
 605
 606 AC_SUBST([backenddir],"\$(libdir)/evince/ev_binary_version/backends")
 607 AC_SUBST([backend_binary_version],"ev_binary_version")
 608
 609 # Versioning
 610
 611 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
 612 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
 613 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
 614
 615 AC_SUBST([EV_API_VERSION],[ev_api_version])
 616 AC_SUBST([EV_BINARY_VERSION],[ev_binary_version])
 617
 618 AC_SUBST([EV_DOCUMENT_LT_VERSION_INFO],[ev_document_lt_version_info])
 619 AC_SUBST([EV_DOCUMENT_LT_CURRENT_MINUS_AGE],[ev_document_lt_current_minus_age])
 620 AC_SUBST([EV_VIEW_LT_VERSION_INFO],[ev_view_lt_version_info])
 621 AC_SUBST([EV_VIEW_LT_CURRENT_MINUS_AGE],[ev_view_lt_current_minus_age])
 622
 623 # *****************************************************************************
 624
 625 SHAVE_INIT([], [enable])
 626
 627 AC_CONFIG_FILES([
 628 backend/Makefile
 629 backend/comics/Makefile
 630 backend/djvu/Makefile
 631 backend/dvi/Makefile
 632 backend/dvi/mdvi-lib/Makefile
 633 backend/impress/Makefile
 634 backend/pdf/Makefile
 635 backend/pixbuf/Makefile
 636 backend/ps/Makefile
 637 backend/tiff/Makefile
 638 cut-n-paste/Makefile
 639 cut-n-paste/gedit-message-area/Makefile
 640 cut-n-paste/gimpcellrenderertoggle/Makefile
 641 cut-n-paste/smclient/Makefile
 642 cut-n-paste/toolbar-editor/Makefile
 643 cut-n-paste/zoom-control/Makefile
 644 cut-n-paste/totem-screensaver/Makefile
 645 data/evince.desktop.in
 646 data/Makefile
 647 data/icons/Makefile
 648 data/icons/16x16/Makefile
 649 data/icons/16x16/apps/Makefile
 650 data/icons/16x16/actions/Makefile
 651 data/icons/22x22/Makefile
 652 data/icons/22x22/apps/Makefile
 653 data/icons/22x22/actions/Makefile
 654 data/icons/24x24/Makefile
 655 data/icons/24x24/apps/Makefile
 656 data/icons/24x24/actions/Makefile
 657 data/icons/32x32/Makefile
 658 data/icons/32x32/actions/Makefile
 659 data/icons/48x48/Makefile
 660 data/icons/48x48/apps/Makefile
 661 data/icons/48x48/actions/Makefile
 662 data/icons/scalable/Makefile
 663 data/icons/scalable/apps/Makefile
 664 help/Makefile
 665 help/reference/Makefile
 666 help/reference/libdocument/Makefile
 667 help/reference/libdocument/version.xml
 668 help/reference/libview/Makefile
 669 help/reference/libview/version.xml
 670 help/reference/shell/Makefile
 671 help/reference/shell/version.xml
 672 libdocument/Makefile
 673 libdocument/ev-version.h
 674 libmisc/Makefile
 675 libview/Makefile
 676 Makefile
 677 po/Makefile.in
 678 previewer/Makefile
 679 properties/Makefile
 680 shave
 681 shave-libtool
 682 shell/Makefile
 683 test/Makefile
 684 thumbnailer/Makefile
 685 ])
 686
 687 AC_CONFIG_FILES(evince-document-[]ev_api_version[].pc:evince-document.pc.in)
 688 AC_CONFIG_FILES(evince-view-[]ev_api_version[].pc:evince-view.pc.in)
 689
 690 AC_OUTPUT
 691
 692 echo "
 693 Configure summary:
 694         GConf Support......:  $with_gconf
 695         GTK+ Unix Print....:  $with_gtk_unix_print
 696         Keyring Support....:  $with_keyring
 697         DBUS Support.......:  $enable_dbus
 698         Nautilus Plugin....:  $HAVE_NAUTILUS
 699         Thumbnailer........:  $enable_thumbnailer
 700         Previewer..........:  $enable_previewer
 701         Gtk-Doc Support....:  $enable_gtk_doc
 702         Debug mode.........:  $enable_debug
 703         GObj. Introspection:  $enable_introspection
 704
 705         PDF Backend........:  $enable_pdf
 706         PostScript Backend.:  $enable_ps
 707         TIFF Backend.......:  $enable_tiff
 708         DJVU Backend.......:  $enable_djvu
 709         DVI Backend........:  $enable_dvi
 710         Pixbuf Backend.....:  $enable_pixbuf
 711         Comics Backend.....:  $enable_comics
 712         Impress Backend....:  $enable_impress
 713 "