configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.57)
   4 AC_INIT(evince, 0.3.2)
   5 AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)
   6
   7 GNOME_COMMON_INIT
   8 GNOME_MAINTAINER_MODE_DEFINES
   9 GNOME_COMPILE_WARNINGS
  10 GNOME_CXX_WARNINGS
  11
  12 AM_CONFIG_HEADER(config.h)
  13
  14 AM_MAINTAINER_MODE
  15
  16 AM_PROG_LIBTOOL
  17
  18 AC_ISC_POSIX
  19 AC_PROG_CC
  20 AM_PROG_CC_STDC
  21 AC_PROG_CXX
  22 AC_STDC_HEADERS
  23 AC_PROG_INTLTOOL
  24 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  25 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  26
  27 GNOME_DEBUG_CHECK
  28
  29 ALL_LINGUAS="bg ca cs da de el en_CA en_GB es eu fi fr hu ja ko lt nb nl no pt_BR ru rw sk sv th uk wa zh_CN zh_TW"
  30
  31 AM_GLIB_GNU_GETTEXT
  32
  33 GETTEXT_PACKAGE=AC_PACKAGE_NAME
  34 AC_SUBST(GETTEXT_PACKAGE)
  35 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package.])
  36
  37 POPPLER_REQUIRED=0.3.3
  38 DBUS_GLIB_REQUIRED=0.33
  39 GTK_REQUIRED=2.6.0
  40 LIBGNOMEUI_REQUIRED=2.6.0
  41
  42 PKG_CHECK_MODULES(TOOLBAR_EDITOR, gtk+-2.0 >= $GTK_REQUIRED libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED)
  43 PKG_CHECK_MODULES(RECENT_FILES, gtk+-2.0 >= $GTK_REQUIRED libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED)
  44 PKG_CHECK_MODULES(ZOOM_CONTROL, gtk+-2.0 >= $GTK_REQUIRED)
  45 PKG_CHECK_MODULES(SHELL, gtk+-2.0 >= $GTK_REQUIRED libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED gnome-vfs-2.0 libgnomeprint-2.2 >= 2.5.1 libgnomeprintui-2.2 libglade-2.0 gconf-2.0 poppler-glib >= $POPPLER_REQUIRED)
  46 PKG_CHECK_MODULES(THUMBNAILER, gtk+-2.0 >= $GTK_REQUIRED gnome-vfs-2.0)
  47 PKG_CHECK_MODULES(PROPERTIES, gtk+-2.0 >= $GTK_REQUIRED libglade-2.0)
  48 PKG_CHECK_MODULES(DVI, gtk+-2.0 >= $GTK_REQUIRED)
  49 PKG_CHECK_MODULES(PS, gtk+-2.0 >= $GTK_REQUIRED gnome-vfs-2.0 libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED)
  50 PKG_CHECK_MODULES(PDF, gtk+-2.0 >= $GTK_REQUIRED poppler-glib >= $POPPLER_REQUIRED)
  51 PKG_CHECK_MODULES(PIXBUF, gtk+-2.0 >= $GTK_REQUIRED)
  52 PKG_CHECK_MODULES(TIFF, gtk+-2.0 >= $GTK_REQUIRED)
  53 PKG_CHECK_MODULES(LIB, gtk+-2.0 >= $GTK_REQUIRED libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED)
  54 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
  55
  56 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
  57 AC_SUBST(GLIB_GENMARSHAL)
  58
  59 PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
  60         [enable_dbus=yes],[enable_dbus=no])
  61 AC_SUBST([DBUS_CFLAGS])
  62 AC_SUBST([DBUS_LIBS])
  63
  64 if test "x$enable_dbus" = "xno"; then
  65         AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
  66 fi
  67
  68 if test "x$enable_dbus" = "xyes" ; then
  69         AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
  70
  71         if test x$DBUS_BINDING_TOOL = "xno" ; then
  72                 AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
  73         fi
  74
  75         AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
  76         AC_DEFINE([ENABLE_METADATA],[1],[Define if metadata support is enabled])
  77
  78         DBUS_VERSION=`$PKG_CONFIG --modversion dbus-glib-1 | sed 's/0.\([[0-9]]*\)/\1/'`
  79         AC_DEFINE_UNQUOTED(DBUS_VERSION, $DBUS_VERSION, [DBUS version.])
  80 fi
  81
  82 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
  83 AM_CONDITIONAL([ENABLE_METADATA], [test "x$enable_dbus" = "xyes"])
  84 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
  85
  86 dnl Check for Nautilus property page build
  87 AC_ARG_ENABLE(nautilus,
  88         AC_HELP_STRING([--enable-nautilus],[compile the nautilus plugin]),
  89         [case "${enableval}" in
  90         yes) ENABLE_NAUTILUS=yes ;;
  91         no) ENABLE_NAUTILUS=no ;;
  92         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nautilus) ;;
  93         esac],
  94         [ENABLE_NAUTILUS=yes]) dnl Default value
  95
  96 if test x$ENABLE_NAUTILUS = "xyes" ; then
  97         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
  98                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
  99 fi
 100
 101 AC_SUBST(NAUTILUS_CFLAGS)
 102 AC_SUBST(NAUTILUS_LIBS)
 103 if test x$HAVE_NAUTILUS = "xyes"; then
 104         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
 105 fi
 106 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
 107
 108 evince_save_LIBS=$LIBS
 109 LIBS="$LIBS $GTK_LIBS"
 110 AC_CHECK_FUNCS(gtk_icon_view_get_visible_range)
 111 LIBS=$evince_save_LIBS
 112
 113 AM_GCONF_SOURCE_2
 114
 115 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
 116 if test "x$GCONFTOOL" = "xno"; then
 117         AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 118 fi
 119
 120 dnl ================== ggv checks ===================================================
 121 AC_ARG_WITH(gs-pkg,
 122             [  --with-gs=dir       Directory Where GhostScript package is installed.])
 123
 124 if test "x$with_gs" = "x"; then
 125         AC_PATH_PROG(GS_PROG, gs)
 126         if test -z "$GS_PROG"; then
 127                 AC_MSG_ERROR(Unable to find GhostScript in the PATH. Provide the full path for GhostScript(--with-gs=PATH). You need to have Ghostscript installed in order to run evince)
 128         fi
 129 else
 130         GS_PROG=$with_gs
 131 fi
 132
 133 AC_DEFINE_UNQUOTED(GS_PATH, "$GS_PROG", [Path to the 'gs' executable.])
 134
 135
 136 dnl check for GS version
 137 AC_MSG_CHECKING(for Ghostscript version...)
 138 GS_VERSION=`gs --version | head -n 1 | sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
 139 AC_MSG_RESULT(found $GS_VERSION)
 140 if test "$GS_VERSION" -lt "7"; then
 141         AC_MSG_ERROR([You need Ghostscript version >= 7 in order to run evince])
 142 fi
 143 AA_PARMS="-sDEVICE=x11alpha -dNOPLATFONTS"
 144 AC_DEFINE_UNQUOTED(ALPHA_PARAMS, "$AA_PARMS", [Anti-aliasing parameters for Ghostscript.])
 145 AC_MSG_RESULT(Antialiasing parameters for Ghostscript: $AA_PARMS)
 146 dnl ======================== End of ggv checks =================================
 147
 148 dnl ================== tiff checks ===================================================
 149 AC_ARG_ENABLE(tiff,
 150             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 151
 152 if test "x$enable_tiff" = "xyes"; then
 153     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 154     if test "x$enable_tiff" = "xyes"; then
 155         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 156         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 157     fi
 158     if test "x$enable_tiff" = "xyes"; then
 159             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 160     else
 161             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 162     fi
 163 fi
 164
 165 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 166 dnl ================== end of tiff checks ============================================
 167
 168 dnl ================== djvu checks ===================================================
 169
 170 AC_ARG_ENABLE(djvu,
 171             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=no)
 172
 173 if test "x$enable_djvu" = "xyes"; then
 174     AC_CHECK_HEADERS([libdjvu/ddjvuapi.h],enable_djvu=yes,enable_djvu=no,)
 175
 176     if test "x$enable_djvu" = "xyes"; then
 177         AC_CHECK_LIB([djvulibre],ddjvu_context_create,enable_djvu=yes,enable_djvu=no,"-lpthread")
 178         AC_CHECK_LIB([djvulibre],ddjvu_document_get_pageinfo,enable_djvu=yes,enable_djvu=no,"-lpthread")
 179     fi
 180
 181     if test "x$enable_djvu" = "xyes"; then
 182         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 183     else
 184         AC_MSG_WARN([
 185 ** Djvu support is disabled since recent version of djvulibre
 186 ** library was not found. To get proper djvu support you need to
 187 ** install development version of djvulibre. You can get it from
 188 ** anonymous CVS server on djvulibre.sf.net. Just use something
 189 ** like:
 190
 191 ** cvs -d :pserver:anonymous@cvs.sourceforge.net:/cvsroot/djvu co djvulibre-3.5
 192 ])
 193     fi
 194 fi
 195
 196 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 197
 198 dnl ================== End of djvu checks ===================================================
 199
 200 dnl ================== dvi checks ===================================================
 201
 202 AC_ARG_ENABLE(dvi,
 203             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=no)
 204
 205 AC_ARG_ENABLE(t1lib,
 206             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 207
 208 if test "x$enable_dvi" = "xyes"; then
 209     AC_C_CONST
 210     AC_C_INLINE
 211     AC_TYPE_SIZE_T
 212     AC_CHECK_SIZEOF(long, 4)
 213     AC_CHECK_SIZEOF(int, 4)
 214     AC_CHECK_SIZEOF(short, 2)
 215     AC_CHECK_SIZEOF(void *, 4)
 216     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 217
 218     if test "x$enable_dvi" = "xyes"; then
 219         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 220     else
 221         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 222     fi
 223 fi
 224 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 225
 226 if test "x$enable_dvi" = "xyes"; then
 227     if test "x$enable_type1_fonts" = "xyes"; then
 228         AC_CHECK_LIB([t1lib],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no)
 229     fi
 230
 231     if test "x$enable_type1_fonts" = xyes; then
 232         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 233     fi
 234 else
 235     enable_type1_fonts=no
 236 fi
 237 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 238
 239 dnl ================== End of dvi checks ===================================================
 240
 241 dnl =================== Mime types list ====================================================
 242
 243 EVINCE_MIME_TYPES="application/pdf;application/postscript;application/x-gzpostscript"
 244
 245 if test "x$enable_dvi" = "xyes"; then
 246         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;application/x-dvi"
 247 fi
 248 if test "x$enable_djvu" = "xyes"; then
 249         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;image/vnd.djvu"
 250 fi
 251 if test "x$enable_tiff" = "xyes"; then
 252         EVINCE_MIME_TYPES="$EVINCE_MIME_TYPES;image/tiff"
 253 fi
 254 AC_SUBST(EVINCE_MIME_TYPES)
 255
 256 AC_OUTPUT([
 257 Makefile
 258 cut-n-paste/Makefile
 259 cut-n-paste/recent-files/Makefile
 260 cut-n-paste/zoom-control/Makefile
 261 cut-n-paste/toolbar-editor/Makefile
 262 data/Makefile
 263 data/evince.desktop.in
 264 lib/Makefile
 265 pdf/Makefile
 266 pixbuf/Makefile
 267 tiff/Makefile
 268 ps/Makefile
 269 djvu/Makefile
 270 dvi/Makefile
 271 dvi/mdvi-lib/Makefile
 272 po/Makefile.in
 273 backend/Makefile
 274 properties/Makefile
 275 shell/Makefile
 276 thumbnailer/Makefile
 277 help/Makefile
 278 help/C/Makefile
 279 ])