configure.ac

   1 # *****************************************************************************
   2 # Versioning
   3 # *****************************************************************************
   4
   5 m4_define([ev_major_version],[2])
   6 m4_define([ev_minor_version],[27])
   7 m4_define([ev_micro_version],[90])
   8 m4_define([ev_extra_version],[])
   9 m4_define([ev_version],[ev_major_version.ev_minor_version.ev_micro_version()ev_extra_version])
  10
  11 # The evince API version
  12 m4_define([ev_api_version], [2.25])
  13
  14 # Libtool versioning. The backend and view libraries have separate versions.
  15 # Before making a release, the libtool version should be modified.
  16 # The string is of the form C:R:A.
  17 # - If interfaces have been changed or added, but binary compatibility has
  18 #   been preserved, change to C+1:0:A+1
  19 # - If binary compatibility has been broken (eg removed or changed interfaces)
  20 #   change to C+1:0:0
  21 # - If the interface is the same as the previous version, change to C:R+1:A
  22
  23 # Libtool version of the backend library
  24 m4_define([ev_document_lt_current],[1])
  25 m4_define([ev_document_lt_revision],[0])
  26 m4_define([ev_document_lt_age],[0])
  27 m4_define([ev_document_lt_version_info],[ev_document_lt_current:ev_document_lt_revision:ev_document_lt_age])
  28 m4_define([ev_document_lt_current_minus_age],[m4_eval(ev_document_lt_current - ev_document_lt_age)])
  29
  30 # Libtool version of the view library
  31 m4_define([ev_view_lt_current],[1])
  32 m4_define([ev_view_lt_revision],[0])
  33 m4_define([ev_view_lt_age],[0])
  34 m4_define([ev_view_lt_version_info],[ev_view_lt_current:ev_view_lt_revision:ev_view_lt_age])
  35 m4_define([ev_view_lt_current_minus_age],[m4_eval(ev_view_lt_current - ev_view_lt_age)])
  36
  37 # Binary version for the document backends
  38 m4_define([ev_binary_version],[ev_document_lt_current])
  39
  40 # *****************************************************************************
  41
  42 AC_PREREQ([2.57])
  43 AC_INIT([Evince],[ev_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
  44 AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip])
  45
  46 AC_CONFIG_HEADERS([config.h])
  47 AC_CONFIG_MACRO_DIR([m4])
  48
  49 if test -z "$enable_maintainer_mode"; then
  50   enable_maintainer_mode=yes
  51 fi
  52 AM_MAINTAINER_MODE([enable])
  53
  54 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  55
  56 AM_PROG_LIBTOOL
  57
  58 AC_ISC_POSIX
  59 AC_PROG_CC
  60 AM_PROG_CC_STDC
  61 AM_PROG_CC_C_O
  62 AC_PROG_CXX
  63 AC_STDC_HEADERS
  64
  65 AC_PROG_SED
  66 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  67 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  68
  69 GNOME_COMMON_INIT
  70 GNOME_DOC_INIT
  71 GNOME_MAINTAINER_MODE_DEFINES
  72 GNOME_COMPILE_WARNINGS
  73 GNOME_CXX_WARNINGS
  74
  75 GTK_DOC_CHECK(1.0)
  76
  77 IT_PROG_INTLTOOL([0.35.0])
  78
  79 GETTEXT_PACKAGE=evince
  80 AC_SUBST(GETTEXT_PACKAGE)
  81 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  82 AM_GLIB_GNU_GETTEXT
  83
  84 m4_pattern_allow([AM_V_GEN])dnl Make autoconf not complain about the rule below
  85 EV_INTLTOOL_EVINCE_BACKEND_RULE='%.evince-backend:   %.evince-backend.in   $(INTLTOOL_MERGE) $(wildcard $(top_srcdir)/po/*.po) ; $(AM_V_GEN) LC_ALL=C $(INTLTOOL_MERGE) -d -u -c $(top_builddir)/po/.intltool-merge-cache $(top_srcdir)/po $< [$]@'
  86 AC_SUBST([EV_INTLTOOL_EVINCE_BACKEND_RULE])
  87
  88 # Check which platform to use
  89
  90 AC_MSG_CHECKING([for which platform to build])
  91 AC_ARG_WITH([platform],
  92   [AS_HELP_STRING([--with-platform=gnome|win32|hildon (default: gnome)])],
  93   [case "$withval" in
  94     gnome|win32|hildon) ;;
  95     *) AC_MSG_ERROR([invalid argument "$withval" for --with-platform]) ;;
  96    esac],
  97   [case "$host" in
  98      *-*-mingw*|*-*-cygwin*) with_platform="win32" ;;
  99      *) with_platform=gnome ;;
 100    esac])
 101
 102 AC_MSG_RESULT([$with_platform])
 103
 104 if test "$with_platform" = "win32"; then
 105   AC_CHECK_TOOL([WINDRES],[windres])
 106   AC_MSG_CHECKING([for native Win32])
 107   case "$host" in
 108     *-*-mingw*)
 109       os_win32=yes
 110       ;;
 111     *)
 112       os_win32=no
 113       ;;
 114   esac
 115   AC_MSG_RESULT([$os_win32])
 116 fi
 117
 118 AM_CONDITIONAL([PLATFORM_HILDON],[test "$with_platform" = "hildon"])
 119 AM_CONDITIONAL([PLATFORM_WIN32],[test "$with_platform" = "win32"])
 120
 121 dnl Specify required versions of dependencies
 122 DBUS_GLIB_REQUIRED=0.70
 123 GTK_REQUIRED=2.14.0
 124 GLIB_REQUIRED=2.18.0
 125 KEYRING_REQUIRED=2.22.0
 126 AC_SUBST([GLIB_REQUIRED])
 127 AC_SUBST([GTK_REQUIRED])
 128
 129 GNOME_ICON_THEME_REQUIRED=2.17.1
 130 LIBXML_REQUIRED=2.5.0
 131
 132 dnl Check dependencies
 133
 134 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
 135 # BACKEND_CFLAGS   for backend implementations.
 136 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
 137 # FRONTEND_LIBS
 138 # SHELL_CFLAGS     for shell implementation.
 139 # SHELL_LIBS
 140
 141 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
 142 PKG_CHECK_MODULES(LIBVIEW, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 143 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
 144 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 145 PKG_CHECK_MODULES(PREVIEWER, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 146
 147 SHELL_PLATFORM_PKGS=
 148 case "$with_platform" in
 149   hildon) AC_DEFINE([PLATFORM_HILDON],[1],[Define if building for the hildon platform])
 150           SHELL_PLATFORM_PKGS="hildon-1 hildon-fm-2 libosso"
 151           ;;
 152   *) SHELL_PLATFORM_PKGS="gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED"
 153      ;;
 154 esac
 155
 156 PKG_CHECK_MODULES([SHELL_CORE],[libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gthread-2.0 $SHELL_PLATFORM_PKGS])
 157
 158 # *********
 159 # SM client
 160 # *********
 161
 162 GDK_TARGET="$($PKG_CONFIG --variable target gdk-2.0)"
 163
 164 SMCLIENT_PKGS=
 165 AC_MSG_CHECKING([which smclient backend to use])
 166 AC_ARG_WITH([smclient],
 167   [AS_HELP_STRING([--with-smclient-backend],[which smclient backend to use (no|xsmp|win32|quartz)])],
 168   [],
 169   [case "$GDK_TARGET" in
 170     x11) case "$with_platform" in
 171            gnome) with_smclient=xsmp SMCLIENT_PKGS="sm >= 1.0.0" ;;
 172            *) with_smclient=no ;;
 173          esac ;;
 174     win32|quartz) with_smclient=$GDK_TARGET ;;
 175     *) with_smclient=no ;;
 176    esac])
 177 AC_MSG_RESULT([$with_smclient])
 178
 179 if test "$with_smclient" != "no"; then
 180   AC_DEFINE([WITH_SMCLIENT],[1],[Define if smclient is enabled])
 181
 182   PKG_CHECK_MODULES([SMCLIENT],[gtk+-2.0 gthread-2.0 $SMCLIENT_PKGS])
 183   AC_SUBST([SMCLIENT_CFLAGS])
 184   AC_SUBST([SMCLIENT_LIBS])
 185 fi
 186
 187 AM_CONDITIONAL([WITH_SMCLIENT],[test "$with_smclient" != "no"])
 188 AM_CONDITIONAL([WITH_SMCLIENT_XSMP],[test "$with_smclient" = "xsmp"])
 189 AM_CONDITIONAL([WITH_SMCLIENT_WIN32],[test "$with_smclient" = "win32"])
 190 AM_CONDITIONAL([WITH_SMCLIENT_QUARTZ],[test "$with_smclient" = "quartz"])
 191
 192 # ***
 193
 194 BACKEND_LIBTOOL_FLAGS="-module -avoid-version -no-undefined -export-symbols \$(top_srcdir)/backend/backend.symbols"
 195 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
 196
 197 dnl ===== Check special functions
 198 evince_save_LIBS=$LIBS
 199 LIBS="$LIBS $BACKEND_LIBS"
 200 AC_CHECK_FUNCS(cairo_format_stride_for_width)
 201 AC_CHECK_FUNCS(gtk_print_operation_get_n_pages_to_print)
 202 LIBS=$evince_save_LIBS
 203
 204 # ******************
 205 # GKT+ Unix Printing
 206 # ******************
 207
 208 AC_MSG_CHECKING([whether gtk+-unix-print support is requested])
 209 AC_ARG_WITH([gtk-unix-print],
 210   [AS_HELP_STRING([--without-gtk-unix-print],[disable the use of gtk-unix-print])],
 211   [],[case "$os_win32" in
 212         yes) with_gtk_unix_print=no ;;
 213         *) with_gtk_unix_print=yes ;;
 214       esac])
 215 AC_MSG_RESULT([$with_gtk_unix_print])
 216
 217 if test "$with_gtk_unix_print" = "yes"; then
 218    PKG_CHECK_MODULES(GTKUNIXPRINT, [gtk+-unix-print-2.0 >= $GTK_REQUIRED])
 219    AC_DEFINE([GTKUNIXPRINT_ENABLED], [1], [Define if gtk+-unix-print is enabled.])
 220 fi
 221
 222 # *********************
 223 # GNOME Keyring support
 224 # *********************
 225
 226 AC_ARG_WITH(keyring,
 227         [AS_HELP_STRING([--without-keyring],[disable the use of gnome-keyring])],
 228         [],
 229         [case "$with_platform" in
 230            gnome) with_keyring=yes ;;
 231            hildon|win32) with_keyring=no ;;
 232          esac])
 233
 234 AM_CONDITIONAL([WITH_KEYRING],[test "$with_keyring" = "yes"])
 235
 236 if test "$with_keyring" = "yes"; then
 237         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
 238         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
 239 fi
 240
 241 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
 242 AC_SUBST(GLIB_GENMARSHAL)
 243
 244 # ****
 245 # DBUS
 246 # ****
 247
 248 AC_ARG_ENABLE([dbus],
 249   [AS_HELP_STRING([--enable-dbus], [Compile with support for dbus])],
 250   [],
 251   [case "$with_platform" in
 252       gnome) enable_dbus=yes ;;
 253       hildon) enable_dbus=no ;;
 254     esac])
 255
 256 if test "$enable_dbus" = "yes"; then
 257   PKG_CHECK_MODULES([DBUS],[dbus-glib-1 >= $DBUS_GLIB_REQUIRED],[],
 258                     [AC_MSG_ERROR([DBUS not found; use --disable-dbus to disable DBUS support])])
 259
 260   AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 261   if test x$DBUS_BINDING_TOOL = "xno" ; then
 262           AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 263   fi
 264
 265   AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 266 fi
 267
 268 AC_SUBST([DBUS_CFLAGS])
 269 AC_SUBST([DBUS_LIBS])
 270
 271 AM_CONDITIONAL([ENABLE_DBUS], [test "$enable_dbus" = "yes"])
 272
 273 if test "$enable_dbus" = "yes"; then
 274    PKG_CHECK_MODULES([EV_DAEMON], [gthread-2.0 gio-2.0 >= $GLIB_REQUIRED dbus-glib-1 >= $DBUS_GLIB_REQUIRED])
 275 fi
 276
 277 dnl ========= Check for GConf
 278
 279 AC_MSG_CHECKING([whether GConf support is requested])
 280 AC_ARG_WITH([gconf],
 281   [AS_HELP_STRING([--without-gconf],[disable the use of gconf])],
 282   [],
 283   [case "$os_win32" in
 284      yes) with_gconf=no ;;
 285      *) with_gconf=yes ;;
 286    esac])
 287 AC_MSG_RESULT([$with_gconf])
 288
 289 AM_CONDITIONAL([WITH_GCONF],[test "$with_gconf" = "yes"])
 290
 291 if test "$with_gconf" = "yes"; then
 292    PKG_CHECK_MODULES([GCONF],[gconf-2.0])
 293    AC_DEFINE([WITH_GCONF],[1],[Define if GConf support is enabled])
 294
 295    AM_GCONF_SOURCE_2
 296
 297    AC_PATH_PROG([GCONFTOOL], [gconftool-2], [false])
 298    if test "$GCONFTOOL" = "false"; then
 299       AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 300    fi
 301 else
 302    AM_CONDITIONAL([GCONF_SCHEMAS_INSTALL],false)
 303 fi
 304
 305 dnl Debug mode
 306
 307 AC_ARG_ENABLE([debug],
 308         AC_HELP_STRING([--enable-debug],
 309                         [Turn on evince debug mode]),,
 310                 [enable_debug=no])
 311
 312 if test "x$enable_debug" = "xyes"; then
 313    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 314 fi
 315
 316 AC_ARG_ENABLE([tests],
 317         AC_HELP_STRING([--enable-tests], [Disable tests]),
 318         enable_tests="$enableval",
 319         enable_tests=yes)
 320
 321 AM_CONDITIONAL(ENABLE_TESTS, test x$enable_tests = xyes)
 322
 323 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 324 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 325 AC_SUBST(LIBDOCUMENT_CFLAGS)
 326 AC_SUBST(LIBDOCUMENT_LIBS)
 327
 328 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $DEBUG_FLAGS"
 329 LIBVIEW_LIBS="$LIBVIEW_LIBS"
 330 AC_SUBST(LIBVIEW_CFLAGS)
 331 AC_SUBST(LIBVIEW_LIBS)
 332
 333 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 334 AC_SUBST(BACKEND_CFLAGS)
 335 AC_SUBST(BACKEND_LIBS)
 336
 337 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $GTKUNIXPRINT_CFLAGS $DBUS_CFLAGS $KEYRING_CFLAGS $GCONF_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 338 SHELL_LIBS="$SHELL_CORE_LIBS $GTKUNIXPRINT_CFLAGS $DBUS_LIBS $KEYRING_LIBS $GCONF_LIBS -lz"
 339 AC_SUBST(SHELL_CFLAGS)
 340 AC_SUBST(SHELL_LIBS)
 341
 342 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 343 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 344 AC_SUBST(FRONTEND_CFLAGS)
 345 AC_SUBST(FRONTEND_LIBS)
 346
 347 EV_DAEMON_CFLAGS="$EV_DAEMON_CFLAGS $DEBUG_FLAGS"
 348 AC_SUBST([EV_DAEMON_CFLAGS])
 349 AC_SUBST([EV_DAEMON_LIBS])
 350
 351 # Check for Nautilus property page build
 352 AC_ARG_ENABLE([nautilus],
 353   [AS_HELP_STRING([--disable-nautilus],[Build the nautilus extensions])],
 354   [],
 355   [case "$with_platform" in
 356      gnome) enable_nautilus=yes ;;
 357      *) enable_nautilus=no ;;
 358     esac])
 359
 360 if test "$enable_nautilus" = "yes" ; then
 361   PKG_CHECK_MODULES([NAUTILUS],[gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension],
 362                     [],[AC_MSG_ERROR([libnautilus-extension not found; use --disable-nautilus to disable the nautilus extensions])])
 363   NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 364   AC_SUBST([nautilusextensiondir],[$NAUTILUS_EXTENSION_DIR])
 365   AC_SUBST(NAUTILUS_CFLAGS)
 366   AC_SUBST(NAUTILUS_LIBS)
 367
 368   AC_DEFINE([HAVE_NAUTILUS],[1], [defined if you build the nautilus plugin])
 369 fi
 370
 371 AM_CONDITIONAL([ENABLE_NAUTILUS],[test "$enable_nautilus" = "yes"])
 372
 373 # Check for thumbnailer build
 374
 375 AC_ARG_ENABLE([thumbnailer],
 376   [AS_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer])],
 377   [],
 378   [case "$with_platform" in
 379      gnome) enable_thumbnailer=yes ;;
 380      *) enable_thumbnailer=no ;;
 381     esac])
 382
 383 AM_CONDITIONAL([ENABLE_THUMBNAILER],[test "$enable_thumbnailer" = "yes"])
 384
 385 # ***************
 386 # Print Previewer
 387 # ***************
 388
 389 AC_ARG_ENABLE([previewer],
 390   [AS_HELP_STRING([--disable-previewer],[disable the GNOME Document Previewer])],
 391   [],
 392   [case "$with_platform" in
 393       gnome) enable_previewer=yes ;;
 394       *) enable_previewer=no ;;
 395     esac])
 396
 397 if test x$enable_previewer = "xyes" ; then
 398   PKG_CHECK_MODULES([PREVIEWER],[gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED])
 399 fi
 400
 401 AM_CONDITIONAL([ENABLE_PREVIEWER],[test "$enable_previewer" = "yes"])
 402 PREVIEWER_CFLAGS="$PREVIEWER_CFLAGS $GTKUNIXPRINT_CFLAGS $DEBUG_FLAGS"
 403 PREVIEWER_LIBS="$PREVIEWER_LIBS $GTKUNIXPRINT_LIBS -lz"
 404 AC_SUBST(PREVIEWER_CFLAGS)
 405 AC_SUBST(PREVIEWER_LIBS)
 406
 407 # ***
 408 # GIR
 409 # ***
 410
 411 AC_MSG_CHECKING([whether GObject introspection is requested])
 412 AC_ARG_ENABLE([introspection],
 413         AS_HELP_STRING([--enable-introspection],[Enable GObject introspection]),
 414         [],[enable_introspection=no])
 415 AC_MSG_RESULT([$enable_introspection])
 416
 417 G_IR_SCANNER=
 418 G_IR_COMPILER=
 419 G_IR_GENERATE=
 420 GIRDIR=
 421 GIRTYPELIBDIR=
 422
 423 if test "$enable_introspection" = "yes"; then
 424   GOBJECT_INTROSPECTION_REQUIRED=0.6
 425   PKG_CHECK_MODULES([GOBJECT_INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
 426
 427   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
 428   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
 429   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
 430   GIRDIR="$($PKG_CONFIG --variable=girdir gobject-introspection-1.0)"
 431   GIRTYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
 432 fi
 433
 434 AC_SUBST([G_IR_SCANNER])
 435 AC_SUBST([G_IR_COMPILER])
 436 AC_SUBST([G_IR_GENERATE])
 437 AC_SUBST([GIRDIR])
 438 AC_SUBST([GIRTYPELIBDIR])
 439
 440 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
 441
 442 dnl ================== portability checks ===========================================
 443
 444 dnl for backtrace()
 445 AC_CHECK_HEADERS([execinfo.h])
 446
 447 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 448   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 449   ],[],[#include <langinfo.h>])
 450
 451 dnl ================== pdf checks ===================================================
 452 AC_ARG_ENABLE(pdf,
 453               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 454
 455 if test "x$enable_pdf" = "xyes"; then
 456     POPPLER_REQUIRED=0.12.0
 457     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED,enable_pdf=yes,enable_pdf=no)
 458
 459     if test "x$enable_pdf" = "xyes"; then
 460             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 461             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 462             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 463
 464             evince_save_LIBS=$LIBS
 465             LIBS="$LIBS $POPPLER_LIBS"
 466             AC_CHECK_FUNCS(poppler_page_render)
 467             AC_CHECK_FUNCS(poppler_page_get_image)
 468             LIBS=$evince_save_LIBS
 469
 470             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 471             if test x$enable_cairo_pdf = xyes; then
 472                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 473             fi
 474
 475             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 476             if test x$enable_cairo_ps = xyes; then
 477                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 478             fi
 479     else
 480             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 481     fi
 482 fi
 483
 484 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 485 dnl ================== end of pdf checks ============================================
 486
 487 dnl libspectre (used by ps and dvi backends)
 488 SPECTRE_REQUIRED=0.2.0
 489 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 490 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 491 if test "x$have_spectre" = "xyes"; then
 492    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 493 fi
 494
 495 dnl ================== ps checks ====================================================
 496 AC_ARG_ENABLE(ps,
 497         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 498
 499 if test "x$enable_ps" = "xyes"; then
 500    if test "x$have_spectre" = "xyes"; then
 501       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 502    else
 503       enable_ps="no"
 504       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 505    fi
 506 fi
 507 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 508 dnl ======================== End of ps checks ===================================
 509
 510 dnl ================== tiff checks ===================================================
 511 AC_ARG_ENABLE(tiff,
 512             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 513
 514 if test "x$enable_tiff" = "xyes"; then
 515     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 516     if test "x$enable_tiff" = "xyes"; then
 517         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 518         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 519     fi
 520     if test "x$enable_tiff" = "xyes"; then
 521             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 522     else
 523             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 524     fi
 525 fi
 526
 527 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 528 dnl ================== end of tiff checks ============================================
 529
 530 dnl ================== djvu checks ===================================================
 531
 532 AC_ARG_ENABLE(djvu,
 533             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=yes)
 534
 535 if test "x$enable_djvu" = "xyes"; then
 536     DJVULIBRE_REQUIRED=3.5.17
 537     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 538
 539     if test "x$enable_djvu" = "xyes"; then
 540         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 541     else
 542         AC_MSG_WARN([
 543 ** Djvu support is disabled since a recent version of the djvulibre
 544 ** library was not found. You need at least djvulibre-3.5.17 which
 545 ** can be found on http://djvulibre.djvuzone.org
 546 ])
 547     fi
 548 fi
 549
 550 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 551
 552 dnl ================== End of djvu checks ===================================================
 553
 554 dnl ================== dvi checks ===================================================
 555
 556 AC_ARG_ENABLE(dvi,
 557             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=yes)
 558
 559 AC_ARG_ENABLE(t1lib,
 560             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 561
 562 if test "x$enable_dvi" = "xyes"; then
 563     AC_C_CONST
 564     AC_C_INLINE
 565     AC_TYPE_SIZE_T
 566     AC_CHECK_SIZEOF(long, 4)
 567     AC_CHECK_SIZEOF(int, 4)
 568     AC_CHECK_SIZEOF(short, 2)
 569     AC_CHECK_SIZEOF(void *, 4)
 570     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 571
 572     if test "x$enable_dvi" = "xyes"; then
 573         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 574     else
 575         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 576     fi
 577 fi
 578 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 579
 580 if test "x$enable_dvi" = "xyes"; then
 581     if test "x$enable_type1_fonts" = "xyes"; then
 582         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 583     fi
 584
 585     if test "x$enable_type1_fonts" = xyes; then
 586         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 587     fi
 588 else
 589     enable_type1_fonts=no
 590 fi
 591 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 592
 593 dnl ================== End of dvi checks ===================================================
 594
 595 dnl ================== pixbuf checks ===================================================
 596
 597 AC_ARG_ENABLE(pixbuf,
 598             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 599 if test "x$enable_pixbuf" = "xyes"; then
 600         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 601 fi
 602 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 603
 604 dnl ================== End of pixbuf checks ===================================================
 605
 606 dnl ================== comic book checks ===================================================
 607
 608 AC_ARG_ENABLE(comics,
 609         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=yes)
 610 if test "x$enable_comics" = "xyes"; then
 611         if test "x$os_win32" = "xyes"; then
 612                 # The comics backend is disabled on windows because:
 613                 # 1) it uses unix functions from sys/wait.h.
 614                 # 2) it uses external decompression tools not generally available on windows.
 615                 enable_comics=no
 616                 AC_MSG_WARN(The comics backend is not supported on windows.)
 617         else
 618                 AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 619         fi
 620 fi
 621 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 622
 623 dnl ================== End of comic book checks ============================================
 624
 625 dnl ================== impress book checks ===================================================
 626
 627 AC_ARG_ENABLE(impress,
 628         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 629 if test "x$enable_impress" = "xyes"; then
 630         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 631 fi
 632 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 633
 634 dnl ================== End of impress book checks ============================================
 635
 636 dnl =================== Mime types list ====================================================
 637
 638 if test "x$enable_pdf" = "xyes" ; then
 639         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 640 fi
 641 if test "x$enable_ps" = "xyes" ; then
 642         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 643 fi
 644 if test "x$enable_dvi" = "xyes"; then
 645         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 646 fi
 647 if test "x$enable_djvu" = "xyes"; then
 648         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 649 fi
 650 if test "x$enable_tiff" = "xyes"; then
 651         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 652 fi
 653 if test "x$enable_comics" = "xyes"; then
 654         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;"
 655 fi
 656 if test "x$enable_pixbuf" = "xyes"; then
 657         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 658 fi
 659 if test "x$enable_impress" = "xyes"; then
 660         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 661 fi
 662 AC_SUBST(EVINCE_MIME_TYPES)
 663
 664 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 665
 666 # Backends directory
 667
 668 AC_SUBST([backenddir],"\$(libdir)/evince/ev_binary_version/backends")
 669 AC_SUBST([backend_binary_version],"ev_binary_version")
 670
 671 # Versioning
 672
 673 AC_SUBST([EV_MAJOR_VERSION],[ev_major_version])
 674 AC_SUBST([EV_MINOR_VERSION],[ev_minor_version])
 675 AC_SUBST([EV_MICRO_VERSION],[ev_micro_version])
 676
 677 AC_SUBST([EV_API_VERSION],[ev_api_version])
 678 AC_SUBST([EV_BINARY_VERSION],[ev_binary_version])
 679
 680 AC_SUBST([EV_DOCUMENT_LT_VERSION_INFO],[ev_document_lt_version_info])
 681 AC_SUBST([EV_DOCUMENT_LT_CURRENT_MINUS_AGE],[ev_document_lt_current_minus_age])
 682 AC_SUBST([EV_VIEW_LT_VERSION_INFO],[ev_view_lt_version_info])
 683 AC_SUBST([EV_VIEW_LT_CURRENT_MINUS_AGE],[ev_view_lt_current_minus_age])
 684
 685 # *****************************************************************************
 686
 687 AC_CONFIG_FILES([
 688 backend/Makefile
 689 backend/comics/Makefile
 690 backend/djvu/Makefile
 691 backend/dvi/Makefile
 692 backend/dvi/mdvi-lib/Makefile
 693 backend/impress/Makefile
 694 backend/pdf/Makefile
 695 backend/pixbuf/Makefile
 696 backend/ps/Makefile
 697 backend/tiff/Makefile
 698 cut-n-paste/Makefile
 699 cut-n-paste/evinfobar/Makefile
 700 cut-n-paste/gimpcellrenderertoggle/Makefile
 701 cut-n-paste/smclient/Makefile
 702 cut-n-paste/toolbar-editor/Makefile
 703 cut-n-paste/zoom-control/Makefile
 704 cut-n-paste/totem-screensaver/Makefile
 705 data/evince.desktop.in
 706 data/Makefile
 707 data/icons/Makefile
 708 data/icons/16x16/Makefile
 709 data/icons/16x16/apps/Makefile
 710 data/icons/16x16/actions/Makefile
 711 data/icons/22x22/Makefile
 712 data/icons/22x22/apps/Makefile
 713 data/icons/22x22/actions/Makefile
 714 data/icons/24x24/Makefile
 715 data/icons/24x24/apps/Makefile
 716 data/icons/24x24/actions/Makefile
 717 data/icons/32x32/Makefile
 718 data/icons/32x32/actions/Makefile
 719 data/icons/48x48/Makefile
 720 data/icons/48x48/apps/Makefile
 721 data/icons/48x48/actions/Makefile
 722 data/icons/scalable/Makefile
 723 data/icons/scalable/apps/Makefile
 724 help/Makefile
 725 help/reference/Makefile
 726 help/reference/libdocument/Makefile
 727 help/reference/libdocument/version.xml
 728 help/reference/libview/Makefile
 729 help/reference/libview/version.xml
 730 help/reference/shell/Makefile
 731 help/reference/shell/version.xml
 732 libdocument/Makefile
 733 libdocument/ev-version.h
 734 libmisc/Makefile
 735 libview/Makefile
 736 Makefile
 737 po/Makefile.in
 738 previewer/Makefile
 739 properties/Makefile
 740 shell/Makefile
 741 test/Makefile
 742 thumbnailer/Makefile
 743 ])
 744
 745 AC_CONFIG_FILES(evince-document-[]ev_api_version[].pc:evince-document.pc.in)
 746 AC_CONFIG_FILES(evince-view-[]ev_api_version[].pc:evince-view.pc.in)
 747
 748 AC_OUTPUT
 749
 750 echo "
 751 Configure summary:
 752         Platform...........:  $with_platform
 753         GConf Support......:  $with_gconf
 754         GTK+ Unix Print....:  $with_gtk_unix_print
 755         Keyring Support....:  $with_keyring
 756         DBUS Support.......:  $enable_dbus
 757         SM client support..:  $with_smclient
 758         Nautilus Plugin....:  $enable_nautilus
 759         Thumbnailer........:  $enable_thumbnailer
 760         Previewer..........:  $enable_previewer
 761         Gtk-Doc Support....:  $enable_gtk_doc
 762         Debug mode.........:  $enable_debug
 763         GObj. Introspection:  $enable_introspection
 764         Tests..............:  $enable_tests
 765
 766         PDF Backend........:  $enable_pdf
 767         PostScript Backend.:  $enable_ps
 768         TIFF Backend.......:  $enable_tiff
 769         DJVU Backend.......:  $enable_djvu
 770         DVI Backend........:  $enable_dvi
 771         Pixbuf Backend.....:  $enable_pixbuf
 772         Comics Backend.....:  $enable_comics
 773         Impress Backend....:  $enable_impress
 774 "