configure.ac

   1 # *****************************************************************************
   2 # Versioning
   3 # *****************************************************************************
   4
   5 m4_define([ev_major_version],[2])
   6 m4_define([ev_minor_version],[26])
   7 m4_define([ev_micro_version],[0])
   8 m4_define([ev_extra_version],[])
   9 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version()ev_extra_version])
  10
  11 # The evince API version
  12 m4_define([ev_api_version], [2.25])
  13
  14 # Libtool versioning. The backend and view libraries have separate versions.
  15 # Before making a release, the libtool version should be modified.
  16 # The string is of the form C:R:A.
  17 # - If interfaces have been changed or added, but binary compatibility has
  18 #   been preserved, change to C+1:0:A+1
  19 # - If binary compatibility has been broken (eg removed or changed interfaces)
  20 #   change to C+1:0:0
  21 # - If the interface is the same as the previous version, change to C:R+1:A
  22
  23 # Libtool version of the backend library
  24 m4_define([ev_document_lt_current],[1])
  25 m4_define([ev_document_lt_revision],[0])
  26 m4_define([ev_document_lt_age],[0])
  27 m4_define([ev_document_lt_version_info],[ev_document_lt_current:ev_document_lt_revision:ev_document_lt_age])
  28 m4_define([ev_document_lt_current_minus_age],[m4_eval(ev_document_lt_current - ev_document_lt_age)])
  29
  30 # Libtool version of the view library
  31 m4_define([ev_view_lt_current],[1])
  32 m4_define([ev_view_lt_revision],[0])
  33 m4_define([ev_view_lt_age],[0])
  34 m4_define([ev_view_lt_version_info],[ev_view_lt_current:ev_view_lt_revision:ev_view_lt_age])
  35 m4_define([ev_view_lt_current_minus_age],[m4_eval(ev_view_lt_current - ev_view_lt_age)])
  36
  37 # Binary version for the document backends
  38 m4_define([ev_binary_version],[ev_document_lt_current])
  39
  40 # *****************************************************************************
  41
  42 AC_PREREQ([2.57])
  43 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
  44 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-dist-gzip])
  45
  46 AM_CONFIG_HEADER(config.h)
  47
  48 AM_MAINTAINER_MODE
  49
  50 AM_PROG_LIBTOOL
  51
  52 AC_ISC_POSIX
  53 AC_PROG_CC
  54 AM_PROG_CC_STDC
  55 AM_PROG_CC_C_O
  56 AC_PROG_CXX
  57 AC_STDC_HEADERS
  58 IT_PROG_INTLTOOL([0.35.0])
  59 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  60 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  61
  62 GNOME_COMMON_INIT
  63 GNOME_DOC_INIT
  64 GNOME_MAINTAINER_MODE_DEFINES
  65 GNOME_COMPILE_WARNINGS
  66 GNOME_CXX_WARNINGS
  67
  68 GTK_DOC_CHECK(1.0)
  69
  70 GETTEXT_PACKAGE=evince
  71 AC_SUBST(GETTEXT_PACKAGE)
  72 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  73 AM_GLIB_GNU_GETTEXT
  74
  75 dnl check for win32 platform
  76 AC_MSG_CHECKING([for Win32 platform])
  77 case "$host" in
  78   *-*-mingw*|*-*-cygwin*)
  79     platform_win32=yes
  80     AC_CHECK_TOOL(WINDRES, windres)
  81     ;;
  82   *)
  83     platform_win32=no
  84     ;;
  85 esac
  86 AC_MSG_RESULT([$platform_win32])
  87 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
  88
  89 AC_MSG_CHECKING([for native Win32])
  90 case "$host" in
  91   *-*-mingw*)
  92     os_win32=yes
  93     ;;
  94   *)
  95     os_win32=no
  96     ;;
  97 esac
  98 AC_MSG_RESULT([$os_win32])
  99 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 100
 101 dnl Check dependencies
 102
 103 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
 104 # BACKEND_CFLAGS   for backend implementations.
 105 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
 106 # FRONTEND_LIBS
 107 # SHELL_CFLAGS     for shell implementation.
 108 # SHELL_LIBS
 109
 110 DBUS_GLIB_REQUIRED=0.70
 111 GTK_REQUIRED=2.14.0
 112 GLIB_REQUIRED=2.18.0
 113 KEYRING_REQUIRED=2.22.0
 114 AC_SUBST([GLIB_REQUIRED])
 115 AC_SUBST([GTK_REQUIRED])
 116
 117 GNOME_ICON_THEME_REQUIRED=2.17.1
 118 LIBXML_REQUIRED=2.5.0
 119
 120 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
 121 PKG_CHECK_MODULES(LIBVIEW, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 122 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
 123 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 124 PKG_CHECK_MODULES(PREVIEWER, gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 125 PKG_CHECK_MODULES(SHELL_CORE, libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED gthread-2.0)
 126
 127 if test "$os_win32" = no; then
 128         PKG_CHECK_MODULES(SMCLIENT, gtk+-2.0 gthread-2.0 sm >= 1.0.0)
 129 else
 130         PKG_CHECK_MODULES(SMCLIENT, gtk+-2.0 gthread-2.0)
 131 fi
 132
 133 AC_SUBST(SMCLIENT_CFLAGS)
 134 AC_SUBST(SMCLIENT_LIBS)
 135
 136 BACKEND_LIBTOOL_FLAGS="-module -avoid-version -no-undefined -export-symbols \$(top_srcdir)/backend/backend.symbols"
 137 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
 138
 139 dnl ===== Check special functions
 140 evince_save_LIBS=$LIBS
 141 LIBS="$LIBS $BACKEND_LIBS"
 142 AC_CHECK_FUNCS(cairo_format_stride_for_width)
 143 LIBS=$evince_save_LIBS
 144
 145 dnl ========= Check for Keyring
 146 AC_ARG_WITH(keyring,
 147         AC_HELP_STRING([--without-keyring],[disable the use of gnome-keyring]),
 148         [case "${withval}" in
 149         yes) WITH_KEYRING=yes ;;
 150         no) WITH_KEYRING=no ;;
 151         *) AC_MSG_ERROR(bad value ${withval} for --with-keyring) ;;
 152         esac],
 153         [WITH_KEYRING=yes]) dnl Default value
 154 AM_CONDITIONAL(WITH_KEYRING, test x$WITH_KEYRING = "xyes")
 155
 156 if test x$WITH_KEYRING = "xyes"; then
 157         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
 158         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
 159 fi
 160
 161 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
 162 AC_SUBST(GLIB_GENMARSHAL)
 163
 164 dnl ========= Check for DBUS
 165 AC_ARG_ENABLE(dbus,
 166         [AC_HELP_STRING([--enable-dbus], [Compile with support for dbus])],
 167         enable_dbus="$enableval",enable_dbus=yes)
 168 if test "x$enable_dbus" != "xno"; then
 169         PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
 170         [enable_dbus=yes],[enable_dbus=no])
 171
 172         if test "x$enable_dbus" = "xno"; then
 173            AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
 174         fi
 175
 176         if test "x$enable_dbus" = "xyes" ; then
 177                 AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 178
 179                 if test x$DBUS_BINDING_TOOL = "xno" ; then
 180                         AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 181                 fi
 182
 183                 AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 184         fi
 185 fi
 186
 187 AC_SUBST([DBUS_CFLAGS])
 188 AC_SUBST([DBUS_LIBS])
 189
 190 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
 191 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
 192
 193 dnl ========= Check for GConf
 194
 195 AC_MSG_CHECKING([whether GConf support is requested])
 196 AC_ARG_WITH([gconf],
 197   [AS_HELP_STRING([--without-gconf],[disable the use of gconf])],
 198   [],[with_gconf=yes])
 199 AC_MSG_RESULT([$with_gconf])
 200
 201 AM_CONDITIONAL([WITH_GCONF],[test "$with_gconf" = "yes"])
 202
 203 if test "$with_gconf" = "yes"; then
 204    PKG_CHECK_MODULES([GCONF],[gconf-2.0])
 205    AC_DEFINE([WITH_GCONF],[1],[Define if GConf support is enabled])
 206 fi
 207
 208 AM_GCONF_SOURCE_2
 209
 210 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [false])
 211 if test "$with_gconf" = "yes" -a "$GCONFTOOL" = "false"; then
 212   AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 213 fi
 214
 215 dnl Debug mode
 216
 217 AC_ARG_ENABLE([debug],
 218         AC_HELP_STRING([--enable-debug],
 219                         [Turn on evince debug mode]),,
 220                 [enable_debug=no])
 221
 222 if test "x$enable_debug" = "xyes"; then
 223    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 224 fi
 225
 226
 227 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 228 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 229 AC_SUBST(LIBDOCUMENT_CFLAGS)
 230 AC_SUBST(LIBDOCUMENT_LIBS)
 231
 232 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $DEBUG_FLAGS"
 233 LIBVIEW_LIBS="$LIBVIEW_LIBS"
 234 AC_SUBST(LIBVIEW_CFLAGS)
 235 AC_SUBST(LIBVIEW_LIBS)
 236
 237 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 238 AC_SUBST(BACKEND_CFLAGS)
 239 AC_SUBST(BACKEND_LIBS)
 240
 241 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS $KEYRING_CFLAGS $GCONF_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 242 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS $KEYRING_LIBS $GCONF_LIBS -lz"
 243 AC_SUBST(SHELL_CFLAGS)
 244 AC_SUBST(SHELL_LIBS)
 245
 246 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 247 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 248 AC_SUBST(FRONTEND_CFLAGS)
 249 AC_SUBST(FRONTEND_LIBS)
 250
 251 dnl Check for Nautilus property page build
 252 AC_ARG_ENABLE(nautilus,
 253         AC_HELP_STRING([--enable-nautilus],[compile the nautilus plugin]),
 254         [case "${enableval}" in
 255         yes) ENABLE_NAUTILUS=yes ;;
 256         no) ENABLE_NAUTILUS=no ;;
 257         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nautilus) ;;
 258         esac],
 259         [ENABLE_NAUTILUS=yes]) dnl Default value
 260
 261 if test x$ENABLE_NAUTILUS = "xyes" ; then
 262         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
 263                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
 264         NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 265         AC_SUBST(NAUTILUS_EXTENSION_DIR)
 266 fi
 267
 268 AC_SUBST(NAUTILUS_CFLAGS)
 269 AC_SUBST(NAUTILUS_LIBS)
 270 if test x$HAVE_NAUTILUS = "xyes"; then
 271         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
 272 fi
 273 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
 274
 275
 276 dnl Check for thumbnailer build
 277 AC_ARG_ENABLE(thumbnailer,
 278         AC_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer]),
 279         [case "${enableval}" in
 280         yes) ENABLE_THUMBNAILER=yes ;;
 281         no) ENABLE_THUMBNAILER=no ;;
 282         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thumbnailer) ;;
 283         esac],
 284         [ENABLE_THUMBNAILER=yes]) dnl Default value
 285 AM_CONDITIONAL(ENABLE_THUMBNAILER, test x$ENABLE_THUMBNAILER = "xyes")
 286
 287 dnl Check for previewer build
 288 AC_ARG_ENABLE(previewer,
 289         AC_HELP_STRING([--disable-previewer],[disable the GNOME Document Previewer]),
 290         [case "${enableval}" in
 291         yes) ENABLE_PREVIEWER=yes ;;
 292         no) ENABLE_PREVIEWER=no ;;
 293         *) AC_MSG_ERROR(bad value ${enableval} for --enable-previewer) ;;
 294         esac],
 295         [ENABLE_PREVIEWER=yes]) dnl Default value
 296 if test x$ENABLE_PREVIEWER = "xyes" ; then
 297    PKG_CHECK_MODULES(PREVIEWER, gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED,
 298                      [ENABLE_PREVIEWER=yes],[ENABLE_PREVIEWER=no])
 299    if test x$ENABLE_PREVIEWER = "xno" ; then
 300       AC_MSG_WARN([Previewer support is disabled since gtk+-unix-print $GTK_REQUIRED or higher was not found])
 301    fi
 302 fi
 303 AM_CONDITIONAL(ENABLE_PREVIEWER, test x$ENABLE_PREVIEWER = "xyes")
 304 PREVIEWER_CFLAGS="$PREVIEWER_CFLAGS $DEBUG_FLAGS"
 305 PREVIEWER_LIBS="$PREVIEWER_LIBS -lz"
 306 AC_SUBST(PREVIEWER_CFLAGS)
 307 AC_SUBST(PREVIEWER_LIBS)
 308
 309 # ***
 310 # GIR
 311 # ***
 312
 313 AC_MSG_CHECKING([whether GObject introspection is requested])
 314 AC_ARG_ENABLE([introspection],
 315         AS_HELP_STRING([--enable-introspection],[Enable GObject introspection]),
 316         [],[enable_introspection=no])
 317 AC_MSG_RESULT([$enable_introspection])
 318
 319 G_IR_SCANNER=
 320 G_IR_COMPILER=
 321 G_IR_GENERATE=
 322 GIRDIR=
 323 GIRTYPELIBDIR=
 324
 325 if test "$enable_introspection" = "yes"; then
 326   GOBJECT_INTROSPECTION_REQUIRED=0.6
 327   PKG_CHECK_MODULES([GOBJECT_INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
 328
 329   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
 330   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
 331   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
 332   GIRDIR="$($PKG_CONFIG --variable=girdir gobject-introspection-1.0)"
 333   GIRTYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
 334 fi
 335
 336 AC_SUBST([G_IR_SCANNER])
 337 AC_SUBST([G_IR_COMPILER])
 338 AC_SUBST([G_IR_GENERATE])
 339 AC_SUBST([GIRDIR])
 340 AC_SUBST([GIRTYPELIBDIR])
 341
 342 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
 343
 344 dnl ================== portability checks ===========================================
 345
 346 dnl for backtrace()
 347 AC_CHECK_HEADERS([execinfo.h])
 348
 349 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 350   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 351   ],[],[#include <langinfo.h>])
 352
 353 dnl ================== pdf checks ===================================================
 354 AC_ARG_ENABLE(pdf,
 355               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 356
 357 if test "x$enable_pdf" = "xyes"; then
 358     POPPLER_REQUIRED=0.11.0
 359     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED,enable_pdf=yes,enable_pdf=no)
 360
 361     if test "x$enable_pdf" = "xyes"; then
 362             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 363             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 364             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 365
 366             evince_save_LIBS=$LIBS
 367             LIBS="$LIBS $POPPLER_LIBS"
 368             AC_CHECK_FUNCS(poppler_page_render)
 369             AC_CHECK_FUNCS(poppler_layers_iter_new)
 370             LIBS=$evince_save_LIBS
 371
 372             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 373             if test x$enable_cairo_pdf = xyes; then
 374                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 375             fi
 376
 377             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 378             if test x$enable_cairo_ps = xyes; then
 379                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 380             fi
 381     else
 382             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 383     fi
 384 fi
 385
 386 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 387 dnl ================== end of pdf checks ============================================
 388
 389 dnl libspectre (used by ps and dvi backends)
 390 SPECTRE_REQUIRED=0.2.0
 391 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 392 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 393 if test "x$have_spectre" = "xyes"; then
 394    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 395 fi
 396
 397 dnl ================== ps checks ====================================================
 398 AC_ARG_ENABLE(ps,
 399         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 400
 401 if test "x$enable_ps" = "xyes"; then
 402    if test "x$have_spectre" = "xyes"; then
 403       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 404    else
 405       enable_ps="no"
 406       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 407    fi
 408 fi
 409 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 410 dnl ======================== End of ps checks ===================================
 411
 412 dnl ================== tiff checks ===================================================
 413 AC_ARG_ENABLE(tiff,
 414             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 415
 416 if test "x$enable_tiff" = "xyes"; then
 417     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 418     if test "x$enable_tiff" = "xyes"; then
 419         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 420         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 421     fi
 422     if test "x$enable_tiff" = "xyes"; then
 423             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 424     else
 425             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 426     fi
 427 fi
 428
 429 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 430 dnl ================== end of tiff checks ============================================
 431
 432 dnl ================== djvu checks ===================================================
 433
 434 AC_ARG_ENABLE(djvu,
 435             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=yes)
 436
 437 if test "x$enable_djvu" = "xyes"; then
 438     DJVULIBRE_REQUIRED=3.5.17
 439     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 440
 441     if test "x$enable_djvu" = "xyes"; then
 442         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 443     else
 444         AC_MSG_WARN([
 445 ** Djvu support is disabled since a recent version of the djvulibre
 446 ** library was not found. You need at least djvulibre-3.5.17 which
 447 ** can be found on http://djvulibre.djvuzone.org
 448 ])
 449     fi
 450 fi
 451
 452 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 453
 454 dnl ================== End of djvu checks ===================================================
 455
 456 dnl ================== dvi checks ===================================================
 457
 458 AC_ARG_ENABLE(dvi,
 459             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=yes)
 460
 461 AC_ARG_ENABLE(t1lib,
 462             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 463
 464 if test "x$enable_dvi" = "xyes"; then
 465     AC_C_CONST
 466     AC_C_INLINE
 467     AC_TYPE_SIZE_T
 468     AC_CHECK_SIZEOF(long, 4)
 469     AC_CHECK_SIZEOF(int, 4)
 470     AC_CHECK_SIZEOF(short, 2)
 471     AC_CHECK_SIZEOF(void *, 4)
 472     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 473
 474     if test "x$enable_dvi" = "xyes"; then
 475         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 476     else
 477         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 478     fi
 479 fi
 480 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 481
 482 if test "x$enable_dvi" = "xyes"; then
 483     if test "x$enable_type1_fonts" = "xyes"; then
 484         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 485     fi
 486
 487     if test "x$enable_type1_fonts" = xyes; then
 488         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 489     fi
 490 else
 491     enable_type1_fonts=no
 492 fi
 493 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 494
 495 dnl ================== End of dvi checks ===================================================
 496
 497 dnl ================== pixbuf checks ===================================================
 498
 499 AC_ARG_ENABLE(pixbuf,
 500             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 501 if test "x$enable_pixbuf" = "xyes"; then
 502         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 503 fi
 504 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 505
 506 dnl ================== End of pixbuf checks ===================================================
 507
 508 dnl ================== comic book checks ===================================================
 509
 510 AC_ARG_ENABLE(comics,
 511         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=yes)
 512 if test "x$enable_comics" = "xyes"; then
 513         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 514 fi
 515 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 516
 517 dnl ================== End of comic book checks ============================================
 518
 519 dnl ================== impress book checks ===================================================
 520
 521 AC_ARG_ENABLE(impress,
 522         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 523 if test "x$enable_impress" = "xyes"; then
 524         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 525 fi
 526 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 527
 528 dnl ================== End of impress book checks ============================================
 529
 530 dnl =================== Mime types list ====================================================
 531
 532 if test "x$enable_pdf" = "xyes" ; then
 533         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 534 fi
 535 if test "x$enable_ps" = "xyes" ; then
 536         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 537 fi
 538 if test "x$enable_dvi" = "xyes"; then
 539         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 540 fi
 541 if test "x$enable_djvu" = "xyes"; then
 542         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 543 fi
 544 if test "x$enable_tiff" = "xyes"; then
 545         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 546 fi
 547 if test "x$enable_comics" = "xyes"; then
 548         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;"
 549 fi
 550 if test "x$enable_pixbuf" = "xyes"; then
 551         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 552 fi
 553 if test "x$enable_impress" = "xyes"; then
 554         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 555 fi
 556 AC_SUBST(EVINCE_MIME_TYPES)
 557
 558 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 559
 560 # Backends directory
 561
 562 AC_SUBST([backenddir],"\$(libdir)/evince/ev_binary_version/backends")
 563
 564 # Versioning
 565
 566 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
 567 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
 568 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
 569
 570 AC_SUBST([EV_API_VERSION],[ev_api_version])
 571 AC_SUBST([EV_BINARY_VERSION],[ev_binary_version])
 572
 573 AC_SUBST([EV_DOCUMENT_LT_VERSION_INFO],[ev_document_lt_version_info])
 574 AC_SUBST([EV_DOCUMENT_LT_CURRENT_MINUS_AGE],[ev_document_lt_current_minus_age])
 575 AC_SUBST([EV_VIEW_LT_VERSION_INFO],[ev_view_lt_version_info])
 576 AC_SUBST([EV_VIEW_LT_CURRENT_MINUS_AGE],[ev_view_lt_current_minus_age])
 577
 578 # *****************************************************************************
 579
 580 AC_CONFIG_FILES([
 581 backend/Makefile
 582 backend/comics/Makefile
 583 backend/djvu/Makefile
 584 backend/dvi/Makefile
 585 backend/dvi/mdvi-lib/Makefile
 586 backend/impress/Makefile
 587 backend/pdf/Makefile
 588 backend/pixbuf/Makefile
 589 backend/ps/Makefile
 590 backend/tiff/Makefile
 591 cut-n-paste/Makefile
 592 cut-n-paste/gedit-message-area/Makefile
 593 cut-n-paste/gimpcellrenderertoggle/Makefile
 594 cut-n-paste/smclient/Makefile
 595 cut-n-paste/toolbar-editor/Makefile
 596 cut-n-paste/zoom-control/Makefile
 597 cut-n-paste/totem-screensaver/Makefile
 598 data/evince.desktop.in
 599 data/Makefile
 600 data/icons/Makefile
 601 data/icons/16x16/Makefile
 602 data/icons/16x16/apps/Makefile
 603 data/icons/16x16/actions/Makefile
 604 data/icons/22x22/Makefile
 605 data/icons/22x22/apps/Makefile
 606 data/icons/22x22/actions/Makefile
 607 data/icons/24x24/Makefile
 608 data/icons/24x24/apps/Makefile
 609 data/icons/24x24/actions/Makefile
 610 data/icons/32x32/Makefile
 611 data/icons/32x32/actions/Makefile
 612 data/icons/48x48/Makefile
 613 data/icons/48x48/apps/Makefile
 614 data/icons/48x48/actions/Makefile
 615 data/icons/scalable/Makefile
 616 data/icons/scalable/apps/Makefile
 617 help/Makefile
 618 help/reference/Makefile
 619 help/reference/libdocument/Makefile
 620 help/reference/libdocument/version.xml
 621 help/reference/libview/Makefile
 622 help/reference/libview/version.xml
 623 help/reference/shell/Makefile
 624 help/reference/shell/version.xml
 625 libdocument/Makefile
 626 libdocument/ev-version.h
 627 libmisc/Makefile
 628 libview/Makefile
 629 Makefile
 630 po/Makefile.in
 631 previewer/Makefile
 632 properties/Makefile
 633 shell/Makefile
 634 test/Makefile
 635 thumbnailer/Makefile
 636 ])
 637
 638 AC_CONFIG_FILES(evince-document-[]ev_api_version[].pc:evince-document.pc.in)
 639 AC_CONFIG_FILES(evince-view-[]ev_api_version[].pc:evince-view.pc.in)
 640
 641 AC_OUTPUT
 642
 643 echo "
 644 Configure summary:
 645         GConf Support......:  $with_gconf
 646         Keyring Support....:  $WITH_KEYRING
 647         DBUS Support.......:  $enable_dbus
 648         Nautilus Plugin....:  $HAVE_NAUTILUS
 649         Thumbnailer........:  $ENABLE_THUMBNAILER
 650         Previewer..........:  $ENABLE_PREVIEWER
 651         Gtk-Doc Support....:  $enable_gtk_doc
 652         Debug mode.........:  $enable_debug
 653         GObj. Introspection:  $enable_introspection
 654
 655         PDF Backend........:  $enable_pdf
 656         PostScript Backend.:  $enable_ps
 657         TIFF Backend.......:  $enable_tiff
 658         DJVU Backend.......:  $enable_djvu
 659         DVI Backend........:  $enable_dvi
 660         Pixbuf Backend.....:  $enable_pixbuf
 661         Comics Backend.....:  $enable_comics
 662         Impress Backend....:  $enable_impress
 663 "