configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.57)
   4 AC_INIT([Evince],[2.25.4],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
   5 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-dist-gzip])
   6
   7 EV_API_VERSION=2.25
   8 AC_SUBST(EV_API_VERSION)
   9
  10 AM_CONFIG_HEADER(config.h)
  11
  12 AM_MAINTAINER_MODE
  13
  14 AM_PROG_LIBTOOL
  15
  16 AC_ISC_POSIX
  17 AC_PROG_CC
  18 AM_PROG_CC_STDC
  19 AC_PROG_CXX
  20 AC_STDC_HEADERS
  21 IT_PROG_INTLTOOL([0.35.0])
  22 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  23 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  24
  25 GNOME_COMMON_INIT
  26 GNOME_DOC_INIT
  27 GNOME_MAINTAINER_MODE_DEFINES
  28 GNOME_COMPILE_WARNINGS
  29 GNOME_CXX_WARNINGS
  30
  31 GTK_DOC_CHECK(1.0)
  32
  33 GETTEXT_PACKAGE=evince
  34 AC_SUBST(GETTEXT_PACKAGE)
  35 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  36 AM_GLIB_GNU_GETTEXT
  37
  38 dnl Check dependencies
  39
  40 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
  41 # BACKEND_CFLAGS   for backend implementations.
  42 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
  43 # FRONTEND_LIBS
  44 # SHELL_CFLAGS     for shell implementation.
  45 # SHELL_LIBS
  46
  47 DBUS_GLIB_REQUIRED=0.70
  48 GTK_REQUIRED=2.12.0
  49 GLIB_REQUIRED=2.18.0
  50 KEYRING_REQUIRED=2.22.0
  51
  52 GNOME_ICON_THEME_REQUIRED=2.17.1
  53 LIBXML_REQUIRED=2.5.0
  54
  55 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
  56 PKG_CHECK_MODULES(LIBVIEW, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
  57 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
  58 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
  59 PKG_CHECK_MODULES(SHELL_CORE, libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED gthread-2.0 gconf-2.0)
  60
  61 PKG_CHECK_MODULES(SMCLIENT, gtk+-2.0 gthread-2.0)
  62 AC_SUBST(SMCLIENT_CFLAGS)
  63 AC_SUBST(SMCLIENT_LIBS)
  64
  65 BACKEND_LIBTOOL_FLAGS="-module -avoid-version"
  66 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
  67
  68 dnl ===== Check special functions
  69 evince_save_LIBS=$LIBS
  70 LIBS="$LIBS $BACKEND_LIBS"
  71 AC_CHECK_FUNCS(cairo_format_stride_for_width)
  72 LIBS=$evince_save_LIBS
  73
  74 AC_ARG_WITH(keyring,
  75         AC_HELP_STRING([--without-keyring],[disable the use of gnome-keyring]),
  76         [case "${withval}" in
  77         yes) WITH_KEYRING=yes ;;
  78         no) WITH_KEYRING=no ;;
  79         *) AC_MSG_ERROR(bad value ${withval} for --with-keyring) ;;
  80         esac],
  81         [WITH_KEYRING=yes]) dnl Default value
  82 AM_CONDITIONAL(WITH_KEYRING, test x$WITH_KEYRING = "xyes")
  83
  84 if test x$WITH_KEYRING = "xyes"; then
  85         PKG_CHECK_MODULES(KEYRING, gnome-keyring-1 >= $KEYRING_REQUIRED)
  86         AC_DEFINE([WITH_KEYRING],[1],[Define if KEYRING support is enabled])
  87 fi
  88
  89 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
  90 AC_SUBST(GLIB_GENMARSHAL)
  91
  92 dnl ========= Check for DBUS
  93 AC_ARG_ENABLE(dbus,
  94         [AC_HELP_STRING([--enable-dbus], [Compile with support for dbus])],
  95         enable_dbus="$enableval",enable_dbus=yes)
  96 if test "x$enable_dbus" != "xno"; then
  97         PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
  98         [enable_dbus=yes],[enable_dbus=no])
  99
 100         if test "x$enable_dbus" = "xno"; then
 101            AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
 102         fi
 103
 104         if test "x$enable_dbus" = "xyes" ; then
 105                 AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 106
 107                 if test x$DBUS_BINDING_TOOL = "xno" ; then
 108                         AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 109                 fi
 110
 111                 AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 112         fi
 113 fi
 114
 115 AC_SUBST([DBUS_CFLAGS])
 116 AC_SUBST([DBUS_LIBS])
 117
 118 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
 119 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
 120
 121 dnl Debug mode
 122 AC_ARG_ENABLE([debug],
 123         AC_HELP_STRING([--enable-debug],
 124                         [Turn on evince debug mode]),,
 125                 [enable_debug=no])
 126
 127 if test "x$enable_debug" = "xyes"; then
 128    DEBUG_FLAGS="-DEV_ENABLE_DEBUG"
 129 fi
 130
 131
 132 LIBDOCUMENT_CFLAGS="$LIBDOCUMENT_CFLAGS $DEBUG_FLAGS"
 133 LIBDOCUMENT_LIBS="$LIBDOCUMENT_LIBS"
 134 AC_SUBST(LIBDOCUMENT_CFLAGS)
 135 AC_SUBST(LIBDOCUMENT_LIBS)
 136
 137 LIBVIEW_CFLAGS="$LIBVIEW_CFLAGS $DEBUG_FLAGS"
 138 LIBVIEW_LIBS="$LIBVIEW_LIBS"
 139 AC_SUBST(LIBVIEW_CFLAGS)
 140 AC_SUBST(LIBVIEW_LIBS)
 141
 142 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 143 AC_SUBST(BACKEND_CFLAGS)
 144 AC_SUBST(BACKEND_LIBS)
 145
 146 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS $KEYRING_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE $DEBUG_FLAGS"
 147 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS $KEYRING_LIBS -lz"
 148 AC_SUBST(SHELL_CFLAGS)
 149 AC_SUBST(SHELL_LIBS)
 150
 151 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $DEBUG_FLAGS"
 152 FRONTEND_LIBS="$FRONTEND_CORE_LIBS -lz"
 153 AC_SUBST(FRONTEND_CFLAGS)
 154 AC_SUBST(FRONTEND_LIBS)
 155
 156 dnl Check for Nautilus property page build
 157 AC_ARG_ENABLE(nautilus,
 158         AC_HELP_STRING([--enable-nautilus],[compile the nautilus plugin]),
 159         [case "${enableval}" in
 160         yes) ENABLE_NAUTILUS=yes ;;
 161         no) ENABLE_NAUTILUS=no ;;
 162         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nautilus) ;;
 163         esac],
 164         [ENABLE_NAUTILUS=yes]) dnl Default value
 165
 166 if test x$ENABLE_NAUTILUS = "xyes" ; then
 167         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
 168                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
 169         NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 170         AC_SUBST(NAUTILUS_EXTENSION_DIR)
 171 fi
 172
 173 AC_SUBST(NAUTILUS_CFLAGS)
 174 AC_SUBST(NAUTILUS_LIBS)
 175 if test x$HAVE_NAUTILUS = "xyes"; then
 176         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
 177 fi
 178 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
 179
 180
 181 dnl Check for thumbnailer build
 182 AC_ARG_ENABLE(thumbnailer,
 183         AC_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer]),
 184         [case "${enableval}" in
 185         yes) ENABLE_THUMBNAILER=yes ;;
 186         no) ENABLE_THUMBNAILER=no ;;
 187         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thumbnailer) ;;
 188         esac],
 189         [ENABLE_THUMBNAILER=yes]) dnl Default value
 190 AM_CONDITIONAL(ENABLE_THUMBNAILER, test x$ENABLE_THUMBNAILER = "xyes")
 191
 192 dnl GConf configuration
 193 AM_GCONF_SOURCE_2
 194
 195 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
 196 if test "x$GCONFTOOL" = "xno"; then
 197         AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 198 fi
 199
 200 dnl ================== portability checks ===========================================
 201
 202 dnl for backtrace()
 203 AC_CHECK_HEADERS([execinfo.h])
 204
 205 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 206   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 207   ],[],[#include <langinfo.h>])
 208
 209 dnl ================== pdf checks ===================================================
 210 AC_ARG_ENABLE(pdf,
 211               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 212
 213 if test "x$enable_pdf" = "xyes"; then
 214     POPPLER_REQUIRED=0.8.0
 215     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED,enable_pdf=yes,enable_pdf=no)
 216
 217     if test "x$enable_pdf" = "xyes"; then
 218             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 219             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 220             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 221
 222             evince_save_LIBS=$LIBS
 223             LIBS="$LIBS $POPPLER_LIBS"
 224             AC_CHECK_FUNCS(poppler_page_render)
 225             AC_CHECK_FUNCS(poppler_layers_iter_new)
 226             LIBS=$evince_save_LIBS
 227
 228             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 229             if test x$enable_cairo_pdf = xyes; then
 230                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 231             fi
 232
 233             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 234             if test x$enable_cairo_ps = xyes; then
 235                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 236             fi
 237     else
 238             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 239     fi
 240 fi
 241
 242 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 243 dnl ================== end of pdf checks ============================================
 244
 245 dnl libspectre (used by ps and dvi backends)
 246 SPECTRE_REQUIRED=0.2.0
 247 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 248 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 249 if test "x$have_spectre" = "xyes"; then
 250    AC_DEFINE([HAVE_SPECTRE], [1], [Have libspectre])
 251 fi
 252
 253 dnl ================== ps checks ====================================================
 254 AC_ARG_ENABLE(ps,
 255         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 256
 257 if test "x$enable_ps" = "xyes"; then
 258    if test "x$have_spectre" = "xyes"; then
 259       AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 260    else
 261       enable_ps="no"
 262       AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) is needed])
 263    fi
 264 fi
 265 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 266 dnl ======================== End of ps checks ===================================
 267
 268 dnl ================== tiff checks ===================================================
 269 AC_ARG_ENABLE(tiff,
 270             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 271
 272 if test "x$enable_tiff" = "xyes"; then
 273     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 274     if test "x$enable_tiff" = "xyes"; then
 275         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 276         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 277     fi
 278     if test "x$enable_tiff" = "xyes"; then
 279             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 280     else
 281             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 282     fi
 283 fi
 284
 285 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 286 dnl ================== end of tiff checks ============================================
 287
 288 dnl ================== djvu checks ===================================================
 289
 290 AC_ARG_ENABLE(djvu,
 291             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=yes)
 292
 293 if test "x$enable_djvu" = "xyes"; then
 294     DJVULIBRE_REQUIRED=3.5.17
 295     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 296
 297     if test "x$enable_djvu" = "xyes"; then
 298         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 299     else
 300         AC_MSG_WARN([
 301 ** Djvu support is disabled since a recent version of the djvulibre
 302 ** library was not found. You need at least djvulibre-3.5.17 which
 303 ** can be found on http://djvulibre.djvuzone.org
 304 ])
 305     fi
 306 fi
 307
 308 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 309
 310 dnl ================== End of djvu checks ===================================================
 311
 312 dnl ================== dvi checks ===================================================
 313
 314 AC_ARG_ENABLE(dvi,
 315             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=yes)
 316
 317 AC_ARG_ENABLE(t1lib,
 318             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 319
 320 if test "x$enable_dvi" = "xyes"; then
 321     AC_C_CONST
 322     AC_C_INLINE
 323     AC_TYPE_SIZE_T
 324     AC_CHECK_SIZEOF(long, 4)
 325     AC_CHECK_SIZEOF(int, 4)
 326     AC_CHECK_SIZEOF(short, 2)
 327     AC_CHECK_SIZEOF(void *, 4)
 328     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 329
 330     if test "x$enable_dvi" = "xyes"; then
 331         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 332     else
 333         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 334     fi
 335 fi
 336 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 337
 338 if test "x$enable_dvi" = "xyes"; then
 339     if test "x$enable_type1_fonts" = "xyes"; then
 340         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 341     fi
 342
 343     if test "x$enable_type1_fonts" = xyes; then
 344         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 345     fi
 346 else
 347     enable_type1_fonts=no
 348 fi
 349 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 350
 351 dnl ================== End of dvi checks ===================================================
 352
 353 dnl ================== pixbuf checks ===================================================
 354
 355 AC_ARG_ENABLE(pixbuf,
 356             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 357 if test "x$enable_pixbuf" = "xyes"; then
 358         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 359 fi
 360 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 361
 362 dnl ================== End of pixbuf checks ===================================================
 363
 364 dnl ================== comic book checks ===================================================
 365
 366 AC_ARG_ENABLE(comics,
 367         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=yes)
 368 if test "x$enable_comics" = "xyes"; then
 369         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 370 fi
 371 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 372
 373 dnl ================== End of comic book checks ============================================
 374
 375 dnl ================== impress book checks ===================================================
 376
 377 AC_ARG_ENABLE(impress,
 378         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 379 if test "x$enable_impress" = "xyes"; then
 380         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 381 fi
 382 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 383
 384 dnl ================== End of impress book checks ============================================
 385
 386 dnl =================== Mime types list ====================================================
 387
 388 if test "x$enable_pdf" = "xyes" ; then
 389         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 390 fi
 391 if test "x$enable_ps" = "xyes" ; then
 392         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 393 fi
 394 if test "x$enable_dvi" = "xyes"; then
 395         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;application/x-bzdvi;application/x-gzdvi;"
 396 fi
 397 if test "x$enable_djvu" = "xyes"; then
 398         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 399 fi
 400 if test "x$enable_tiff" = "xyes"; then
 401         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 402 fi
 403 if test "x$enable_comics" = "xyes"; then
 404         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;application/x-cb7;"
 405 fi
 406 if test "x$enable_pixbuf" = "xyes"; then
 407         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 408 fi
 409 if test "x$enable_impress" = "xyes"; then
 410         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 411 fi
 412 AC_SUBST(EVINCE_MIME_TYPES)
 413
 414 AC_CHECK_FUNC(localtime_r, AC_DEFINE(HAVE_LOCALTIME_R, 1, [Defines if localtime_r is available on your system]))
 415
 416 AC_CONFIG_FILES([
 417 backend/Makefile
 418 backend/comics/Makefile
 419 backend/djvu/Makefile
 420 backend/dvi/Makefile
 421 backend/dvi/mdvi-lib/Makefile
 422 backend/impress/Makefile
 423 backend/pdf/Makefile
 424 backend/pixbuf/Makefile
 425 backend/ps/Makefile
 426 backend/tiff/Makefile
 427 cut-n-paste/Makefile
 428 cut-n-paste/evmountoperation/Makefile
 429 cut-n-paste/gedit-message-area/Makefile
 430 cut-n-paste/gimpcellrenderertoggle/Makefile
 431 cut-n-paste/smclient/Makefile
 432 cut-n-paste/toolbar-editor/Makefile
 433 cut-n-paste/zoom-control/Makefile
 434 cut-n-paste/totem-screensaver/Makefile
 435 data/evince.desktop.in
 436 data/Makefile
 437 data/icons/Makefile
 438 data/icons/16x16/Makefile
 439 data/icons/16x16/apps/Makefile
 440 data/icons/16x16/actions/Makefile
 441 data/icons/22x22/Makefile
 442 data/icons/22x22/apps/Makefile
 443 data/icons/22x22/actions/Makefile
 444 data/icons/24x24/Makefile
 445 data/icons/24x24/apps/Makefile
 446 data/icons/24x24/actions/Makefile
 447 data/icons/32x32/Makefile
 448 data/icons/32x32/actions/Makefile
 449 data/icons/48x48/Makefile
 450 data/icons/48x48/apps/Makefile
 451 data/icons/48x48/actions/Makefile
 452 data/icons/scalable/Makefile
 453 data/icons/scalable/apps/Makefile
 454 help/Makefile
 455 help/reference/Makefile
 456 help/reference/version.xml
 457 libdocument/Makefile
 458 libview/Makefile
 459 Makefile
 460 po/Makefile.in
 461 properties/Makefile
 462 shell/Makefile
 463 test/Makefile
 464 thumbnailer/Makefile
 465 ])
 466
 467 AC_OUTPUT
 468
 469 echo "
 470 Configure summary:
 471         Keyring Support....:  $WITH_KEYRING
 472         DBUS Support.......:  $enable_dbus
 473         Nautilus Plugin....:  $HAVE_NAUTILUS
 474         Thumbnailer........:  $ENABLE_THUMBNAILER
 475         Gtk-Doc Support....:  $enable_gtk_doc
 476         Debug mode.........:  $enable_debug
 477
 478         PDF Backend........:  $enable_pdf
 479         PostScript Backend.:  $enable_ps
 480         TIFF Backend.......:  $enable_tiff
 481         DJVU Backend.......:  $enable_djvu
 482         DVI Backend........:  $enable_dvi
 483         Pixbuf Backend.....:  $enable_pixbuf
 484         Comics Backend.....:  $enable_comics
 485         Impress Backend....:  $enable_impress
 486 "