configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 m4_define([ev_major_version],[2])
   4 m4_define([ev_minor_version],[25])
   5 m4_define([ev_micro_version],[5])
   6 m4_define([ev_extra_version],[])
   7 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version()ev_extra_version])
   8
   9 # The evince API version
  10 m4_define([ev_api_version], [2.25])
  11
  12 AC_PREREQ([2.57])
  13 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
  14 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-dist-gzip])
  15
  16 AM_CONFIG_HEADER(config.h)
  17
  18 AM_MAINTAINER_MODE
  19
  20 AM_PROG_LIBTOOL
  21
  22 AC_ISC_POSIX
  23 AC_PROG_CC
  24 AM_PROG_CC_STDC
  25 AC_PROG_CXX
  26 AC_STDC_HEADERS
  27 IT_PROG_INTLTOOL([0.35.0])
  28 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  29 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  30
  31 GNOME_COMMON_INIT
  32 GNOME_DOC_INIT
  33 GNOME_MAINTAINER_MODE_DEFINES
  34 GNOME_COMPILE_WARNINGS
  35 GNOME_CXX_WARNINGS
  36
  37 GTK_DOC_CHECK(1.0)
  38
  39 GETTEXT_PACKAGE=evince
  40 AC_SUBST(GETTEXT_PACKAGE)
  41 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  42 AM_GLIB_GNU_GETTEXT
  43
  44 dnl Check dependencies
  45
  46 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
  47 # BACKEND_CFLAGS   for backend implementations.
  48 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
  49 # FRONTEND_LIBS
  50 # SHELL_CFLAGS     for shell implementation.
  51 # SHELL_LIBS
  52
  53 DBUS_GLIB_REQUIRED=0.70
  54 GTK_REQUIRED=2.12.0
  55 GLIB_REQUIRED=2.18.0
  56 KEYRING_REQUIRED=2.22.0
  57 AC_SUBST([GLIB_REQUIRED])
  58 AC_SUBST([GTK_REQUIRED])
  59
  60 GNOME_ICON_THEME_REQUIRED=2.17.1
  61 LIBXML_REQUIRED=2.5.0
  62
  63 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
  64 PKG_CHECK_MODULES(LIBVIEW, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
  65 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
  66 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
  67 PKG_CHECK_MODULES(SHELL_CORE, libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED gthread-2.0 gconf-2.0)
  68
  69 PKG_CHECK_MODULES(SMCLIENT, gtk+-2.0 gthread-2.0)
  70 AC_SUBST(SMCLIENT_CFLAGS)
  71 AC_SUBST(SMCLIENT_LIBS)
  72
  73 BACKEND_LIBTOOL_FLAGS="-module -avoid-version"
  74 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
  75
  76 dnl ===== Check special functions
  77 evince_save_LIBS=$LIBS
  78 LIBS="$LIBS $BACKEND_LIBS"
  79 AC_CHECK_FUNCS(cairo_format_stride_for_width)
  80 LIBS=$evince_save_LIBS
  81
  82 AC_ARG_WITH(keyring,
  83         AC_HELP_STRING([--without-keyring],[disable the use of gnome-keyring]),
  84         [case "${withval}" in
  85         yes) WITH_KEYRING=yes ;;
  86         no) WITH_KEYRING=no ;;
  87         *) AC_MSG_ERROR(bad value ${withval} for --with-keyring) ;;
  88         esac],
  89         [WITH_KEYRING=yes]) dnl Default value
  90 AM_CONDITIONAL(WITH_KEYRING, test x$WITH_KEYRING = "xyes")
  91
  92 if test x$WITH_KEYRING = "xyes"; then
  93         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
  94         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
  95 fi
  96
  97 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
  98 AC_SUBST(GLIB_GENMARSHAL)
  99
 100 dnl ========= Check for DBUS
 101 AC_ARG_ENABLE(dbus,
 102         [AC_HELP_STRING([--enable-dbus], [Compile with support for dbus])],
 103         enable_dbus="$enableval",enable_dbus=yes)
 104 if test "x$enable_dbus" != "xno"; then
 105         PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
 106         [enable_dbus=yes],[enable_dbus=no])
 107
 108         if test "x$enable_dbus" = "xno"; then
 109            AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
 110         fi
 111
 112         if test "x$enable_dbus" = "xyes" ; then
 113                 AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 114
 115                 if test x$DBUS_BINDING_TOOL = "xno" ; then
 116                         AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 117                 fi
 118
 119                 AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 120         fi
 121 fi
 122
 123 AC_SUBST([DBUS_CFLAGS])
 124 AC_SUBST([DBUS_LIBS])
 125
 126 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
 127 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
 128
 129 dnl Debug mode
 130 AC_ARG_ENABLE([debug],
 131         AC_HELP_STRING([--enable-debug],
 132                         [Turn on evince debug mode]),,
 133                 [enable_debug=no])
 134
 135 if test "x$enable_debug" = "xyes"; then
 136    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 137 fi
 138
 139
 140 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 141 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 142 AC_SUBST(LIBDOCUMENT_CFLAGS)
 143 AC_SUBST(LIBDOCUMENT_LIBS)
 144
 145 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $DEBUG_FLAGS"
 146 LIBVIEW_LIBS="$LIBVIEW_LIBS"
 147 AC_SUBST(LIBVIEW_CFLAGS)
 148 AC_SUBST(LIBVIEW_LIBS)
 149
 150 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 151 AC_SUBST(BACKEND_CFLAGS)
 152 AC_SUBST(BACKEND_LIBS)
 153
 154 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS $KEYRING_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 155 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS $KEYRING_LIBS -lz"
 156 AC_SUBST(SHELL_CFLAGS)
 157 AC_SUBST(SHELL_LIBS)
 158
 159 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 160 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 161 AC_SUBST(FRONTEND_CFLAGS)
 162 AC_SUBST(FRONTEND_LIBS)
 163
 164 dnl Check for Nautilus property page build
 165 AC_ARG_ENABLE(nautilus,
 166         AC_HELP_STRING([--enable-nautilus],[compile the nautilus plugin]),
 167         [case "${enableval}" in
 168         yes) ENABLE_NAUTILUS=yes ;;
 169         no) ENABLE_NAUTILUS=no ;;
 170         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nautilus) ;;
 171         esac],
 172         [ENABLE_NAUTILUS=yes]) dnl Default value
 173
 174 if test x$ENABLE_NAUTILUS = "xyes" ; then
 175         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
 176                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
 177         NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 178         AC_SUBST(NAUTILUS_EXTENSION_DIR)
 179 fi
 180
 181 AC_SUBST(NAUTILUS_CFLAGS)
 182 AC_SUBST(NAUTILUS_LIBS)
 183 if test x$HAVE_NAUTILUS = "xyes"; then
 184         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
 185 fi
 186 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
 187
 188
 189 dnl Check for thumbnailer build
 190 AC_ARG_ENABLE(thumbnailer,
 191         AC_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer]),
 192         [case "${enableval}" in
 193         yes) ENABLE_THUMBNAILER=yes ;;
 194         no) ENABLE_THUMBNAILER=no ;;
 195         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thumbnailer) ;;
 196         esac],
 197         [ENABLE_THUMBNAILER=yes]) dnl Default value
 198 AM_CONDITIONAL(ENABLE_THUMBNAILER, test x$ENABLE_THUMBNAILER = "xyes")
 199
 200 dnl GConf configuration
 201 AM_GCONF_SOURCE_2
 202
 203 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
 204 if test "x$GCONFTOOL" = "xno"; then
 205         AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 206 fi
 207
 208 dnl ================== portability checks ===========================================
 209
 210 dnl for backtrace()
 211 AC_CHECK_HEADERS([execinfo.h])
 212
 213 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 214   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 215   ],[],[#include <langinfo.h>])
 216
 217 dnl ================== pdf checks ===================================================
 218 AC_ARG_ENABLE(pdf,
 219               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 220
 221 if test "x$enable_pdf" = "xyes"; then
 222     POPPLER_REQUIRED=0.8.0
 223     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED,enable_pdf=yes,enable_pdf=no)
 224
 225     if test "x$enable_pdf" = "xyes"; then
 226             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 227             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 228             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 229
 230             evince_save_LIBS=$LIBS
 231             LIBS="$LIBS $POPPLER_LIBS"
 232             AC_CHECK_FUNCS(poppler_page_render)
 233             AC_CHECK_FUNCS(poppler_layers_iter_new)
 234             LIBS=$evince_save_LIBS
 235
 236             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 237             if test x$enable_cairo_pdf = xyes; then
 238                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 239             fi
 240
 241             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 242             if test x$enable_cairo_ps = xyes; then
 243                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 244             fi
 245     else
 246             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 247     fi
 248 fi
 249
 250 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 251 dnl ================== end of pdf checks ============================================
 252
 253 dnl libspectre (used by ps and dvi backends)
 254 SPECTRE_REQUIRED=0.2.0
 255 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 256 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 257 if test "x$have_spectre" = "xyes"; then
 258    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 259 fi
 260
 261 dnl ================== ps checks ====================================================
 262 AC_ARG_ENABLE(ps,
 263         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 264
 265 if test "x$enable_ps" = "xyes"; then
 266    if test "x$have_spectre" = "xyes"; then
 267       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 268    else
 269       enable_ps="no"
 270       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 271    fi
 272 fi
 273 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 274 dnl ======================== End of ps checks ===================================
 275
 276 dnl ================== tiff checks ===================================================
 277 AC_ARG_ENABLE(tiff,
 278             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 279
 280 if test "x$enable_tiff" = "xyes"; then
 281     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 282     if test "x$enable_tiff" = "xyes"; then
 283         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 284         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 285     fi
 286     if test "x$enable_tiff" = "xyes"; then
 287             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 288     else
 289             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 290     fi
 291 fi
 292
 293 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 294 dnl ================== end of tiff checks ============================================
 295
 296 dnl ================== djvu checks ===================================================
 297
 298 AC_ARG_ENABLE(djvu,
 299             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=yes)
 300
 301 if test "x$enable_djvu" = "xyes"; then
 302     DJVULIBRE_REQUIRED=3.5.17
 303     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 304
 305     if test "x$enable_djvu" = "xyes"; then
 306         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 307     else
 308         AC_MSG_WARN([
 309 ** Djvu support is disabled since a recent version of the djvulibre
 310 ** library was not found. You need at least djvulibre-3.5.17 which
 311 ** can be found on http://djvulibre.djvuzone.org
 312 ])
 313     fi
 314 fi
 315
 316 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 317
 318 dnl ================== End of djvu checks ===================================================
 319
 320 dnl ================== dvi checks ===================================================
 321
 322 AC_ARG_ENABLE(dvi,
 323             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=yes)
 324
 325 AC_ARG_ENABLE(t1lib,
 326             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 327
 328 if test "x$enable_dvi" = "xyes"; then
 329     AC_C_CONST
 330     AC_C_INLINE
 331     AC_TYPE_SIZE_T
 332     AC_CHECK_SIZEOF(long, 4)
 333     AC_CHECK_SIZEOF(int, 4)
 334     AC_CHECK_SIZEOF(short, 2)
 335     AC_CHECK_SIZEOF(void *, 4)
 336     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 337
 338     if test "x$enable_dvi" = "xyes"; then
 339         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 340     else
 341         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 342     fi
 343 fi
 344 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 345
 346 if test "x$enable_dvi" = "xyes"; then
 347     if test "x$enable_type1_fonts" = "xyes"; then
 348         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 349     fi
 350
 351     if test "x$enable_type1_fonts" = xyes; then
 352         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 353     fi
 354 else
 355     enable_type1_fonts=no
 356 fi
 357 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 358
 359 dnl ================== End of dvi checks ===================================================
 360
 361 dnl ================== pixbuf checks ===================================================
 362
 363 AC_ARG_ENABLE(pixbuf,
 364             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 365 if test "x$enable_pixbuf" = "xyes"; then
 366         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 367 fi
 368 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 369
 370 dnl ================== End of pixbuf checks ===================================================
 371
 372 dnl ================== comic book checks ===================================================
 373
 374 AC_ARG_ENABLE(comics,
 375         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=yes)
 376 if test "x$enable_comics" = "xyes"; then
 377         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 378 fi
 379 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 380
 381 dnl ================== End of comic book checks ============================================
 382
 383 dnl ================== impress book checks ===================================================
 384
 385 AC_ARG_ENABLE(impress,
 386         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 387 if test "x$enable_impress" = "xyes"; then
 388         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 389 fi
 390 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 391
 392 dnl ================== End of impress book checks ============================================
 393
 394 dnl =================== Mime types list ====================================================
 395
 396 if test "x$enable_pdf" = "xyes" ; then
 397         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 398 fi
 399 if test "x$enable_ps" = "xyes" ; then
 400         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 401 fi
 402 if test "x$enable_dvi" = "xyes"; then
 403         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 404 fi
 405 if test "x$enable_djvu" = "xyes"; then
 406         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 407 fi
 408 if test "x$enable_tiff" = "xyes"; then
 409         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 410 fi
 411 if test "x$enable_comics" = "xyes"; then
 412         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;"
 413 fi
 414 if test "x$enable_pixbuf" = "xyes"; then
 415         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 416 fi
 417 if test "x$enable_impress" = "xyes"; then
 418         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 419 fi
 420 AC_SUBST(EVINCE_MIME_TYPES)
 421
 422 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 423
 424 # Versioning
 425
 426 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
 427 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
 428 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
 429
 430 AC_SUBST([EV_API_VERSION],[ev_api_version])
 431
 432 # *****************************************************************************
 433
 434 AC_CONFIG_FILES([
 435 backend/Makefile
 436 backend/comics/Makefile
 437 backend/djvu/Makefile
 438 backend/dvi/Makefile
 439 backend/dvi/mdvi-lib/Makefile
 440 backend/impress/Makefile
 441 backend/pdf/Makefile
 442 backend/pixbuf/Makefile
 443 backend/ps/Makefile
 444 backend/tiff/Makefile
 445 cut-n-paste/Makefile
 446 cut-n-paste/evmountoperation/Makefile
 447 cut-n-paste/gedit-message-area/Makefile
 448 cut-n-paste/gimpcellrenderertoggle/Makefile
 449 cut-n-paste/smclient/Makefile
 450 cut-n-paste/toolbar-editor/Makefile
 451 cut-n-paste/zoom-control/Makefile
 452 cut-n-paste/totem-screensaver/Makefile
 453 data/evince.desktop.in
 454 data/Makefile
 455 data/icons/Makefile
 456 data/icons/16x16/Makefile
 457 data/icons/16x16/apps/Makefile
 458 data/icons/16x16/actions/Makefile
 459 data/icons/22x22/Makefile
 460 data/icons/22x22/apps/Makefile
 461 data/icons/22x22/actions/Makefile
 462 data/icons/24x24/Makefile
 463 data/icons/24x24/apps/Makefile
 464 data/icons/24x24/actions/Makefile
 465 data/icons/32x32/Makefile
 466 data/icons/32x32/actions/Makefile
 467 data/icons/48x48/Makefile
 468 data/icons/48x48/apps/Makefile
 469 data/icons/48x48/actions/Makefile
 470 data/icons/scalable/Makefile
 471 data/icons/scalable/apps/Makefile
 472 help/Makefile
 473 help/reference/Makefile
 474 help/reference/version.xml
 475 libdocument/Makefile
 476 libdocument/ev-version.h
 477 libview/Makefile
 478 Makefile
 479 po/Makefile.in
 480 properties/Makefile
 481 shell/Makefile
 482 test/Makefile
 483 thumbnailer/Makefile
 484 ])
 485
 486 AC_CONFIG_FILES(evince-backend-[]ev_api_version[].pc:evince-backend.pc.in)
 487 AC_CONFIG_FILES(evince-view-[]ev_api_version[].pc:evince-view.pc.in)
 488
 489 AC_OUTPUT
 490
 491 echo "
 492 Configure summary:
 493         Keyring Support....:  $WITH_KEYRING
 494         DBUS Support.......:  $enable_dbus
 495         Nautilus Plugin....:  $HAVE_NAUTILUS
 496         Thumbnailer........:  $ENABLE_THUMBNAILER
 497         Gtk-Doc Support....:  $enable_gtk_doc
 498         Debug mode.........:  $enable_debug
 499
 500         PDF Backend........:  $enable_pdf
 501         PostScript Backend.:  $enable_ps
 502         TIFF Backend.......:  $enable_tiff
 503         DJVU Backend.......:  $enable_djvu
 504         DVI Backend........:  $enable_dvi
 505         Pixbuf Backend.....:  $enable_pixbuf
 506         Comics Backend.....:  $enable_comics
 507         Impress Backend....:  $enable_impress
 508 "