configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.57)
   4 AC_INIT([Evince],[2.21.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
   5 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-dist-gzip])
   6
   7 AM_CONFIG_HEADER(config.h)
   8
   9 AM_MAINTAINER_MODE
  10
  11 AM_PROG_LIBTOOL
  12
  13 AC_ISC_POSIX
  14 AC_PROG_CC
  15 AM_PROG_CC_STDC
  16 AC_PROG_CXX
  17 AC_STDC_HEADERS
  18 IT_PROG_INTLTOOL([0.35.0])
  19 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  20 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  21
  22 GNOME_COMMON_INIT
  23 GNOME_DOC_INIT
  24 GNOME_MAINTAINER_MODE_DEFINES
  25 GNOME_COMPILE_WARNINGS
  26 GNOME_CXX_WARNINGS
  27 GNOME_DEBUG_CHECK
  28
  29 GTK_DOC_CHECK(1.0)
  30
  31 GETTEXT_PACKAGE=evince
  32 AC_SUBST(GETTEXT_PACKAGE)
  33 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  34 AM_GLIB_GNU_GETTEXT
  35
  36 dnl Check dependencies
  37
  38 # LIB_CFLAGS       for helpers and generic widgets. (lib, cut-and-paste)
  39 # BACKEND_CFLAGS   for backend implementations.
  40 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
  41 # FRONTEND_LIBS
  42 # SHELL_CFLAGS     for shell implementation.
  43 # SHELL_LIBS
  44
  45 DBUS_GLIB_REQUIRED=0.70
  46 GTK_REQUIRED=2.10.0
  47 KEYRING_REQUIRED=0.4.0
  48
  49 LIBGNOMEUI_REQUIRED=2.14.0
  50 LIBGNOME_REQUIRED=2.14.0
  51 LIBGNOMEPRINTUI_REQUIRED=2.6.0
  52 GNOME_ICON_THEME_REQUIRED=2.17.1
  53 LIBXML_REQUIRED=2.5.0
  54
  55 GTK_PRINT_REQUIRED=2.10.0
  56
  57 PKG_CHECK_MODULES(LIB, gtk+-2.0 >= $GTK_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED)
  58 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED gnome-vfs-2.0)
  59 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED libglade-2.0 gnome-vfs-2.0)
  60 PKG_CHECK_MODULES(SHELL_CORE, libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED gnome-vfs-2.0 libglade-2.0 gconf-2.0 gnome-keyring-1 >= $KEYRING_REQUIRED)
  61
  62 AC_ARG_WITH(libgnome,
  63         AC_HELP_STRING([--without-libgnome],[disable the use of libgnome]),
  64         [case "${withval}" in
  65         yes) WITH_GNOME=yes ;;
  66         no) WITH_GNOME=no ;;
  67         *) AC_MSG_ERROR(bad value ${withval} for --with-libgnome) ;;
  68         esac],
  69         [WITH_GNOME=yes]) dnl Default value
  70 AM_CONDITIONAL(WITH_GNOME, test x$WITH_GNOME = "xyes")
  71
  72 if test x$WITH_GNOME = "xyes"; then
  73         PKG_CHECK_MODULES(GNOME, libgnome-2.0 >= $LIBGNOME_REQUIRED)
  74         PKG_CHECK_MODULES(GNOMEUI, libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED)
  75         AC_DEFINE([WITH_GNOME],[1],[Define if GNOME support is enabled])
  76 fi
  77
  78 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
  79 AC_SUBST(GLIB_GENMARSHAL)
  80
  81 dnl ========= Print support
  82 AC_ARG_WITH(print,
  83             [AC_HELP_STRING([--with-print=no/gtk/gnome/auto], [Compile with print support [default=auto]])],
  84             PRINT=$withval,
  85             PRINT="auto")
  86
  87 PKG_CHECK_MODULES(GNOME_PRINT,
  88                   libgnomeprintui-2.2 >= $LIBGNOMEPRINTUI_REQUIRED,
  89                   enable_gnome_print=yes, enable_gnome_print=no)
  90 PKG_CHECK_MODULES(GTK_PRINT,
  91                   gtk+-unix-print-2.0 >= $GTK_PRINT_REQUIRED,
  92                   enable_gtk_print=yes, enable_gtk_print=no)
  93 enable_print=no
  94 if test x$PRINT = xgnome -a x$enable_gnome_print = xyes; then
  95    enable_print=gnome
  96 else
  97    if test x$PRINT = xgtk -a x$enable_gtk_print = xyes; then
  98       enable_print=gtk
  99    else
 100       if test x$PRINT = xauto; then
 101          if test x$enable_gtk_print = xyes; then
 102             enable_print=gtk
 103          else
 104             if test x$enable_gnome_print = xyes; then
 105                enable_print=gnome
 106             fi
 107          fi
 108       fi
 109    fi
 110 fi
 111
 112 if test x$enable_print = xgnome; then
 113    AC_SUBST(GNOME_PRINT_CFLAGS)
 114    AC_SUBST(GNOME_PRINT_LIBS)
 115    AC_DEFINE([WITH_GNOME_PRINT],[1],[Enable GNOME Print Support.])
 116    AC_DEFINE([WITH_PRINT],[1],[Enable Print Support.])
 117 fi
 118
 119 if test x$enable_print = xgtk; then
 120    AC_SUBST(GTK_PRINT_CFLAGS)
 121    AC_SUBST(GTK_PRINT_LIBS)
 122    AC_DEFINE([WITH_GTK_PRINT],[1],[Enable GTK Print Support.])
 123    AC_DEFINE([WITH_PRINT],[1],[Enable Print Support.])
 124 fi
 125
 126 AM_CONDITIONAL(WITH_GNOME_PRINT, test x$enable_print = xgnome)
 127 AM_CONDITIONAL(WITH_GTK_PRINT, test x$enable_print = xgtk)
 128
 129
 130 dnl ========= Check for DBUS
 131 PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
 132         [enable_dbus=yes],[enable_dbus=no])
 133 AC_SUBST([DBUS_CFLAGS])
 134 AC_SUBST([DBUS_LIBS])
 135
 136 if test "x$enable_dbus" = "xno"; then
 137         AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
 138 fi
 139
 140 if test "x$enable_dbus" = "xyes" ; then
 141         AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 142
 143         if test x$DBUS_BINDING_TOOL = "xno" ; then
 144                 AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 145         fi
 146
 147         AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 148 fi
 149
 150 LIB_CFLAGS="$LIB_CFLAGS $GNOME_CFLAGS"
 151 LIB_LIBS="$LIB_LIBS $GNOME_LIBS"
 152 AC_SUBST(LIB_CFLAGS)
 153 AC_SUBST(LIB_LIBS)
 154
 155 BACKEND_CFLAGS="$BACKEND_CFLAGS $GNOME_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE"
 156 BACKEND_LIBS="$BACKEND_LIBS $GNOME_LIBS"
 157 AC_SUBST(BACKEND_CFLAGS)
 158 AC_SUBST(BACKEND_LIBS)
 159
 160 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS $GNOMEUI_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE"
 161 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS $GNOMEUI_LIBS -lz"
 162 AC_SUBST(SHELL_CFLAGS)
 163 AC_SUBST(SHELL_LIBS)
 164
 165 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $GNOME_CFLAGS"
 166 FRONTEND_LIBS="$FRONTEND_CORE_LIBS $GNOME_LIBS -lz"
 167 AC_SUBST(FRONTEND_CFLAGS)
 168 AC_SUBST(FRONTEND_LIBS)
 169
 170 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
 171 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
 172
 173 dnl Check for Nautilus property page build
 174 AC_ARG_ENABLE(nautilus,
 175         AC_HELP_STRING([--enable-nautilus],[compile the nautilus plugin]),
 176         [case "${enableval}" in
 177         yes) ENABLE_NAUTILUS=yes ;;
 178         no) ENABLE_NAUTILUS=no ;;
 179         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nautilus) ;;
 180         esac],
 181         [ENABLE_NAUTILUS=yes]) dnl Default value
 182
 183 if test x$ENABLE_NAUTILUS = "xyes" ; then
 184         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
 185                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
 186 fi
 187
 188 AC_SUBST(NAUTILUS_CFLAGS)
 189 AC_SUBST(NAUTILUS_LIBS)
 190 if test x$HAVE_NAUTILUS = "xyes"; then
 191         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
 192 fi
 193 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
 194
 195
 196 dnl Check for thumbnailer build
 197 AC_ARG_ENABLE(thumbnailer,
 198         AC_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer]),
 199         [case "${enableval}" in
 200         yes) ENABLE_THUMBNAILER=yes ;;
 201         no) ENABLE_THUMBNAILER=no ;;
 202         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thumbnailer) ;;
 203         esac],
 204         [ENABLE_THUMBNAILER=yes]) dnl Default value
 205 AM_CONDITIONAL(ENABLE_THUMBNAILER, test x$ENABLE_THUMBNAILER = "xyes")
 206
 207 dnl GConf configuration
 208 AM_GCONF_SOURCE_2
 209
 210 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
 211 if test "x$GCONFTOOL" = "xno"; then
 212         AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 213 fi
 214
 215 dnl ================== portability checks ===========================================
 216
 217 dnl for backtrace()
 218 AC_CHECK_HEADERS([execinfo.h])
 219
 220 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 221   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 222   ],[],[#include <langinfo.h>])
 223
 224 dnl ================== pdf checks ===================================================
 225 AC_ARG_ENABLE(pdf,
 226               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 227
 228 if test "x$enable_pdf" = "xyes"; then
 229     POPPLER_REQUIRED=0.6
 230     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED,enable_pdf=yes,enable_pdf=no)
 231
 232     if test "x$enable_pdf" = "xyes"; then
 233             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 234             FRONTEND_LIBS="$FRONTEND_LIBS $POPPLER_LIBS"
 235             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 236             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 237
 238             evince_save_LIBS=$LIBS
 239             LIBS="$LIBS $FRONTEND_LIBS"
 240             AC_CHECK_FUNCS(poppler_page_render)
 241             AC_CHECK_FUNCS(poppler_page_render_for_printing)
 242             LIBS=$evince_save_LIBS
 243
 244             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 245             if test x$enable_cairo_pdf == xyes; then
 246                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 247             fi
 248
 249             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 250             if test x$enable_cairo_ps == xyes; then
 251                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 252             fi
 253     else
 254             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 255     fi
 256 fi
 257
 258 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 259 dnl ================== end of pdf checks ============================================
 260
 261 dnl libspectre (used by ps and dvi backends)
 262 PKG_CHECK_MODULES(SPECTRE, libspectre,have_spectre=yes,have_spectre=no)
 263 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 264 if test "x$have_spectre" = "xyes"; then
 265    AC_DEFINE([HAVE_SPECTRE], [1], [Have libpectre])
 266 fi
 267
 268 dnl ================== ps checks ====================================================
 269 AC_ARG_ENABLE(ps,
 270         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 271
 272 ps_backend=""
 273 if test x$enable_ps = xyes; then
 274    AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 275
 276    if test "x$have_spectre" = "xyes"; then
 277       FRONTEND_LIBS="$FRONTEND_LIBS $SPECTRE_LIBS"
 278       SHELL_LIBS="$SHELL_LIBS $SPECTRE_LIBS"
 279       SHELL_CFLAGS="$SHELL_CFLAGS $SPECTRE_CFLAGS"
 280       ps_backend="(libspectre)"
 281    else
 282       dnl check for GS version
 283       AC_MSG_CHECKING(for Ghostscript version...)
 284       GS_VERSION=`gs --version | head -n 1 | sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
 285       AC_MSG_RESULT(found $GS_VERSION)
 286       if test "$GS_VERSION" -lt "7"; then
 287          AC_MSG_WARN([PS support is disabled since libspectre or Ghostscript (version >= 7) are needed])
 288          enable_ps=no
 289       else
 290          AC_ARG_WITH(gs-aa-params,
 291                      [AC_HELP_STRING([--with-gs-aa-params], [Define antialiasing params for ghostscript])],AA_PARAMS=$withval,
 292                      AA_PARMS="-sDEVICE=x11alpha -dNOPLATFONTS -dGraphicsAlphaBits=4 -dTextAlphaBits=4 -dDOINTERPOLATE"
 293                      )
 294          AC_DEFINE_UNQUOTED(ALPHA_PARAMS, "$AA_PARMS", [Anti-aliasing parameters for Ghostscript.])
 295          AC_MSG_RESULT(Antialiasing parameters for Ghostscript: $AA_PARMS)
 296          ps_backend="(gs)"
 297       fi
 298    fi
 299 fi
 300 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 301 dnl ======================== End of ps checks ===================================
 302
 303 dnl ================== tiff checks ===================================================
 304 AC_ARG_ENABLE(tiff,
 305             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 306
 307 if test "x$enable_tiff" = "xyes"; then
 308     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 309     if test "x$enable_tiff" = "xyes"; then
 310         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 311         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 312     fi
 313     if test "x$enable_tiff" = "xyes"; then
 314             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 315             FRONTEND_LIBS="$FRONTEND_LIBS -ltiff"
 316             SHELL_LIBS="$SHELL_LIBS -ltiff"
 317     else
 318             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 319     fi
 320 fi
 321
 322 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 323 dnl ================== end of tiff checks ============================================
 324
 325 dnl ================== djvu checks ===================================================
 326
 327 AC_ARG_ENABLE(djvu,
 328             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=yes)
 329
 330 if test "x$enable_djvu" = "xyes"; then
 331     DJVULIBRE_REQUIRED=3.5.17
 332     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 333
 334     if test "x$enable_djvu" = "xyes"; then
 335         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 336     else
 337         AC_MSG_WARN([
 338 ** Djvu support is disabled since a recent version of the djvulibre
 339 ** library was not found. You need at least djvulibre-3.5.17 which
 340 ** can be found on http://djvulibre.djvuzone.org
 341 ])
 342     fi
 343 fi
 344
 345 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 346
 347 dnl ================== End of djvu checks ===================================================
 348
 349 dnl ================== dvi checks ===================================================
 350
 351 AC_ARG_ENABLE(dvi,
 352             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=yes)
 353
 354 AC_ARG_ENABLE(t1lib,
 355             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 356
 357 if test "x$enable_dvi" = "xyes"; then
 358     AC_C_CONST
 359     AC_C_INLINE
 360     AC_TYPE_SIZE_T
 361     AC_CHECK_SIZEOF(long, 4)
 362     AC_CHECK_SIZEOF(int, 4)
 363     AC_CHECK_SIZEOF(short, 2)
 364     AC_CHECK_SIZEOF(void *, 4)
 365     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 366
 367     if test "x$enable_dvi" = "xyes"; then
 368         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 369     else
 370         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 371     fi
 372 fi
 373 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 374
 375 if test "x$enable_dvi" = "xyes"; then
 376     if test "x$enable_type1_fonts" = "xyes"; then
 377         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 378     fi
 379
 380     if test "x$enable_type1_fonts" = xyes; then
 381         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 382     fi
 383 else
 384     enable_type1_fonts=no
 385 fi
 386 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 387
 388 dnl ================== End of dvi checks ===================================================
 389
 390 dnl ================== pixbuf checks ===================================================
 391
 392 AC_ARG_ENABLE(pixbuf,
 393             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 394 if test "x$enable_pixbuf" = "xyes"; then
 395         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 396 fi
 397 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 398
 399 dnl ================== End of pixbuf checks ===================================================
 400
 401 dnl ================== comic book checks ===================================================
 402
 403 AC_ARG_ENABLE(comics,
 404         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=yes)
 405 if test "x$enable_comics" = "xyes"; then
 406         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 407 fi
 408 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 409
 410 dnl ================== End of comic book checks ============================================
 411
 412 dnl ================== impress book checks ===================================================
 413
 414 AC_ARG_ENABLE(impress,
 415         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 416 if test "x$enable_impress" = "xyes"; then
 417         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 418 fi
 419 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 420
 421 dnl ================== End of impress book checks ============================================
 422
 423 dnl =================== Mime types list ====================================================
 424
 425 if test "x$enable_pdf" = "xyes" ; then
 426         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 427 fi
 428 if test "x$enable_ps" = "xyes" ; then
 429         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 430 fi
 431 if test "x$enable_dvi" = "xyes"; then
 432         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;"
 433 fi
 434 if test "x$enable_djvu" = "xyes"; then
 435         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 436 fi
 437 if test "x$enable_tiff" = "xyes"; then
 438         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 439 fi
 440 if test "x$enable_comics" = "xyes"; then
 441         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;"
 442 fi
 443 if test "x$enable_pixbuf" = "xyes"; then
 444         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 445 fi
 446 if test "x$enable_impress" = "xyes"; then
 447         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 448 fi
 449 AC_SUBST(EVINCE_MIME_TYPES)
 450
 451 AC_CONFIG_FILES([
 452 backend/Makefile
 453 backend/comics/Makefile
 454 backend/djvu/Makefile
 455 backend/dvi/Makefile
 456 backend/dvi/mdvi-lib/Makefile
 457 backend/impress/Makefile
 458 backend/pdf/Makefile
 459 backend/pixbuf/Makefile
 460 backend/ps/Makefile
 461 backend/tiff/Makefile
 462 cut-n-paste/Makefile
 463 cut-n-paste/gedit-message-area/Makefile
 464 cut-n-paste/toolbar-editor/Makefile
 465 cut-n-paste/zoom-control/Makefile
 466 cut-n-paste/totem-screensaver/Makefile
 467 data/evince.desktop.in
 468 data/Makefile
 469 data/icons/Makefile
 470 data/icons/16x16/Makefile
 471 data/icons/16x16/apps/Makefile
 472 data/icons/16x16/actions/Makefile
 473 data/icons/22x22/Makefile
 474 data/icons/22x22/apps/Makefile
 475 data/icons/22x22/actions/Makefile
 476 data/icons/24x24/Makefile
 477 data/icons/24x24/apps/Makefile
 478 data/icons/24x24/actions/Makefile
 479 data/icons/32x32/Makefile
 480 data/icons/32x32/actions/Makefile
 481 data/icons/48x48/Makefile
 482 data/icons/48x48/apps/Makefile
 483 data/icons/48x48/actions/Makefile
 484 data/icons/scalable/Makefile
 485 data/icons/scalable/apps/Makefile
 486 help/Makefile
 487 help/reference/Makefile
 488 help/reference/version.xml
 489 libdocument/Makefile
 490 Makefile
 491 po/Makefile.in
 492 properties/Makefile
 493 shell/Makefile
 494 test/Makefile
 495 thumbnailer/Makefile
 496 ])
 497
 498 AC_OUTPUT
 499
 500 echo "
 501 Configure summary:
 502         GNOME Support......:  $WITH_GNOME
 503         Print Support......:  $enable_print
 504         DBUS Support.......:  $enable_dbus
 505         Nautilus Plugin....:  $HAVE_NAUTILUS
 506         Thumbnailer........:  $ENABLE_THUMBNAILER
 507         Gtk-Doc Support....:  $enable_gtk_doc
 508
 509         PDF Backend........:  $enable_pdf
 510         PostScript Backend.:  $enable_ps $ps_backend
 511         TIFF Backend.......:  $enable_tiff
 512         DJVU Backend.......:  $enable_djvu
 513         DVI Backend........:  $enable_dvi
 514         Pixbuf Backend.....:  $enable_pixbuf
 515         Comics Backend.....:  $enable_comics
 516         Impress Backend....:  $enable_impress
 517 "