configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 m4_define([ev_major_version],[2])
   4 m4_define([ev_minor_version],[25])
   5 m4_define([ev_micro_version],[5])
   6 m4_define([ev_extra_version],[])
   7 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version()ev_extra_version])
   8
   9 # The evince API version
  10 m4_define([ev_api_version], [2.25])
  11
  12 AC_PREREQ([2.57])
  13 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
  14 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-dist-gzip])
  15
  16 AM_CONFIG_HEADER(config.h)
  17
  18 AM_MAINTAINER_MODE
  19
  20 AM_PROG_LIBTOOL
  21
  22 AC_ISC_POSIX
  23 AC_PROG_CC
  24 AM_PROG_CC_STDC
  25 AC_PROG_CXX
  26 AC_STDC_HEADERS
  27 IT_PROG_INTLTOOL([0.35.0])
  28 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  29 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  30
  31 GNOME_COMMON_INIT
  32 GNOME_DOC_INIT
  33 GNOME_MAINTAINER_MODE_DEFINES
  34 GNOME_COMPILE_WARNINGS
  35 GNOME_CXX_WARNINGS
  36
  37 GTK_DOC_CHECK(1.0)
  38
  39 GETTEXT_PACKAGE=evince
  40 AC_SUBST(GETTEXT_PACKAGE)
  41 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  42 AM_GLIB_GNU_GETTEXT
  43
  44 dnl Check dependencies
  45
  46 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
  47 # BACKEND_CFLAGS   for backend implementations.
  48 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
  49 # FRONTEND_LIBS
  50 # SHELL_CFLAGS     for shell implementation.
  51 # SHELL_LIBS
  52
  53 DBUS_GLIB_REQUIRED=0.70
  54 GTK_REQUIRED=2.12.0
  55 GLIB_REQUIRED=2.18.0
  56 KEYRING_REQUIRED=2.22.0
  57
  58 GNOME_ICON_THEME_REQUIRED=2.17.1
  59 LIBXML_REQUIRED=2.5.0
  60
  61 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
  62 PKG_CHECK_MODULES(LIBVIEW, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
  63 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
  64 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
  65 PKG_CHECK_MODULES(SHELL_CORE, libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED gthread-2.0 gconf-2.0)
  66
  67 PKG_CHECK_MODULES(SMCLIENT, gtk+-2.0 gthread-2.0)
  68 AC_SUBST(SMCLIENT_CFLAGS)
  69 AC_SUBST(SMCLIENT_LIBS)
  70
  71 BACKEND_LIBTOOL_FLAGS="-module -avoid-version"
  72 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
  73
  74 dnl ===== Check special functions
  75 evince_save_LIBS=$LIBS
  76 LIBS="$LIBS $BACKEND_LIBS"
  77 AC_CHECK_FUNCS(cairo_format_stride_for_width)
  78 LIBS=$evince_save_LIBS
  79
  80 AC_ARG_WITH(keyring,
  81         AC_HELP_STRING([--without-keyring],[disable the use of gnome-keyring]),
  82         [case "${withval}" in
  83         yes) WITH_KEYRING=yes ;;
  84         no) WITH_KEYRING=no ;;
  85         *) AC_MSG_ERROR(bad value ${withval} for --with-keyring) ;;
  86         esac],
  87         [WITH_KEYRING=yes]) dnl Default value
  88 AM_CONDITIONAL(WITH_KEYRING, test x$WITH_KEYRING = "xyes")
  89
  90 if test x$WITH_KEYRING = "xyes"; then
  91         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
  92         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
  93 fi
  94
  95 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
  96 AC_SUBST(GLIB_GENMARSHAL)
  97
  98 dnl ========= Check for DBUS
  99 AC_ARG_ENABLE(dbus,
 100         [AC_HELP_STRING([--enable-dbus], [Compile with support for dbus])],
 101         enable_dbus="$enableval",enable_dbus=yes)
 102 if test "x$enable_dbus" != "xno"; then
 103         PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
 104         [enable_dbus=yes],[enable_dbus=no])
 105
 106         if test "x$enable_dbus" = "xno"; then
 107            AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
 108         fi
 109
 110         if test "x$enable_dbus" = "xyes" ; then
 111                 AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 112
 113                 if test x$DBUS_BINDING_TOOL = "xno" ; then
 114                         AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 115                 fi
 116
 117                 AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 118         fi
 119 fi
 120
 121 AC_SUBST([DBUS_CFLAGS])
 122 AC_SUBST([DBUS_LIBS])
 123
 124 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
 125 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
 126
 127 dnl Debug mode
 128 AC_ARG_ENABLE([debug],
 129         AC_HELP_STRING([--enable-debug],
 130                         [Turn on evince debug mode]),,
 131                 [enable_debug=no])
 132
 133 if test "x$enable_debug" = "xyes"; then
 134    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 135 fi
 136
 137
 138 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 139 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 140 AC_SUBST(LIBDOCUMENT_CFLAGS)
 141 AC_SUBST(LIBDOCUMENT_LIBS)
 142
 143 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $DEBUG_FLAGS"
 144 LIBVIEW_LIBS="$LIBVIEW_LIBS"
 145 AC_SUBST(LIBVIEW_CFLAGS)
 146 AC_SUBST(LIBVIEW_LIBS)
 147
 148 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 149 AC_SUBST(BACKEND_CFLAGS)
 150 AC_SUBST(BACKEND_LIBS)
 151
 152 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS $KEYRING_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 153 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS $KEYRING_LIBS -lz"
 154 AC_SUBST(SHELL_CFLAGS)
 155 AC_SUBST(SHELL_LIBS)
 156
 157 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 158 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 159 AC_SUBST(FRONTEND_CFLAGS)
 160 AC_SUBST(FRONTEND_LIBS)
 161
 162 dnl Check for Nautilus property page build
 163 AC_ARG_ENABLE(nautilus,
 164         AC_HELP_STRING([--enable-nautilus],[compile the nautilus plugin]),
 165         [case "${enableval}" in
 166         yes) ENABLE_NAUTILUS=yes ;;
 167         no) ENABLE_NAUTILUS=no ;;
 168         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nautilus) ;;
 169         esac],
 170         [ENABLE_NAUTILUS=yes]) dnl Default value
 171
 172 if test x$ENABLE_NAUTILUS = "xyes" ; then
 173         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
 174                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
 175         NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 176         AC_SUBST(NAUTILUS_EXTENSION_DIR)
 177 fi
 178
 179 AC_SUBST(NAUTILUS_CFLAGS)
 180 AC_SUBST(NAUTILUS_LIBS)
 181 if test x$HAVE_NAUTILUS = "xyes"; then
 182         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
 183 fi
 184 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
 185
 186
 187 dnl Check for thumbnailer build
 188 AC_ARG_ENABLE(thumbnailer,
 189         AC_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer]),
 190         [case "${enableval}" in
 191         yes) ENABLE_THUMBNAILER=yes ;;
 192         no) ENABLE_THUMBNAILER=no ;;
 193         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thumbnailer) ;;
 194         esac],
 195         [ENABLE_THUMBNAILER=yes]) dnl Default value
 196 AM_CONDITIONAL(ENABLE_THUMBNAILER, test x$ENABLE_THUMBNAILER = "xyes")
 197
 198 dnl GConf configuration
 199 AM_GCONF_SOURCE_2
 200
 201 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
 202 if test "x$GCONFTOOL" = "xno"; then
 203         AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 204 fi
 205
 206 dnl ================== portability checks ===========================================
 207
 208 dnl for backtrace()
 209 AC_CHECK_HEADERS([execinfo.h])
 210
 211 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 212   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 213   ],[],[#include <langinfo.h>])
 214
 215 dnl ================== pdf checks ===================================================
 216 AC_ARG_ENABLE(pdf,
 217               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 218
 219 if test "x$enable_pdf" = "xyes"; then
 220     POPPLER_REQUIRED=0.8.0
 221     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED,enable_pdf=yes,enable_pdf=no)
 222
 223     if test "x$enable_pdf" = "xyes"; then
 224             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 225             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 226             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 227
 228             evince_save_LIBS=$LIBS
 229             LIBS="$LIBS $POPPLER_LIBS"
 230             AC_CHECK_FUNCS(poppler_page_render)
 231             AC_CHECK_FUNCS(poppler_layers_iter_new)
 232             LIBS=$evince_save_LIBS
 233
 234             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 235             if test x$enable_cairo_pdf = xyes; then
 236                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 237             fi
 238
 239             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 240             if test x$enable_cairo_ps = xyes; then
 241                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 242             fi
 243     else
 244             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 245     fi
 246 fi
 247
 248 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 249 dnl ================== end of pdf checks ============================================
 250
 251 dnl libspectre (used by ps and dvi backends)
 252 SPECTRE_REQUIRED=0.2.0
 253 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 254 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 255 if test "x$have_spectre" = "xyes"; then
 256    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 257 fi
 258
 259 dnl ================== ps checks ====================================================
 260 AC_ARG_ENABLE(ps,
 261         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 262
 263 if test "x$enable_ps" = "xyes"; then
 264    if test "x$have_spectre" = "xyes"; then
 265       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 266    else
 267       enable_ps="no"
 268       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 269    fi
 270 fi
 271 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 272 dnl ======================== End of ps checks ===================================
 273
 274 dnl ================== tiff checks ===================================================
 275 AC_ARG_ENABLE(tiff,
 276             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 277
 278 if test "x$enable_tiff" = "xyes"; then
 279     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 280     if test "x$enable_tiff" = "xyes"; then
 281         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 282         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 283     fi
 284     if test "x$enable_tiff" = "xyes"; then
 285             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 286     else
 287             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 288     fi
 289 fi
 290
 291 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 292 dnl ================== end of tiff checks ============================================
 293
 294 dnl ================== djvu checks ===================================================
 295
 296 AC_ARG_ENABLE(djvu,
 297             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=yes)
 298
 299 if test "x$enable_djvu" = "xyes"; then
 300     DJVULIBRE_REQUIRED=3.5.17
 301     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 302
 303     if test "x$enable_djvu" = "xyes"; then
 304         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 305     else
 306         AC_MSG_WARN([
 307 ** Djvu support is disabled since a recent version of the djvulibre
 308 ** library was not found. You need at least djvulibre-3.5.17 which
 309 ** can be found on http://djvulibre.djvuzone.org
 310 ])
 311     fi
 312 fi
 313
 314 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 315
 316 dnl ================== End of djvu checks ===================================================
 317
 318 dnl ================== dvi checks ===================================================
 319
 320 AC_ARG_ENABLE(dvi,
 321             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=yes)
 322
 323 AC_ARG_ENABLE(t1lib,
 324             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 325
 326 if test "x$enable_dvi" = "xyes"; then
 327     AC_C_CONST
 328     AC_C_INLINE
 329     AC_TYPE_SIZE_T
 330     AC_CHECK_SIZEOF(long, 4)
 331     AC_CHECK_SIZEOF(int, 4)
 332     AC_CHECK_SIZEOF(short, 2)
 333     AC_CHECK_SIZEOF(void *, 4)
 334     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 335
 336     if test "x$enable_dvi" = "xyes"; then
 337         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 338     else
 339         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 340     fi
 341 fi
 342 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 343
 344 if test "x$enable_dvi" = "xyes"; then
 345     if test "x$enable_type1_fonts" = "xyes"; then
 346         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 347     fi
 348
 349     if test "x$enable_type1_fonts" = xyes; then
 350         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 351     fi
 352 else
 353     enable_type1_fonts=no
 354 fi
 355 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 356
 357 dnl ================== End of dvi checks ===================================================
 358
 359 dnl ================== pixbuf checks ===================================================
 360
 361 AC_ARG_ENABLE(pixbuf,
 362             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 363 if test "x$enable_pixbuf" = "xyes"; then
 364         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 365 fi
 366 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 367
 368 dnl ================== End of pixbuf checks ===================================================
 369
 370 dnl ================== comic book checks ===================================================
 371
 372 AC_ARG_ENABLE(comics,
 373         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=yes)
 374 if test "x$enable_comics" = "xyes"; then
 375         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 376 fi
 377 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 378
 379 dnl ================== End of comic book checks ============================================
 380
 381 dnl ================== impress book checks ===================================================
 382
 383 AC_ARG_ENABLE(impress,
 384         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 385 if test "x$enable_impress" = "xyes"; then
 386         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 387 fi
 388 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 389
 390 dnl ================== End of impress book checks ============================================
 391
 392 dnl =================== Mime types list ====================================================
 393
 394 if test "x$enable_pdf" = "xyes" ; then
 395         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 396 fi
 397 if test "x$enable_ps" = "xyes" ; then
 398         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 399 fi
 400 if test "x$enable_dvi" = "xyes"; then
 401         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 402 fi
 403 if test "x$enable_djvu" = "xyes"; then
 404         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 405 fi
 406 if test "x$enable_tiff" = "xyes"; then
 407         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 408 fi
 409 if test "x$enable_comics" = "xyes"; then
 410         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;"
 411 fi
 412 if test "x$enable_pixbuf" = "xyes"; then
 413         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 414 fi
 415 if test "x$enable_impress" = "xyes"; then
 416         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 417 fi
 418 AC_SUBST(EVINCE_MIME_TYPES)
 419
 420 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 421
 422 # Versioning
 423
 424 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
 425 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
 426 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
 427
 428 AC_SUBST([EV_API_VERSION],[ev_api_version])
 429
 430 # *****************************************************************************
 431
 432 AC_CONFIG_FILES([
 433 backend/Makefile
 434 backend/comics/Makefile
 435 backend/djvu/Makefile
 436 backend/dvi/Makefile
 437 backend/dvi/mdvi-lib/Makefile
 438 backend/impress/Makefile
 439 backend/pdf/Makefile
 440 backend/pixbuf/Makefile
 441 backend/ps/Makefile
 442 backend/tiff/Makefile
 443 cut-n-paste/Makefile
 444 cut-n-paste/evmountoperation/Makefile
 445 cut-n-paste/gedit-message-area/Makefile
 446 cut-n-paste/gimpcellrenderertoggle/Makefile
 447 cut-n-paste/smclient/Makefile
 448 cut-n-paste/toolbar-editor/Makefile
 449 cut-n-paste/zoom-control/Makefile
 450 cut-n-paste/totem-screensaver/Makefile
 451 data/evince.desktop.in
 452 data/Makefile
 453 data/icons/Makefile
 454 data/icons/16x16/Makefile
 455 data/icons/16x16/apps/Makefile
 456 data/icons/16x16/actions/Makefile
 457 data/icons/22x22/Makefile
 458 data/icons/22x22/apps/Makefile
 459 data/icons/22x22/actions/Makefile
 460 data/icons/24x24/Makefile
 461 data/icons/24x24/apps/Makefile
 462 data/icons/24x24/actions/Makefile
 463 data/icons/32x32/Makefile
 464 data/icons/32x32/actions/Makefile
 465 data/icons/48x48/Makefile
 466 data/icons/48x48/apps/Makefile
 467 data/icons/48x48/actions/Makefile
 468 data/icons/scalable/Makefile
 469 data/icons/scalable/apps/Makefile
 470 help/Makefile
 471 help/reference/Makefile
 472 help/reference/version.xml
 473 libdocument/Makefile
 474 libdocument/ev-version.h
 475 libview/Makefile
 476 Makefile
 477 po/Makefile.in
 478 properties/Makefile
 479 shell/Makefile
 480 test/Makefile
 481 thumbnailer/Makefile
 482 ])
 483
 484 AC_OUTPUT
 485
 486 echo "
 487 Configure summary:
 488         Keyring Support....:  $WITH_KEYRING
 489         DBUS Support.......:  $enable_dbus
 490         Nautilus Plugin....:  $HAVE_NAUTILUS
 491         Thumbnailer........:  $ENABLE_THUMBNAILER
 492         Gtk-Doc Support....:  $enable_gtk_doc
 493         Debug mode.........:  $enable_debug
 494
 495         PDF Backend........:  $enable_pdf
 496         PostScript Backend.:  $enable_ps
 497         TIFF Backend.......:  $enable_tiff
 498         DJVU Backend.......:  $enable_djvu
 499         DVI Backend........:  $enable_dvi
 500         Pixbuf Backend.....:  $enable_pixbuf
 501         Comics Backend.....:  $enable_comics
 502         Impress Backend....:  $enable_impress
 503 "