configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.57)
   4 AC_INIT([Evince],[2.21.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
   5 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-dist-gzip])
   6
   7 EV_API_VERSION=2.20
   8 AC_SUBST(EV_API_VERSION)
   9
  10 AM_CONFIG_HEADER(config.h)
  11
  12 AM_MAINTAINER_MODE
  13
  14 AM_PROG_LIBTOOL
  15
  16 AC_ISC_POSIX
  17 AC_PROG_CC
  18 AM_PROG_CC_STDC
  19 AC_PROG_CXX
  20 AC_STDC_HEADERS
  21 IT_PROG_INTLTOOL([0.35.0])
  22 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  23 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  24
  25 GNOME_COMMON_INIT
  26 GNOME_DOC_INIT
  27 GNOME_MAINTAINER_MODE_DEFINES
  28 GNOME_COMPILE_WARNINGS
  29 GNOME_CXX_WARNINGS
  30 GNOME_DEBUG_CHECK
  31
  32 GTK_DOC_CHECK(1.0)
  33
  34 GETTEXT_PACKAGE=evince
  35 AC_SUBST(GETTEXT_PACKAGE)
  36 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  37 AM_GLIB_GNU_GETTEXT
  38
  39 dnl Check dependencies
  40
  41 # LIB_CFLAGS       for helpers and generic widgets. (libdocument, cut-and-paste)
  42 # BACKEND_CFLAGS   for backend implementations.
  43 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
  44 # FRONTEND_LIBS
  45 # SHELL_CFLAGS     for shell implementation.
  46 # SHELL_LIBS
  47
  48 DBUS_GLIB_REQUIRED=0.70
  49 GTK_REQUIRED=2.10.0
  50 KEYRING_REQUIRED=0.4.0
  51
  52 LIBGNOMEUI_REQUIRED=2.14.0
  53 LIBGNOME_REQUIRED=2.14.0
  54 LIBGNOMEPRINTUI_REQUIRED=2.6.0
  55 GNOME_ICON_THEME_REQUIRED=2.17.1
  56 LIBXML_REQUIRED=2.5.0
  57
  58 GTK_PRINT_REQUIRED=2.10.0
  59
  60 PKG_CHECK_MODULES(LIB, gtk+-2.0 >= $GTK_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED gnome-vfs-2.0)
  61 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
  62 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED libglade-2.0 gnome-vfs-2.0)
  63 PKG_CHECK_MODULES(SHELL_CORE, libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED gnome-vfs-2.0 libglade-2.0 gconf-2.0 gnome-keyring-1 >= $KEYRING_REQUIRED)
  64
  65 BACKEND_LIBTOOL_FLAGS="-module -avoid-version"
  66 AC_SUBST(BACKEND_LIBTOOL_FLAGS)
  67
  68 AC_ARG_WITH(libgnome,
  69         AC_HELP_STRING([--without-libgnome],[disable the use of libgnome]),
  70         [case "${withval}" in
  71         yes) WITH_GNOME=yes ;;
  72         no) WITH_GNOME=no ;;
  73         *) AC_MSG_ERROR(bad value ${withval} for --with-libgnome) ;;
  74         esac],
  75         [WITH_GNOME=yes]) dnl Default value
  76 AM_CONDITIONAL(WITH_GNOME, test x$WITH_GNOME = "xyes")
  77
  78 if test x$WITH_GNOME = "xyes"; then
  79         PKG_CHECK_MODULES(GNOME, libgnome-2.0 >= $LIBGNOME_REQUIRED)
  80         PKG_CHECK_MODULES(GNOMEUI, libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED)
  81         AC_DEFINE([WITH_GNOME],[1],[Define if GNOME support is enabled])
  82 fi
  83
  84 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
  85 AC_SUBST(GLIB_GENMARSHAL)
  86
  87 dnl ========= Print support
  88 AC_ARG_WITH(print,
  89             [AC_HELP_STRING([--with-print=no/gtk/gnome/auto], [Compile with print support [default=auto]])],
  90             PRINT=$withval,
  91             PRINT="auto")
  92
  93 PKG_CHECK_MODULES(GNOME_PRINT,
  94                   libgnomeprintui-2.2 >= $LIBGNOMEPRINTUI_REQUIRED,
  95                   enable_gnome_print=yes, enable_gnome_print=no)
  96 PKG_CHECK_MODULES(GTK_PRINT,
  97                   gtk+-unix-print-2.0 >= $GTK_PRINT_REQUIRED,
  98                   enable_gtk_print=yes, enable_gtk_print=no)
  99 enable_print=no
 100 if test x$PRINT = xgnome -a x$enable_gnome_print = xyes; then
 101    enable_print=gnome
 102 else
 103    if test x$PRINT = xgtk -a x$enable_gtk_print = xyes; then
 104       enable_print=gtk
 105    else
 106       if test x$PRINT = xauto; then
 107          if test x$enable_gtk_print = xyes; then
 108             enable_print=gtk
 109          else
 110             if test x$enable_gnome_print = xyes; then
 111                enable_print=gnome
 112             fi
 113          fi
 114       fi
 115    fi
 116 fi
 117
 118 if test x$enable_print = xgnome; then
 119    AC_SUBST(GNOME_PRINT_CFLAGS)
 120    AC_SUBST(GNOME_PRINT_LIBS)
 121    AC_DEFINE([WITH_GNOME_PRINT],[1],[Enable GNOME Print Support.])
 122    AC_DEFINE([WITH_PRINT],[1],[Enable Print Support.])
 123 fi
 124
 125 if test x$enable_print = xgtk; then
 126    AC_SUBST(GTK_PRINT_CFLAGS)
 127    AC_SUBST(GTK_PRINT_LIBS)
 128    AC_DEFINE([WITH_GTK_PRINT],[1],[Enable GTK Print Support.])
 129    AC_DEFINE([WITH_PRINT],[1],[Enable Print Support.])
 130 fi
 131
 132 AM_CONDITIONAL(WITH_GNOME_PRINT, test x$enable_print = xgnome)
 133 AM_CONDITIONAL(WITH_GTK_PRINT, test x$enable_print = xgtk)
 134
 135
 136 dnl ========= Check for DBUS
 137 PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
 138         [enable_dbus=yes],[enable_dbus=no])
 139 AC_SUBST([DBUS_CFLAGS])
 140 AC_SUBST([DBUS_LIBS])
 141
 142 if test "x$enable_dbus" = "xno"; then
 143         AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
 144 fi
 145
 146 if test "x$enable_dbus" = "xyes" ; then
 147         AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 148
 149         if test x$DBUS_BINDING_TOOL = "xno" ; then
 150                 AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 151         fi
 152
 153         AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 154 fi
 155
 156 LIB_CFLAGS="$LIB_CFLAGS $GNOME_CFLAGS"
 157 LIB_LIBS="$LIB_LIBS $GNOME_LIBS"
 158 AC_SUBST(LIB_CFLAGS)
 159 AC_SUBST(LIB_LIBS)
 160
 161 BACKEND_CFLAGS="$BACKEND_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE"
 162 AC_SUBST(BACKEND_CFLAGS)
 163 AC_SUBST(BACKEND_LIBS)
 164
 165 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS $GNOMEUI_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE"
 166 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS $GNOMEUI_LIBS -lz"
 167 AC_SUBST(SHELL_CFLAGS)
 168 AC_SUBST(SHELL_LIBS)
 169
 170 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $GNOME_CFLAGS"
 171 FRONTEND_LIBS="$FRONTEND_CORE_LIBS $GNOME_LIBS -lz"
 172 AC_SUBST(FRONTEND_CFLAGS)
 173 AC_SUBST(FRONTEND_LIBS)
 174
 175 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
 176 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
 177
 178 dnl Check for Nautilus property page build
 179 AC_ARG_ENABLE(nautilus,
 180         AC_HELP_STRING([--enable-nautilus],[compile the nautilus plugin]),
 181         [case "${enableval}" in
 182         yes) ENABLE_NAUTILUS=yes ;;
 183         no) ENABLE_NAUTILUS=no ;;
 184         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nautilus) ;;
 185         esac],
 186         [ENABLE_NAUTILUS=yes]) dnl Default value
 187
 188 if test x$ENABLE_NAUTILUS = "xyes" ; then
 189         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
 190                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
 191         NAUTILUS_EXTENSION_DIR=`$PKG_CONFIG --variable=extensiondir libnautilus-extension`
 192         AC_SUBST(NAUTILUS_EXTENSION_DIR)
 193 fi
 194
 195 AC_SUBST(NAUTILUS_CFLAGS)
 196 AC_SUBST(NAUTILUS_LIBS)
 197 if test x$HAVE_NAUTILUS = "xyes"; then
 198         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
 199 fi
 200 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
 201
 202
 203 dnl Check for thumbnailer build
 204 AC_ARG_ENABLE(thumbnailer,
 205         AC_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer]),
 206         [case "${enableval}" in
 207         yes) ENABLE_THUMBNAILER=yes ;;
 208         no) ENABLE_THUMBNAILER=no ;;
 209         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thumbnailer) ;;
 210         esac],
 211         [ENABLE_THUMBNAILER=yes]) dnl Default value
 212 AM_CONDITIONAL(ENABLE_THUMBNAILER, test x$ENABLE_THUMBNAILER = "xyes")
 213
 214 dnl GConf configuration
 215 AM_GCONF_SOURCE_2
 216
 217 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
 218 if test "x$GCONFTOOL" = "xno"; then
 219         AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 220 fi
 221
 222 dnl ================== portability checks ===========================================
 223
 224 dnl for backtrace()
 225 AC_CHECK_HEADERS([execinfo.h])
 226
 227 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 228   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 229   ],[],[#include <langinfo.h>])
 230
 231 dnl ================== pdf checks ===================================================
 232 AC_ARG_ENABLE(pdf,
 233               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 234
 235 if test "x$enable_pdf" = "xyes"; then
 236     POPPLER_REQUIRED=0.6
 237     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED,enable_pdf=yes,enable_pdf=no)
 238
 239     if test "x$enable_pdf" = "xyes"; then
 240             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 241             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 242             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 243
 244             evince_save_LIBS=$LIBS
 245             LIBS="$LIBS $POPPLER_LIBS"
 246             AC_CHECK_FUNCS(poppler_page_render)
 247             AC_CHECK_FUNCS(poppler_page_render_for_printing)
 248             LIBS=$evince_save_LIBS
 249
 250             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 251             if test x$enable_cairo_pdf == xyes; then
 252                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 253             fi
 254
 255             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 256             if test x$enable_cairo_ps == xyes; then
 257                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 258             fi
 259     else
 260             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 261     fi
 262 fi
 263
 264 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 265 dnl ================== end of pdf checks ============================================
 266 SPECTRE_REQUIRED=0.2.0
 267
 268 dnl libspectre (used by ps and dvi backends)
 269 PKG_CHECK_MODULES(SPECTRE, libspectre >= $SPECTRE_REQUIRED,have_spectre=yes,have_spectre=no)
 270 AM_CONDITIONAL(HAVE_SPECTRE, test x$have_spectre = xyes)
 271 if test "x$have_spectre" = "xyes"; then
 272    AC_DEFINE([HAVE_SPECTRE], [1], [Have libpectre])
 273 fi
 274
 275 dnl ================== ps checks ====================================================
 276 AC_ARG_ENABLE(ps,
 277         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 278
 279 ps_backend=""
 280 if test x$enable_ps = xyes; then
 281    AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 282
 283    if test "x$have_spectre" = "xyes"; then
 284       ps_backend="(libspectre)"
 285    else
 286       dnl check for GS version
 287       AC_MSG_CHECKING(for Ghostscript version...)
 288       GS_VERSION=`gs --version | head -n 1 | sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
 289       AC_MSG_RESULT(found $GS_VERSION)
 290       if test "$GS_VERSION" -lt "7"; then
 291          AC_MSG_WARN([PS support is disabled since libspectre (version >= $SPECTRE_REQUIRED) or Ghostscript (version >= 7) are needed])
 292          enable_ps=no
 293       else
 294          AC_ARG_WITH(gs-aa-params,
 295                      [AC_HELP_STRING([--with-gs-aa-params], [Define antialiasing params for ghostscript])],AA_PARAMS=$withval,
 296                      AA_PARMS="-sDEVICE=x11alpha -dNOPLATFONTS -dGraphicsAlphaBits=4 -dTextAlphaBits=4 -dDOINTERPOLATE"
 297                      )
 298          AC_DEFINE_UNQUOTED(ALPHA_PARAMS, "$AA_PARMS", [Anti-aliasing parameters for Ghostscript.])
 299          AC_MSG_RESULT(Antialiasing parameters for Ghostscript: $AA_PARMS)
 300          ps_backend="(gs)"
 301       fi
 302    fi
 303 fi
 304 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 305 dnl ======================== End of ps checks ===================================
 306
 307 dnl ================== tiff checks ===================================================
 308 AC_ARG_ENABLE(tiff,
 309             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 310
 311 if test "x$enable_tiff" = "xyes"; then
 312     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 313     if test "x$enable_tiff" = "xyes"; then
 314         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 315         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 316     fi
 317     if test "x$enable_tiff" = "xyes"; then
 318             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 319     else
 320             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 321     fi
 322 fi
 323
 324 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 325 dnl ================== end of tiff checks ============================================
 326
 327 dnl ================== djvu checks ===================================================
 328
 329 AC_ARG_ENABLE(djvu,
 330             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=yes)
 331
 332 if test "x$enable_djvu" = "xyes"; then
 333     DJVULIBRE_REQUIRED=3.5.17
 334     PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 335
 336     if test "x$enable_djvu" = "xyes"; then
 337         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 338     else
 339         AC_MSG_WARN([
 340 ** Djvu support is disabled since a recent version of the djvulibre
 341 ** library was not found. You need at least djvulibre-3.5.17 which
 342 ** can be found on http://djvulibre.djvuzone.org
 343 ])
 344     fi
 345 fi
 346
 347 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 348
 349 dnl ================== End of djvu checks ===================================================
 350
 351 dnl ================== dvi checks ===================================================
 352
 353 AC_ARG_ENABLE(dvi,
 354             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=yes)
 355
 356 AC_ARG_ENABLE(t1lib,
 357             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 358
 359 if test "x$enable_dvi" = "xyes"; then
 360     AC_C_CONST
 361     AC_C_INLINE
 362     AC_TYPE_SIZE_T
 363     AC_CHECK_SIZEOF(long, 4)
 364     AC_CHECK_SIZEOF(int, 4)
 365     AC_CHECK_SIZEOF(short, 2)
 366     AC_CHECK_SIZEOF(void *, 4)
 367     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 368
 369     if test "x$enable_dvi" = "xyes"; then
 370         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 371     else
 372         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 373     fi
 374 fi
 375 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 376
 377 if test "x$enable_dvi" = "xyes"; then
 378     if test "x$enable_type1_fonts" = "xyes"; then
 379         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 380     fi
 381
 382     if test "x$enable_type1_fonts" = xyes; then
 383         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 384     fi
 385 else
 386     enable_type1_fonts=no
 387 fi
 388 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 389
 390 dnl ================== End of dvi checks ===================================================
 391
 392 dnl ================== pixbuf checks ===================================================
 393
 394 AC_ARG_ENABLE(pixbuf,
 395             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 396 if test "x$enable_pixbuf" = "xyes"; then
 397         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 398 fi
 399 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 400
 401 dnl ================== End of pixbuf checks ===================================================
 402
 403 dnl ================== comic book checks ===================================================
 404
 405 AC_ARG_ENABLE(comics,
 406         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=yes)
 407 if test "x$enable_comics" = "xyes"; then
 408         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 409 fi
 410 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 411
 412 dnl ================== End of comic book checks ============================================
 413
 414 dnl ================== impress book checks ===================================================
 415
 416 AC_ARG_ENABLE(impress,
 417         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 418 if test "x$enable_impress" = "xyes"; then
 419         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 420 fi
 421 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 422
 423 dnl ================== End of impress book checks ============================================
 424
 425 dnl =================== Mime types list ====================================================
 426
 427 if test "x$enable_pdf" = "xyes" ; then
 428         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 429 fi
 430 if test "x$enable_ps" = "xyes" ; then
 431         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 432 fi
 433 if test "x$enable_dvi" = "xyes"; then
 434         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;"
 435 fi
 436 if test "x$enable_djvu" = "xyes"; then
 437         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 438 fi
 439 if test "x$enable_tiff" = "xyes"; then
 440         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 441 fi
 442 if test "x$enable_comics" = "xyes"; then
 443         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;"
 444 fi
 445 if test "x$enable_pixbuf" = "xyes"; then
 446         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 447 fi
 448 if test "x$enable_impress" = "xyes"; then
 449         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 450 fi
 451 AC_SUBST(EVINCE_MIME_TYPES)
 452
 453 AC_CONFIG_FILES([
 454 backend/Makefile
 455 backend/comics/Makefile
 456 backend/djvu/Makefile
 457 backend/dvi/Makefile
 458 backend/dvi/mdvi-lib/Makefile
 459 backend/impress/Makefile
 460 backend/pdf/Makefile
 461 backend/pixbuf/Makefile
 462 backend/ps/Makefile
 463 backend/tiff/Makefile
 464 cut-n-paste/Makefile
 465 cut-n-paste/gedit-message-area/Makefile
 466 cut-n-paste/toolbar-editor/Makefile
 467 cut-n-paste/zoom-control/Makefile
 468 cut-n-paste/totem-screensaver/Makefile
 469 data/evince.desktop.in
 470 data/Makefile
 471 data/icons/Makefile
 472 data/icons/16x16/Makefile
 473 data/icons/16x16/apps/Makefile
 474 data/icons/16x16/actions/Makefile
 475 data/icons/22x22/Makefile
 476 data/icons/22x22/apps/Makefile
 477 data/icons/22x22/actions/Makefile
 478 data/icons/24x24/Makefile
 479 data/icons/24x24/apps/Makefile
 480 data/icons/24x24/actions/Makefile
 481 data/icons/32x32/Makefile
 482 data/icons/32x32/actions/Makefile
 483 data/icons/48x48/Makefile
 484 data/icons/48x48/apps/Makefile
 485 data/icons/48x48/actions/Makefile
 486 data/icons/scalable/Makefile
 487 data/icons/scalable/apps/Makefile
 488 help/Makefile
 489 help/reference/Makefile
 490 help/reference/version.xml
 491 libdocument/Makefile
 492 Makefile
 493 po/Makefile.in
 494 properties/Makefile
 495 shell/Makefile
 496 test/Makefile
 497 thumbnailer/Makefile
 498 ])
 499
 500 AC_OUTPUT
 501
 502 echo "
 503 Configure summary:
 504         GNOME Support......:  $WITH_GNOME
 505         Print Support......:  $enable_print
 506         DBUS Support.......:  $enable_dbus
 507         Nautilus Plugin....:  $HAVE_NAUTILUS
 508         Thumbnailer........:  $ENABLE_THUMBNAILER
 509         Gtk-Doc Support....:  $enable_gtk_doc
 510
 511         PDF Backend........:  $enable_pdf
 512         PostScript Backend.:  $enable_ps $ps_backend
 513         TIFF Backend.......:  $enable_tiff
 514         DJVU Backend.......:  $enable_djvu
 515         DVI Backend........:  $enable_dvi
 516         Pixbuf Backend.....:  $enable_pixbuf
 517         Comics Backend.....:  $enable_comics
 518         Impress Backend....:  $enable_impress
 519 "