configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.57)
   4 AC_INIT(evince, 0.5.0)
   5 AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)
   6
   7 AM_CONFIG_HEADER(config.h)
   8
   9 AM_MAINTAINER_MODE
  10
  11 AM_PROG_LIBTOOL
  12
  13 AC_ISC_POSIX
  14 AC_PROG_CC
  15 AM_PROG_CC_STDC
  16 AC_PROG_CXX
  17 AC_STDC_HEADERS
  18 AC_PROG_INTLTOOL
  19 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  20 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  21
  22 GNOME_COMMON_INIT
  23 GNOME_DOC_INIT
  24 GNOME_MAINTAINER_MODE_DEFINES
  25 GNOME_COMPILE_WARNINGS
  26 GNOME_CXX_WARNINGS
  27 GNOME_DEBUG_CHECK
  28
  29 ALL_LINGUAS="be bg bn ca cs cy da de el en_CA en_GB es et eu fa fi fr gl gu he hi hu id it ja ko ku lt mk nb ne nl no pa pl pt pt_BR ro ru rw sk sq sr sr@Latn sv th tr uk vi wa zh_CN zh_HK zh_TW"
  30
  31 AM_GLIB_GNU_GETTEXT
  32
  33 GETTEXT_PACKAGE=AC_PACKAGE_NAME
  34 AC_SUBST(GETTEXT_PACKAGE)
  35 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package.])
  36
  37 dnl Check dependencies
  38
  39 # LIB_CFLAGS       for helpers and generic widgets. (lib, cut-and-paste)
  40 # BACKEND_CFLAGS   for backend implementations.
  41 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
  42 # FRONTEND_LIBS
  43 # SHELL_CFLAGS     for shell implementation.
  44 # SHELL_LIBS
  45
  46 POPPLER_REQUIRED=0.5.0
  47 DBUS_GLIB_REQUIRED=0.33
  48 GTK_REQUIRED=2.6.0
  49 LIBGNOMEUI_REQUIRED=2.6.0
  50 KEYRING_REQUIRED=0.4.0
  51 LIBGNOMEPRINTUI_REQUIRED=2.5.1
  52
  53 PKG_CHECK_MODULES(LIB, gtk+-2.0 >= $GTK_REQUIRED libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED)
  54 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED gnome-vfs-2.0)
  55 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED libglade-2.0 poppler-glib >= $POPPLER_REQUIRED)
  56 PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED)
  57 PKG_CHECK_MODULES(SHELL_CORE, gtk+-2.0 >= $GTK_REQUIRED libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED gnome-vfs-2.0 libglade-2.0 gconf-2.0 poppler-glib >= $POPPLER_REQUIRED gnome-keyring-1 >= $KEYRING_REQUIRED)
  58
  59 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
  60 AC_SUBST(GLIB_GENMARSHAL)
  61
  62
  63 dnl ========= Check for libgnomeprintui
  64 AC_ARG_ENABLE(gnome-print,
  65         [AC_HELP_STRING([--disable-gnome-print], [Compile without print support])],
  66         enable_gnome_print="$enableval",
  67         enable_gnome_print=yes)
  68
  69 if test x$enable_gnome_print = xyes; then
  70         PKG_CHECK_MODULES(GNOME_PRINT,
  71                 libgnomeprintui-2.2 >= $LIBGNOMEPRINTUI_REQUIRED,
  72                 enable_gnome_print=yes, enable_gnome_print=no)
  73 fi
  74
  75 AC_SUBST(GNOME_PRINT_CFLAGS)
  76 AC_SUBST(GNOME_PRINT_LIBS)
  77
  78 if test x$enable_gnome_print = xyes; then
  79         AC_DEFINE([WITH_GNOME_PRINT],[1],[Enable Print Support.])
  80 fi
  81
  82 AM_CONDITIONAL(WITH_GNOME_PRINT, test x$enable_gnome_print = xyes)
  83
  84 dnl ========= Check for DBUS
  85 PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
  86         [enable_dbus=yes],[enable_dbus=no])
  87 AC_SUBST([DBUS_CFLAGS])
  88 AC_SUBST([DBUS_LIBS])
  89
  90 if test "x$enable_dbus" = "xno"; then
  91         AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
  92 fi
  93
  94 if test "x$enable_dbus" = "xyes" ; then
  95         AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
  96
  97         if test x$DBUS_BINDING_TOOL = "xno" ; then
  98                 AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
  99         fi
 100
 101         AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 102
 103         DBUS_VERSION=`$PKG_CONFIG --modversion dbus-glib-1 | sed 's/0\.\([[0-9]]*\)\.\{0,1\}\([[0-9]]*\)/\1/'`
 104         AC_DEFINE_UNQUOTED(DBUS_VERSION, $DBUS_VERSION, [DBUS version.])
 105 fi
 106
 107 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS"
 108 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS -lz"
 109 AC_SUBST(SHELL_CFLAGS)
 110 AC_SUBST(SHELL_LIBS)
 111
 112 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS"
 113 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 114 AC_SUBST(FRONTEND_CFLAGS)
 115 AC_SUBST(FRONTEND_LIBS)
 116
 117 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
 118 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
 119
 120 dnl Check for Nautilus property page build
 121 AC_ARG_ENABLE(nautilus,
 122         AC_HELP_STRING([--enable-nautilus],[compile the nautilus plugin]),
 123         [case "${enableval}" in
 124         yes) ENABLE_NAUTILUS=yes ;;
 125         no) ENABLE_NAUTILUS=no ;;
 126         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nautilus) ;;
 127         esac],
 128         [ENABLE_NAUTILUS=yes]) dnl Default value
 129
 130 if test x$ENABLE_NAUTILUS = "xyes" ; then
 131         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
 132                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
 133 fi
 134
 135 AC_SUBST(NAUTILUS_CFLAGS)
 136 AC_SUBST(NAUTILUS_LIBS)
 137 if test x$HAVE_NAUTILUS = "xyes"; then
 138         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
 139 fi
 140 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
 141
 142 dnl Check for functions not present in gtk 2.6
 143 evince_save_LIBS=$LIBS
 144 LIBS="$LIBS $FRONTEND_CORE_LIBS"
 145 AC_CHECK_FUNCS(gtk_icon_view_get_visible_range)
 146 AC_CHECK_FUNCS(gtk_window_present_with_time)
 147 AC_CHECK_FUNCS(g_file_set_contents)
 148 LIBS=$evince_save_LIBS
 149
 150 dnl GConf configuration
 151 AM_GCONF_SOURCE_2
 152
 153 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
 154 if test "x$GCONFTOOL" = "xno"; then
 155         AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 156 fi
 157
 158 dnl ================== portability checks ===========================================
 159
 160 dnl for backtrace()
 161 AC_CHECK_HEADERS([execinfo.h])
 162
 163 dnl ================== ggv checks ===================================================
 164 AC_ARG_ENABLE(ps,
 165         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 166
 167 if test x$enable_ps = xyes; then
 168         AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 169 fi
 170
 171 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 172
 173 if test x$enable_ps = xyes; then
 174
 175 dnl check for GS version
 176 AC_MSG_CHECKING(for Ghostscript version...)
 177 GS_VERSION=`gs --version | head -n 1 | sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
 178 AC_MSG_RESULT(found $GS_VERSION)
 179 if test "$GS_VERSION" -lt "7"; then
 180         AC_MSG_ERROR([You need Ghostscript version >= 7 in order to run evince])
 181 fi
 182
 183 AC_ARG_WITH(gs-aa-params,
 184             [AC_HELP_STRING([--with-gs-aa-params], [Define antialiasing params for ghostscript])],AA_PARAMS=$withval,
 185             AA_PARMS="-sDEVICE=x11alpha -dNOPLATFONTS -dGraphicsAlphaBits=4 -dTextAlphaBits=4 -dDOINTERPOLATE"
 186             )
 187 AC_DEFINE_UNQUOTED(ALPHA_PARAMS, "$AA_PARMS", [Anti-aliasing parameters for Ghostscript.])
 188 AC_MSG_RESULT(Antialiasing parameters for Ghostscript: $AA_PARMS)
 189
 190 fi
 191 dnl ======================== End of ggv checks =================================
 192
 193 dnl ================== tiff checks ===================================================
 194 AC_ARG_ENABLE(tiff,
 195             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 196
 197 if test "x$enable_tiff" = "xyes"; then
 198     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 199     if test "x$enable_tiff" = "xyes"; then
 200         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 201         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 202     fi
 203     if test "x$enable_tiff" = "xyes"; then
 204             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 205             FRONTEND_LIBS="$FRONTEND_LIBS -ltiff"
 206             SHELL_LIBS="$SHELL_LIBS -ltiff"
 207     else
 208             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 209     fi
 210 fi
 211
 212 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 213 dnl ================== end of tiff checks ============================================
 214
 215 dnl ================== djvu checks ===================================================
 216
 217 AC_ARG_ENABLE(djvu,
 218             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=no)
 219
 220 if test "x$enable_djvu" = "xyes"; then
 221     AC_CHECK_HEADERS([libdjvu/ddjvuapi.h],enable_djvu=yes,enable_djvu=no,)
 222
 223     if test "x$enable_djvu" = "xyes"; then
 224         AC_CHECK_LIB([djvulibre],ddjvu_context_create,enable_djvu=yes,enable_djvu=no,"-lpthread")
 225         AC_CHECK_LIB([djvulibre],ddjvu_document_get_pageinfo,enable_djvu=yes,enable_djvu=no,"-lpthread")
 226     fi
 227
 228     if test "x$enable_djvu" = "xyes"; then
 229         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 230     else
 231         AC_MSG_WARN([
 232 ** Djvu support is disabled since a recent version of the djvulibre
 233 ** library was not found. You need at least djvulibre-3.5.15 which
 234 ** can be found on http://djvulibre.djvuzone.org
 235 ])
 236     fi
 237 fi
 238
 239 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 240
 241 dnl ================== End of djvu checks ===================================================
 242
 243 dnl ================== dvi checks ===================================================
 244
 245 AC_ARG_ENABLE(dvi,
 246             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=no)
 247
 248 AC_ARG_ENABLE(t1lib,
 249             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 250
 251 if test "x$enable_dvi" = "xyes"; then
 252     AC_C_CONST
 253     AC_C_INLINE
 254     AC_TYPE_SIZE_T
 255     AC_CHECK_SIZEOF(long, 4)
 256     AC_CHECK_SIZEOF(int, 4)
 257     AC_CHECK_SIZEOF(short, 2)
 258     AC_CHECK_SIZEOF(void *, 4)
 259     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 260
 261     if test "x$enable_dvi" = "xyes"; then
 262         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 263     else
 264         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 265     fi
 266 fi
 267 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 268
 269 if test "x$enable_dvi" = "xyes"; then
 270     if test "x$enable_type1_fonts" = "xyes"; then
 271         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 272     fi
 273
 274     if test "x$enable_type1_fonts" = xyes; then
 275         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 276     fi
 277 else
 278     enable_type1_fonts=no
 279 fi
 280 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 281
 282 dnl ================== End of dvi checks ===================================================
 283
 284 dnl ================== pixbuf checks ===================================================
 285
 286 AC_ARG_ENABLE(pixbuf,
 287             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 288 if test "x$enable_pixbuf" = "xyes"; then
 289         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 290 fi
 291 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 292
 293 dnl ================== End of pixbuf checks ===================================================
 294
 295 dnl ================== comic book checks ===================================================
 296
 297 AC_ARG_ENABLE(comics,
 298         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=no)
 299 if test "x$enable_comics" = "xyes"; then
 300         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 301 fi
 302 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 303
 304 dnl ================== End of comic book checks ============================================
 305
 306 dnl =================== Mime types list ====================================================
 307
 308 EVINCE_MIME_TYPES="application/pdf"
 309
 310 if test "x$disable_ps" = "xno" ; then
 311         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;application/postscript;application/x-gzpostscript"
 312 fi
 313 if test "x$enable_dvi" = "xyes"; then
 314         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;application/x-dvi"
 315 fi
 316 if test "x$enable_djvu" = "xyes"; then
 317         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;image/vnd.djvu"
 318 fi
 319 if test "x$enable_tiff" = "xyes"; then
 320         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;image/tiff"
 321 fi
 322 if test "x$enable_comics" = "xyes"; then
 323         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;application/x-cbr;application/x-cbz"
 324 fi
 325 AC_SUBST(EVINCE_MIME_TYPES)
 326
 327 AC_CONFIG_FILES([
 328 Makefile
 329 cut-n-paste/Makefile
 330 cut-n-paste/recent-files/Makefile
 331 cut-n-paste/zoom-control/Makefile
 332 cut-n-paste/toolbar-editor/Makefile
 333 data/Makefile
 334 data/evince.desktop.in
 335 lib/Makefile
 336 pdf/Makefile
 337 pixbuf/Makefile
 338 tiff/Makefile
 339 ps/Makefile
 340 djvu/Makefile
 341 dvi/Makefile
 342 dvi/mdvi-lib/Makefile
 343 comics/Makefile
 344 po/Makefile.in
 345 backend/Makefile
 346 properties/Makefile
 347 shell/Makefile
 348 thumbnailer/Makefile
 349 help/Makefile
 350 ])
 351
 352 AC_OUTPUT
 353
 354 echo "
 355 Configure summary:
 356         Print Support......:  $enable_gnome_print
 357         DBUS Support.......:  $enable_dbus
 358         Nautilus Plugin....:  $HAVE_NAUTILUS
 359
 360         PostScript Backend.:  $enable_ps
 361         TIFF Backend.......:  $enable_tiff
 362         DJVU Backend.......:  $enable_djvu
 363         DVI Backend........:  $enable_dvi
 364         Pixbuf Backend.....:  $enable_pixbuf
 365         Comics Backend.....:  $enable_comics
 366 "