configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.57)
   4 AC_INIT(evince, 0.5.2)
   5 AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)
   6
   7 AM_CONFIG_HEADER(config.h)
   8
   9 AM_MAINTAINER_MODE
  10
  11 AM_PROG_LIBTOOL
  12
  13 AC_ISC_POSIX
  14 AC_PROG_CC
  15 AM_PROG_CC_STDC
  16 AC_PROG_CXX
  17 AC_STDC_HEADERS
  18 IT_PROG_INTLTOOL([0.34.90])
  19 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  20 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  21
  22 GNOME_COMMON_INIT
  23 GNOME_DOC_INIT
  24 GNOME_MAINTAINER_MODE_DEFINES
  25 GNOME_COMPILE_WARNINGS
  26 GNOME_CXX_WARNINGS
  27 GNOME_DEBUG_CHECK
  28
  29 AM_GLIB_GNU_GETTEXT
  30
  31 GETTEXT_PACKAGE=AC_PACKAGE_NAME
  32 AC_SUBST(GETTEXT_PACKAGE)
  33 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package.])
  34
  35 dnl Check dependencies
  36
  37 # LIB_CFLAGS       for helpers and generic widgets. (lib, cut-and-paste)
  38 # BACKEND_CFLAGS   for backend implementations.
  39 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
  40 # FRONTEND_LIBS
  41 # SHELL_CFLAGS     for shell implementation.
  42 # SHELL_LIBS
  43
  44 POPPLER_REQUIRED=0.5.1
  45 DBUS_GLIB_REQUIRED=0.33
  46 GTK_REQUIRED=2.6.0
  47 LIBGNOMEUI_REQUIRED=2.6.0
  48 KEYRING_REQUIRED=0.4.0
  49 LIBGNOMEPRINTUI_REQUIRED=2.5.1
  50
  51 PKG_CHECK_MODULES(LIB, gtk+-2.0 >= $GTK_REQUIRED libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED)
  52 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED gnome-vfs-2.0)
  53 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED libglade-2.0 poppler-glib >= $POPPLER_REQUIRED)
  54 PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED)
  55 PKG_CHECK_MODULES(SHELL_CORE, gtk+-2.0 >= $GTK_REQUIRED libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED gnome-vfs-2.0 libglade-2.0 gconf-2.0 poppler-glib >= $POPPLER_REQUIRED gnome-keyring-1 >= $KEYRING_REQUIRED)
  56
  57 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
  58 AC_SUBST(GLIB_GENMARSHAL)
  59
  60
  61 dnl ========= Check for libgnomeprintui
  62 AC_ARG_ENABLE(gnome-print,
  63         [AC_HELP_STRING([--disable-gnome-print], [Compile without print support])],
  64         enable_gnome_print="$enableval",
  65         enable_gnome_print=yes)
  66
  67 if test x$enable_gnome_print = xyes; then
  68         PKG_CHECK_MODULES(GNOME_PRINT,
  69                 libgnomeprintui-2.2 >= $LIBGNOMEPRINTUI_REQUIRED,
  70                 enable_gnome_print=yes, enable_gnome_print=no)
  71 fi
  72
  73 AC_SUBST(GNOME_PRINT_CFLAGS)
  74 AC_SUBST(GNOME_PRINT_LIBS)
  75
  76 if test x$enable_gnome_print = xyes; then
  77         AC_DEFINE([WITH_GNOME_PRINT],[1],[Enable Print Support.])
  78 fi
  79
  80 AM_CONDITIONAL(WITH_GNOME_PRINT, test x$enable_gnome_print = xyes)
  81
  82 dnl ========= Check for DBUS
  83 PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
  84         [enable_dbus=yes],[enable_dbus=no])
  85 AC_SUBST([DBUS_CFLAGS])
  86 AC_SUBST([DBUS_LIBS])
  87
  88 if test "x$enable_dbus" = "xno"; then
  89         AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
  90 fi
  91
  92 if test "x$enable_dbus" = "xyes" ; then
  93         AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
  94
  95         if test x$DBUS_BINDING_TOOL = "xno" ; then
  96                 AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
  97         fi
  98
  99         AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 100
 101         DBUS_VERSION=`$PKG_CONFIG --modversion dbus-glib-1 | sed 's/0\.\([[0-9]]*\)\.\{0,1\}\([[0-9]]*\)/\1/'`
 102         AC_DEFINE_UNQUOTED(DBUS_VERSION, $DBUS_VERSION, [DBUS version.])
 103 fi
 104
 105 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS"
 106 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS -lz"
 107 AC_SUBST(SHELL_CFLAGS)
 108 AC_SUBST(SHELL_LIBS)
 109
 110 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS"
 111 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 112 AC_SUBST(FRONTEND_CFLAGS)
 113 AC_SUBST(FRONTEND_LIBS)
 114
 115 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
 116 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
 117
 118 dnl Check for Nautilus property page build
 119 AC_ARG_ENABLE(nautilus,
 120         AC_HELP_STRING([--enable-nautilus],[compile the nautilus plugin]),
 121         [case "${enableval}" in
 122         yes) ENABLE_NAUTILUS=yes ;;
 123         no) ENABLE_NAUTILUS=no ;;
 124         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nautilus) ;;
 125         esac],
 126         [ENABLE_NAUTILUS=yes]) dnl Default value
 127
 128 if test x$ENABLE_NAUTILUS = "xyes" ; then
 129         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
 130                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
 131 fi
 132
 133 AC_SUBST(NAUTILUS_CFLAGS)
 134 AC_SUBST(NAUTILUS_LIBS)
 135 if test x$HAVE_NAUTILUS = "xyes"; then
 136         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
 137 fi
 138 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
 139
 140 dnl Check for functions not present in gtk 2.6
 141 evince_save_LIBS=$LIBS
 142 LIBS="$LIBS $FRONTEND_CORE_LIBS"
 143 AC_CHECK_FUNCS(gtk_icon_view_get_visible_range)
 144 AC_CHECK_FUNCS(gtk_window_present_with_time)
 145 AC_CHECK_FUNCS(g_file_set_contents)
 146 AC_CHECK_FUNCS(gtk_file_chooser_set_do_overwrite_confirmation)
 147 AC_CHECK_FUNCS(gtk_icon_view_enable_model_drag_source)
 148 LIBS=$evince_save_LIBS
 149
 150 dnl GConf configuration
 151 AM_GCONF_SOURCE_2
 152
 153 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
 154 if test "x$GCONFTOOL" = "xno"; then
 155         AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 156 fi
 157
 158 dnl ================== portability checks ===========================================
 159
 160 dnl for backtrace()
 161 AC_CHECK_HEADERS([execinfo.h])
 162
 163 dnl ================== ggv checks ===================================================
 164 AC_ARG_ENABLE(ps,
 165         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 166
 167 if test x$enable_ps = xyes; then
 168         AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 169 fi
 170
 171 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 172
 173 if test x$enable_ps = xyes; then
 174
 175 dnl check for GS version
 176 AC_MSG_CHECKING(for Ghostscript version...)
 177 GS_VERSION=`gs --version | head -n 1 | sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
 178 AC_MSG_RESULT(found $GS_VERSION)
 179 if test "$GS_VERSION" -lt "7"; then
 180         AC_MSG_ERROR([You need Ghostscript version >= 7 in order to run evince])
 181 fi
 182
 183 AC_ARG_WITH(gs-aa-params,
 184             [AC_HELP_STRING([--with-gs-aa-params], [Define antialiasing params for ghostscript])],AA_PARAMS=$withval,
 185             AA_PARMS="-sDEVICE=x11alpha -dNOPLATFONTS -dGraphicsAlphaBits=4 -dTextAlphaBits=4 -dDOINTERPOLATE"
 186             )
 187 AC_DEFINE_UNQUOTED(ALPHA_PARAMS, "$AA_PARMS", [Anti-aliasing parameters for Ghostscript.])
 188 AC_MSG_RESULT(Antialiasing parameters for Ghostscript: $AA_PARMS)
 189
 190 fi
 191 dnl ======================== End of ggv checks =================================
 192
 193 dnl ================== tiff checks ===================================================
 194 AC_ARG_ENABLE(tiff,
 195             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 196
 197 if test "x$enable_tiff" = "xyes"; then
 198     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 199     if test "x$enable_tiff" = "xyes"; then
 200         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 201         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 202     fi
 203     if test "x$enable_tiff" = "xyes"; then
 204             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 205             FRONTEND_LIBS="$FRONTEND_LIBS -ltiff"
 206             SHELL_LIBS="$SHELL_LIBS -ltiff"
 207     else
 208             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 209     fi
 210 fi
 211
 212 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 213 dnl ================== end of tiff checks ============================================
 214
 215 dnl ================== djvu checks ===================================================
 216
 217 AC_ARG_ENABLE(djvu,
 218             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=no)
 219
 220 if test "x$enable_djvu" = "xyes"; then
 221
 222 DJVULIBRE_REQUIRED=3.5.17
 223
 224 PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 225
 226     if test "x$enable_djvu" = "xyes"; then
 227         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 228     else
 229         AC_MSG_WARN([
 230 ** Djvu support is disabled since a recent version of the djvulibre
 231 ** library was not found. You need at least djvulibre-3.5.17 which
 232 ** can be found on http://djvulibre.djvuzone.org
 233 ])
 234     fi
 235 fi
 236
 237 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 238
 239 dnl ================== End of djvu checks ===================================================
 240
 241 dnl ================== dvi checks ===================================================
 242
 243 AC_ARG_ENABLE(dvi,
 244             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=no)
 245
 246 AC_ARG_ENABLE(t1lib,
 247             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 248
 249 if test "x$enable_dvi" = "xyes"; then
 250     AC_C_CONST
 251     AC_C_INLINE
 252     AC_TYPE_SIZE_T
 253     AC_CHECK_SIZEOF(long, 4)
 254     AC_CHECK_SIZEOF(int, 4)
 255     AC_CHECK_SIZEOF(short, 2)
 256     AC_CHECK_SIZEOF(void *, 4)
 257     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 258
 259     if test "x$enable_dvi" = "xyes"; then
 260         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 261     else
 262         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 263     fi
 264 fi
 265 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 266
 267 if test "x$enable_dvi" = "xyes"; then
 268     if test "x$enable_type1_fonts" = "xyes"; then
 269         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 270     fi
 271
 272     if test "x$enable_type1_fonts" = xyes; then
 273         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 274     fi
 275 else
 276     enable_type1_fonts=no
 277 fi
 278 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 279
 280 dnl ================== End of dvi checks ===================================================
 281
 282 dnl ================== pixbuf checks ===================================================
 283
 284 AC_ARG_ENABLE(pixbuf,
 285             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 286 if test "x$enable_pixbuf" = "xyes"; then
 287         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 288 fi
 289 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 290
 291 dnl ================== End of pixbuf checks ===================================================
 292
 293 dnl ================== comic book checks ===================================================
 294
 295 AC_ARG_ENABLE(comics,
 296         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=no)
 297 if test "x$enable_comics" = "xyes"; then
 298         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 299 fi
 300 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 301
 302 dnl ================== End of comic book checks ============================================
 303
 304 dnl =================== Mime types list ====================================================
 305
 306 EVINCE_MIME_TYPES="application/pdf"
 307
 308 if test "x$enable_ps" = "xyes" ; then
 309         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;application/postscript;application/x-gzpostscript"
 310 fi
 311 if test "x$enable_dvi" = "xyes"; then
 312         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;application/x-dvi"
 313 fi
 314 if test "x$enable_djvu" = "xyes"; then
 315         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;image/vnd.djvu"
 316 fi
 317 if test "x$enable_tiff" = "xyes"; then
 318         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;image/tiff"
 319 fi
 320 if test "x$enable_comics" = "xyes"; then
 321         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;application/x-cbr;application/x-cbz"
 322 fi
 323 AC_SUBST(EVINCE_MIME_TYPES)
 324
 325 AC_CONFIG_FILES([
 326 Makefile
 327 cut-n-paste/Makefile
 328 cut-n-paste/recent-files/Makefile
 329 cut-n-paste/zoom-control/Makefile
 330 cut-n-paste/toolbar-editor/Makefile
 331 data/Makefile
 332 data/evince.desktop.in
 333 lib/Makefile
 334 pdf/Makefile
 335 pixbuf/Makefile
 336 tiff/Makefile
 337 ps/Makefile
 338 djvu/Makefile
 339 dvi/Makefile
 340 dvi/mdvi-lib/Makefile
 341 comics/Makefile
 342 po/Makefile.in
 343 backend/Makefile
 344 properties/Makefile
 345 shell/Makefile
 346 thumbnailer/Makefile
 347 help/Makefile
 348 ])
 349
 350 AC_OUTPUT
 351
 352 echo "
 353 Configure summary:
 354         Print Support......:  $enable_gnome_print
 355         DBUS Support.......:  $enable_dbus
 356         Nautilus Plugin....:  $HAVE_NAUTILUS
 357
 358         PostScript Backend.:  $enable_ps
 359         TIFF Backend.......:  $enable_tiff
 360         DJVU Backend.......:  $enable_djvu
 361         DVI Backend........:  $enable_dvi
 362         Pixbuf Backend.....:  $enable_pixbuf
 363         Comics Backend.....:  $enable_comics
 364 "