configure.ac

   1 # *****************************************************************************
   2 # Versioning
   3 # *****************************************************************************
   4
   5 m4_define([ev_major_version],[2])
   6 m4_define([ev_minor_version],[27])
   7 m4_define([ev_micro_version],[1])
   8 m4_define([ev_extra_version],[])
   9 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version()ev_extra_version])
  10
  11 # The evince API version
  12 m4_define([ev_api_version], [2.25])
  13
  14 # Libtool versioning. The backend and view libraries have separate versions.
  15 # Before making a release, the libtool version should be modified.
  16 # The string is of the form C:R:A.
  17 # - If interfaces have been changed or added, but binary compatibility has
  18 #   been preserved, change to C+1:0:A+1
  19 # - If binary compatibility has been broken (eg removed or changed interfaces)
  20 #   change to C+1:0:0
  21 # - If the interface is the same as the previous version, change to C:R+1:A
  22
  23 # Libtool version of the backend library
  24 m4_define([ev_document_lt_current],[1])
  25 m4_define([ev_document_lt_revision],[0])
  26 m4_define([ev_document_lt_age],[0])
  27 m4_define([ev_document_lt_version_info],[ev_document_lt_current:ev_document_lt_revision:ev_document_lt_age])
  28 m4_define([ev_document_lt_current_minus_age],[m4_eval(ev_document_lt_current - ev_document_lt_age)])
  29
  30 # Libtool version of the view library
  31 m4_define([ev_view_lt_current],[1])
  32 m4_define([ev_view_lt_revision],[0])
  33 m4_define([ev_view_lt_age],[0])
  34 m4_define([ev_view_lt_version_info],[ev_view_lt_current:ev_view_lt_revision:ev_view_lt_age])
  35 m4_define([ev_view_lt_current_minus_age],[m4_eval(ev_view_lt_current - ev_view_lt_age)])
  36
  37 # Binary version for the document backends
  38 m4_define([ev_binary_version],[ev_document_lt_current])
  39
  40 # *****************************************************************************
  41
  42 AC_PREREQ([2.57])
  43 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
  44 AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip])
  45
  46 AC_CONFIG_HEADERS([config.h])
  47 AC_CONFIG_MACRO_DIR([m4])
  48
  49 if test -z "$enable_maintainer_mode"; then
  50   enable_maintainer_mode=yes
  51 fi
  52 AM_MAINTAINER_MODE([enable])
  53
  54 AM_PROG_LIBTOOL
  55
  56 AC_ISC_POSIX
  57 AC_PROG_CC
  58 AM_PROG_CC_STDC
  59 AM_PROG_CC_C_O
  60 AC_PROG_CXX
  61 AC_STDC_HEADERS
  62 IT_PROG_INTLTOOL([0.35.0])
  63 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  64 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  65
  66 GNOME_COMMON_INIT
  67 GNOME_DOC_INIT
  68 GNOME_MAINTAINER_MODE_DEFINES
  69 GNOME_COMPILE_WARNINGS
  70 GNOME_CXX_WARNINGS
  71
  72 GTK_DOC_CHECK(1.0)
  73
  74 GETTEXT_PACKAGE=evince
  75 AC_SUBST(GETTEXT_PACKAGE)
  76 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  77 AM_GLIB_GNU_GETTEXT
  78
  79 # Check which platform to use
  80
  81 AC_MSG_CHECKING([for which platform to build])
  82 AC_ARG_WITH([platform],
  83   [AS_HELP_STRING([--with-platform=gnome|win32|hildon (default: gnome)])],
  84   [case "$withval" in
  85     gnome|win32|hildon) ;;
  86     *) AC_MSG_ERROR([invalid argument "$withval" for --with-platform]) ;;
  87    esac],
  88   [case "$host" in
  89      *-*-mingw*|*-*-cygwin*) with_platform="win32" ;;
  90      *) with_platform=gnome ;;
  91    esac])
  92
  93 AC_MSG_RESULT([$with_platform])
  94
  95 if test "$with_platform" = "win32"; then
  96   AC_CHECK_TOOL([WINDRES],[windres])
  97   AC_MSG_CHECKING([for native Win32])
  98   case "$host" in
  99     *-*-mingw*)
 100       os_win32=yes
 101       ;;
 102     *)
 103       os_win32=no
 104       ;;
 105   esac
 106   AC_MSG_RESULT([$os_win32])
 107 fi
 108
 109 AM_CONDITIONAL([PLATFORM_WIN32],[test "with_platform" = "win32"])
 110 AM_CONDITIONAL([OS_WIN32],[test "$os_win32" = "yes"])
 111
 112 dnl Specify required versions of dependencies
 113 DBUS_GLIB_REQUIRED=0.70
 114 GTK_REQUIRED=2.12.0
 115 GLIB_REQUIRED=2.18.0
 116 KEYRING_REQUIRED=2.22.0
 117 AC_SUBST([GLIB_REQUIRED])
 118 AC_SUBST([GTK_REQUIRED])
 119
 120 GNOME_ICON_THEME_REQUIRED=2.17.1
 121 LIBXML_REQUIRED=2.5.0
 122
 123 dnl Check dependencies
 124
 125 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
 126 # BACKEND_CFLAGS   for backend implementations.
 127 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
 128 # FRONTEND_LIBS
 129 # SHELL_CFLAGS     for shell implementation.
 130 # SHELL_LIBS
 131
 132 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
 133 PKG_CHECK_MODULES(LIBVIEW, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 134 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
 135 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 136 PKG_CHECK_MODULES(PREVIEWER, gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 137 PKG_CHECK_MODULES(SHELL_CORE, libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gthread-2.0)
 138
 139 if test "$os_win32" = no; then
 140         PKG_CHECK_MODULES(SMCLIENT, gtk+-2.0 gthread-2.0 sm >= 1.0.0)
 141 else
 142         PKG_CHECK_MODULES(SMCLIENT, gtk+-2.0 gthread-2.0)
 143 fi
 144
 145 AC_SUBST(SMCLIENT_CFLAGS)
 146 AC_SUBST(SMCLIENT_LIBS)
 147
 148 BACKEND_LIBTOOL_FLAGS="-module -avoid-version -no-undefined -export-symbols \$(top_srcdir)/backend/backend.symbols"
 149 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
 150
 151 if test "$with_platform" = "gnome"; then
 152   PKG_CHECK_EXISTS([gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED])
 153 fi
 154
 155 dnl ===== Check special functions
 156 evince_save_LIBS=$LIBS
 157 LIBS="$LIBS $BACKEND_LIBS"
 158 AC_CHECK_FUNCS(cairo_format_stride_for_width)
 159 LIBS=$evince_save_LIBS
 160
 161 # ******************
 162 # GKT+ Unix Printing
 163 # ******************
 164
 165 AC_MSG_CHECKING([whether gtk+-unix-print support is requested])
 166 AC_ARG_WITH([gtk-unix-print],
 167   [AS_HELP_STRING([--without-gtk-unix-print],[disable the use of gtk-unix-print])],
 168   [],[case "$os_win32" in
 169         yes) with_gtk_unix_print=no ;;
 170         *) with_gtk_unix_print=yes ;;
 171       esac])
 172 AC_MSG_RESULT([$with_gtk_unix_print])
 173
 174 if test "$with_gtk_unix_print" = "yes"; then
 175    PKG_CHECK_MODULES(GTKUNIXPRINT, [gtk+-unix-print-2.0 >= $GTK_REQUIRED])
 176    AC_DEFINE([GTKUNIXPRINT_ENABLED], [1], [Define if gtk+-unix-print is enabled.])
 177 fi
 178
 179 # *********************
 180 # GNOME Keyring support
 181 # *********************
 182
 183 AC_ARG_WITH(keyring,
 184         [AS_HELP_STRING([--without-keyring],[disable the use of gnome-keyring])],
 185         [],
 186         [case "$with_platform" in
 187            gnome) with_keyring=yes ;;
 188            hildon|win32) with_keyring=no ;;
 189          esac])
 190
 191 AM_CONDITIONAL([WITH_KEYRING],[test "$with_keyring" = "yes"])
 192
 193 if test "$with_keyring" = "yes"; then
 194         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
 195         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
 196 fi
 197
 198 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
 199 AC_SUBST(GLIB_GENMARSHAL)
 200
 201 dnl ========= Check for DBUS
 202 AC_ARG_ENABLE(dbus,
 203         [AC_HELP_STRING([--enable-dbus], [Compile with support for dbus])],
 204         enable_dbus="$enableval",enable_dbus=yes)
 205 if test "x$enable_dbus" != "xno"; then
 206         PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
 207         [enable_dbus=yes],[enable_dbus=no])
 208
 209         if test "x$enable_dbus" = "xno"; then
 210            AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
 211         fi
 212
 213         if test "x$enable_dbus" = "xyes" ; then
 214                 AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 215
 216                 if test x$DBUS_BINDING_TOOL = "xno" ; then
 217                         AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 218                 fi
 219
 220                 AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 221         fi
 222 fi
 223
 224 AC_SUBST([DBUS_CFLAGS])
 225 AC_SUBST([DBUS_LIBS])
 226
 227 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
 228 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
 229
 230 dnl ========= Check for GConf
 231
 232 AC_MSG_CHECKING([whether GConf support is requested])
 233 AC_ARG_WITH([gconf],
 234   [AS_HELP_STRING([--without-gconf],[disable the use of gconf])],
 235   [],
 236   [case "$os_win32" in
 237      yes) with_gconf=no ;;
 238      *) with_gconf=yes ;;
 239    esac])
 240 AC_MSG_RESULT([$with_gconf])
 241
 242 AM_CONDITIONAL([WITH_GCONF],[test "$with_gconf" = "yes"])
 243
 244 if test "$with_gconf" = "yes"; then
 245    PKG_CHECK_MODULES([GCONF],[gconf-2.0])
 246    AC_DEFINE([WITH_GCONF],[1],[Define if GConf support is enabled])
 247 fi
 248
 249 AM_GCONF_SOURCE_2
 250
 251 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [false])
 252 if test "$with_gconf" = "yes" -a "$GCONFTOOL" = "false"; then
 253   AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 254 fi
 255
 256 dnl Debug mode
 257
 258 AC_ARG_ENABLE([debug],
 259         AC_HELP_STRING([--enable-debug],
 260                         [Turn on evince debug mode]),,
 261                 [enable_debug=no])
 262
 263 if test "x$enable_debug" = "xyes"; then
 264    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 265 fi
 266
 267
 268 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 269 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 270 AC_SUBST(LIBDOCUMENT_CFLAGS)
 271 AC_SUBST(LIBDOCUMENT_LIBS)
 272
 273 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $DEBUG_FLAGS"
 274 LIBVIEW_LIBS="$LIBVIEW_LIBS"
 275 AC_SUBST(LIBVIEW_CFLAGS)
 276 AC_SUBST(LIBVIEW_LIBS)
 277
 278 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 279 AC_SUBST(BACKEND_CFLAGS)
 280 AC_SUBST(BACKEND_LIBS)
 281
 282 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $GTKUNIXPRINT_CFLAGS $DBUS_CFLAGS $KEYRING_CFLAGS $GCONF_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 283 SHELL_LIBS="$SHELL_CORE_LIBS $GTKUNIXPRINT_CFLAGS $DBUS_LIBS $KEYRING_LIBS $GCONF_LIBS -lz"
 284 AC_SUBST(SHELL_CFLAGS)
 285 AC_SUBST(SHELL_LIBS)
 286
 287 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 288 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 289 AC_SUBST(FRONTEND_CFLAGS)
 290 AC_SUBST(FRONTEND_LIBS)
 291
 292 # Check for Nautilus property page build
 293 AC_ARG_ENABLE([nautilus],
 294   [AS_HELP_STRING([--enable-nautilus],[compile the nautilus plugin])],
 295   [],
 296   [case "$with_platform" in
 297      gnome) enable_nautilus=yes ;;
 298      *) enable_nautilus=no ;;
 299     esac])
 300
 301 if test "$enable_nautilus" = "yes" ; then
 302   PKG_CHECK_MODULES([NAUTILUS],[gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension])
 303   NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 304   AC_SUBST([nautilusextensiondir],[$NAUTILUS_EXTENSION_DIR])
 305   AC_SUBST(NAUTILUS_CFLAGS)
 306   AC_SUBST(NAUTILUS_LIBS)
 307
 308   AC_DEFINE([HAVE_NAUTILUS],[1], [defined if you build the nautilus plugin])
 309 fi
 310
 311 AM_CONDITIONAL([ENABLE_NAUTILUS],[test "$enable_nautilus" = "yes"])
 312
 313 # Check for thumbnailer build
 314
 315 AC_ARG_ENABLE([thumbnailer],
 316   [AS_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer])],
 317   [],
 318   [case "$with_platform" in
 319      gnome) enable_thumbnailer=yes ;;
 320      *) enable_thumbnailer=no ;;
 321     esac])
 322
 323 AM_CONDITIONAL([ENABLE_THUMBNAILER],[test "$enable_thumbnailer" = "yes"])
 324
 325 # ***************
 326 # Print Previewer
 327 # ***************
 328
 329 AC_ARG_ENABLE([previewer],
 330   [AS_HELP_STRING([--disable-previewer],[disable the GNOME Document Previewer])],
 331   [],
 332   [case "$with_platform" in
 333       gnome) enable_previewer=yes ;;
 334       *) enable_previewer=no ;;
 335     esac])
 336
 337 if test x$enable_previewer = "xyes" ; then
 338   PKG_CHECK_MODULES([PREVIEWER],[gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED])
 339 fi
 340
 341 AM_CONDITIONAL([ENABLE_PREVIEWER],[test "$enable_previewer" = "yes"])
 342 PREVIEWER_CFLAGS="$PREVIEWER_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 343 PREVIEWER_LIBS="$PREVIEWER_LIBS $GTKUNIXPRINT_LIBS -lz"
 344 AC_SUBST(PREVIEWER_CFLAGS)
 345 AC_SUBST(PREVIEWER_LIBS)
 346
 347 # ***
 348 # GIR
 349 # ***
 350
 351 AC_MSG_CHECKING([whether GObject introspection is requested])
 352 AC_ARG_ENABLE([introspection],
 353         AS_HELP_STRING([--enable-introspection],[Enable GObject introspection]),
 354         [],[enable_introspection=no])
 355 AC_MSG_RESULT([$enable_introspection])
 356
 357 G_IR_SCANNER=
 358 G_IR_COMPILER=
 359 G_IR_GENERATE=
 360 GIRDIR=
 361 GIRTYPELIBDIR=
 362
 363 if test "$enable_introspection" = "yes"; then
 364   GOBJECT_INTROSPECTION_REQUIRED=0.6
 365   PKG_CHECK_MODULES([GOBJECT_INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
 366
 367   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
 368   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
 369   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
 370   GIRDIR="$($PKG_CONFIG --variable=girdir gobject-introspection-1.0)"
 371   GIRTYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
 372 fi
 373
 374 AC_SUBST([G_IR_SCANNER])
 375 AC_SUBST([G_IR_COMPILER])
 376 AC_SUBST([G_IR_GENERATE])
 377 AC_SUBST([GIRDIR])
 378 AC_SUBST([GIRTYPELIBDIR])
 379
 380 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
 381
 382 dnl ================== portability checks ===========================================
 383
 384 dnl for backtrace()
 385 AC_CHECK_HEADERS([execinfo.h])
 386
 387 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 388   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 389   ],[],[#include <langinfo.h>])
 390
 391 dnl ================== pdf checks ===================================================
 392 AC_ARG_ENABLE(pdf,
 393               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 394
 395 if test "x$enable_pdf" = "xyes"; then
 396     POPPLER_REQUIRED=0.11.0
 397     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED,enable_pdf=yes,enable_pdf=no)
 398
 399     if test "x$enable_pdf" = "xyes"; then
 400             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 401             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 402             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 403
 404             evince_save_LIBS=$LIBS
 405             LIBS="$LIBS $POPPLER_LIBS"
 406             AC_CHECK_FUNCS(poppler_page_render)
 407             AC_CHECK_FUNCS(poppler_page_get_image)
 408             LIBS=$evince_save_LIBS
 409
 410             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 411             if test x$enable_cairo_pdf = xyes; then
 412                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 413             fi
 414
 415             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 416             if test x$enable_cairo_ps = xyes; then
 417                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 418             fi
 419     else
 420             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 421     fi
 422 fi
 423
 424 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 425 dnl ================== end of pdf checks ============================================
 426
 427 dnl libspectre (used by ps and dvi backends)
 428 SPECTRE_REQUIRED=0.2.0
 429 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 430 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 431 if test "x$have_spectre" = "xyes"; then
 432    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 433 fi
 434
 435 dnl ================== ps checks ====================================================
 436 AC_ARG_ENABLE(ps,
 437         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 438
 439 if test "x$enable_ps" = "xyes"; then
 440    if test "x$have_spectre" = "xyes"; then
 441       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 442    else
 443       enable_ps="no"
 444       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 445    fi
 446 fi
 447 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 448 dnl ======================== End of ps checks ===================================
 449
 450 dnl ================== tiff checks ===================================================
 451 AC_ARG_ENABLE(tiff,
 452             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 453
 454 if test "x$enable_tiff" = "xyes"; then
 455     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 456     if test "x$enable_tiff" = "xyes"; then
 457         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 458         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 459     fi
 460     if test "x$enable_tiff" = "xyes"; then
 461             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 462     else
 463             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 464     fi
 465 fi
 466
 467 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 468 dnl ================== end of tiff checks ============================================
 469
 470 dnl ================== djvu checks ===================================================
 471
 472 AC_ARG_ENABLE(djvu,
 473             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=yes)
 474
 475 if test "x$enable_djvu" = "xyes"; then
 476     DJVULIBRE_REQUIRED=3.5.17
 477     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 478
 479     if test "x$enable_djvu" = "xyes"; then
 480         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 481     else
 482         AC_MSG_WARN([
 483 ** Djvu support is disabled since a recent version of the djvulibre
 484 ** library was not found. You need at least djvulibre-3.5.17 which
 485 ** can be found on http://djvulibre.djvuzone.org
 486 ])
 487     fi
 488 fi
 489
 490 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 491
 492 dnl ================== End of djvu checks ===================================================
 493
 494 dnl ================== dvi checks ===================================================
 495
 496 AC_ARG_ENABLE(dvi,
 497             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=yes)
 498
 499 AC_ARG_ENABLE(t1lib,
 500             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 501
 502 if test "x$enable_dvi" = "xyes"; then
 503     AC_C_CONST
 504     AC_C_INLINE
 505     AC_TYPE_SIZE_T
 506     AC_CHECK_SIZEOF(long, 4)
 507     AC_CHECK_SIZEOF(int, 4)
 508     AC_CHECK_SIZEOF(short, 2)
 509     AC_CHECK_SIZEOF(void *, 4)
 510     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 511
 512     if test "x$enable_dvi" = "xyes"; then
 513         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 514     else
 515         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 516     fi
 517 fi
 518 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 519
 520 if test "x$enable_dvi" = "xyes"; then
 521     if test "x$enable_type1_fonts" = "xyes"; then
 522         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 523     fi
 524
 525     if test "x$enable_type1_fonts" = xyes; then
 526         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 527     fi
 528 else
 529     enable_type1_fonts=no
 530 fi
 531 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 532
 533 dnl ================== End of dvi checks ===================================================
 534
 535 dnl ================== pixbuf checks ===================================================
 536
 537 AC_ARG_ENABLE(pixbuf,
 538             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 539 if test "x$enable_pixbuf" = "xyes"; then
 540         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 541 fi
 542 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 543
 544 dnl ================== End of pixbuf checks ===================================================
 545
 546 dnl ================== comic book checks ===================================================
 547
 548 AC_ARG_ENABLE(comics,
 549         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=yes)
 550 if test "x$enable_comics" = "xyes"; then
 551         if test "x$os_win32" = "xyes"; then
 552                 # The comics backend is disabled on windows because:
 553                 # 1) it uses unix functions from sys/wait.h.
 554                 # 2) it uses external decompression tools not generally available on windows.
 555                 enable_comics=no
 556                 AC_MSG_WARN(The comics backend is not supported on windows.)
 557         else
 558                 AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 559         fi
 560 fi
 561 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 562
 563 dnl ================== End of comic book checks ============================================
 564
 565 dnl ================== impress book checks ===================================================
 566
 567 AC_ARG_ENABLE(impress,
 568         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 569 if test "x$enable_impress" = "xyes"; then
 570         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 571 fi
 572 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 573
 574 dnl ================== End of impress book checks ============================================
 575
 576 dnl =================== Mime types list ====================================================
 577
 578 if test "x$enable_pdf" = "xyes" ; then
 579         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 580 fi
 581 if test "x$enable_ps" = "xyes" ; then
 582         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 583 fi
 584 if test "x$enable_dvi" = "xyes"; then
 585         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 586 fi
 587 if test "x$enable_djvu" = "xyes"; then
 588         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 589 fi
 590 if test "x$enable_tiff" = "xyes"; then
 591         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 592 fi
 593 if test "x$enable_comics" = "xyes"; then
 594         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;"
 595 fi
 596 if test "x$enable_pixbuf" = "xyes"; then
 597         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 598 fi
 599 if test "x$enable_impress" = "xyes"; then
 600         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 601 fi
 602 AC_SUBST(EVINCE_MIME_TYPES)
 603
 604 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 605
 606 # Backends directory
 607
 608 AC_SUBST([backenddir],"\$(libdir)/evince/ev_binary_version/backends")
 609 AC_SUBST([backend_binary_version],"ev_binary_version")
 610
 611 # Versioning
 612
 613 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
 614 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
 615 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
 616
 617 AC_SUBST([EV_API_VERSION],[ev_api_version])
 618 AC_SUBST([EV_BINARY_VERSION],[ev_binary_version])
 619
 620 AC_SUBST([EV_DOCUMENT_LT_VERSION_INFO],[ev_document_lt_version_info])
 621 AC_SUBST([EV_DOCUMENT_LT_CURRENT_MINUS_AGE],[ev_document_lt_current_minus_age])
 622 AC_SUBST([EV_VIEW_LT_VERSION_INFO],[ev_view_lt_version_info])
 623 AC_SUBST([EV_VIEW_LT_CURRENT_MINUS_AGE],[ev_view_lt_current_minus_age])
 624
 625 # *****************************************************************************
 626
 627 SHAVE_INIT([], [enable])
 628
 629 AC_CONFIG_FILES([
 630 backend/Makefile
 631 backend/comics/Makefile
 632 backend/djvu/Makefile
 633 backend/dvi/Makefile
 634 backend/dvi/mdvi-lib/Makefile
 635 backend/impress/Makefile
 636 backend/pdf/Makefile
 637 backend/pixbuf/Makefile
 638 backend/ps/Makefile
 639 backend/tiff/Makefile
 640 cut-n-paste/Makefile
 641 cut-n-paste/gedit-message-area/Makefile
 642 cut-n-paste/gimpcellrenderertoggle/Makefile
 643 cut-n-paste/smclient/Makefile
 644 cut-n-paste/toolbar-editor/Makefile
 645 cut-n-paste/zoom-control/Makefile
 646 cut-n-paste/totem-screensaver/Makefile
 647 data/evince.desktop.in
 648 data/Makefile
 649 data/icons/Makefile
 650 data/icons/16x16/Makefile
 651 data/icons/16x16/apps/Makefile
 652 data/icons/16x16/actions/Makefile
 653 data/icons/22x22/Makefile
 654 data/icons/22x22/apps/Makefile
 655 data/icons/22x22/actions/Makefile
 656 data/icons/24x24/Makefile
 657 data/icons/24x24/apps/Makefile
 658 data/icons/24x24/actions/Makefile
 659 data/icons/32x32/Makefile
 660 data/icons/32x32/actions/Makefile
 661 data/icons/48x48/Makefile
 662 data/icons/48x48/apps/Makefile
 663 data/icons/48x48/actions/Makefile
 664 data/icons/scalable/Makefile
 665 data/icons/scalable/apps/Makefile
 666 help/Makefile
 667 help/reference/Makefile
 668 help/reference/libdocument/Makefile
 669 help/reference/libdocument/version.xml
 670 help/reference/libview/Makefile
 671 help/reference/libview/version.xml
 672 help/reference/shell/Makefile
 673 help/reference/shell/version.xml
 674 libdocument/Makefile
 675 libdocument/ev-version.h
 676 libmisc/Makefile
 677 libview/Makefile
 678 Makefile
 679 po/Makefile.in
 680 previewer/Makefile
 681 properties/Makefile
 682 shave
 683 shave-libtool
 684 shell/Makefile
 685 test/Makefile
 686 thumbnailer/Makefile
 687 ])
 688
 689 AC_CONFIG_FILES(evince-document-[]ev_api_version[].pc:evince-document.pc.in)
 690 AC_CONFIG_FILES(evince-view-[]ev_api_version[].pc:evince-view.pc.in)
 691
 692 AC_OUTPUT
 693
 694 echo "
 695 Configure summary:
 696         GConf Support......:  $with_gconf
 697         GTK+ Unix Print....:  $with_gtk_unix_print
 698         Keyring Support....:  $with_keyring
 699         DBUS Support.......:  $enable_dbus
 700         Nautilus Plugin....:  $enable_nautilus
 701         Thumbnailer........:  $enable_thumbnailer
 702         Previewer..........:  $enable_previewer
 703         Gtk-Doc Support....:  $enable_gtk_doc
 704         Debug mode.........:  $enable_debug
 705         GObj. Introspection:  $enable_introspection
 706
 707         PDF Backend........:  $enable_pdf
 708         PostScript Backend.:  $enable_ps
 709         TIFF Backend.......:  $enable_tiff
 710         DJVU Backend.......:  $enable_djvu
 711         DVI Backend........:  $enable_dvi
 712         Pixbuf Backend.....:  $enable_pixbuf
 713         Comics Backend.....:  $enable_comics
 714         Impress Backend....:  $enable_impress
 715 "