configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.57)
   4 AC_INIT([Evince],[2.21.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
   5 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-dist-gzip])
   6
   7 EV_API_VERSION=2.20
   8 AC_SUBST(EV_API_VERSION)
   9
  10 AM_CONFIG_HEADER(config.h)
  11
  12 AM_MAINTAINER_MODE
  13
  14 AM_PROG_LIBTOOL
  15
  16 AC_ISC_POSIX
  17 AC_PROG_CC
  18 AM_PROG_CC_STDC
  19 AC_PROG_CXX
  20 AC_STDC_HEADERS
  21 IT_PROG_INTLTOOL([0.35.0])
  22 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  23 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  24
  25 GNOME_COMMON_INIT
  26 GNOME_DOC_INIT
  27 GNOME_MAINTAINER_MODE_DEFINES
  28 GNOME_COMPILE_WARNINGS
  29 GNOME_CXX_WARNINGS
  30 GNOME_DEBUG_CHECK
  31
  32 GTK_DOC_CHECK(1.0)
  33
  34 GETTEXT_PACKAGE=evince
  35 AC_SUBST(GETTEXT_PACKAGE)
  36 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  37 AM_GLIB_GNU_GETTEXT
  38
  39 dnl Check dependencies
  40
  41 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
  42 # BACKEND_CFLAGS   for backend implementations.
  43 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
  44 # FRONTEND_LIBS
  45 # SHELL_CFLAGS     for shell implementation.
  46 # SHELL_LIBS
  47
  48 DBUS_GLIB_REQUIRED=0.70
  49 GTK_REQUIRED=2.10.0
  50 KEYRING_REQUIRED=0.4.0
  51
  52 LIBGNOMEUI_REQUIRED=2.14.0
  53 LIBGNOME_REQUIRED=2.14.0
  54 LIBGNOMEPRINTUI_REQUIRED=2.6.0
  55 GNOME_ICON_THEME_REQUIRED=2.17.1
  56 LIBXML_REQUIRED=2.5.0
  57
  58 GTK_PRINT_REQUIRED=2.10.0
  59
  60 PKG_CHECK_MODULES(LIB, gtk+-2.0 >= $GTK_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED gnome-vfs-2.0)
  61 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
  62 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED libglade-2.0 gnome-vfs-2.0)
  63 PKG_CHECK_MODULES(SHELL_CORE, libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED gnome-vfs-2.0 libglade-2.0 gconf-2.0)
  64
  65 BACKEND_LIBTOOL_FLAGS="-module -avoid-version"
  66 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
  67
  68 AC_ARG_WITH(keyring,
  69         AC_HELP_STRING([--without-keyring],[disable the use of gnome-keyring]),
  70         [case "${withval}" in
  71         yes) WITH_KEYRING=yes ;;
  72         no) WITH_KEYRING=no ;;
  73         *) AC_MSG_ERROR(bad value ${withval} for --with-keyring) ;;
  74         esac],
  75         [WITH_KEYRING=yes]) dnl Default value
  76 AM_CONDITIONAL(WITH_KEYRING, test x$WITH_KEYRING = "xyes")
  77
  78 if test x$WITH_KEYRING = "xyes"; then
  79         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
  80         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
  81 fi
  82
  83 AC_ARG_WITH(libgnome,
  84         AC_HELP_STRING([--without-libgnome],[disable the use of libgnome]),
  85         [case "${withval}" in
  86         yes) WITH_GNOME=yes ;;
  87         no) WITH_GNOME=no ;;
  88         *) AC_MSG_ERROR(bad value ${withval} for --with-libgnome) ;;
  89         esac],
  90         [WITH_GNOME=yes]) dnl Default value
  91 AM_CONDITIONAL(WITH_GNOME, test x$WITH_GNOME = "xyes")
  92
  93 if test x$WITH_GNOME = "xyes"; then
  94         PKG_CHECK_MODULES(GNOME, libgnome-2.0 >= $LIBGNOME_REQUIRED)
  95         PKG_CHECK_MODULES(GNOMEUI, libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED)
  96         AC_DEFINE([WITH_GNOME],[1],[Define if GNOME support is enabled])
  97 fi
  98
  99 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
 100 AC_SUBST(GLIB_GENMARSHAL)
 101
 102 dnl ========= Print support
 103 AC_ARG_WITH(print,
 104             [AC_HELP_STRING([--with-print=no/gtk/gnome/auto], [Compile with print support [default=auto]])],
 105             PRINT=$withval,
 106             PRINT="auto")
 107
 108 PKG_CHECK_MODULES(GNOME_PRINT,
 109                   libgnomeprintui-2.2 >= $LIBGNOMEPRINTUI_REQUIRED,
 110                   enable_gnome_print=yes, enable_gnome_print=no)
 111 PKG_CHECK_MODULES(GTK_PRINT,
 112                   gtk+-unix-print-2.0 >= $GTK_PRINT_REQUIRED,
 113                   enable_gtk_print=yes, enable_gtk_print=no)
 114 enable_print=no
 115 if test x$PRINT = xgnome -a x$enable_gnome_print = xyes; then
 116    enable_print=gnome
 117 else
 118    if test x$PRINT = xgtk -a x$enable_gtk_print = xyes; then
 119       enable_print=gtk
 120    else
 121       if test x$PRINT = xauto; then
 122          if test x$enable_gtk_print = xyes; then
 123             enable_print=gtk
 124          else
 125             if test x$enable_gnome_print = xyes; then
 126                enable_print=gnome
 127             fi
 128          fi
 129       fi
 130    fi
 131 fi
 132
 133 if test x$enable_print = xgnome; then
 134    AC_SUBST(GNOME_PRINT_CFLAGS)
 135    AC_SUBST(GNOME_PRINT_LIBS)
 136    AC_DEFINE([WITH_GNOME_PRINT],[1],[Enable GNOME Print Support.])
 137    AC_DEFINE([WITH_PRINT],[1],[Enable Print Support.])
 138 fi
 139
 140 if test x$enable_print = xgtk; then
 141    AC_SUBST(GTK_PRINT_CFLAGS)
 142    AC_SUBST(GTK_PRINT_LIBS)
 143    AC_DEFINE([WITH_GTK_PRINT],[1],[Enable GTK Print Support.])
 144    AC_DEFINE([WITH_PRINT],[1],[Enable Print Support.])
 145 fi
 146
 147 AM_CONDITIONAL(WITH_GNOME_PRINT, test x$enable_print = xgnome)
 148 AM_CONDITIONAL(WITH_GTK_PRINT, test x$enable_print = xgtk)
 149
 150
 151 dnl ========= Check for DBUS
 152 PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
 153         [enable_dbus=yes],[enable_dbus=no])
 154 AC_SUBST([DBUS_CFLAGS])
 155 AC_SUBST([DBUS_LIBS])
 156
 157 if test "x$enable_dbus" = "xno"; then
 158         AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
 159 fi
 160
 161 if test "x$enable_dbus" = "xyes" ; then
 162         AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 163
 164         if test x$DBUS_BINDING_TOOL = "xno" ; then
 165                 AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 166         fi
 167
 168         AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 169 fi
 170
 171 LIB_CFLAGS="$LIB_CFLAGS $GNOME_CFLAGS"
 172 LIB_LIBS="$LIB_LIBS $GNOME_LIBS"
 173 AC_SUBST(LIB_CFLAGS)
 174 AC_SUBST(LIB_LIBS)
 175
 176 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE"
 177 AC_SUBST(BACKEND_CFLAGS)
 178 AC_SUBST(BACKEND_LIBS)
 179
 180 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS $GNOMEUI_CFLAGS $KEYRING_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE"
 181 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS $GNOMEUI_LIBS $KEYRING_LIBS -lz"
 182 AC_SUBST(SHELL_CFLAGS)
 183 AC_SUBST(SHELL_LIBS)
 184
 185 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $GNOME_CFLAGS"
 186 FRONTEND_LIBS="$FRONTEND_CORE_LIBS $GNOME_LIBS -lz"
 187 AC_SUBST(FRONTEND_CFLAGS)
 188 AC_SUBST(FRONTEND_LIBS)
 189
 190 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
 191 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
 192
 193 dnl Check for Nautilus property page build
 194 AC_ARG_ENABLE(nautilus,
 195         AC_HELP_STRING([--enable-nautilus],[compile the nautilus plugin]),
 196         [case "${enableval}" in
 197         yes) ENABLE_NAUTILUS=yes ;;
 198         no) ENABLE_NAUTILUS=no ;;
 199         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nautilus) ;;
 200         esac],
 201         [ENABLE_NAUTILUS=yes]) dnl Default value
 202
 203 if test x$ENABLE_NAUTILUS = "xyes" ; then
 204         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
 205                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
 206         NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 207         AC_SUBST(NAUTILUS_EXTENSION_DIR)
 208 fi
 209
 210 AC_SUBST(NAUTILUS_CFLAGS)
 211 AC_SUBST(NAUTILUS_LIBS)
 212 if test x$HAVE_NAUTILUS = "xyes"; then
 213         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
 214 fi
 215 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
 216
 217
 218 dnl Check for thumbnailer build
 219 AC_ARG_ENABLE(thumbnailer,
 220         AC_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer]),
 221         [case "${enableval}" in
 222         yes) ENABLE_THUMBNAILER=yes ;;
 223         no) ENABLE_THUMBNAILER=no ;;
 224         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thumbnailer) ;;
 225         esac],
 226         [ENABLE_THUMBNAILER=yes]) dnl Default value
 227 AM_CONDITIONAL(ENABLE_THUMBNAILER, test x$ENABLE_THUMBNAILER = "xyes")
 228
 229 dnl GConf configuration
 230 AM_GCONF_SOURCE_2
 231
 232 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
 233 if test "x$GCONFTOOL" = "xno"; then
 234         AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 235 fi
 236
 237 dnl ================== portability checks ===========================================
 238
 239 dnl for backtrace()
 240 AC_CHECK_HEADERS([execinfo.h])
 241
 242 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 243   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 244   ],[],[#include <langinfo.h>])
 245
 246 dnl ================== pdf checks ===================================================
 247 AC_ARG_ENABLE(pdf,
 248               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 249
 250 if test "x$enable_pdf" = "xyes"; then
 251     POPPLER_REQUIRED=0.6
 252     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED,enable_pdf=yes,enable_pdf=no)
 253
 254     if test "x$enable_pdf" = "xyes"; then
 255             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 256             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 257             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 258
 259             evince_save_LIBS=$LIBS
 260             LIBS="$LIBS $POPPLER_LIBS"
 261             AC_CHECK_FUNCS(poppler_page_render)
 262             AC_CHECK_FUNCS(poppler_page_render_for_printing)
 263             AC_CHECK_FUNCS(poppler_page_get_image)
 264             LIBS=$evince_save_LIBS
 265
 266             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 267             if test x$enable_cairo_pdf == xyes; then
 268                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 269             fi
 270
 271             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 272             if test x$enable_cairo_ps == xyes; then
 273                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 274             fi
 275     else
 276             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 277     fi
 278 fi
 279
 280 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 281 dnl ================== end of pdf checks ============================================
 282 SPECTRE_REQUIRED=0.2.0
 283
 284 dnl libspectre (used by ps and dvi backends)
 285 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 286 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 287 if test "x$have_spectre" = "xyes"; then
 288    AC_DEFINE([HAVE_SPECTRE], [1], [Have libpectre])
 289 fi
 290
 291 dnl ================== ps checks ====================================================
 292 AC_ARG_ENABLE(ps,
 293         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 294
 295 ps_backend=""
 296 if test x$enable_ps = xyes; then
 297    AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 298
 299    if test "x$have_spectre" = "xyes"; then
 300       ps_backend="(libspectre)"
 301    else
 302       dnl check for GS version
 303       AC_MSG_CHECKING(for Ghostscript version...)
 304       GS_VERSION=`gs --version | head -n 1 | sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
 305       AC_MSG_RESULT(found $GS_VERSION)
 306       if test "$GS_VERSION" -lt "7"; then
 307          AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) or Ghostscript (version >= 7) are needed])
 308          enable_ps=no
 309       else
 310          AC_ARG_WITH(gs-aa-params,
 311                      [AC_HELP_STRING([--with-gs-aa-params], [Define antialiasing params for ghostscript])],AA_PARAMS=$withval,
 312                      AA_PARMS="-sDEVICE=x11alpha -dNOPLATFONTS -dGraphicsAlphaBits=4 -dTextAlphaBits=4 -dDOINTERPOLATE"
 313                      )
 314          AC_DEFINE_UNQUOTED(ALPHA_PARAMS, "$AA_PARMS", [Anti-aliasing parameters for Ghostscript.])
 315          AC_MSG_RESULT(Antialiasing parameters for Ghostscript: $AA_PARMS)
 316          ps_backend="(gs)"
 317       fi
 318    fi
 319 fi
 320 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 321 dnl ======================== End of ps checks ===================================
 322
 323 dnl ================== tiff checks ===================================================
 324 AC_ARG_ENABLE(tiff,
 325             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 326
 327 if test "x$enable_tiff" = "xyes"; then
 328     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 329     if test "x$enable_tiff" = "xyes"; then
 330         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 331         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 332     fi
 333     if test "x$enable_tiff" = "xyes"; then
 334             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 335     else
 336             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 337     fi
 338 fi
 339
 340 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 341 dnl ================== end of tiff checks ============================================
 342
 343 dnl ================== djvu checks ===================================================
 344
 345 AC_ARG_ENABLE(djvu,
 346             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=yes)
 347
 348 if test "x$enable_djvu" = "xyes"; then
 349     DJVULIBRE_REQUIRED=3.5.17
 350     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 351
 352     if test "x$enable_djvu" = "xyes"; then
 353         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 354     else
 355         AC_MSG_WARN([
 356 ** Djvu support is disabled since a recent version of the djvulibre
 357 ** library was not found. You need at least djvulibre-3.5.17 which
 358 ** can be found on http://djvulibre.djvuzone.org
 359 ])
 360     fi
 361 fi
 362
 363 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 364
 365 dnl ================== End of djvu checks ===================================================
 366
 367 dnl ================== dvi checks ===================================================
 368
 369 AC_ARG_ENABLE(dvi,
 370             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=yes)
 371
 372 AC_ARG_ENABLE(t1lib,
 373             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 374
 375 if test "x$enable_dvi" = "xyes"; then
 376     AC_C_CONST
 377     AC_C_INLINE
 378     AC_TYPE_SIZE_T
 379     AC_CHECK_SIZEOF(long, 4)
 380     AC_CHECK_SIZEOF(int, 4)
 381     AC_CHECK_SIZEOF(short, 2)
 382     AC_CHECK_SIZEOF(void *, 4)
 383     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 384
 385     if test "x$enable_dvi" = "xyes"; then
 386         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 387     else
 388         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 389     fi
 390 fi
 391 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 392
 393 if test "x$enable_dvi" = "xyes"; then
 394     if test "x$enable_type1_fonts" = "xyes"; then
 395         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 396     fi
 397
 398     if test "x$enable_type1_fonts" = xyes; then
 399         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 400     fi
 401 else
 402     enable_type1_fonts=no
 403 fi
 404 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 405
 406 dnl ================== End of dvi checks ===================================================
 407
 408 dnl ================== pixbuf checks ===================================================
 409
 410 AC_ARG_ENABLE(pixbuf,
 411             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 412 if test "x$enable_pixbuf" = "xyes"; then
 413         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 414 fi
 415 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 416
 417 dnl ================== End of pixbuf checks ===================================================
 418
 419 dnl ================== comic book checks ===================================================
 420
 421 AC_ARG_ENABLE(comics,
 422         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=yes)
 423 if test "x$enable_comics" = "xyes"; then
 424         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 425 fi
 426 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 427
 428 dnl ================== End of comic book checks ============================================
 429
 430 dnl ================== impress book checks ===================================================
 431
 432 AC_ARG_ENABLE(impress,
 433         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 434 if test "x$enable_impress" = "xyes"; then
 435         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 436 fi
 437 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 438
 439 dnl ================== End of impress book checks ============================================
 440
 441 dnl =================== Mime types list ====================================================
 442
 443 if test "x$enable_pdf" = "xyes" ; then
 444         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 445 fi
 446 if test "x$enable_ps" = "xyes" ; then
 447         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 448 fi
 449 if test "x$enable_dvi" = "xyes"; then
 450         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;"
 451 fi
 452 if test "x$enable_djvu" = "xyes"; then
 453         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 454 fi
 455 if test "x$enable_tiff" = "xyes"; then
 456         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 457 fi
 458 if test "x$enable_comics" = "xyes"; then
 459         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;"
 460 fi
 461 if test "x$enable_pixbuf" = "xyes"; then
 462         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 463 fi
 464 if test "x$enable_impress" = "xyes"; then
 465         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 466 fi
 467 AC_SUBST(EVINCE_MIME_TYPES)
 468
 469 AC_CONFIG_FILES([
 470 backend/Makefile
 471 backend/comics/Makefile
 472 backend/djvu/Makefile
 473 backend/dvi/Makefile
 474 backend/dvi/mdvi-lib/Makefile
 475 backend/impress/Makefile
 476 backend/pdf/Makefile
 477 backend/pixbuf/Makefile
 478 backend/ps/Makefile
 479 backend/tiff/Makefile
 480 cut-n-paste/Makefile
 481 cut-n-paste/gedit-message-area/Makefile
 482 cut-n-paste/toolbar-editor/Makefile
 483 cut-n-paste/zoom-control/Makefile
 484 cut-n-paste/totem-screensaver/Makefile
 485 data/evince.desktop.in
 486 data/Makefile
 487 data/icons/Makefile
 488 data/icons/16x16/Makefile
 489 data/icons/16x16/apps/Makefile
 490 data/icons/16x16/actions/Makefile
 491 data/icons/22x22/Makefile
 492 data/icons/22x22/apps/Makefile
 493 data/icons/22x22/actions/Makefile
 494 data/icons/24x24/Makefile
 495 data/icons/24x24/apps/Makefile
 496 data/icons/24x24/actions/Makefile
 497 data/icons/32x32/Makefile
 498 data/icons/32x32/actions/Makefile
 499 data/icons/48x48/Makefile
 500 data/icons/48x48/apps/Makefile
 501 data/icons/48x48/actions/Makefile
 502 data/icons/scalable/Makefile
 503 data/icons/scalable/apps/Makefile
 504 help/Makefile
 505 help/reference/Makefile
 506 help/reference/version.xml
 507 libdocument/Makefile
 508 Makefile
 509 po/Makefile.in
 510 properties/Makefile
 511 shell/Makefile
 512 test/Makefile
 513 thumbnailer/Makefile
 514 ])
 515
 516 AC_OUTPUT
 517
 518 echo "
 519 Configure summary:
 520         GNOME Support......:  $WITH_GNOME
 521         Print Support......:  $enable_print
 522         Keyring Support....:  $WITH_KEYRING
 523         DBUS Support.......:  $enable_dbus
 524         Nautilus Plugin....:  $HAVE_NAUTILUS
 525         Thumbnailer........:  $ENABLE_THUMBNAILER
 526         Gtk-Doc Support....:  $enable_gtk_doc
 527
 528         PDF Backend........:  $enable_pdf
 529         PostScript Backend.:  $enable_ps $ps_backend
 530         TIFF Backend.......:  $enable_tiff
 531         DJVU Backend.......:  $enable_djvu
 532         DVI Backend........:  $enable_dvi
 533         Pixbuf Backend.....:  $enable_pixbuf
 534         Comics Backend.....:  $enable_comics
 535         Impress Backend....:  $enable_impress
 536 "