configure.ac

   1 # *****************************************************************************
   2 # Versioning
   3 # *****************************************************************************
   4
   5 m4_define([ev_major_version],[2])
   6 m4_define([ev_minor_version],[25])
   7 m4_define([ev_micro_version],[90])
   8 m4_define([ev_extra_version],[])
   9 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version()ev_extra_version])
  10
  11 # The evince API version
  12 m4_define([ev_api_version], [2.25])
  13
  14 # Libtool versioning. The backend and view libraries have separate versions.
  15 # Before making a release, the libtool version should be modified.
  16 # The string is of the form C:R:A.
  17 # - If interfaces have been changed or added, but binary compatibility has
  18 #   been preserved, change to C+1:0:A+1
  19 # - If binary compatibility has been broken (eg removed or changed interfaces)
  20 #   change to C+1:0:0
  21 # - If the interface is the same as the previous version, change to C:R+1:A
  22
  23 # Libtool version of the backend library
  24 m4_define([ev_document_lt_current],[1])
  25 m4_define([ev_document_lt_revision],[0])
  26 m4_define([ev_document_lt_age],[0])
  27 m4_define([ev_document_lt_version_info],[ev_document_lt_current:ev_document_lt_revision:ev_document_lt_age])
  28 m4_define([ev_document_lt_current_minus_age],[m4_eval(ev_document_lt_current - ev_document_lt_age)])
  29
  30 # Libtool version of the view library
  31 m4_define([ev_view_lt_current],[1])
  32 m4_define([ev_view_lt_revision],[0])
  33 m4_define([ev_view_lt_age],[0])
  34 m4_define([ev_view_lt_version_info],[ev_view_lt_current:ev_view_lt_revision:ev_view_lt_age])
  35 m4_define([ev_view_lt_current_minus_age],[m4_eval(ev_view_lt_current - ev_view_lt_age)])
  36
  37 # Binary version for the document backends
  38 m4_define([ev_binary_version],[ev_document_lt_current])
  39
  40 # *****************************************************************************
  41
  42 AC_PREREQ([2.57])
  43 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
  44 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-dist-gzip])
  45
  46 AM_CONFIG_HEADER(config.h)
  47
  48 AM_MAINTAINER_MODE
  49
  50 AM_PROG_LIBTOOL
  51
  52 AC_ISC_POSIX
  53 AC_PROG_CC
  54 AM_PROG_CC_STDC
  55 AM_PROG_CC_C_O
  56 AC_PROG_CXX
  57 AC_STDC_HEADERS
  58 IT_PROG_INTLTOOL([0.35.0])
  59 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  60 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  61
  62 GNOME_COMMON_INIT
  63 GNOME_DOC_INIT
  64 GNOME_MAINTAINER_MODE_DEFINES
  65 GNOME_COMPILE_WARNINGS
  66 GNOME_CXX_WARNINGS
  67
  68 GTK_DOC_CHECK(1.0)
  69
  70 GETTEXT_PACKAGE=evince
  71 AC_SUBST(GETTEXT_PACKAGE)
  72 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  73 AM_GLIB_GNU_GETTEXT
  74
  75 dnl check for win32 platform
  76 AC_MSG_CHECKING([for Win32 platform])
  77 case "$host" in
  78   *-*-mingw*|*-*-cygwin*)
  79     platform_win32=yes
  80     AC_CHECK_TOOL(WINDRES, windres)
  81     ;;
  82   *)
  83     platform_win32=no
  84     ;;
  85 esac
  86 AC_MSG_RESULT([$platform_win32])
  87 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
  88
  89 dnl Check dependencies
  90
  91 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
  92 # BACKEND_CFLAGS   for backend implementations.
  93 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
  94 # FRONTEND_LIBS
  95 # SHELL_CFLAGS     for shell implementation.
  96 # SHELL_LIBS
  97
  98 DBUS_GLIB_REQUIRED=0.70
  99 GTK_REQUIRED=2.12.0
 100 GLIB_REQUIRED=2.18.0
 101 KEYRING_REQUIRED=2.22.0
 102 AC_SUBST([GLIB_REQUIRED])
 103 AC_SUBST([GTK_REQUIRED])
 104
 105 GNOME_ICON_THEME_REQUIRED=2.17.1
 106 LIBXML_REQUIRED=2.5.0
 107
 108 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
 109 PKG_CHECK_MODULES(LIBVIEW, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 110 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
 111 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 112 PKG_CHECK_MODULES(SHELL_CORE, libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED gthread-2.0)
 113
 114 PKG_CHECK_MODULES(SMCLIENT, gtk+-2.0 gthread-2.0)
 115 AC_SUBST(SMCLIENT_CFLAGS)
 116 AC_SUBST(SMCLIENT_LIBS)
 117
 118 BACKEND_LIBTOOL_FLAGS="-module -avoid-version -export-symbols \$(top_srcdir)/backend/backend.symbols"
 119 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
 120
 121 dnl ===== Check special functions
 122 evince_save_LIBS=$LIBS
 123 LIBS="$LIBS $BACKEND_LIBS"
 124 AC_CHECK_FUNCS(cairo_format_stride_for_width)
 125 LIBS=$evince_save_LIBS
 126
 127 dnl ========= Check for Keyring
 128 AC_ARG_WITH(keyring,
 129         AC_HELP_STRING([--without-keyring],[disable the use of gnome-keyring]),
 130         [case "${withval}" in
 131         yes) WITH_KEYRING=yes ;;
 132         no) WITH_KEYRING=no ;;
 133         *) AC_MSG_ERROR(bad value ${withval} for --with-keyring) ;;
 134         esac],
 135         [WITH_KEYRING=yes]) dnl Default value
 136 AM_CONDITIONAL(WITH_KEYRING, test x$WITH_KEYRING = "xyes")
 137
 138 if test x$WITH_KEYRING = "xyes"; then
 139         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
 140         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
 141 fi
 142
 143 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
 144 AC_SUBST(GLIB_GENMARSHAL)
 145
 146 dnl ========= Check for DBUS
 147 AC_ARG_ENABLE(dbus,
 148         [AC_HELP_STRING([--enable-dbus], [Compile with support for dbus])],
 149         enable_dbus="$enableval",enable_dbus=yes)
 150 if test "x$enable_dbus" != "xno"; then
 151         PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
 152         [enable_dbus=yes],[enable_dbus=no])
 153
 154         if test "x$enable_dbus" = "xno"; then
 155            AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
 156         fi
 157
 158         if test "x$enable_dbus" = "xyes" ; then
 159                 AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 160
 161                 if test x$DBUS_BINDING_TOOL = "xno" ; then
 162                         AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 163                 fi
 164
 165                 AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 166         fi
 167 fi
 168
 169 AC_SUBST([DBUS_CFLAGS])
 170 AC_SUBST([DBUS_LIBS])
 171
 172 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
 173 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
 174
 175 dnl ========= Check for GConf
 176 AC_ARG_WITH(gconf,
 177         AC_HELP_STRING([--without-gconf],[disable the use of gconf]),
 178         [case "${withval}" in
 179         yes) WITH_GCONF=yes ;;
 180         no) WITH_GCONF=no ;;
 181         *) AC_MSG_ERROR(bad value ${withval} for --with-gconf) ;;
 182         esac],
 183         [WITH_GCONF=yes]) dnl Default value
 184 AM_CONDITIONAL(WITH_GCONF, test x$WITH_GCONF = "xyes")
 185
 186 if test x$WITH_GCONF = "xyes"; then
 187    PKG_CHECK_MODULES(GCONF, gconf-2.0)
 188    AC_DEFINE([WITH_GCONF],[1],[Define if GConf support is enabled])
 189 fi
 190
 191 dnl Debug mode
 192 AC_ARG_ENABLE([debug],
 193         AC_HELP_STRING([--enable-debug],
 194                         [Turn on evince debug mode]),,
 195                 [enable_debug=no])
 196
 197 if test "x$enable_debug" = "xyes"; then
 198    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 199 fi
 200
 201
 202 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 203 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 204 AC_SUBST(LIBDOCUMENT_CFLAGS)
 205 AC_SUBST(LIBDOCUMENT_LIBS)
 206
 207 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $DEBUG_FLAGS"
 208 LIBVIEW_LIBS="$LIBVIEW_LIBS"
 209 AC_SUBST(LIBVIEW_CFLAGS)
 210 AC_SUBST(LIBVIEW_LIBS)
 211
 212 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 213 AC_SUBST(BACKEND_CFLAGS)
 214 AC_SUBST(BACKEND_LIBS)
 215
 216 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS $KEYRING_CFLAGS $GCONF_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 217 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS $KEYRING_LIBS $GCONF_LIBS -lz"
 218 AC_SUBST(SHELL_CFLAGS)
 219 AC_SUBST(SHELL_LIBS)
 220
 221 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 222 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 223 AC_SUBST(FRONTEND_CFLAGS)
 224 AC_SUBST(FRONTEND_LIBS)
 225
 226 dnl Check for Nautilus property page build
 227 AC_ARG_ENABLE(nautilus,
 228         AC_HELP_STRING([--enable-nautilus],[compile the nautilus plugin]),
 229         [case "${enableval}" in
 230         yes) ENABLE_NAUTILUS=yes ;;
 231         no) ENABLE_NAUTILUS=no ;;
 232         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nautilus) ;;
 233         esac],
 234         [ENABLE_NAUTILUS=yes]) dnl Default value
 235
 236 if test x$ENABLE_NAUTILUS = "xyes" ; then
 237         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
 238                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
 239         NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 240         AC_SUBST(NAUTILUS_EXTENSION_DIR)
 241 fi
 242
 243 AC_SUBST(NAUTILUS_CFLAGS)
 244 AC_SUBST(NAUTILUS_LIBS)
 245 if test x$HAVE_NAUTILUS = "xyes"; then
 246         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
 247 fi
 248 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
 249
 250
 251 dnl Check for thumbnailer build
 252 AC_ARG_ENABLE(thumbnailer,
 253         AC_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer]),
 254         [case "${enableval}" in
 255         yes) ENABLE_THUMBNAILER=yes ;;
 256         no) ENABLE_THUMBNAILER=no ;;
 257         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thumbnailer) ;;
 258         esac],
 259         [ENABLE_THUMBNAILER=yes]) dnl Default value
 260 AM_CONDITIONAL(ENABLE_THUMBNAILER, test x$ENABLE_THUMBNAILER = "xyes")
 261
 262 dnl GConf configuration
 263 AM_GCONF_SOURCE_2
 264
 265 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
 266 if test "x$GCONFTOOL" = "xno"; then
 267         AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 268 fi
 269
 270 # ***
 271 # GIR
 272 # ***
 273
 274 AC_MSG_CHECKING([whether GObject introspection is requested])
 275 AC_ARG_ENABLE([introspection],
 276         AS_HELP_STRING([--enable-introspection],[Enable GObject introspection]),
 277         [],[enable_introspection=no])
 278 AC_MSG_RESULT([$enable_introspection])
 279
 280 G_IR_SCANNER=
 281 G_IR_COMPILER=
 282 G_IR_GENERATE=
 283 GIRDIR=
 284 GIRTYPELIBDIR=
 285
 286 if test "$enable_introspection" = "yes"; then
 287   GOBJECT_INTROSPECTION_REQUIRED=0.6
 288   PKG_CHECK_MODULES([GOBJECT_INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
 289
 290   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
 291   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
 292   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
 293   GIRDIR="$($PKG_CONFIG --variable=girdir gobject-introspection-1.0)"
 294   GIRTYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
 295 fi
 296
 297 AC_SUBST([G_IR_SCANNER])
 298 AC_SUBST([G_IR_COMPILER])
 299 AC_SUBST([G_IR_GENERATE])
 300 AC_SUBST([GIRDIR])
 301 AC_SUBST([GIRTYPELIBDIR])
 302
 303 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
 304
 305 dnl ================== portability checks ===========================================
 306
 307 dnl for backtrace()
 308 AC_CHECK_HEADERS([execinfo.h])
 309
 310 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 311   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 312   ],[],[#include <langinfo.h>])
 313
 314 dnl ================== pdf checks ===================================================
 315 AC_ARG_ENABLE(pdf,
 316               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 317
 318 if test "x$enable_pdf" = "xyes"; then
 319     POPPLER_REQUIRED=0.8.0
 320     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED,enable_pdf=yes,enable_pdf=no)
 321
 322     if test "x$enable_pdf" = "xyes"; then
 323             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 324             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 325             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 326
 327             evince_save_LIBS=$LIBS
 328             LIBS="$LIBS $POPPLER_LIBS"
 329             AC_CHECK_FUNCS(poppler_page_render)
 330             AC_CHECK_FUNCS(poppler_layers_iter_new)
 331             LIBS=$evince_save_LIBS
 332
 333             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 334             if test x$enable_cairo_pdf = xyes; then
 335                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 336             fi
 337
 338             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 339             if test x$enable_cairo_ps = xyes; then
 340                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 341             fi
 342     else
 343             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 344     fi
 345 fi
 346
 347 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 348 dnl ================== end of pdf checks ============================================
 349
 350 dnl libspectre (used by ps and dvi backends)
 351 SPECTRE_REQUIRED=0.2.0
 352 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 353 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 354 if test "x$have_spectre" = "xyes"; then
 355    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 356 fi
 357
 358 dnl ================== ps checks ====================================================
 359 AC_ARG_ENABLE(ps,
 360         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 361
 362 if test "x$enable_ps" = "xyes"; then
 363    if test "x$have_spectre" = "xyes"; then
 364       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 365    else
 366       enable_ps="no"
 367       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 368    fi
 369 fi
 370 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 371 dnl ======================== End of ps checks ===================================
 372
 373 dnl ================== tiff checks ===================================================
 374 AC_ARG_ENABLE(tiff,
 375             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 376
 377 if test "x$enable_tiff" = "xyes"; then
 378     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 379     if test "x$enable_tiff" = "xyes"; then
 380         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 381         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 382     fi
 383     if test "x$enable_tiff" = "xyes"; then
 384             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 385     else
 386             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 387     fi
 388 fi
 389
 390 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 391 dnl ================== end of tiff checks ============================================
 392
 393 dnl ================== djvu checks ===================================================
 394
 395 AC_ARG_ENABLE(djvu,
 396             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=yes)
 397
 398 if test "x$enable_djvu" = "xyes"; then
 399     DJVULIBRE_REQUIRED=3.5.17
 400     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 401
 402     if test "x$enable_djvu" = "xyes"; then
 403         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 404     else
 405         AC_MSG_WARN([
 406 ** Djvu support is disabled since a recent version of the djvulibre
 407 ** library was not found. You need at least djvulibre-3.5.17 which
 408 ** can be found on http://djvulibre.djvuzone.org
 409 ])
 410     fi
 411 fi
 412
 413 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 414
 415 dnl ================== End of djvu checks ===================================================
 416
 417 dnl ================== dvi checks ===================================================
 418
 419 AC_ARG_ENABLE(dvi,
 420             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=yes)
 421
 422 AC_ARG_ENABLE(t1lib,
 423             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 424
 425 if test "x$enable_dvi" = "xyes"; then
 426     AC_C_CONST
 427     AC_C_INLINE
 428     AC_TYPE_SIZE_T
 429     AC_CHECK_SIZEOF(long, 4)
 430     AC_CHECK_SIZEOF(int, 4)
 431     AC_CHECK_SIZEOF(short, 2)
 432     AC_CHECK_SIZEOF(void *, 4)
 433     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 434
 435     if test "x$enable_dvi" = "xyes"; then
 436         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 437     else
 438         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 439     fi
 440 fi
 441 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 442
 443 if test "x$enable_dvi" = "xyes"; then
 444     if test "x$enable_type1_fonts" = "xyes"; then
 445         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 446     fi
 447
 448     if test "x$enable_type1_fonts" = xyes; then
 449         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 450     fi
 451 else
 452     enable_type1_fonts=no
 453 fi
 454 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 455
 456 dnl ================== End of dvi checks ===================================================
 457
 458 dnl ================== pixbuf checks ===================================================
 459
 460 AC_ARG_ENABLE(pixbuf,
 461             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 462 if test "x$enable_pixbuf" = "xyes"; then
 463         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 464 fi
 465 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 466
 467 dnl ================== End of pixbuf checks ===================================================
 468
 469 dnl ================== comic book checks ===================================================
 470
 471 AC_ARG_ENABLE(comics,
 472         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=yes)
 473 if test "x$enable_comics" = "xyes"; then
 474         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 475 fi
 476 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 477
 478 dnl ================== End of comic book checks ============================================
 479
 480 dnl ================== impress book checks ===================================================
 481
 482 AC_ARG_ENABLE(impress,
 483         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 484 if test "x$enable_impress" = "xyes"; then
 485         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 486 fi
 487 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 488
 489 dnl ================== End of impress book checks ============================================
 490
 491 dnl =================== Mime types list ====================================================
 492
 493 if test "x$enable_pdf" = "xyes" ; then
 494         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 495 fi
 496 if test "x$enable_ps" = "xyes" ; then
 497         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 498 fi
 499 if test "x$enable_dvi" = "xyes"; then
 500         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 501 fi
 502 if test "x$enable_djvu" = "xyes"; then
 503         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 504 fi
 505 if test "x$enable_tiff" = "xyes"; then
 506         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 507 fi
 508 if test "x$enable_comics" = "xyes"; then
 509         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;"
 510 fi
 511 if test "x$enable_pixbuf" = "xyes"; then
 512         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 513 fi
 514 if test "x$enable_impress" = "xyes"; then
 515         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 516 fi
 517 AC_SUBST(EVINCE_MIME_TYPES)
 518
 519 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 520
 521 # Backends directory
 522
 523 AC_SUBST([backenddir],"\$(libdir)/evince/ev_binary_version/backends")
 524
 525 # Versioning
 526
 527 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
 528 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
 529 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
 530
 531 AC_SUBST([EV_API_VERSION],[ev_api_version])
 532 AC_SUBST([EV_BINARY_VERSION],[ev_binary_version])
 533
 534 AC_SUBST([EV_DOCUMENT_LT_VERSION_INFO],[ev_document_lt_version_info])
 535 AC_SUBST([EV_DOCUMENT_LT_CURRENT_MINUS_AGE],[ev_document_lt_current_minus_age])
 536 AC_SUBST([EV_VIEW_LT_VERSION_INFO],[ev_view_lt_version_info])
 537 AC_SUBST([EV_VIEW_LT_CURRENT_MINUS_AGE],[ev_view_lt_current_minus_age])
 538
 539 # *****************************************************************************
 540
 541 AC_CONFIG_FILES([
 542 backend/Makefile
 543 backend/comics/Makefile
 544 backend/djvu/Makefile
 545 backend/dvi/Makefile
 546 backend/dvi/mdvi-lib/Makefile
 547 backend/impress/Makefile
 548 backend/pdf/Makefile
 549 backend/pixbuf/Makefile
 550 backend/ps/Makefile
 551 backend/tiff/Makefile
 552 cut-n-paste/Makefile
 553 cut-n-paste/evmountoperation/Makefile
 554 cut-n-paste/gedit-message-area/Makefile
 555 cut-n-paste/gimpcellrenderertoggle/Makefile
 556 cut-n-paste/smclient/Makefile
 557 cut-n-paste/toolbar-editor/Makefile
 558 cut-n-paste/zoom-control/Makefile
 559 cut-n-paste/totem-screensaver/Makefile
 560 data/evince.desktop.in
 561 data/Makefile
 562 data/icons/Makefile
 563 data/icons/16x16/Makefile
 564 data/icons/16x16/apps/Makefile
 565 data/icons/16x16/actions/Makefile
 566 data/icons/22x22/Makefile
 567 data/icons/22x22/apps/Makefile
 568 data/icons/22x22/actions/Makefile
 569 data/icons/24x24/Makefile
 570 data/icons/24x24/apps/Makefile
 571 data/icons/24x24/actions/Makefile
 572 data/icons/32x32/Makefile
 573 data/icons/32x32/actions/Makefile
 574 data/icons/48x48/Makefile
 575 data/icons/48x48/apps/Makefile
 576 data/icons/48x48/actions/Makefile
 577 data/icons/scalable/Makefile
 578 data/icons/scalable/apps/Makefile
 579 help/Makefile
 580 help/reference/Makefile
 581 help/reference/libdocument/Makefile
 582 help/reference/libdocument/version.xml
 583 help/reference/libview/Makefile
 584 help/reference/libview/version.xml
 585 help/reference/shell/Makefile
 586 help/reference/shell/version.xml
 587 libdocument/Makefile
 588 libdocument/ev-version.h
 589 libview/Makefile
 590 Makefile
 591 po/Makefile.in
 592 properties/Makefile
 593 shell/Makefile
 594 test/Makefile
 595 thumbnailer/Makefile
 596 ])
 597
 598 AC_CONFIG_FILES(evince-document-[]ev_api_version[].pc:evince-document.pc.in)
 599 AC_CONFIG_FILES(evince-view-[]ev_api_version[].pc:evince-view.pc.in)
 600
 601 AC_OUTPUT
 602
 603 echo "
 604 Configure summary:
 605         GConf Support......:  $WITH_GCONF
 606         Keyring Support....:  $WITH_KEYRING
 607         DBUS Support.......:  $enable_dbus
 608         Nautilus Plugin....:  $HAVE_NAUTILUS
 609         Thumbnailer........:  $ENABLE_THUMBNAILER
 610         Gtk-Doc Support....:  $enable_gtk_doc
 611         Debug mode.........:  $enable_debug
 612         GObj. Introspection:  $enable_introspection
 613
 614         PDF Backend........:  $enable_pdf
 615         PostScript Backend.:  $enable_ps
 616         TIFF Backend.......:  $enable_tiff
 617         DJVU Backend.......:  $enable_djvu
 618         DVI Backend........:  $enable_dvi
 619         Pixbuf Backend.....:  $enable_pixbuf
 620         Comics Backend.....:  $enable_comics
 621         Impress Backend....:  $enable_impress
 622 "