configure.ac

   1 # *****************************************************************************
   2 # Versioning
   3 # *****************************************************************************
   4
   5 m4_define([ev_major_version],[2])
   6 m4_define([ev_minor_version],[25])
   7 m4_define([ev_micro_version],[90])
   8 m4_define([ev_extra_version],[])
   9 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version()ev_extra_version])
  10
  11 # The evince API version
  12 m4_define([ev_api_version], [2.25])
  13
  14 # Libtool versioning. The backend and view libraries have separate versions.
  15 # Before making a release, the libtool version should be modified.
  16 # The string is of the form C:R:A.
  17 # - If interfaces have been changed or added, but binary compatibility has
  18 #   been preserved, change to C+1:0:A+1
  19 # - If binary compatibility has been broken (eg removed or changed interfaces)
  20 #   change to C+1:0:0
  21 # - If the interface is the same as the previous version, change to C:R+1:A
  22
  23 # Libtool version of the backend library
  24 m4_define([ev_document_lt_current],[1])
  25 m4_define([ev_document_lt_revision],[0])
  26 m4_define([ev_document_lt_age],[0])
  27 m4_define([ev_document_lt_version_info],[ev_document_lt_current:ev_document_lt_revision:ev_document_lt_age])
  28 m4_define([ev_document_lt_current_minus_age],[m4_eval(ev_document_lt_current - ev_document_lt_age)])
  29
  30 # Libtool version of the view library
  31 m4_define([ev_view_lt_current],[1])
  32 m4_define([ev_view_lt_revision],[0])
  33 m4_define([ev_view_lt_age],[0])
  34 m4_define([ev_view_lt_version_info],[ev_view_lt_current:ev_view_lt_revision:ev_view_lt_age])
  35 m4_define([ev_view_lt_current_minus_age],[m4_eval(ev_view_lt_current - ev_view_lt_age)])
  36
  37 # Binary version for the document backends
  38 m4_define([ev_binary_version],[ev_document_lt_current])
  39
  40 # *****************************************************************************
  41
  42 AC_PREREQ([2.57])
  43 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
  44 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-dist-gzip])
  45
  46 AM_CONFIG_HEADER(config.h)
  47
  48 AM_MAINTAINER_MODE
  49
  50 AM_PROG_LIBTOOL
  51
  52 AC_ISC_POSIX
  53 AC_PROG_CC
  54 AM_PROG_CC_STDC
  55 AM_PROG_CC_C_O
  56 AC_PROG_CXX
  57 AC_STDC_HEADERS
  58 IT_PROG_INTLTOOL([0.35.0])
  59 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  60 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  61
  62 GNOME_COMMON_INIT
  63 GNOME_DOC_INIT
  64 GNOME_MAINTAINER_MODE_DEFINES
  65 GNOME_COMPILE_WARNINGS
  66 GNOME_CXX_WARNINGS
  67
  68 GTK_DOC_CHECK(1.0)
  69
  70 GETTEXT_PACKAGE=evince
  71 AC_SUBST(GETTEXT_PACKAGE)
  72 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  73 AM_GLIB_GNU_GETTEXT
  74
  75 dnl Check dependencies
  76
  77 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
  78 # BACKEND_CFLAGS   for backend implementations.
  79 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
  80 # FRONTEND_LIBS
  81 # SHELL_CFLAGS     for shell implementation.
  82 # SHELL_LIBS
  83
  84 DBUS_GLIB_REQUIRED=0.70
  85 GTK_REQUIRED=2.12.0
  86 GLIB_REQUIRED=2.18.0
  87 KEYRING_REQUIRED=2.22.0
  88 AC_SUBST([GLIB_REQUIRED])
  89 AC_SUBST([GTK_REQUIRED])
  90
  91 GNOME_ICON_THEME_REQUIRED=2.17.1
  92 LIBXML_REQUIRED=2.5.0
  93
  94 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
  95 PKG_CHECK_MODULES(LIBVIEW, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
  96 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
  97 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
  98 PKG_CHECK_MODULES(SHELL_CORE, libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED gthread-2.0)
  99
 100 PKG_CHECK_MODULES(SMCLIENT, gtk+-2.0 gthread-2.0)
 101 AC_SUBST(SMCLIENT_CFLAGS)
 102 AC_SUBST(SMCLIENT_LIBS)
 103
 104 BACKEND_LIBTOOL_FLAGS="-module -avoid-version -export-symbols \$(top_srcdir)/backend/backend.symbols"
 105 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
 106
 107 dnl ===== Check special functions
 108 evince_save_LIBS=$LIBS
 109 LIBS="$LIBS $BACKEND_LIBS"
 110 AC_CHECK_FUNCS(cairo_format_stride_for_width)
 111 LIBS=$evince_save_LIBS
 112
 113 dnl ========= Check for Keyring
 114 AC_ARG_WITH(keyring,
 115         AC_HELP_STRING([--without-keyring],[disable the use of gnome-keyring]),
 116         [case "${withval}" in
 117         yes) WITH_KEYRING=yes ;;
 118         no) WITH_KEYRING=no ;;
 119         *) AC_MSG_ERROR(bad value ${withval} for --with-keyring) ;;
 120         esac],
 121         [WITH_KEYRING=yes]) dnl Default value
 122 AM_CONDITIONAL(WITH_KEYRING, test x$WITH_KEYRING = "xyes")
 123
 124 if test x$WITH_KEYRING = "xyes"; then
 125         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
 126         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
 127 fi
 128
 129 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
 130 AC_SUBST(GLIB_GENMARSHAL)
 131
 132 dnl ========= Check for DBUS
 133 AC_ARG_ENABLE(dbus,
 134         [AC_HELP_STRING([--enable-dbus], [Compile with support for dbus])],
 135         enable_dbus="$enableval",enable_dbus=yes)
 136 if test "x$enable_dbus" != "xno"; then
 137         PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
 138         [enable_dbus=yes],[enable_dbus=no])
 139
 140         if test "x$enable_dbus" = "xno"; then
 141            AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
 142         fi
 143
 144         if test "x$enable_dbus" = "xyes" ; then
 145                 AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 146
 147                 if test x$DBUS_BINDING_TOOL = "xno" ; then
 148                         AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 149                 fi
 150
 151                 AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 152         fi
 153 fi
 154
 155 AC_SUBST([DBUS_CFLAGS])
 156 AC_SUBST([DBUS_LIBS])
 157
 158 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
 159 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
 160
 161 dnl ========= Check for GConf
 162 AC_ARG_WITH(gconf,
 163         AC_HELP_STRING([--without-gconf],[disable the use of gconf]),
 164         [case "${withval}" in
 165         yes) WITH_GCONF=yes ;;
 166         no) WITH_GCONF=no ;;
 167         *) AC_MSG_ERROR(bad value ${withval} for --with-gconf) ;;
 168         esac],
 169         [WITH_GCONF=yes]) dnl Default value
 170 AM_CONDITIONAL(WITH_GCONF, test x$WITH_GCONF = "xyes")
 171
 172 if test x$WITH_GCONF = "xyes"; then
 173    PKG_CHECK_MODULES(GCONF, gconf-2.0)
 174    AC_DEFINE([WITH_GCONF],[1],[Define if GConf support is enabled])
 175 fi
 176
 177 dnl Debug mode
 178 AC_ARG_ENABLE([debug],
 179         AC_HELP_STRING([--enable-debug],
 180                         [Turn on evince debug mode]),,
 181                 [enable_debug=no])
 182
 183 if test "x$enable_debug" = "xyes"; then
 184    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 185 fi
 186
 187
 188 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 189 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 190 AC_SUBST(LIBDOCUMENT_CFLAGS)
 191 AC_SUBST(LIBDOCUMENT_LIBS)
 192
 193 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $DEBUG_FLAGS"
 194 LIBVIEW_LIBS="$LIBVIEW_LIBS"
 195 AC_SUBST(LIBVIEW_CFLAGS)
 196 AC_SUBST(LIBVIEW_LIBS)
 197
 198 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 199 AC_SUBST(BACKEND_CFLAGS)
 200 AC_SUBST(BACKEND_LIBS)
 201
 202 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS $KEYRING_CFLAGS $GCONF_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 203 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS $KEYRING_LIBS $GCONF_LIBS -lz"
 204 AC_SUBST(SHELL_CFLAGS)
 205 AC_SUBST(SHELL_LIBS)
 206
 207 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 208 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 209 AC_SUBST(FRONTEND_CFLAGS)
 210 AC_SUBST(FRONTEND_LIBS)
 211
 212 dnl Check for Nautilus property page build
 213 AC_ARG_ENABLE(nautilus,
 214         AC_HELP_STRING([--enable-nautilus],[compile the nautilus plugin]),
 215         [case "${enableval}" in
 216         yes) ENABLE_NAUTILUS=yes ;;
 217         no) ENABLE_NAUTILUS=no ;;
 218         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nautilus) ;;
 219         esac],
 220         [ENABLE_NAUTILUS=yes]) dnl Default value
 221
 222 if test x$ENABLE_NAUTILUS = "xyes" ; then
 223         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
 224                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
 225         NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 226         AC_SUBST(NAUTILUS_EXTENSION_DIR)
 227 fi
 228
 229 AC_SUBST(NAUTILUS_CFLAGS)
 230 AC_SUBST(NAUTILUS_LIBS)
 231 if test x$HAVE_NAUTILUS = "xyes"; then
 232         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
 233 fi
 234 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
 235
 236
 237 dnl Check for thumbnailer build
 238 AC_ARG_ENABLE(thumbnailer,
 239         AC_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer]),
 240         [case "${enableval}" in
 241         yes) ENABLE_THUMBNAILER=yes ;;
 242         no) ENABLE_THUMBNAILER=no ;;
 243         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thumbnailer) ;;
 244         esac],
 245         [ENABLE_THUMBNAILER=yes]) dnl Default value
 246 AM_CONDITIONAL(ENABLE_THUMBNAILER, test x$ENABLE_THUMBNAILER = "xyes")
 247
 248 dnl GConf configuration
 249 AM_GCONF_SOURCE_2
 250
 251 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
 252 if test "x$GCONFTOOL" = "xno"; then
 253         AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 254 fi
 255
 256 dnl ================== portability checks ===========================================
 257
 258 dnl for backtrace()
 259 AC_CHECK_HEADERS([execinfo.h])
 260
 261 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 262   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 263   ],[],[#include <langinfo.h>])
 264
 265 dnl ================== pdf checks ===================================================
 266 AC_ARG_ENABLE(pdf,
 267               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 268
 269 if test "x$enable_pdf" = "xyes"; then
 270     POPPLER_REQUIRED=0.8.0
 271     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED,enable_pdf=yes,enable_pdf=no)
 272
 273     if test "x$enable_pdf" = "xyes"; then
 274             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 275             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 276             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 277
 278             evince_save_LIBS=$LIBS
 279             LIBS="$LIBS $POPPLER_LIBS"
 280             AC_CHECK_FUNCS(poppler_page_render)
 281             AC_CHECK_FUNCS(poppler_layers_iter_new)
 282             LIBS=$evince_save_LIBS
 283
 284             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 285             if test x$enable_cairo_pdf = xyes; then
 286                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 287             fi
 288
 289             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 290             if test x$enable_cairo_ps = xyes; then
 291                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 292             fi
 293     else
 294             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 295     fi
 296 fi
 297
 298 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 299 dnl ================== end of pdf checks ============================================
 300
 301 dnl libspectre (used by ps and dvi backends)
 302 SPECTRE_REQUIRED=0.2.0
 303 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 304 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 305 if test "x$have_spectre" = "xyes"; then
 306    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 307 fi
 308
 309 dnl ================== ps checks ====================================================
 310 AC_ARG_ENABLE(ps,
 311         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 312
 313 if test "x$enable_ps" = "xyes"; then
 314    if test "x$have_spectre" = "xyes"; then
 315       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 316    else
 317       enable_ps="no"
 318       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 319    fi
 320 fi
 321 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 322 dnl ======================== End of ps checks ===================================
 323
 324 dnl ================== tiff checks ===================================================
 325 AC_ARG_ENABLE(tiff,
 326             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 327
 328 if test "x$enable_tiff" = "xyes"; then
 329     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 330     if test "x$enable_tiff" = "xyes"; then
 331         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 332         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 333     fi
 334     if test "x$enable_tiff" = "xyes"; then
 335             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 336     else
 337             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 338     fi
 339 fi
 340
 341 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 342 dnl ================== end of tiff checks ============================================
 343
 344 dnl ================== djvu checks ===================================================
 345
 346 AC_ARG_ENABLE(djvu,
 347             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=yes)
 348
 349 if test "x$enable_djvu" = "xyes"; then
 350     DJVULIBRE_REQUIRED=3.5.17
 351     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 352
 353     if test "x$enable_djvu" = "xyes"; then
 354         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 355     else
 356         AC_MSG_WARN([
 357 ** Djvu support is disabled since a recent version of the djvulibre
 358 ** library was not found. You need at least djvulibre-3.5.17 which
 359 ** can be found on http://djvulibre.djvuzone.org
 360 ])
 361     fi
 362 fi
 363
 364 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 365
 366 dnl ================== End of djvu checks ===================================================
 367
 368 dnl ================== dvi checks ===================================================
 369
 370 AC_ARG_ENABLE(dvi,
 371             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=yes)
 372
 373 AC_ARG_ENABLE(t1lib,
 374             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 375
 376 if test "x$enable_dvi" = "xyes"; then
 377     AC_C_CONST
 378     AC_C_INLINE
 379     AC_TYPE_SIZE_T
 380     AC_CHECK_SIZEOF(long, 4)
 381     AC_CHECK_SIZEOF(int, 4)
 382     AC_CHECK_SIZEOF(short, 2)
 383     AC_CHECK_SIZEOF(void *, 4)
 384     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 385
 386     if test "x$enable_dvi" = "xyes"; then
 387         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 388     else
 389         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 390     fi
 391 fi
 392 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 393
 394 if test "x$enable_dvi" = "xyes"; then
 395     if test "x$enable_type1_fonts" = "xyes"; then
 396         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 397     fi
 398
 399     if test "x$enable_type1_fonts" = xyes; then
 400         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 401     fi
 402 else
 403     enable_type1_fonts=no
 404 fi
 405 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 406
 407 dnl ================== End of dvi checks ===================================================
 408
 409 dnl ================== pixbuf checks ===================================================
 410
 411 AC_ARG_ENABLE(pixbuf,
 412             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 413 if test "x$enable_pixbuf" = "xyes"; then
 414         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 415 fi
 416 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 417
 418 dnl ================== End of pixbuf checks ===================================================
 419
 420 dnl ================== comic book checks ===================================================
 421
 422 AC_ARG_ENABLE(comics,
 423         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=yes)
 424 if test "x$enable_comics" = "xyes"; then
 425         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 426 fi
 427 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 428
 429 dnl ================== End of comic book checks ============================================
 430
 431 dnl ================== impress book checks ===================================================
 432
 433 AC_ARG_ENABLE(impress,
 434         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 435 if test "x$enable_impress" = "xyes"; then
 436         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 437 fi
 438 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 439
 440 dnl ================== End of impress book checks ============================================
 441
 442 dnl =================== Mime types list ====================================================
 443
 444 if test "x$enable_pdf" = "xyes" ; then
 445         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 446 fi
 447 if test "x$enable_ps" = "xyes" ; then
 448         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 449 fi
 450 if test "x$enable_dvi" = "xyes"; then
 451         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 452 fi
 453 if test "x$enable_djvu" = "xyes"; then
 454         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 455 fi
 456 if test "x$enable_tiff" = "xyes"; then
 457         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 458 fi
 459 if test "x$enable_comics" = "xyes"; then
 460         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;"
 461 fi
 462 if test "x$enable_pixbuf" = "xyes"; then
 463         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 464 fi
 465 if test "x$enable_impress" = "xyes"; then
 466         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 467 fi
 468 AC_SUBST(EVINCE_MIME_TYPES)
 469
 470 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 471
 472 # Backends directory
 473
 474 AC_SUBST([backenddir],"\$(libdir)/evince/ev_binary_version/backends")
 475
 476 # Versioning
 477
 478 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
 479 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
 480 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
 481
 482 AC_SUBST([EV_API_VERSION],[ev_api_version])
 483 AC_SUBST([EV_BINARY_VERSION],[ev_binary_version])
 484
 485 AC_SUBST([EV_DOCUMENT_LT_VERSION_INFO],[ev_document_lt_version_info])
 486 AC_SUBST([EV_DOCUMENT_LT_CURRENT_MINUS_AGE],[ev_document_lt_current_minus_age])
 487 AC_SUBST([EV_VIEW_LT_VERSION_INFO],[ev_view_lt_version_info])
 488 AC_SUBST([EV_VIEW_LT_CURRENT_MINUS_AGE],[ev_view_lt_current_minus_age])
 489
 490 # *****************************************************************************
 491
 492 AC_CONFIG_FILES([
 493 backend/Makefile
 494 backend/comics/Makefile
 495 backend/djvu/Makefile
 496 backend/dvi/Makefile
 497 backend/dvi/mdvi-lib/Makefile
 498 backend/impress/Makefile
 499 backend/pdf/Makefile
 500 backend/pixbuf/Makefile
 501 backend/ps/Makefile
 502 backend/tiff/Makefile
 503 cut-n-paste/Makefile
 504 cut-n-paste/evmountoperation/Makefile
 505 cut-n-paste/gedit-message-area/Makefile
 506 cut-n-paste/gimpcellrenderertoggle/Makefile
 507 cut-n-paste/smclient/Makefile
 508 cut-n-paste/toolbar-editor/Makefile
 509 cut-n-paste/zoom-control/Makefile
 510 cut-n-paste/totem-screensaver/Makefile
 511 data/evince.desktop.in
 512 data/Makefile
 513 data/icons/Makefile
 514 data/icons/16x16/Makefile
 515 data/icons/16x16/apps/Makefile
 516 data/icons/16x16/actions/Makefile
 517 data/icons/22x22/Makefile
 518 data/icons/22x22/apps/Makefile
 519 data/icons/22x22/actions/Makefile
 520 data/icons/24x24/Makefile
 521 data/icons/24x24/apps/Makefile
 522 data/icons/24x24/actions/Makefile
 523 data/icons/32x32/Makefile
 524 data/icons/32x32/actions/Makefile
 525 data/icons/48x48/Makefile
 526 data/icons/48x48/apps/Makefile
 527 data/icons/48x48/actions/Makefile
 528 data/icons/scalable/Makefile
 529 data/icons/scalable/apps/Makefile
 530 help/Makefile
 531 help/reference/Makefile
 532 help/reference/libdocument/Makefile
 533 help/reference/libdocument/version.xml
 534 help/reference/libview/Makefile
 535 help/reference/libview/version.xml
 536 help/reference/shell/Makefile
 537 help/reference/shell/version.xml
 538 libdocument/Makefile
 539 libdocument/ev-version.h
 540 libview/Makefile
 541 Makefile
 542 po/Makefile.in
 543 properties/Makefile
 544 shell/Makefile
 545 test/Makefile
 546 thumbnailer/Makefile
 547 ])
 548
 549 AC_CONFIG_FILES(evince-document-[]ev_api_version[].pc:evince-document.pc.in)
 550 AC_CONFIG_FILES(evince-view-[]ev_api_version[].pc:evince-view.pc.in)
 551
 552 AC_OUTPUT
 553
 554 echo "
 555 Configure summary:
 556         GConf Support......:  $WITH_GCONF
 557         Keyring Support....:  $WITH_KEYRING
 558         DBUS Support.......:  $enable_dbus
 559         Nautilus Plugin....:  $HAVE_NAUTILUS
 560         Thumbnailer........:  $ENABLE_THUMBNAILER
 561         Gtk-Doc Support....:  $enable_gtk_doc
 562         Debug mode.........:  $enable_debug
 563
 564         PDF Backend........:  $enable_pdf
 565         PostScript Backend.:  $enable_ps
 566         TIFF Backend.......:  $enable_tiff
 567         DJVU Backend.......:  $enable_djvu
 568         DVI Backend........:  $enable_dvi
 569         Pixbuf Backend.....:  $enable_pixbuf
 570         Comics Backend.....:  $enable_comics
 571         Impress Backend....:  $enable_impress
 572 "