configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.57)
   4 AC_INIT([Evince],[0.8.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
   5 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-dist-gzip])
   6
   7 AM_CONFIG_HEADER(config.h)
   8
   9 AM_MAINTAINER_MODE
  10
  11 AM_PROG_LIBTOOL
  12
  13 AC_ISC_POSIX
  14 AC_PROG_CC
  15 AM_PROG_CC_STDC
  16 AC_PROG_CXX
  17 AC_STDC_HEADERS
  18 IT_PROG_INTLTOOL([0.35.0])
  19 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  20 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  21
  22 GNOME_COMMON_INIT
  23 GNOME_DOC_INIT
  24 GNOME_MAINTAINER_MODE_DEFINES
  25 GNOME_COMPILE_WARNINGS
  26 GNOME_CXX_WARNINGS
  27 GNOME_DEBUG_CHECK
  28
  29 GTK_DOC_CHECK(1.0)
  30
  31 GETTEXT_PACKAGE=evince
  32 AC_SUBST(GETTEXT_PACKAGE)
  33 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  34 AM_GLIB_GNU_GETTEXT
  35
  36 dnl Check dependencies
  37
  38 # LIB_CFLAGS       for helpers and generic widgets. (lib, cut-and-paste)
  39 # BACKEND_CFLAGS   for backend implementations.
  40 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
  41 # FRONTEND_LIBS
  42 # SHELL_CFLAGS     for shell implementation.
  43 # SHELL_LIBS
  44
  45 DBUS_GLIB_REQUIRED=0.70
  46 GTK_REQUIRED=2.8.15
  47 KEYRING_REQUIRED=0.4.0
  48
  49 LIBGNOMEUI_REQUIRED=2.14.0
  50 LIBGNOME_REQUIRED=2.14.0
  51 LIBGNOMEPRINTUI_REQUIRED=2.6.0
  52 GNOME_ICON_THEME_REQUIRED=2.17.1
  53 LIBXML_REQUIRED=2.5.0
  54
  55 GTK_PRINT_REQUIRED=2.10.0
  56
  57 PKG_CHECK_MODULES(LIB, gtk+-2.0 >= $GTK_REQUIRED libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED)
  58 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED gnome-vfs-2.0 libgnome-2.0 >= $LIBGNOME_REQUIRED)
  59 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED libglade-2.0 gnome-vfs-2.0)
  60 PKG_CHECK_MODULES(SHELL_CORE, gtk+-2.0 >= $GTK_REQUIRED libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED gnome-vfs-2.0 libglade-2.0 gconf-2.0 gnome-keyring-1 >= $KEYRING_REQUIRED)
  61
  62 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE"
  63 AC_SUBST(BACKEND_CFLAGS)
  64
  65 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
  66 AC_SUBST(GLIB_GENMARSHAL)
  67
  68 dnl ========= Print support
  69 AC_ARG_WITH(print,
  70             [AC_HELP_STRING([--with-print=no/gtk/gnome/auto], [Compile with print support [default=auto]])],
  71             PRINT=$withval,
  72             PRINT="auto")
  73
  74 PKG_CHECK_MODULES(GNOME_PRINT,
  75                   libgnomeprintui-2.2 >= $LIBGNOMEPRINTUI_REQUIRED,
  76                   enable_gnome_print=yes, enable_gnome_print=no)
  77 PKG_CHECK_MODULES(GTK_PRINT,
  78                   gtk+-unix-print-2.0 >= $GTK_PRINT_REQUIRED,
  79                   enable_gtk_print=yes, enable_gtk_print=no)
  80 enable_print=no
  81 if test x$PRINT = xgnome -a x$enable_gnome_print = xyes; then
  82    enable_print=gnome
  83 else
  84    if test x$PRINT = xgtk -a x$enable_gtk_print = xyes; then
  85       enable_print=gtk
  86    else
  87       if test x$PRINT = xauto; then
  88          if test x$enable_gtk_print = xyes; then
  89             enable_print=gtk
  90          else
  91             if test x$enable_gnome_print = xyes; then
  92                enable_print=gnome
  93             fi
  94          fi
  95       fi
  96    fi
  97 fi
  98
  99 if test x$enable_print = xgnome; then
 100    AC_SUBST(GNOME_PRINT_CFLAGS)
 101    AC_SUBST(GNOME_PRINT_LIBS)
 102    AC_DEFINE([WITH_GNOME_PRINT],[1],[Enable GNOME Print Support.])
 103    AC_DEFINE([WITH_PRINT],[1],[Enable Print Support.])
 104 fi
 105
 106 if test x$enable_print = xgtk; then
 107    AC_SUBST(GTK_PRINT_CFLAGS)
 108    AC_SUBST(GTK_PRINT_LIBS)
 109    AC_DEFINE([WITH_GTK_PRINT],[1],[Enable GTK Print Support.])
 110    AC_DEFINE([WITH_PRINT],[1],[Enable Print Support.])
 111 fi
 112
 113 AM_CONDITIONAL(WITH_GNOME_PRINT, test x$enable_print = xgnome)
 114 AM_CONDITIONAL(WITH_GTK_PRINT, test x$enable_print = xgtk)
 115
 116
 117 dnl ========= Check for DBUS
 118 PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
 119         [enable_dbus=yes],[enable_dbus=no])
 120 AC_SUBST([DBUS_CFLAGS])
 121 AC_SUBST([DBUS_LIBS])
 122
 123 if test "x$enable_dbus" = "xno"; then
 124         AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
 125 fi
 126
 127 if test "x$enable_dbus" = "xyes" ; then
 128         AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 129
 130         if test x$DBUS_BINDING_TOOL = "xno" ; then
 131                 AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 132         fi
 133
 134         AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 135 fi
 136
 137 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE"
 138 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS -lz"
 139 AC_SUBST(SHELL_CFLAGS)
 140 AC_SUBST(SHELL_LIBS)
 141
 142 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS"
 143 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 144 AC_SUBST(FRONTEND_CFLAGS)
 145 AC_SUBST(FRONTEND_LIBS)
 146
 147 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
 148 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
 149
 150 dnl Check for Nautilus property page build
 151 AC_ARG_ENABLE(nautilus,
 152         AC_HELP_STRING([--enable-nautilus],[compile the nautilus plugin]),
 153         [case "${enableval}" in
 154         yes) ENABLE_NAUTILUS=yes ;;
 155         no) ENABLE_NAUTILUS=no ;;
 156         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nautilus) ;;
 157         esac],
 158         [ENABLE_NAUTILUS=yes]) dnl Default value
 159
 160 if test x$ENABLE_NAUTILUS = "xyes" ; then
 161         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
 162                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
 163 fi
 164
 165 AC_SUBST(NAUTILUS_CFLAGS)
 166 AC_SUBST(NAUTILUS_LIBS)
 167 if test x$HAVE_NAUTILUS = "xyes"; then
 168         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
 169 fi
 170 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
 171
 172
 173 dnl Check for thumbnailer build
 174 AC_ARG_ENABLE(thumbnailer,
 175         AC_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer]),
 176         [case "${enableval}" in
 177         yes) ENABLE_THUMBNAILER=yes ;;
 178         no) ENABLE_THUMBNAILER=no ;;
 179         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thumbnailer) ;;
 180         esac],
 181         [ENABLE_THUMBNAILER=yes]) dnl Default value
 182 AM_CONDITIONAL(ENABLE_THUMBNAILER, test x$ENABLE_THUMBNAILER = "xyes")
 183
 184
 185 dnl Check for GtkRecent
 186 PKG_CHECK_MODULES(GTK_RECENT, gtk+-2.0 >= 2.10.0,
 187                   [HAVE_GTK_RECENT=yes], [HAVE_GTK_RECENT=no])
 188 if test x$HAVE_GTK_RECENT = xyes; then
 189    AC_DEFINE([HAVE_GTK_RECENT], [1], [defined if GtkRecent is available])
 190 fi
 191 AM_CONDITIONAL(HAVE_GTK_RECENT, test x$HAVE_GTK_RECENT = "xyes")
 192
 193 dnl GConf configuration
 194 AM_GCONF_SOURCE_2
 195
 196 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
 197 if test "x$GCONFTOOL" = "xno"; then
 198         AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 199 fi
 200
 201 dnl ================== portability checks ===========================================
 202
 203 dnl for backtrace()
 204 AC_CHECK_HEADERS([execinfo.h])
 205
 206 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 207   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 208   ],[],[#include <langinfo.h>])
 209
 210 dnl ================== pdf checks ===================================================
 211 AC_ARG_ENABLE(pdf,
 212               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 213
 214 if test "x$enable_pdf" = "xyes"; then
 215     POPPLER_REQUIRED=0.5.4
 216     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED,enable_pdf=yes,enable_pdf=no)
 217
 218     if test "x$enable_pdf" = "xyes"; then
 219             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 220             FRONTEND_LIBS="$FRONTEND_LIBS $POPPLER_LIBS"
 221             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 222             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 223
 224             evince_save_LIBS=$LIBS
 225             LIBS="$LIBS $FRONTEND_LIBS"
 226             AC_CHECK_FUNCS(poppler_page_render)
 227             AC_CHECK_FUNCS(poppler_page_get_duration)
 228             AC_CHECK_FUNCS(poppler_page_get_image_mapping)
 229             LIBS=$evince_save_LIBS
 230
 231             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 232             if test x$enable_cairo_pdf == xyes; then
 233                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 234             fi
 235     else
 236             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 237     fi
 238 fi
 239
 240 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 241 dnl ================== end of pdf checks ============================================
 242
 243 dnl ================== ggv checks ===================================================
 244 AC_ARG_ENABLE(ps,
 245         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 246
 247 if test x$enable_ps = xyes; then
 248         AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 249 fi
 250
 251 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 252
 253 if test x$enable_ps = xyes; then
 254
 255 dnl check for GS version
 256 AC_MSG_CHECKING(for Ghostscript version...)
 257 GS_VERSION=`gs --version | head -n 1 | sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
 258 AC_MSG_RESULT(found $GS_VERSION)
 259 if test "$GS_VERSION" -lt "7"; then
 260         AC_MSG_ERROR([You need Ghostscript version >= 7 in order to run evince])
 261 fi
 262
 263 AC_ARG_WITH(gs-aa-params,
 264             [AC_HELP_STRING([--with-gs-aa-params], [Define antialiasing params for ghostscript])],AA_PARAMS=$withval,
 265             AA_PARMS="-sDEVICE=x11alpha -dNOPLATFONTS -dGraphicsAlphaBits=4 -dTextAlphaBits=4 -dDOINTERPOLATE"
 266             )
 267 AC_DEFINE_UNQUOTED(ALPHA_PARAMS, "$AA_PARMS", [Anti-aliasing parameters for Ghostscript.])
 268 AC_MSG_RESULT(Antialiasing parameters for Ghostscript: $AA_PARMS)
 269
 270 fi
 271 dnl ======================== End of ggv checks =================================
 272
 273 dnl ================== tiff checks ===================================================
 274 AC_ARG_ENABLE(tiff,
 275             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 276
 277 if test "x$enable_tiff" = "xyes"; then
 278     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 279     if test "x$enable_tiff" = "xyes"; then
 280         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 281         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 282     fi
 283     if test "x$enable_tiff" = "xyes"; then
 284             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 285             FRONTEND_LIBS="$FRONTEND_LIBS -ltiff"
 286             SHELL_LIBS="$SHELL_LIBS -ltiff"
 287     else
 288             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 289     fi
 290 fi
 291
 292 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 293 dnl ================== end of tiff checks ============================================
 294
 295 dnl ================== djvu checks ===================================================
 296
 297 AC_ARG_ENABLE(djvu,
 298             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=no)
 299
 300 if test "x$enable_djvu" = "xyes"; then
 301
 302 DJVULIBRE_REQUIRED=3.5.17
 303
 304 PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 305
 306     if test "x$enable_djvu" = "xyes"; then
 307         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 308     else
 309         AC_MSG_WARN([
 310 ** Djvu support is disabled since a recent version of the djvulibre
 311 ** library was not found. You need at least djvulibre-3.5.17 which
 312 ** can be found on http://djvulibre.djvuzone.org
 313 ])
 314     fi
 315 fi
 316
 317 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 318
 319 dnl ================== End of djvu checks ===================================================
 320
 321 dnl ================== dvi checks ===================================================
 322
 323 AC_ARG_ENABLE(dvi,
 324             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=no)
 325
 326 AC_ARG_ENABLE(t1lib,
 327             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 328
 329 if test "x$enable_dvi" = "xyes"; then
 330     AC_C_CONST
 331     AC_C_INLINE
 332     AC_TYPE_SIZE_T
 333     AC_CHECK_SIZEOF(long, 4)
 334     AC_CHECK_SIZEOF(int, 4)
 335     AC_CHECK_SIZEOF(short, 2)
 336     AC_CHECK_SIZEOF(void *, 4)
 337     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 338
 339     if test "x$enable_dvi" = "xyes"; then
 340         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 341     else
 342         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 343     fi
 344 fi
 345 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 346
 347 if test "x$enable_dvi" = "xyes"; then
 348     if test "x$enable_type1_fonts" = "xyes"; then
 349         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 350     fi
 351
 352     if test "x$enable_type1_fonts" = xyes; then
 353         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 354     fi
 355 else
 356     enable_type1_fonts=no
 357 fi
 358 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 359
 360 dnl ================== End of dvi checks ===================================================
 361
 362 dnl ================== pixbuf checks ===================================================
 363
 364 AC_ARG_ENABLE(pixbuf,
 365             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 366 if test "x$enable_pixbuf" = "xyes"; then
 367         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 368 fi
 369 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 370
 371 dnl ================== End of pixbuf checks ===================================================
 372
 373 dnl ================== comic book checks ===================================================
 374
 375 AC_ARG_ENABLE(comics,
 376         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=no)
 377 if test "x$enable_comics" = "xyes"; then
 378         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 379 fi
 380 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 381
 382 dnl ================== End of comic book checks ============================================
 383
 384 dnl ================== impress book checks ===================================================
 385
 386 AC_ARG_ENABLE(impress,
 387         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 388 if test "x$enable_impress" = "xyes"; then
 389         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 390 fi
 391 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 392
 393 dnl ================== End of impress book checks ============================================
 394
 395 dnl =================== Mime types list ====================================================
 396
 397 if test "x$enable_pdf" = "xyes" ; then
 398         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf"
 399 fi
 400 if test "x$enable_ps" = "xyes" ; then
 401         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps"
 402 fi
 403 if test "x$enable_dvi" = "xyes"; then
 404         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;application/x-dvi"
 405 fi
 406 if test "x$enable_djvu" = "xyes"; then
 407         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;image/vnd.djvu"
 408 fi
 409 if test "x$enable_tiff" = "xyes"; then
 410         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;image/tiff"
 411 fi
 412 if test "x$enable_comics" = "xyes"; then
 413         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;application/x-cbr;application/x-cbz"
 414 fi
 415 if test "x$enable_pixbuf" = "xyes"; then
 416         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;image/*"
 417 fi
 418 if test "x$enable_impress" = "xyes"; then
 419         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation"
 420 fi
 421 AC_SUBST(EVINCE_MIME_TYPES)
 422
 423 AC_CONFIG_FILES([
 424 backend/Makefile
 425 backend/comics/Makefile
 426 backend/djvu/Makefile
 427 backend/dvi/Makefile
 428 backend/dvi/mdvi-lib/Makefile
 429 backend/impress/Makefile
 430 backend/pdf/Makefile
 431 backend/pixbuf/Makefile
 432 backend/ps/Makefile
 433 backend/tiff/Makefile
 434 cut-n-paste/Makefile
 435 cut-n-paste/recent-files/Makefile
 436 cut-n-paste/toolbar-editor/Makefile
 437 cut-n-paste/zoom-control/Makefile
 438 cut-n-paste/totem-screensaver/Makefile
 439 data/evince.desktop.in
 440 data/Makefile
 441 data/icons/Makefile
 442 data/icons/16x16/Makefile
 443 data/icons/16x16/apps/Makefile
 444 data/icons/16x16/actions/Makefile
 445 data/icons/22x22/Makefile
 446 data/icons/22x22/apps/Makefile
 447 data/icons/22x22/actions/Makefile
 448 data/icons/24x24/Makefile
 449 data/icons/24x24/apps/Makefile
 450 data/icons/24x24/actions/Makefile
 451 data/icons/48x48/Makefile
 452 data/icons/48x48/apps/Makefile
 453 data/icons/scalable/Makefile
 454 data/icons/scalable/apps/Makefile
 455 help/Makefile
 456 help/reference/Makefile
 457 help/reference/version.xml
 458 libdocument/Makefile
 459 Makefile
 460 po/Makefile.in
 461 properties/Makefile
 462 shell/Makefile
 463 test/Makefile
 464 thumbnailer/Makefile
 465 ])
 466
 467 AC_OUTPUT
 468
 469 echo "
 470 Configure summary:
 471         Print Support......:  $enable_print
 472         DBUS Support.......:  $enable_dbus
 473         Nautilus Plugin....:  $HAVE_NAUTILUS
 474         Thumbnailer........:  $ENABLE_THUMBNAILER
 475         Gtk-Doc Support....:  $enable_gtk_doc
 476
 477         PDF Backend........:  $enable_pdf
 478         PostScript Backend.:  $enable_ps
 479         TIFF Backend.......:  $enable_tiff
 480         DJVU Backend.......:  $enable_djvu
 481         DVI Backend........:  $enable_dvi
 482         Pixbuf Backend.....:  $enable_pixbuf
 483         Comics Backend.....:  $enable_comics
 484         Impress Backend....:  $enable_impress
 485 "