configure.ac

   1 # *****************************************************************************
   2 # Versioning
   3 # *****************************************************************************
   4
   5 m4_define([ev_major_version],[2])
   6 m4_define([ev_minor_version],[27])
   7 m4_define([ev_micro_version],[90])
   8 m4_define([ev_extra_version],[])
   9 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version()ev_extra_version])
  10
  11 # The evince API version
  12 m4_define([ev_api_version], [2.25])
  13
  14 # Libtool versioning. The backend and view libraries have separate versions.
  15 # Before making a release, the libtool version should be modified.
  16 # The string is of the form C:R:A.
  17 # - If interfaces have been changed or added, but binary compatibility has
  18 #   been preserved, change to C+1:0:A+1
  19 # - If binary compatibility has been broken (eg removed or changed interfaces)
  20 #   change to C+1:0:0
  21 # - If the interface is the same as the previous version, change to C:R+1:A
  22
  23 # Libtool version of the backend library
  24 m4_define([ev_document_lt_current],[1])
  25 m4_define([ev_document_lt_revision],[0])
  26 m4_define([ev_document_lt_age],[0])
  27 m4_define([ev_document_lt_version_info],[ev_document_lt_current:ev_document_lt_revision:ev_document_lt_age])
  28 m4_define([ev_document_lt_current_minus_age],[m4_eval(ev_document_lt_current - ev_document_lt_age)])
  29
  30 # Libtool version of the view library
  31 m4_define([ev_view_lt_current],[1])
  32 m4_define([ev_view_lt_revision],[0])
  33 m4_define([ev_view_lt_age],[0])
  34 m4_define([ev_view_lt_version_info],[ev_view_lt_current:ev_view_lt_revision:ev_view_lt_age])
  35 m4_define([ev_view_lt_current_minus_age],[m4_eval(ev_view_lt_current - ev_view_lt_age)])
  36
  37 # Binary version for the document backends
  38 m4_define([ev_binary_version],[ev_document_lt_current])
  39
  40 # *****************************************************************************
  41
  42 AC_PREREQ([2.57])
  43 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
  44 AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip])
  45
  46 AC_CONFIG_HEADERS([config.h])
  47 AC_CONFIG_MACRO_DIR([m4])
  48
  49 if test -z "$enable_maintainer_mode"; then
  50   enable_maintainer_mode=yes
  51 fi
  52 AM_MAINTAINER_MODE([enable])
  53
  54 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  55
  56 AM_PROG_LIBTOOL
  57
  58 AC_ISC_POSIX
  59 AC_PROG_CC
  60 AM_PROG_CC_STDC
  61 AM_PROG_CC_C_O
  62 AC_PROG_CXX
  63 AC_STDC_HEADERS
  64 IT_PROG_INTLTOOL([0.35.0])
  65 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  66 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  67
  68 GNOME_COMMON_INIT
  69 GNOME_DOC_INIT
  70 GNOME_MAINTAINER_MODE_DEFINES
  71 GNOME_COMPILE_WARNINGS
  72 GNOME_CXX_WARNINGS
  73
  74 GTK_DOC_CHECK(1.0)
  75
  76 GETTEXT_PACKAGE=evince
  77 AC_SUBST(GETTEXT_PACKAGE)
  78 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  79 AM_GLIB_GNU_GETTEXT
  80
  81 # Check which platform to use
  82
  83 AC_MSG_CHECKING([for which platform to build])
  84 AC_ARG_WITH([platform],
  85   [AS_HELP_STRING([--with-platform=gnome|win32|hildon (default: gnome)])],
  86   [case "$withval" in
  87     gnome|win32|hildon) ;;
  88     *) AC_MSG_ERROR([invalid argument "$withval" for --with-platform]) ;;
  89    esac],
  90   [case "$host" in
  91      *-*-mingw*|*-*-cygwin*) with_platform="win32" ;;
  92      *) with_platform=gnome ;;
  93    esac])
  94
  95 AC_MSG_RESULT([$with_platform])
  96
  97 if test "$with_platform" = "win32"; then
  98   AC_CHECK_TOOL([WINDRES],[windres])
  99   AC_MSG_CHECKING([for native Win32])
 100   case "$host" in
 101     *-*-mingw*)
 102       os_win32=yes
 103       ;;
 104     *)
 105       os_win32=no
 106       ;;
 107   esac
 108   AC_MSG_RESULT([$os_win32])
 109 fi
 110
 111 AM_CONDITIONAL([PLATFORM_HILDON],[test "$with_platform" = "hildon"])
 112 AM_CONDITIONAL([PLATFORM_WIN32],[test "$with_platform" = "win32"])
 113
 114 dnl Specify required versions of dependencies
 115 DBUS_GLIB_REQUIRED=0.70
 116 GTK_REQUIRED=2.12.0
 117 GLIB_REQUIRED=2.18.0
 118 KEYRING_REQUIRED=2.22.0
 119 AC_SUBST([GLIB_REQUIRED])
 120 AC_SUBST([GTK_REQUIRED])
 121
 122 GNOME_ICON_THEME_REQUIRED=2.17.1
 123 LIBXML_REQUIRED=2.5.0
 124
 125 dnl Check dependencies
 126
 127 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
 128 # BACKEND_CFLAGS   for backend implementations.
 129 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
 130 # FRONTEND_LIBS
 131 # SHELL_CFLAGS     for shell implementation.
 132 # SHELL_LIBS
 133
 134 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
 135 PKG_CHECK_MODULES(LIBVIEW, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 136 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
 137 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 138 PKG_CHECK_MODULES(PREVIEWER, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 139
 140 SHELL_PLATFORM_PKGS=
 141 case "$with_platform" in
 142   hildon) AC_DEFINE([PLATFORM_HILDON],[1],[Define if building for the hildon platform])
 143           SHELL_PLATFORM_PKGS="hildon-1 hildon-fm-2 libosso"
 144           ;;
 145   *) SHELL_PLATFORM_PKGS="gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED"
 146      ;;
 147 esac
 148
 149 PKG_CHECK_MODULES([SHELL_CORE],[libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gthread-2.0 $SHELL_PLATFORM_PKGS])
 150
 151 # *********
 152 # SM client
 153 # *********
 154
 155 GDK_TARGET="$($PKG_CONFIG --variable target gdk-2.0)"
 156
 157 SMCLIENT_PKGS=
 158 AC_MSG_CHECKING([which smclient backend to use])
 159 AC_ARG_WITH([smclient],
 160   [AS_HELP_STRING([--with-smclient-backend],[which smclient backend to use (no|xsmp|win32|quartz)])],
 161   [],
 162   [case "$GDK_TARGET" in
 163     x11) case "$with_platform" in
 164            gnome) with_smclient=xsmp SMCLIENT_PKGS="sm >= 1.0.0" ;;
 165            *) with_smclient=no ;;
 166          esac ;;
 167     win32|quartz) with_smclient=$GDK_TARGET ;;
 168     *) with_smclient=no ;;
 169    esac])
 170 AC_MSG_RESULT([$with_smclient])
 171
 172 if test "$with_smclient" != "no"; then
 173   AC_DEFINE([WITH_SMCLIENT],[1],[Define if smclient is enabled])
 174
 175   PKG_CHECK_MODULES([SMCLIENT],[gtk+-2.0 gthread-2.0 $SMCLIENT_PKGS])
 176   AC_SUBST([SMCLIENT_CFLAGS])
 177   AC_SUBST([SMCLIENT_LIBS])
 178 fi
 179
 180 AM_CONDITIONAL([WITH_SMCLIENT],[test "$with_smclient" != "no"])
 181 AM_CONDITIONAL([WITH_SMCLIENT_XSMP],[test "$with_smclient" = "xsmp"])
 182 AM_CONDITIONAL([WITH_SMCLIENT_WIN32],[test "$with_smclient" = "win32"])
 183 AM_CONDITIONAL([WITH_SMCLIENT_QUARTZ],[test "$with_smclient" = "quartz"])
 184
 185 # ***
 186
 187 BACKEND_LIBTOOL_FLAGS="-module -avoid-version -no-undefined -export-symbols \$(top_srcdir)/backend/backend.symbols"
 188 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
 189
 190 dnl ===== Check special functions
 191 evince_save_LIBS=$LIBS
 192 LIBS="$LIBS $BACKEND_LIBS"
 193 AC_CHECK_FUNCS(cairo_format_stride_for_width)
 194 AC_CHECK_FUNCS(gtk_print_operation_get_n_pages_to_print)
 195 LIBS=$evince_save_LIBS
 196
 197 # ******************
 198 # GKT+ Unix Printing
 199 # ******************
 200
 201 AC_MSG_CHECKING([whether gtk+-unix-print support is requested])
 202 AC_ARG_WITH([gtk-unix-print],
 203   [AS_HELP_STRING([--without-gtk-unix-print],[disable the use of gtk-unix-print])],
 204   [],[case "$os_win32" in
 205         yes) with_gtk_unix_print=no ;;
 206         *) with_gtk_unix_print=yes ;;
 207       esac])
 208 AC_MSG_RESULT([$with_gtk_unix_print])
 209
 210 if test "$with_gtk_unix_print" = "yes"; then
 211    PKG_CHECK_MODULES(GTKUNIXPRINT, [gtk+-unix-print-2.0 >= $GTK_REQUIRED])
 212    AC_DEFINE([GTKUNIXPRINT_ENABLED], [1], [Define if gtk+-unix-print is enabled.])
 213 fi
 214
 215 # *********************
 216 # GNOME Keyring support
 217 # *********************
 218
 219 AC_ARG_WITH(keyring,
 220         [AS_HELP_STRING([--without-keyring],[disable the use of gnome-keyring])],
 221         [],
 222         [case "$with_platform" in
 223            gnome) with_keyring=yes ;;
 224            hildon|win32) with_keyring=no ;;
 225          esac])
 226
 227 AM_CONDITIONAL([WITH_KEYRING],[test "$with_keyring" = "yes"])
 228
 229 if test "$with_keyring" = "yes"; then
 230         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
 231         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
 232 fi
 233
 234 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
 235 AC_SUBST(GLIB_GENMARSHAL)
 236
 237 # ****
 238 # DBUS
 239 # ****
 240
 241 AC_ARG_ENABLE([dbus],
 242   [AS_HELP_STRING([--enable-dbus], [Compile with support for dbus])],
 243   [],
 244   [case "$with_platform" in
 245       gnome) enable_dbus=yes ;;
 246       hildon) enable_dbus=no ;;
 247     esac])
 248
 249 if test "$enable_dbus" = "yes"; then
 250   PKG_CHECK_MODULES([DBUS],[dbus-glib-1 >= $DBUS_GLIB_REQUIRED],[],
 251                     [AC_MSG_ERROR([DBUS not found; use --disable-dbus to disable DBUS support])])
 252
 253   AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 254   if test x$DBUS_BINDING_TOOL = "xno" ; then
 255           AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 256   fi
 257
 258   AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 259 fi
 260
 261 AC_SUBST([DBUS_CFLAGS])
 262 AC_SUBST([DBUS_LIBS])
 263
 264 AM_CONDITIONAL([ENABLE_DBUS], [test "$enable_dbus" = "yes"])
 265
 266 dnl ========= Check for GConf
 267
 268 AC_MSG_CHECKING([whether GConf support is requested])
 269 AC_ARG_WITH([gconf],
 270   [AS_HELP_STRING([--without-gconf],[disable the use of gconf])],
 271   [],
 272   [case "$os_win32" in
 273      yes) with_gconf=no ;;
 274      *) with_gconf=yes ;;
 275    esac])
 276 AC_MSG_RESULT([$with_gconf])
 277
 278 AM_CONDITIONAL([WITH_GCONF],[test "$with_gconf" = "yes"])
 279
 280 if test "$with_gconf" = "yes"; then
 281    PKG_CHECK_MODULES([GCONF],[gconf-2.0])
 282    AC_DEFINE([WITH_GCONF],[1],[Define if GConf support is enabled])
 283
 284    AM_GCONF_SOURCE_2
 285
 286    AC_PATH_PROG([GCONFTOOL], [gconftool-2], [false])
 287    if test "$GCONFTOOL" = "false"; then
 288       AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 289    fi
 290 else
 291    AM_CONDITIONAL([GCONF_SCHEMAS_INSTALL],false)
 292 fi
 293
 294 dnl Debug mode
 295
 296 AC_ARG_ENABLE([debug],
 297         AC_HELP_STRING([--enable-debug],
 298                         [Turn on evince debug mode]),,
 299                 [enable_debug=no])
 300
 301 if test "x$enable_debug" = "xyes"; then
 302    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 303 fi
 304
 305
 306 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 307 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 308 AC_SUBST(LIBDOCUMENT_CFLAGS)
 309 AC_SUBST(LIBDOCUMENT_LIBS)
 310
 311 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $DEBUG_FLAGS"
 312 LIBVIEW_LIBS="$LIBVIEW_LIBS"
 313 AC_SUBST(LIBVIEW_CFLAGS)
 314 AC_SUBST(LIBVIEW_LIBS)
 315
 316 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 317 AC_SUBST(BACKEND_CFLAGS)
 318 AC_SUBST(BACKEND_LIBS)
 319
 320 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $GTKUNIXPRINT_CFLAGS $DBUS_CFLAGS $KEYRING_CFLAGS $GCONF_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 321 SHELL_LIBS="$SHELL_CORE_LIBS $GTKUNIXPRINT_CFLAGS $DBUS_LIBS $KEYRING_LIBS $GCONF_LIBS -lz"
 322 AC_SUBST(SHELL_CFLAGS)
 323 AC_SUBST(SHELL_LIBS)
 324
 325 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 326 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 327 AC_SUBST(FRONTEND_CFLAGS)
 328 AC_SUBST(FRONTEND_LIBS)
 329
 330 # Check for Nautilus property page build
 331 AC_ARG_ENABLE([nautilus],
 332   [AS_HELP_STRING([--disable-nautilus],[Build the nautilus extensions])],
 333   [],
 334   [case "$with_platform" in
 335      gnome) enable_nautilus=yes ;;
 336      *) enable_nautilus=no ;;
 337     esac])
 338
 339 if test "$enable_nautilus" = "yes" ; then
 340   PKG_CHECK_MODULES([NAUTILUS],[gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension],
 341                     [],[AC_MSG_ERROR([libnautilus-extension not found; use --disable-nautilus to disable the nautilus extensions])])
 342   NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 343   AC_SUBST([nautilusextensiondir],[$NAUTILUS_EXTENSION_DIR])
 344   AC_SUBST(NAUTILUS_CFLAGS)
 345   AC_SUBST(NAUTILUS_LIBS)
 346
 347   AC_DEFINE([HAVE_NAUTILUS],[1], [defined if you build the nautilus plugin])
 348 fi
 349
 350 AM_CONDITIONAL([ENABLE_NAUTILUS],[test "$enable_nautilus" = "yes"])
 351
 352 # Check for thumbnailer build
 353
 354 AC_ARG_ENABLE([thumbnailer],
 355   [AS_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer])],
 356   [],
 357   [case "$with_platform" in
 358      gnome) enable_thumbnailer=yes ;;
 359      *) enable_thumbnailer=no ;;
 360     esac])
 361
 362 AM_CONDITIONAL([ENABLE_THUMBNAILER],[test "$enable_thumbnailer" = "yes"])
 363
 364 # ***************
 365 # Print Previewer
 366 # ***************
 367
 368 AC_ARG_ENABLE([previewer],
 369   [AS_HELP_STRING([--disable-previewer],[disable the GNOME Document Previewer])],
 370   [],
 371   [case "$with_platform" in
 372       gnome) enable_previewer=yes ;;
 373       *) enable_previewer=no ;;
 374     esac])
 375
 376 if test x$enable_previewer = "xyes" ; then
 377   PKG_CHECK_MODULES([PREVIEWER],[gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED])
 378 fi
 379
 380 AM_CONDITIONAL([ENABLE_PREVIEWER],[test "$enable_previewer" = "yes"])
 381 PREVIEWER_CFLAGS="$PREVIEWER_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 382 PREVIEWER_LIBS="$PREVIEWER_LIBS $GTKUNIXPRINT_LIBS -lz"
 383 AC_SUBST(PREVIEWER_CFLAGS)
 384 AC_SUBST(PREVIEWER_LIBS)
 385
 386 # ***
 387 # GIR
 388 # ***
 389
 390 AC_MSG_CHECKING([whether GObject introspection is requested])
 391 AC_ARG_ENABLE([introspection],
 392         AS_HELP_STRING([--enable-introspection],[Enable GObject introspection]),
 393         [],[enable_introspection=no])
 394 AC_MSG_RESULT([$enable_introspection])
 395
 396 G_IR_SCANNER=
 397 G_IR_COMPILER=
 398 G_IR_GENERATE=
 399 GIRDIR=
 400 GIRTYPELIBDIR=
 401
 402 if test "$enable_introspection" = "yes"; then
 403   GOBJECT_INTROSPECTION_REQUIRED=0.6
 404   PKG_CHECK_MODULES([GOBJECT_INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
 405
 406   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
 407   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
 408   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
 409   GIRDIR="$($PKG_CONFIG --variable=girdir gobject-introspection-1.0)"
 410   GIRTYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
 411 fi
 412
 413 AC_SUBST([G_IR_SCANNER])
 414 AC_SUBST([G_IR_COMPILER])
 415 AC_SUBST([G_IR_GENERATE])
 416 AC_SUBST([GIRDIR])
 417 AC_SUBST([GIRTYPELIBDIR])
 418
 419 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
 420
 421 dnl ================== portability checks ===========================================
 422
 423 dnl for backtrace()
 424 AC_CHECK_HEADERS([execinfo.h])
 425
 426 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 427   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 428   ],[],[#include <langinfo.h>])
 429
 430 dnl ================== pdf checks ===================================================
 431 AC_ARG_ENABLE(pdf,
 432               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 433
 434 if test "x$enable_pdf" = "xyes"; then
 435     POPPLER_REQUIRED=0.11.0
 436     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED,enable_pdf=yes,enable_pdf=no)
 437
 438     if test "x$enable_pdf" = "xyes"; then
 439             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 440             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 441             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 442
 443             evince_save_LIBS=$LIBS
 444             LIBS="$LIBS $POPPLER_LIBS"
 445             AC_CHECK_FUNCS(poppler_page_render)
 446             AC_CHECK_FUNCS(poppler_page_get_image)
 447             LIBS=$evince_save_LIBS
 448
 449             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 450             if test x$enable_cairo_pdf = xyes; then
 451                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 452             fi
 453
 454             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 455             if test x$enable_cairo_ps = xyes; then
 456                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 457             fi
 458     else
 459             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 460     fi
 461 fi
 462
 463 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 464 dnl ================== end of pdf checks ============================================
 465
 466 dnl libspectre (used by ps and dvi backends)
 467 SPECTRE_REQUIRED=0.2.0
 468 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 469 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 470 if test "x$have_spectre" = "xyes"; then
 471    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 472 fi
 473
 474 dnl ================== ps checks ====================================================
 475 AC_ARG_ENABLE(ps,
 476         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 477
 478 if test "x$enable_ps" = "xyes"; then
 479    if test "x$have_spectre" = "xyes"; then
 480       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 481    else
 482       enable_ps="no"
 483       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 484    fi
 485 fi
 486 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 487 dnl ======================== End of ps checks ===================================
 488
 489 dnl ================== tiff checks ===================================================
 490 AC_ARG_ENABLE(tiff,
 491             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 492
 493 if test "x$enable_tiff" = "xyes"; then
 494     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 495     if test "x$enable_tiff" = "xyes"; then
 496         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 497         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 498     fi
 499     if test "x$enable_tiff" = "xyes"; then
 500             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 501     else
 502             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 503     fi
 504 fi
 505
 506 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 507 dnl ================== end of tiff checks ============================================
 508
 509 dnl ================== djvu checks ===================================================
 510
 511 AC_ARG_ENABLE(djvu,
 512             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=yes)
 513
 514 if test "x$enable_djvu" = "xyes"; then
 515     DJVULIBRE_REQUIRED=3.5.17
 516     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 517
 518     if test "x$enable_djvu" = "xyes"; then
 519         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 520     else
 521         AC_MSG_WARN([
 522 ** Djvu support is disabled since a recent version of the djvulibre
 523 ** library was not found. You need at least djvulibre-3.5.17 which
 524 ** can be found on http://djvulibre.djvuzone.org
 525 ])
 526     fi
 527 fi
 528
 529 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 530
 531 dnl ================== End of djvu checks ===================================================
 532
 533 dnl ================== dvi checks ===================================================
 534
 535 AC_ARG_ENABLE(dvi,
 536             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=yes)
 537
 538 AC_ARG_ENABLE(t1lib,
 539             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 540
 541 if test "x$enable_dvi" = "xyes"; then
 542     AC_C_CONST
 543     AC_C_INLINE
 544     AC_TYPE_SIZE_T
 545     AC_CHECK_SIZEOF(long, 4)
 546     AC_CHECK_SIZEOF(int, 4)
 547     AC_CHECK_SIZEOF(short, 2)
 548     AC_CHECK_SIZEOF(void *, 4)
 549     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 550
 551     if test "x$enable_dvi" = "xyes"; then
 552         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 553     else
 554         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 555     fi
 556 fi
 557 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 558
 559 if test "x$enable_dvi" = "xyes"; then
 560     if test "x$enable_type1_fonts" = "xyes"; then
 561         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 562     fi
 563
 564     if test "x$enable_type1_fonts" = xyes; then
 565         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 566     fi
 567 else
 568     enable_type1_fonts=no
 569 fi
 570 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 571
 572 dnl ================== End of dvi checks ===================================================
 573
 574 dnl ================== pixbuf checks ===================================================
 575
 576 AC_ARG_ENABLE(pixbuf,
 577             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 578 if test "x$enable_pixbuf" = "xyes"; then
 579         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 580 fi
 581 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 582
 583 dnl ================== End of pixbuf checks ===================================================
 584
 585 dnl ================== comic book checks ===================================================
 586
 587 AC_ARG_ENABLE(comics,
 588         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=yes)
 589 if test "x$enable_comics" = "xyes"; then
 590         if test "x$os_win32" = "xyes"; then
 591                 # The comics backend is disabled on windows because:
 592                 # 1) it uses unix functions from sys/wait.h.
 593                 # 2) it uses external decompression tools not generally available on windows.
 594                 enable_comics=no
 595                 AC_MSG_WARN(The comics backend is not supported on windows.)
 596         else
 597                 AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 598         fi
 599 fi
 600 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 601
 602 dnl ================== End of comic book checks ============================================
 603
 604 dnl ================== impress book checks ===================================================
 605
 606 AC_ARG_ENABLE(impress,
 607         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 608 if test "x$enable_impress" = "xyes"; then
 609         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 610 fi
 611 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 612
 613 dnl ================== End of impress book checks ============================================
 614
 615 dnl =================== Mime types list ====================================================
 616
 617 if test "x$enable_pdf" = "xyes" ; then
 618         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 619 fi
 620 if test "x$enable_ps" = "xyes" ; then
 621         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 622 fi
 623 if test "x$enable_dvi" = "xyes"; then
 624         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 625 fi
 626 if test "x$enable_djvu" = "xyes"; then
 627         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 628 fi
 629 if test "x$enable_tiff" = "xyes"; then
 630         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 631 fi
 632 if test "x$enable_comics" = "xyes"; then
 633         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;"
 634 fi
 635 if test "x$enable_pixbuf" = "xyes"; then
 636         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 637 fi
 638 if test "x$enable_impress" = "xyes"; then
 639         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 640 fi
 641 AC_SUBST(EVINCE_MIME_TYPES)
 642
 643 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 644
 645 # Backends directory
 646
 647 AC_SUBST([backenddir],"\$(libdir)/evince/ev_binary_version/backends")
 648 AC_SUBST([backend_binary_version],"ev_binary_version")
 649
 650 # Versioning
 651
 652 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
 653 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
 654 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
 655
 656 AC_SUBST([EV_API_VERSION],[ev_api_version])
 657 AC_SUBST([EV_BINARY_VERSION],[ev_binary_version])
 658
 659 AC_SUBST([EV_DOCUMENT_LT_VERSION_INFO],[ev_document_lt_version_info])
 660 AC_SUBST([EV_DOCUMENT_LT_CURRENT_MINUS_AGE],[ev_document_lt_current_minus_age])
 661 AC_SUBST([EV_VIEW_LT_VERSION_INFO],[ev_view_lt_version_info])
 662 AC_SUBST([EV_VIEW_LT_CURRENT_MINUS_AGE],[ev_view_lt_current_minus_age])
 663
 664 # *****************************************************************************
 665
 666 AC_CONFIG_FILES([
 667 backend/Makefile
 668 backend/comics/Makefile
 669 backend/djvu/Makefile
 670 backend/dvi/Makefile
 671 backend/dvi/mdvi-lib/Makefile
 672 backend/impress/Makefile
 673 backend/pdf/Makefile
 674 backend/pixbuf/Makefile
 675 backend/ps/Makefile
 676 backend/tiff/Makefile
 677 cut-n-paste/Makefile
 678 cut-n-paste/gedit-message-area/Makefile
 679 cut-n-paste/gimpcellrenderertoggle/Makefile
 680 cut-n-paste/smclient/Makefile
 681 cut-n-paste/toolbar-editor/Makefile
 682 cut-n-paste/zoom-control/Makefile
 683 cut-n-paste/totem-screensaver/Makefile
 684 data/evince.desktop.in
 685 data/Makefile
 686 data/icons/Makefile
 687 data/icons/16x16/Makefile
 688 data/icons/16x16/apps/Makefile
 689 data/icons/16x16/actions/Makefile
 690 data/icons/22x22/Makefile
 691 data/icons/22x22/apps/Makefile
 692 data/icons/22x22/actions/Makefile
 693 data/icons/24x24/Makefile
 694 data/icons/24x24/apps/Makefile
 695 data/icons/24x24/actions/Makefile
 696 data/icons/32x32/Makefile
 697 data/icons/32x32/actions/Makefile
 698 data/icons/48x48/Makefile
 699 data/icons/48x48/apps/Makefile
 700 data/icons/48x48/actions/Makefile
 701 data/icons/scalable/Makefile
 702 data/icons/scalable/apps/Makefile
 703 help/Makefile
 704 help/reference/Makefile
 705 help/reference/libdocument/Makefile
 706 help/reference/libdocument/version.xml
 707 help/reference/libview/Makefile
 708 help/reference/libview/version.xml
 709 help/reference/shell/Makefile
 710 help/reference/shell/version.xml
 711 libdocument/Makefile
 712 libdocument/ev-version.h
 713 libmisc/Makefile
 714 libview/Makefile
 715 Makefile
 716 po/Makefile.in
 717 previewer/Makefile
 718 properties/Makefile
 719 shell/Makefile
 720 test/Makefile
 721 thumbnailer/Makefile
 722 ])
 723
 724 AC_CONFIG_FILES(evince-document-[]ev_api_version[].pc:evince-document.pc.in)
 725 AC_CONFIG_FILES(evince-view-[]ev_api_version[].pc:evince-view.pc.in)
 726
 727 AC_OUTPUT
 728
 729 echo "
 730 Configure summary:
 731         Platform...........:  $with_platform
 732         GConf Support......:  $with_gconf
 733         GTK+ Unix Print....:  $with_gtk_unix_print
 734         Keyring Support....:  $with_keyring
 735         DBUS Support.......:  $enable_dbus
 736         SM client support..:  $with_smclient
 737         Nautilus Plugin....:  $enable_nautilus
 738         Thumbnailer........:  $enable_thumbnailer
 739         Previewer..........:  $enable_previewer
 740         Gtk-Doc Support....:  $enable_gtk_doc
 741         Debug mode.........:  $enable_debug
 742         GObj. Introspection:  $enable_introspection
 743
 744         PDF Backend........:  $enable_pdf
 745         PostScript Backend.:  $enable_ps
 746         TIFF Backend.......:  $enable_tiff
 747         DJVU Backend.......:  $enable_djvu
 748         DVI Backend........:  $enable_dvi
 749         Pixbuf Backend.....:  $enable_pixbuf
 750         Comics Backend.....:  $enable_comics
 751         Impress Backend....:  $enable_impress
 752 "