configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.57)
   4 AC_INIT([Evince],[2.20.0],[http://bugzilla.gnome.org/enter_bug.cgi?product=evince],[evince])
   5 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-dist-gzip])
   6
   7 AM_CONFIG_HEADER(config.h)
   8
   9 AM_MAINTAINER_MODE
  10
  11 AM_PROG_LIBTOOL
  12
  13 AC_ISC_POSIX
  14 AC_PROG_CC
  15 AM_PROG_CC_STDC
  16 AC_PROG_CXX
  17 AC_STDC_HEADERS
  18 IT_PROG_INTLTOOL([0.35.0])
  19 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  20 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
  21
  22 GNOME_COMMON_INIT
  23 GNOME_DOC_INIT
  24 GNOME_MAINTAINER_MODE_DEFINES
  25 GNOME_COMPILE_WARNINGS
  26 GNOME_CXX_WARNINGS
  27 GNOME_DEBUG_CHECK
  28
  29 GTK_DOC_CHECK(1.0)
  30
  31 GETTEXT_PACKAGE=evince
  32 AC_SUBST(GETTEXT_PACKAGE)
  33 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  34 AM_GLIB_GNU_GETTEXT
  35
  36 dnl Check dependencies
  37
  38 # LIB_CFLAGS       for helpers and generic widgets. (lib, cut-and-paste)
  39 # BACKEND_CFLAGS   for backend implementations.
  40 # FRONTEND_CFLAGS  for frontend implementations. (properties, thumbnailer)
  41 # FRONTEND_LIBS
  42 # SHELL_CFLAGS     for shell implementation.
  43 # SHELL_LIBS
  44
  45 DBUS_GLIB_REQUIRED=0.70
  46 GTK_REQUIRED=2.10.0
  47 KEYRING_REQUIRED=0.4.0
  48
  49 LIBGNOMEUI_REQUIRED=2.14.0
  50 LIBGNOME_REQUIRED=2.14.0
  51 LIBGNOMEPRINTUI_REQUIRED=2.6.0
  52 GNOME_ICON_THEME_REQUIRED=2.17.1
  53 LIBXML_REQUIRED=2.5.0
  54
  55 GTK_PRINT_REQUIRED=2.10.0
  56
  57 PKG_CHECK_MODULES(LIB, gtk+-2.0 >= $GTK_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED)
  58 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED gnome-vfs-2.0)
  59 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED libglade-2.0 gnome-vfs-2.0)
  60 PKG_CHECK_MODULES(SHELL_CORE, libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED gnome-vfs-2.0 libglade-2.0 gconf-2.0 gnome-keyring-1 >= $KEYRING_REQUIRED)
  61
  62 AC_ARG_WITH(libgnome,
  63         AC_HELP_STRING([--without-libgnome],[disable the use of libgnome]),
  64         [case "${withval}" in
  65         yes) WITH_GNOME=yes ;;
  66         no) WITH_GNOME=no ;;
  67         *) AC_MSG_ERROR(bad value ${withval} for --with-libgnome) ;;
  68         esac],
  69         [WITH_GNOME=yes]) dnl Default value
  70 AM_CONDITIONAL(WITH_GNOME, test x$WITH_GNOME = "xyes")
  71
  72 if test x$WITH_GNOME = "xyes"; then
  73         PKG_CHECK_MODULES(GNOME, libgnome-2.0 >= $LIBGNOME_REQUIRED)
  74         PKG_CHECK_MODULES(GNOMEUI, libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED)
  75         AC_DEFINE([WITH_GNOME],[1],[Define if GNOME support is enabled])
  76 fi
  77
  78 GLIB_GENMARSHAL=`$PKG_CONFIG --variable=glib_genmarshal glib-2.0`
  79 AC_SUBST(GLIB_GENMARSHAL)
  80
  81 dnl ========= Print support
  82 AC_ARG_WITH(print,
  83             [AC_HELP_STRING([--with-print=no/gtk/gnome/auto], [Compile with print support [default=auto]])],
  84             PRINT=$withval,
  85             PRINT="auto")
  86
  87 PKG_CHECK_MODULES(GNOME_PRINT,
  88                   libgnomeprintui-2.2 >= $LIBGNOMEPRINTUI_REQUIRED,
  89                   enable_gnome_print=yes, enable_gnome_print=no)
  90 PKG_CHECK_MODULES(GTK_PRINT,
  91                   gtk+-unix-print-2.0 >= $GTK_PRINT_REQUIRED,
  92                   enable_gtk_print=yes, enable_gtk_print=no)
  93 enable_print=no
  94 if test x$PRINT = xgnome -a x$enable_gnome_print = xyes; then
  95    enable_print=gnome
  96 else
  97    if test x$PRINT = xgtk -a x$enable_gtk_print = xyes; then
  98       enable_print=gtk
  99    else
 100       if test x$PRINT = xauto; then
 101          if test x$enable_gtk_print = xyes; then
 102             enable_print=gtk
 103          else
 104             if test x$enable_gnome_print = xyes; then
 105                enable_print=gnome
 106             fi
 107          fi
 108       fi
 109    fi
 110 fi
 111
 112 if test x$enable_print = xgnome; then
 113    AC_SUBST(GNOME_PRINT_CFLAGS)
 114    AC_SUBST(GNOME_PRINT_LIBS)
 115    AC_DEFINE([WITH_GNOME_PRINT],[1],[Enable GNOME Print Support.])
 116    AC_DEFINE([WITH_PRINT],[1],[Enable Print Support.])
 117 fi
 118
 119 if test x$enable_print = xgtk; then
 120    AC_SUBST(GTK_PRINT_CFLAGS)
 121    AC_SUBST(GTK_PRINT_LIBS)
 122    AC_DEFINE([WITH_GTK_PRINT],[1],[Enable GTK Print Support.])
 123    AC_DEFINE([WITH_PRINT],[1],[Enable Print Support.])
 124 fi
 125
 126 AM_CONDITIONAL(WITH_GNOME_PRINT, test x$enable_print = xgnome)
 127 AM_CONDITIONAL(WITH_GTK_PRINT, test x$enable_print = xgtk)
 128
 129
 130 dnl ========= Check for DBUS
 131 PKG_CHECK_MODULES([DBUS], [dbus-glib-1 >= $DBUS_GLIB_REQUIRED],
 132         [enable_dbus=yes],[enable_dbus=no])
 133 AC_SUBST([DBUS_CFLAGS])
 134 AC_SUBST([DBUS_LIBS])
 135
 136 if test "x$enable_dbus" = "xno"; then
 137         AC_MSG_WARN([DBUS support is disabled since dbus $DBUS_GLIB_REQUIRED or higher was not found])
 138 fi
 139
 140 if test "x$enable_dbus" = "xyes" ; then
 141         AC_PATH_PROG([DBUS_BINDING_TOOL], [dbus-binding-tool], [no])
 142
 143         if test x$DBUS_BINDING_TOOL = "xno" ; then
 144                 AC_MSG_ERROR([dbus-binding-tool executable not found in your path - should be installed with dbus glib bindings])
 145         fi
 146
 147         AC_DEFINE([ENABLE_DBUS],[1],[Define if DBUS support is enabled])
 148 fi
 149
 150 LIB_CFLAGS="$LIB_CFLAGS $GNOME_CFLAGS"
 151 LIB_LIBS="$LIB_LIBS $GNOME_LIBS"
 152 AC_SUBST(LIB_CFLAGS)
 153 AC_SUBST(LIB_LIBS)
 154
 155 BACKEND_CFLAGS="$BACKEND_CFLAGS $GNOME_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE"
 156 BACKEND_LIBS="$BACKEND_LIBS $GNOME_LIBS"
 157 AC_SUBST(BACKEND_CFLAGS)
 158 AC_SUBST(BACKEND_LIBS)
 159
 160 SHELL_CFLAGS="$SHELL_CORE_CFLAGS $DBUS_CFLAGS $GNOMEUI_CFLAGS -DGDK_MULTIHEAD_SAFE -DGTK_MULTIHEAD_SAFE"
 161 SHELL_LIBS="$SHELL_CORE_LIBS $DBUS_LIBS $GNOMEUI_LIBS -lz"
 162 AC_SUBST(SHELL_CFLAGS)
 163 AC_SUBST(SHELL_LIBS)
 164
 165 FRONTEND_CFLAGS="$FRONTEND_CORE_CFLAGS $GNOME_CFLAGS"
 166 FRONTEND_LIBS="$FRONTEND_CORE_LIBS $GNOME_LIBS -lz"
 167 AC_SUBST(FRONTEND_CFLAGS)
 168 AC_SUBST(FRONTEND_LIBS)
 169
 170 AM_CONDITIONAL([ENABLE_DBUS], [test "x$enable_dbus" = "xyes"])
 171 AM_CONDITIONAL([DBUS_TOOL_NO_PREFIX], [test "x$DBUS_VERSION" = "x33"])
 172
 173 dnl Check for Nautilus property page build
 174 AC_ARG_ENABLE(nautilus,
 175         AC_HELP_STRING([--enable-nautilus],[compile the nautilus plugin]),
 176         [case "${enableval}" in
 177         yes) ENABLE_NAUTILUS=yes ;;
 178         no) ENABLE_NAUTILUS=no ;;
 179         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nautilus) ;;
 180         esac],
 181         [ENABLE_NAUTILUS=yes]) dnl Default value
 182
 183 if test x$ENABLE_NAUTILUS = "xyes" ; then
 184         PKG_CHECK_MODULES(NAUTILUS, gtk+-x11-2.0 $MM gthread-2.0 libnautilus-extension,
 185                         [HAVE_NAUTILUS=yes], [HAVE_NAUTILUS=no])
 186 fi
 187
 188 AC_SUBST(NAUTILUS_CFLAGS)
 189 AC_SUBST(NAUTILUS_LIBS)
 190 if test x$HAVE_NAUTILUS = "xyes"; then
 191         AC_DEFINE(HAVE_NAUTILUS, 1, [defined if you build the nautilus plugin])
 192 fi
 193 AM_CONDITIONAL(HAVE_NAUTILUS, test x$HAVE_NAUTILUS = "xyes")
 194
 195
 196 dnl Check for thumbnailer build
 197 AC_ARG_ENABLE(thumbnailer,
 198         AC_HELP_STRING([--disable-thumbnailer],[disable the GNOME thumbnailer]),
 199         [case "${enableval}" in
 200         yes) ENABLE_THUMBNAILER=yes ;;
 201         no) ENABLE_THUMBNAILER=no ;;
 202         *) AC_MSG_ERROR(bad value ${enableval} for --enable-thumbnailer) ;;
 203         esac],
 204         [ENABLE_THUMBNAILER=yes]) dnl Default value
 205 AM_CONDITIONAL(ENABLE_THUMBNAILER, test x$ENABLE_THUMBNAILER = "xyes")
 206
 207 dnl GConf configuration
 208 AM_GCONF_SOURCE_2
 209
 210 AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
 211 if test "x$GCONFTOOL" = "xno"; then
 212         AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
 213 fi
 214
 215 dnl ================== portability checks ===========================================
 216
 217 dnl for backtrace()
 218 AC_CHECK_HEADERS([execinfo.h])
 219
 220 AC_CHECK_DECL([_NL_MEASUREMENT_MEASUREMENT],[
 221   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT],[1],[Define if _NL_MEASUREMENT_MEASUREMENT is available])
 222   ],[],[#include <langinfo.h>])
 223
 224 dnl ================== pdf checks ===================================================
 225 AC_ARG_ENABLE(pdf,
 226               [AC_HELP_STRING([--enable-pdf], [Compile with pdf support])],enable_pdf="$enableval",enable_pdf=yes)
 227
 228 if test "x$enable_pdf" = "xyes"; then
 229     POPPLER_REQUIRED=0.6
 230     PKG_CHECK_MODULES(POPPLER, poppler-glib >= $POPPLER_REQUIRED,enable_pdf=yes,enable_pdf=no)
 231
 232     if test "x$enable_pdf" = "xyes"; then
 233             AC_DEFINE([ENABLE_PDF], [1], [Enable pdf support.])
 234             FRONTEND_LIBS="$FRONTEND_LIBS $POPPLER_LIBS"
 235             SHELL_LIBS="$SHELL_LIBS $POPPLER_LIBS"
 236             SHELL_CFLAGS="$SHELL_CFLAGS $POPPLER_CFLAGS"
 237
 238             evince_save_LIBS=$LIBS
 239             LIBS="$LIBS $FRONTEND_LIBS"
 240             AC_CHECK_FUNCS(poppler_page_render)
 241             AC_CHECK_FUNCS(poppler_page_render_for_printing)
 242             LIBS=$evince_save_LIBS
 243
 244             PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, enable_cairo_pdf=yes, enable_cairo_pdf=no)
 245             if test x$enable_cairo_pdf == xyes; then
 246                     AC_DEFINE([HAVE_CAIRO_PDF], [1], [defined if cairo-pdf is available])
 247             fi
 248
 249             PKG_CHECK_MODULES(CAIRO_PS, cairo-ps, enable_cairo_ps=yes, enable_cairo_ps=no)
 250             if test x$enable_cairo_ps == xyes; then
 251                     AC_DEFINE([HAVE_CAIRO_PS], [1], [defined if cairo-ps is available])
 252             fi
 253     else
 254             AC_MSG_WARN("PDF support is disabled since poppler-glib library version $POPPLER_REQUIRED or newer not found")
 255     fi
 256 fi
 257
 258 AM_CONDITIONAL(ENABLE_PDF, test x$enable_pdf = xyes)
 259 dnl ================== end of pdf checks ============================================
 260
 261 dnl ================== ggv checks ===================================================
 262 AC_ARG_ENABLE(ps,
 263         [AC_HELP_STRING([--disable-ps], [Compile without PostScript backend])],enable_ps=$enableval,enable_ps="yes")
 264
 265 if test x$enable_ps = xyes; then
 266         AC_DEFINE([ENABLE_PS], [1], [Enable support for PostScript files.])
 267 fi
 268
 269 AM_CONDITIONAL(ENABLE_PS, test x$enable_ps = xyes)
 270
 271 if test x$enable_ps = xyes; then
 272
 273 dnl check for GS version
 274 AC_MSG_CHECKING(for Ghostscript version...)
 275 GS_VERSION=`gs --version | head -n 1 | sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
 276 AC_MSG_RESULT(found $GS_VERSION)
 277 if test "$GS_VERSION" -lt "7"; then
 278         AC_MSG_ERROR([You need Ghostscript version >= 7 in order to run evince])
 279 fi
 280
 281 AC_ARG_WITH(gs-aa-params,
 282             [AC_HELP_STRING([--with-gs-aa-params], [Define antialiasing params for ghostscript])],AA_PARAMS=$withval,
 283             AA_PARMS="-sDEVICE=x11alpha -dNOPLATFONTS -dGraphicsAlphaBits=4 -dTextAlphaBits=4 -dDOINTERPOLATE"
 284             )
 285 AC_DEFINE_UNQUOTED(ALPHA_PARAMS, "$AA_PARMS", [Anti-aliasing parameters for Ghostscript.])
 286 AC_MSG_RESULT(Antialiasing parameters for Ghostscript: $AA_PARMS)
 287
 288 fi
 289 dnl ======================== End of ggv checks =================================
 290
 291 dnl ================== tiff checks ===================================================
 292 AC_ARG_ENABLE(tiff,
 293             [AC_HELP_STRING([--enable-tiff], [Compile with support of multipage tiff])],enable_tiff="$enableval",enable_tiff=yes)
 294
 295 if test "x$enable_tiff" = "xyes"; then
 296     AC_CHECK_HEADERS([tiff.h],enable_tiff=yes,enable_tiff=no,)
 297     if test "x$enable_tiff" = "xyes"; then
 298         AC_CHECK_LIB([tiff],TIFFOpen,enable_tiff=yes,enable_tiff=no,"-lz")
 299         AC_CHECK_LIB([tiff],TIFFReadRGBAImageOriented,enable_tiff=yes,enable_tiff=no,"-lz")
 300     fi
 301     if test "x$enable_tiff" = "xyes"; then
 302             AC_DEFINE([ENABLE_TIFF], [1], [Enable multipage tiff support.])
 303             FRONTEND_LIBS="$FRONTEND_LIBS -ltiff"
 304             SHELL_LIBS="$SHELL_LIBS -ltiff"
 305     else
 306             AC_MSG_WARN("Tiff support is disabled since tiff library version 3.6 or newer not found")
 307     fi
 308 fi
 309
 310 AM_CONDITIONAL(ENABLE_TIFF, test x$enable_tiff = xyes)
 311 dnl ================== end of tiff checks ============================================
 312
 313 dnl ================== djvu checks ===================================================
 314
 315 AC_ARG_ENABLE(djvu,
 316             [AC_HELP_STRING([--enable-djvu], [Compile with support of djvu viewer])],enable_djvu="$enableval",enable_djvu=no)
 317
 318 if test "x$enable_djvu" = "xyes"; then
 319
 320 DJVULIBRE_REQUIRED=3.5.17
 321
 322 PKG_CHECK_MODULES(DJVU, ddjvuapi >= $DJVULIBRE_REQUIRED, enable_djvu=yes, enable_djvu=no)
 323
 324     if test "x$enable_djvu" = "xyes"; then
 325         AC_DEFINE([ENABLE_DJVU], [1], [Enable djvu viewer support.])
 326     else
 327         AC_MSG_WARN([
 328 ** Djvu support is disabled since a recent version of the djvulibre
 329 ** library was not found. You need at least djvulibre-3.5.17 which
 330 ** can be found on http://djvulibre.djvuzone.org
 331 ])
 332     fi
 333 fi
 334
 335 AM_CONDITIONAL(ENABLE_DJVU, test x$enable_djvu = xyes)
 336
 337 dnl ================== End of djvu checks ===================================================
 338
 339 dnl ================== dvi checks ===================================================
 340
 341 AC_ARG_ENABLE(dvi,
 342             [AC_HELP_STRING([--enable-dvi], [Compile with support of dvi viewer])],enable_dvi="$enableval",enable_dvi=no)
 343
 344 AC_ARG_ENABLE(t1lib,
 345             [AC_HELP_STRING([--enable-t1lib], [Compile with support of t1lib for type1 fonts in dvi])],enable_type1_fonts="$enableval",enable_type1_fonts=no)
 346
 347 if test "x$enable_dvi" = "xyes"; then
 348     AC_C_CONST
 349     AC_C_INLINE
 350     AC_TYPE_SIZE_T
 351     AC_CHECK_SIZEOF(long, 4)
 352     AC_CHECK_SIZEOF(int, 4)
 353     AC_CHECK_SIZEOF(short, 2)
 354     AC_CHECK_SIZEOF(void *, 4)
 355     AC_CHECK_LIB([kpathsea],[kpse_init_prog],[enable_dvi=yes],[enable_dvi=no])
 356
 357     if test "x$enable_dvi" = "xyes"; then
 358         AC_DEFINE([ENABLE_DVI], [1], [Enable dvi viewer support.])
 359     else
 360         AC_MSG_WARN("Dvi support is disabled since kpathsea library is not found. Check your TeX installation.")
 361     fi
 362 fi
 363 AM_CONDITIONAL(ENABLE_DVI, test x$enable_dvi = xyes)
 364
 365 if test "x$enable_dvi" = "xyes"; then
 366     if test "x$enable_type1_fonts" = "xyes"; then
 367         AC_CHECK_LIB([t1],T1_InitLib,enable_type1_fonts=yes,enable_type1_fonts=no,[-lm])
 368     fi
 369
 370     if test "x$enable_type1_fonts" = xyes; then
 371         AC_DEFINE([WITH_TYPE1_FONTS], [1], [Enable t1lib support in dvi.])
 372     fi
 373 else
 374     enable_type1_fonts=no
 375 fi
 376 AM_CONDITIONAL(WITH_TYPE1_FONTS, test x$enable_type1_fonts = xyes)
 377
 378 dnl ================== End of dvi checks ===================================================
 379
 380 dnl ================== pixbuf checks ===================================================
 381
 382 AC_ARG_ENABLE(pixbuf,
 383             [AC_HELP_STRING([--enable-pixbuf], [Compile with support of pixbuf])],enable_pixbuf="$enableval",enable_pixbuf=no)
 384 if test "x$enable_pixbuf" = "xyes"; then
 385         AC_DEFINE([ENABLE_PIXBUF], [1], [Enable pixbuf support.])
 386 fi
 387 AM_CONDITIONAL(ENABLE_PIXBUF, test x$enable_pixbuf = xyes)
 388
 389 dnl ================== End of pixbuf checks ===================================================
 390
 391 dnl ================== comic book checks ===================================================
 392
 393 AC_ARG_ENABLE(comics,
 394         [AC_HELP_STRING([--enable-comics], [Compile with support for comic book archives])],enable_comics="$enableval",enable_comics=no)
 395 if test "x$enable_comics" = "xyes"; then
 396         AC_DEFINE([ENABLE_COMICS], [1], [Enable support for comics.])
 397 fi
 398 AM_CONDITIONAL(ENABLE_COMICS, test x$enable_comics = xyes)
 399
 400 dnl ================== End of comic book checks ============================================
 401
 402 dnl ================== impress book checks ===================================================
 403
 404 AC_ARG_ENABLE(impress,
 405         [AC_HELP_STRING([--enable-impress], [Compile with support for impress presentations])],enable_impress="$enableval",enable_impress=no)
 406 if test "x$enable_impress" = "xyes"; then
 407         AC_DEFINE([ENABLE_IMPRESS], [1], [Enable support for impress.])
 408 fi
 409 AM_CONDITIONAL(ENABLE_IMPRESS, test x$enable_impress = xyes)
 410
 411 dnl ================== End of impress book checks ============================================
 412
 413 dnl =================== Mime types list ====================================================
 414
 415 if test "x$enable_pdf" = "xyes" ; then
 416         EVINCE_MIME_TYPES="application/pdf;application/x-bzpdf;application/x-gzpdf;"
 417 fi
 418 if test "x$enable_ps" = "xyes" ; then
 419         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/postscript;application/x-bzpostscript;application/x-gzpostscript;image/x-eps;image/x-bzeps;image/x-gzeps;"
 420 fi
 421 if test "x$enable_dvi" = "xyes"; then
 422         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-dvi;"
 423 fi
 424 if test "x$enable_djvu" = "xyes"; then
 425         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/vnd.djvu;"
 426 fi
 427 if test "x$enable_tiff" = "xyes"; then
 428         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/tiff;"
 429 fi
 430 if test "x$enable_comics" = "xyes"; then
 431         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/x-cbr;application/x-cbz;"
 432 fi
 433 if test "x$enable_pixbuf" = "xyes"; then
 434         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}image/*;"
 435 fi
 436 if test "x$enable_impress" = "xyes"; then
 437         EVINCE_MIME_TYPES="${EVINCE_MIME_TYPES}application/vnd.sun.xml.impress;application/vnd.oasis.opendocument.presentation;"
 438 fi
 439 AC_SUBST(EVINCE_MIME_TYPES)
 440
 441 AC_CONFIG_FILES([
 442 backend/Makefile
 443 backend/comics/Makefile
 444 backend/djvu/Makefile
 445 backend/dvi/Makefile
 446 backend/dvi/mdvi-lib/Makefile
 447 backend/impress/Makefile
 448 backend/pdf/Makefile
 449 backend/pixbuf/Makefile
 450 backend/ps/Makefile
 451 backend/tiff/Makefile
 452 cut-n-paste/Makefile
 453 cut-n-paste/toolbar-editor/Makefile
 454 cut-n-paste/zoom-control/Makefile
 455 cut-n-paste/totem-screensaver/Makefile
 456 data/evince.desktop.in
 457 data/Makefile
 458 data/icons/Makefile
 459 data/icons/16x16/Makefile
 460 data/icons/16x16/apps/Makefile
 461 data/icons/16x16/actions/Makefile
 462 data/icons/22x22/Makefile
 463 data/icons/22x22/apps/Makefile
 464 data/icons/22x22/actions/Makefile
 465 data/icons/24x24/Makefile
 466 data/icons/24x24/apps/Makefile
 467 data/icons/24x24/actions/Makefile
 468 data/icons/32x32/Makefile
 469 data/icons/32x32/actions/Makefile
 470 data/icons/48x48/Makefile
 471 data/icons/48x48/apps/Makefile
 472 data/icons/48x48/actions/Makefile
 473 data/icons/scalable/Makefile
 474 data/icons/scalable/apps/Makefile
 475 help/Makefile
 476 help/reference/Makefile
 477 help/reference/version.xml
 478 libdocument/Makefile
 479 Makefile
 480 po/Makefile.in
 481 properties/Makefile
 482 shell/Makefile
 483 test/Makefile
 484 thumbnailer/Makefile
 485 ])
 486
 487 AC_OUTPUT
 488
 489 echo "
 490 Configure summary:
 491         GNOME Support......:  $WITH_GNOME
 492         Print Support......:  $enable_print
 493         DBUS Support.......:  $enable_dbus
 494         Nautilus Plugin....:  $HAVE_NAUTILUS
 495         Thumbnailer........:  $ENABLE_THUMBNAILER
 496         Gtk-Doc Support....:  $enable_gtk_doc
 497
 498         PDF Backend........:  $enable_pdf
 499         PostScript Backend.:  $enable_ps
 500         TIFF Backend.......:  $enable_tiff
 501         DJVU Backend.......:  $enable_djvu
 502         DVI Backend........:  $enable_dvi
 503         Pixbuf Backend.....:  $enable_pixbuf
 504         Comics Backend.....:  $enable_comics
 505         Impress Backend....:  $enable_impress
 506 "