configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.57)
   4 AC_INIT(evince, 0.4.0)
   5 AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)
   6
   7 AM_CONFIG_HEADER(config.h)
   8
   9 AM_MAINTAINER_MODE
  10
  11 AM_PROG_LIBTOOL
  12
  13 AC_ISC_POSIX
  14 AC_PROG_CC
  15 AM_PROG_CC_STDC
  16 AC_PROG_CXX
  17 AC_STDC_HEADERS
  18 AC_PROG_INTLTOOL
  19 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  20 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  21
  22 GNOME_COMMON_INIT
  23 GNOME_DOC_INIT
  24 GNOME_MAINTAINER_MODE_DEFINES
  25 GNOME_COMPILE_WARNINGS
  26 GNOME_CXX_WARNINGS
  27 GNOME_DEBUG_CHECK
  28
  29 ALL_LINGUAS="bg ca cs da de el en_CA en_GB es et eu fi fr gl gu he hi hu id it ja ko lt nb ne nl no pa pl pt pt_BR ro ru rw sk sq sr sr@Latn sv th tr uk wa zh_CN zh_TW"
  30
  31 AM_GLIB_GNU_GETTEXT
  32
  33 GETTEXT_PACKAGE=AC_PACKAGE_NAME
  34 AC_SUBST(GETTEXT_PACKAGE)
  35 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package.])
  36
  37 dnl Check dependencies
  38
  39 # LIB_CFLAGS       for helpers and generic widgets. (lib, cut-and-paste)
  40 # BACKEND_CFLAGS   for backend implementations.
  41 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
  42 # FRONTEND_LIBS
  43 # SHELL_CFLAGS     for shell implementation.
  44 # SHELL_LIBS
  45
  46 POPPLER_REQUIRED=0.4.1
  47 DBUS_GLIB_REQUIRED=0.33
  48 GTK_REQUIRED=2.6.0
  49 LIBGNOMEUI_REQUIRED=2.6.0
  50
  51 PKG_CHECK_MODULES(LIB, gtk+-2.0 >= $GTK_REQUIRED libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED)
  52 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
  53 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED libglade-2.0 poppler-glib >= $POPPLER_REQUIRED)
  54 PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED)
  55 PKG_CHECK_MODULES(SHELL_CORE, gtk+-2.0 >= $GTK_REQUIRED libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED gnome-vfs-2.0 libgnomeprint-2.2 >= 2.5.1 libgnomeprintui-2.2 libglade-2.0 gconf-2.0 poppler-glib >= $POPPLER_REQUIRED)
  56
  57 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
  58 AC_SUBST(GLIB_GENMARSHAL)
  59
  60 PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
  61         [enable_dbus=yes],[enable_dbus=no])
  62 AC_SUBST([DBUS_CFLAGS])
  63 AC_SUBST([DBUS_LIBS])
  64
  65 if test "x$enable_dbus" = "xno"; then
  66         AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
  67 fi
  68
  69 if test "x$enable_dbus" = "xyes" ; then
  70         AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
  71
  72         if test x$DBUS_BINDING_TOOL = "xno" ; then
  73                 AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
  74         fi
  75
  76         AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
  77
  78         DBUS_VERSION=`$PKG_CONFIG --modversion dbus-glib-1 | sed 's/0\.\([[0-9]]*\)\.\{0,1\}\([[0-9]]*\)/\1/'`
  79         AC_DEFINE_UNQUOTED(DBUS_VERSION, $DBUS_VERSION, [DBUS version.])
  80 fi
  81
  82 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS"
  83 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS -ltiff -lz"
  84 AC_SUBST(SHELL_CFLAGS)
  85 AC_SUBST(SHELL_LIBS)
  86
  87 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS"
  88 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -ltiff -lz"
  89 AC_SUBST(FRONTEND_CFLAGS)
  90 AC_SUBST(FRONTEND_LIBS)
  91
  92 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
  93 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
  94
  95 dnl Check for Nautilus property page build
  96 AC_ARG_ENABLE(nautilus,
  97         AC_HELP_STRING([--enable-nautilus],[compile the nautilus plugin]),
  98         [case "${enableval}" in
  99         yes) ENABLE_NAUTILUS=yes ;;
 100         no) ENABLE_NAUTILUS=no ;;
 101         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nautilus) ;;
 102         esac],
 103         [ENABLE_NAUTILUS=yes]) dnl Default value
 104
 105 if test x$ENABLE_NAUTILUS = "xyes" ; then
 106         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
 107                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
 108 fi
 109
 110 AC_SUBST(NAUTILUS_CFLAGS)
 111 AC_SUBST(NAUTILUS_LIBS)
 112 if test x$HAVE_NAUTILUS = "xyes"; then
 113         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
 114 fi
 115 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
 116
 117 dnl Check for functions not present in gtk 2.6
 118 evince_save_LIBS=$LIBS
 119 LIBS="$LIBS $FRONTEND_CORE_LIBS"
 120 AC_CHECK_FUNCS(gtk_icon_view_get_visible_range)
 121 AC_CHECK_FUNCS(gtk_window_present_with_time)
 122 AC_CHECK_FUNCS(g_file_set_contents)
 123 LIBS=$evince_save_LIBS
 124
 125 dnl GConf configuration
 126 AM_GCONF_SOURCE_2
 127
 128 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
 129 if test "x$GCONFTOOL" = "xno"; then
 130         AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 131 fi
 132
 133 dnl ================== portability checks ===========================================
 134
 135 dnl for backtrace()
 136 AC_CHECK_HEADERS([execinfo.h])
 137
 138 dnl ================== ggv checks ===================================================
 139 AC_ARG_WITH(gs-pkg,
 140             [  --with-gs=dir       Directory Where GhostScript package is installed.])
 141
 142 if test "x$with_gs" = "x"; then
 143         AC_PATH_PROG(GS_PROG, gs)
 144         if test -z "$GS_PROG"; then
 145                 AC_MSG_ERROR(Unable to find GhostScript in the PATH. Provide the full path for GhostScript(--with-gs=PATH). You need to have Ghostscript installed in order to run evince)
 146         fi
 147 else
 148         GS_PROG=$with_gs
 149 fi
 150
 151 AC_DEFINE_UNQUOTED(GS_PATH, "$GS_PROG", [Path to the 'gs' executable.])
 152
 153
 154 dnl check for GS version
 155 AC_MSG_CHECKING(for Ghostscript version...)
 156 GS_VERSION=`gs --version | head -n 1 | sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
 157 AC_MSG_RESULT(found $GS_VERSION)
 158 if test "$GS_VERSION" -lt "7"; then
 159         AC_MSG_ERROR([You need Ghostscript version >= 7 in order to run evince])
 160 fi
 161 AA_PARMS="-sDEVICE=x11alpha -dNOPLATFONTS"
 162 AC_DEFINE_UNQUOTED(ALPHA_PARAMS, "$AA_PARMS", [Anti-aliasing parameters for Ghostscript.])
 163 AC_MSG_RESULT(Antialiasing parameters for Ghostscript: $AA_PARMS)
 164 dnl ======================== End of ggv checks =================================
 165
 166 dnl ================== tiff checks ===================================================
 167 AC_ARG_ENABLE(tiff,
 168             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 169
 170 if test "x$enable_tiff" = "xyes"; then
 171     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 172     if test "x$enable_tiff" = "xyes"; then
 173         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 174         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 175     fi
 176     if test "x$enable_tiff" = "xyes"; then
 177             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 178     else
 179             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 180     fi
 181 fi
 182
 183 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 184 dnl ================== end of tiff checks ============================================
 185
 186 dnl ================== djvu checks ===================================================
 187
 188 AC_ARG_ENABLE(djvu,
 189             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=no)
 190
 191 if test "x$enable_djvu" = "xyes"; then
 192     AC_CHECK_HEADERS([libdjvu/ddjvuapi.h],enable_djvu=yes,enable_djvu=no,)
 193
 194     if test "x$enable_djvu" = "xyes"; then
 195         AC_CHECK_LIB([djvulibre],ddjvu_context_create,enable_djvu=yes,enable_djvu=no,"-lpthread")
 196         AC_CHECK_LIB([djvulibre],ddjvu_document_get_pageinfo,enable_djvu=yes,enable_djvu=no,"-lpthread")
 197     fi
 198
 199     if test "x$enable_djvu" = "xyes"; then
 200         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 201     else
 202         AC_MSG_WARN([
 203 ** Djvu support is disabled since a recent version of the djvulibre
 204 ** library was not found. You need at least djvulibre-3.5.15 which
 205 ** can be found on http://djvulibre.djvuzone.org
 206 ])
 207     fi
 208 fi
 209
 210 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 211
 212 dnl ================== End of djvu checks ===================================================
 213
 214 dnl ================== dvi checks ===================================================
 215
 216 AC_ARG_ENABLE(dvi,
 217             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=no)
 218
 219 AC_ARG_ENABLE(t1lib,
 220             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 221
 222 if test "x$enable_dvi" = "xyes"; then
 223     AC_C_CONST
 224     AC_C_INLINE
 225     AC_TYPE_SIZE_T
 226     AC_CHECK_SIZEOF(long, 4)
 227     AC_CHECK_SIZEOF(int, 4)
 228     AC_CHECK_SIZEOF(short, 2)
 229     AC_CHECK_SIZEOF(void *, 4)
 230     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 231
 232     if test "x$enable_dvi" = "xyes"; then
 233         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 234     else
 235         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 236     fi
 237 fi
 238 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 239
 240 if test "x$enable_dvi" = "xyes"; then
 241     if test "x$enable_type1_fonts" = "xyes"; then
 242         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 243     fi
 244
 245     if test "x$enable_type1_fonts" = xyes; then
 246         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 247     fi
 248 else
 249     enable_type1_fonts=no
 250 fi
 251 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 252
 253 dnl ================== End of dvi checks ===================================================
 254
 255 dnl ================== pixbuf checks ===================================================
 256
 257 AC_ARG_ENABLE(pixbuf,
 258             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 259 if test "x$enable_pixbuf" = "xyes"; then
 260         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 261 fi
 262 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 263
 264 dnl ================== End of dvi checks ===================================================
 265
 266 dnl =================== Mime types list ====================================================
 267
 268 EVINCE_MIME_TYPES="application/pdf;application/postscript;application/x-gzpostscript"
 269
 270 if test "x$enable_dvi" = "xyes"; then
 271         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;application/x-dvi"
 272 fi
 273 if test "x$enable_djvu" = "xyes"; then
 274         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;image/vnd.djvu"
 275 fi
 276 if test "x$enable_tiff" = "xyes"; then
 277         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;image/tiff"
 278 fi
 279 AC_SUBST(EVINCE_MIME_TYPES)
 280
 281 AC_CONFIG_FILES([
 282 Makefile
 283 cut-n-paste/Makefile
 284 cut-n-paste/recent-files/Makefile
 285 cut-n-paste/zoom-control/Makefile
 286 cut-n-paste/toolbar-editor/Makefile
 287 data/Makefile
 288 data/evince.desktop.in
 289 lib/Makefile
 290 pdf/Makefile
 291 pixbuf/Makefile
 292 tiff/Makefile
 293 ps/Makefile
 294 djvu/Makefile
 295 dvi/Makefile
 296 dvi/mdvi-lib/Makefile
 297 po/Makefile.in
 298 backend/Makefile
 299 properties/Makefile
 300 shell/Makefile
 301 thumbnailer/Makefile
 302 help/Makefile
 303 ])
 304
 305 AC_OUTPUT